Ipinapakita ng tutorial kung paano gamitin ang IF kasama ang AND function sa Excel upang suriin ang maraming kundisyon sa isang formula.

May hangganan ang ilang bagay sa mundo. Ang iba ay walang hanggan, at ang IF function ay tila isa sa mga ganoong bagay. Sa aming blog, mayroon na kaming ilang mga tutorial sa Excel IF at nakakatuklas pa rin ng mga bagong gamit araw-araw. Ngayon, titingnan natin kung paano mo magagamit ang IF kasama ang AND function upang suriin ang dalawa o higit pang mga kundisyon nang sabay.

IF AND statement sa Excel

Upang mabuo ang IF AND statement, malinaw na kailangan mong pagsamahin ang IF at AND function sa isang formula. Ganito:

Isinalin sa plain English, ang formula ay ganito ang mababasa: IF condition 1 ay totoo AT totoo ang kundisyon 2, gawin ang isang bagay, kung hindi, gawin ang iba.

Bilang halimbawa, gumawa tayo ng formula na nagsusuri kung ang B2 ay "naihatid" at ang C2 ay walang laman, at depende sa mga resulta , ginagawa ang isa sa mga sumusunod:

• Kung ang parehong kundisyon ay TRUE, markahan ang order bilang "Sarado".
• Kung alinman sa kundisyon ay FALSE o pareho ay FALSE, pagkatapos ay ibalik ang isang walang laman. string ("").

=IF(AND(B2="delivered", C2""), "Closed", "")

Ang screenshot sa ibaba ay nagpapakita ng IF AND function sa Excel:

Kung ikaw Gustong magbalik ng ilang halaga kung sakaling mag-evaluate ang logical test sa FALSE, ibigay ang value na iyon sa value_if_false argumento. Halimbawa:

=IF(AND(B2="delivered", C2""), "Closed", "Open")

Ang binagong formula ay naglalabas ng "Sarado" kung ang column B ay "inihatid" at ang C ay may anumang petsa dito (hindi blangko). Sa lahat ng iba pang sitwasyon, ibinabalik nito ang "Bukas":

Tandaan. Kapag gumagamit ng IF AND formula sa Excel upang suriin ang mga kundisyon ng text, pakitandaan na ang lowercase at uppercase ay itinuturing bilang parehong character. Kung naghahanap ka ng isang case-sensitive na IF AND formula, balutin ang isa o higit pang mga argumento ng AND sa EXACT function gaya ng ginagawa nito sa naka-link na halimbawa.

Ngayong alam mo na ang syntax ng Excel IF AND statement, hayaan mong ipakita ko sa iyo kung anong uri ng mga gawain ang kaya nitong lutasin.

Excel IF: mas malaki kaysa AT mas mababa sa

Sa nakaraang halimbawa, sinusuri namin ang dalawang kundisyon sa dalawang magkaibang mga cell. Ngunit kung minsan ay maaaring kailanganin mong magpatakbo ng dalawa o higit pang mga pagsubok sa parehong cell. Ang isang karaniwang halimbawa ay ang pagsuri kung ang isang cell value ay sa pagitan ng dalawang numero . Madali ring magagawa iyon ng Excel IF AND function!

Ipagpalagay nating mayroon kang ilang mga numero ng benta sa column B at hinihiling sa iyong i-flag ang mga halagang higit sa $50 ngunit mas mababa sa $100. Upang magawa ito, ipasok ang formula na ito sa C2 at pagkatapos ay kopyahin ito sa column:

=IF(AND(B2>50, B2<100), "x", "")

Kung kailangan mong isama ang boundary value (50 at 100), gamitin ang mas mababa sa o katumbas ng operator (<=) at mas malaki kaysa o katumbas ng (>=) operator:

=IF(AND(B2>=50, B2<=100), "x", "")

Upang magproseso ng ibamga halaga ng hangganan nang hindi binabago ang formula, ilagay ang minimum at maximum na mga numero sa dalawang magkahiwalay na cell at sumangguni sa mga cell na iyon sa iyong formula. Para gumana nang tama ang formula sa lahat ng row, tiyaking gumamit ng mga absolute reference para sa mga boundary cell ($F$1 at $F$2 sa aming kaso):

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Sa pamamagitan ng paggamit ng katulad na formula, maaari mong tingnan kung ang isang petsa ay nasa sa loob ng isang tinukoy na hanay .

Halimbawa, mag-flag tayo ng mga petsa sa pagitan ng 10 -Sep-2018 at 30-Sep-2018, kasama. Ang isang maliit na hadlang ay ang mga petsa ay hindi maaaring direktang ibigay sa mga lohikal na pagsubok. Para maunawaan ng Excel ang mga petsa, dapat na nakalakip ang mga ito sa function na DATEVALUE, tulad nito:

=IF(AND(B2>=DATEVALUE("9/10/2018"), B2<=DATEVALUE("9/30/2018")), "x", "")

O kaya ay ipasok lamang ang Mula sa at Hanggang mga petsa sa dalawang cell ($F$1 at $F$2 sa halimbawang ito) at "hilahin" ang mga ito mula sa mga cell na iyon sa pamamagitan ng paggamit ng pamilyar nang IF AND formula:

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Para sa higit pang impormasyon, pakitingnan ang Excel IF statement sa pagitan ng dalawang numero o petsa.

KUNG ito AT iyon, pagkatapos ay kalkulahin ang isang bagay

Bukod sa pagbabalik ng mga paunang natukoy na halaga, ang Excel IF Ang AND function ay maaari ding magsagawa ng iba't ibang kalkulasyon depende sa kung ang mga tinukoy na kundisyon ay TAMA o MALI.

Upang ipakita ang diskarte, kakalkulahin namin ang isang bonus na 5% para sa "Sarado" na mga benta na may halagang mas malaki kaysa o katumbas hanggang $100.

Ipagpalagay na ang halaga ay nasa column B at ang order status sa column C,ang formula ay sumusunod:

=IF(AND(B2>=100, C2="closed"), B2*10%, 0)

Ang formula sa itaas ay nagtatalaga ng zero sa iba pang mga order ( value_if_false = 0) . Kung handa kang magbigay ng maliit na stimulating bonus, sabihin nating 3%, sa mga order na hindi nakakatugon sa mga kundisyon, isama ang katumbas na equation sa value_if_false argument:

=IF(AND(B2>=100, C2="closed"), B2*10%, B2*3%)

Maramihang IF AND statement sa Excel

Gaya ng napansin mo, dalawang pamantayan lang ang sinuri namin sa lahat ng mga halimbawa sa itaas. Ngunit walang makakapigil sa iyo na magsama ng tatlo at higit pang pagsubok sa iyong mga IF AND formula hangga't sumusunod ang mga ito sa mga pangkalahatang limitasyong ito ng Excel:

• Sa Excel 2007 at mas mataas, hanggang 255 argumento maaaring gamitin sa isang formula, na may kabuuang haba ng formula na hindi hihigit sa 8,192 character.
• Sa Excel 2003 at mas mababa, hindi hihigit sa 30 argumento ang pinapayagan, na may kabuuang haba na hindi hihigit sa 1,024 character.

Bilang halimbawa ng maramihang mga kundisyon ng AT, mangyaring isaalang-alang ang mga ito:

• Ang halaga (B2) ay dapat na mas malaki sa o katumbas ng $100
• Status ng order (C2) ay "Sarado"
• Ang petsa ng paghahatid (D2) ay nasa kasalukuyang buwan

Ngayon, kailangan namin ng IF AND statement para matukoy ang mga order kung saan ang lahat ng 3 kundisyon ay TOTOO. At narito:

=IF(AND(B2>=100, C2="Closed", MONTH(D2)=MONTH(TODAY())), "x", "")

Dahil ang 'kasalukuyang buwan' sa oras ng pagsulat ay Oktubre, ang formula ay naghahatid ng mga resulta sa ibaba:

Nested KUNG ATmga pahayag

Kapag nagtatrabaho sa malalaking worksheet, malamang na kailangan mong suriin ang ilang hanay ng iba't ibang pamantayan ng AT nang paisa-isa. Para dito, kukuha ka ng isang klasikong Excel nested IF formula at palawigin ang mga lohikal na pagsubok nito gamit ang mga AND statement, tulad nito:

Upang makuha ang pangkalahatang ideya, pakitingnan ang sumusunod na halimbawa.

Ipagpalagay na gusto mong i-rate ang iyong serbisyo batay sa halaga ng kargamento at tinantyang oras ng paghahatid (ETD):

• Mahusay : gastos sa pagpapadala sa ilalim ng $20 at ETD sa ilalim ng 3 araw
• Mahina : mahigit $30 ang halaga ng kargamento at ETD sa loob ng 5 araw
• Karaniwan : kahit ano sa pagitan

Sa gawin ito, magsulat ka ng dalawang indibidwal na IF AND statement:

IF(AND(B2<20, C2<3), "Excellent", …)

IF(AND(B2>30, C2>5), "Poor", …)

…at ilalagay ang isa sa isa:

=IF(AND(B2>30, C2>5), "Poor", IF(AND(B2<20, C2<3), "Excellent", "Average"))

Magiging katulad nito ang resulta:

Makikita ang higit pang mga halimbawa ng formula sa mga statement ng Excel nested IF AND.

Case-sensitive IF AND function sa Excel

Tulad ng nabanggit sa simula ng tutorial na ito, ang Excel IF AND formula ay hindi nakikilala ang pagitan ng uppercase at lowercase na mga character dahil likas sa case-insensitive ang function na AND.

Kung nagtatrabaho ka sa case-sensitive data at gusto mong suriin ang AND kundisyon na isinasaalang-alang ang text case, gawin ang bawat indibidwal na lohikal na pagsubok sa loob ng EXACT function at nestang mga function na iyon sa iyong AND statement:

Para sa halimbawang ito, ipapa-flag namin ang mga order ng isang partikular na customer (hal. ang kumpanyang pinangalanang Cyberspace ) na may halagang lampas sa isang partikular na numero, sabihin nating $100.

Tulad ng makikita mo sa screenshot sa ibaba, ang ilang mga pangalan ng kumpanya sa column B ay mukhang parehong sipi sa case ng mga character, at gayunpaman, magkaibang kumpanya sila, kaya kailangan nating suriin ang mga pangalan eksaktong . Ang mga halaga sa column C ay mga numero, at nagpapatakbo kami ng regular na "mas malaki kaysa" na pagsubok para sa kanila:

=IF(AND(EXACT(B2, "Cyberspace"), C2>100), "x", "")

Upang gawing mas flexible ang formula, maaari mong ipasok ang target na pangalan at halaga ng customer sa dalawang magkahiwalay na mga cell at sumangguni sa mga cell na iyon. Tandaan lamang na i-lock ang mga cell reference gamit ang $ sign ($G$1 at $G$2 sa aming kaso) para hindi sila magbago kapag kinopya mo ang formula sa ibang mga row:

=IF(AND(EXACT(B2, $G$1), C2>$G$2), "x", "")

Ngayon, maaari kang mag-type ng anumang pangalan at halaga sa mga na-refer na cell, at i-flag ng formula ang mga kaukulang order sa iyong talahanayan:

KUNG O AT formula sa Excel

Sa mga formula ng Excel IF, hindi ka limitado sa paggamit lamang ng isang lohikal na function. Upang suriin ang iba't ibang kumbinasyon ng maraming kundisyon, malaya kang pagsamahin ang IF, AND, OR at iba pang mga function upang patakbuhin ang mga kinakailangang lohikal na pagsubok. Narito ang isang halimbawa ng IF AND OR formula na sumusubok sa ilangO kundisyon sa loob ng AT. At ngayon, ipapakita ko sa iyo kung paano ka makakagawa ng dalawa o higit pang mga pagsubok sa AND sa loob ng function na OR.

Ipagpalagay na, gusto mong markahan ang mga order ng dalawang customer na may halagang mas malaki kaysa sa isang tiyak na numero, say $100.

Sa wikang Excel, ang aming mga kundisyon ay ipinahayag sa ganitong paraan:

OR(AND( Customer1 , Amount >100), AND( Customer2 , Amount >100)

Ipagpalagay na ang mga pangalan ng customer ay nasa column B, mga halaga sa column C, ang 2 target na pangalan ay nasa G1 at G2, at ang target na halaga ay nasa G3, ginagamit mo ang formula na ito upang markahan ang mga katumbas na order ng "x":

=IF(OR(AND(B2=$G$1, C2>$G$3), AND(B2=$G$2, C2>$G$3)), "x", "")

Maaaring makamit ang parehong mga resulta sa mas maraming compact syntax:

=IF(AND(OR(B2=$G$1,B2= $G$2), C2>$G$3), "x", "")

Hindi siguradong lubos mong nauunawaan ang lohika ng formula? Higit pang impormasyon ang makikita sa Excel IF na may maraming AND/OR na kundisyon.

Ganyan mo ginagamit ang IF at AND function nang magkasama sa Excel. Salamat sa pagbabasa at magkita-kita tayo sa susunod na linggo!

Practice workbook

IF AND Excel – mga halimbawa ng formula (.xlsx file)