Tutorial menunjukkan cara menggunakan IF bersama-sama dengan fungsi AND dalam Excel untuk menyemak berbilang syarat dalam satu formula.

Sesetengah perkara di dunia adalah terhad. Lain-lain adalah tidak terhingga, dan fungsi IF nampaknya merupakan salah satu daripada perkara sedemikian. Di blog kami, kami sudah mempunyai segelintir tutorial Excel IF dan masih menemui kegunaan baharu setiap hari. Hari ini, kita akan melihat bagaimana anda boleh menggunakan IF bersama-sama dengan fungsi AND untuk menilai dua atau lebih keadaan pada masa yang sama.

JIKA DAN penyataan dalam Excel

Untuk membina pernyataan IF AND, anda jelas perlu menggabungkan fungsi IF dan AND dalam satu formula. Begini caranya:

Diterjemahkan ke dalam bahasa Inggeris biasa, formula berbunyi seperti berikut: JIKA syarat 1 adalah benar DAN syarat 2 adalah benar, lakukan satu perkara, jika tidak lakukan sesuatu yang lain.

Sebagai contoh, mari buat formula yang menyemak sama ada B2 "diserahkan" dan C2 tidak kosong, dan bergantung pada keputusan , melakukan salah satu daripada yang berikut:

• Jika kedua-dua syarat adalah BENAR, tandai pesanan sebagai "Ditutup".
• Jika salah satu syarat adalah FALSE atau kedua-duanya adalah FALSE, kemudian kembalikan kosong rentetan ("").

=IF(AND(B2="delivered", C2""), "Closed", "")

Tangkapan skrin di bawah menunjukkan fungsi IF AND dalam Excel:

Jika anda ingin mengembalikan beberapa nilai sekiranya ujian logik dinilai kepada FALSE, berikan nilai tersebut dalam value_if_false hujah. Contohnya:

=IF(AND(B2="delivered", C2""), "Closed", "Open")

Formula yang diubah suai mengeluarkan "Ditutup" jika lajur B "dihantar" dan C mempunyai sebarang tarikh di dalamnya (tidak kosong). Dalam semua kes lain, ia mengembalikan "Buka":

Nota. Apabila menggunakan formula JIKA DAN dalam Excel untuk menilai keadaan teks, sila ingat bahawa huruf kecil dan huruf besar dianggap sebagai aksara yang sama. Jika anda sedang mencari formula IF AND yang sensitif huruf besar-besaran, bungkus satu atau lebih argumen AND ke dalam fungsi EXACT seperti yang dilakukan dalam contoh yang dipautkan.

Sekarang anda mengetahui sintaks pernyataan Excel IF AND, izinkan saya menunjukkan kepada anda jenis tugas yang boleh diselesaikannya.

Excel IF: lebih besar daripada DAN kurang daripada

Dalam contoh sebelumnya, kami sedang menguji dua keadaan dalam dua sel yang berbeza. Tetapi kadangkala anda mungkin perlu menjalankan dua atau lebih ujian pada sel yang sama. Contoh biasa ialah menyemak sama ada nilai sel adalah antara dua nombor . Fungsi Excel IF AND juga boleh melakukannya dengan mudah!

Katakan anda mempunyai beberapa nombor jualan dalam lajur B dan anda diminta untuk membenderakan jumlah yang lebih besar daripada $50 tetapi kurang daripada $100. Untuk melakukannya, masukkan formula ini dalam C2 dan kemudian salin ke bawah lajur:

=IF(AND(B2>50, B2<100), "x", "")

Jika anda perlu memasukkan sempadan nilai (50 dan 100), gunakan operator kurang daripada atau sama dengan (<=) dan lebih besar daripada atau sama dengan (>=):

=IF(AND(B2>=50, B2<=100), "x", "")

Untuk memproses yang lainnilai sempadan tanpa mengubah formula, masukkan nombor minimum dan maksimum dalam dua sel berasingan dan rujuk sel tersebut dalam formula anda. Untuk formula berfungsi dengan betul dalam semua baris, pastikan anda menggunakan rujukan mutlak untuk sel sempadan ($F$1 dan $F$2 dalam kes kami):

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Dengan menggunakan formula yang serupa, anda boleh menyemak sama ada tarikh jatuh dalam julat yang ditentukan .

Sebagai contoh, mari kita tandakan tarikh antara 10 -Sep-2018 dan 30-Sep-2018, termasuk. Satu halangan kecil ialah tarikh tidak boleh dibekalkan kepada ujian logik secara langsung. Untuk Excel memahami tarikh, tarikh tersebut hendaklah disertakan dalam fungsi DATEVALUE, seperti ini:

=IF(AND(B2>=DATEVALUE("9/10/2018"), B2<=DATEVALUE("9/30/2018")), "x", "")

Atau hanya masukkan Dari dan Ke tarikh dalam dua sel ($F$1 dan $F$2 dalam contoh ini) dan "tarik" mereka daripada sel tersebut dengan menggunakan formula IF AND yang sudah biasa:

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Untuk mendapatkan maklumat lanjut, sila lihat pernyataan Excel IF antara dua nombor atau tarikh.

JIKA ini DAN itu, kemudian hitung sesuatu

Selain daripada mengembalikan nilai yang telah ditetapkan, Excel IF Fungsi DAN juga boleh melakukan pengiraan berbeza bergantung pada sama ada syarat yang dinyatakan adalah BENAR atau SALAH.

Untuk menunjukkan pendekatan, kami akan mengira bonus sebanyak 5% untuk jualan "Tertutup" dengan jumlah yang lebih besar daripada atau sama. kepada $100.

Dengan mengandaikan amaun adalah dalam lajur B dan status pesanan dalam lajur C,formulanya adalah seperti berikut:

=IF(AND(B2>=100, C2="closed"), B2*10%, 0)

Formula di atas memberikan sifar kepada pesanan yang lain ( value_if_false = 0) . Jika anda sanggup memberikan bonus rangsangan kecil, katakan 3%, kepada pesanan yang tidak memenuhi syarat, sertakan persamaan yang sepadan dalam hujah value_if_false :

=IF(AND(B2>=100, C2="closed"), B2*10%, B2*3%)

Berbilang penyataan IF AND dalam Excel

Seperti yang anda mungkin perasan, kami telah menilai hanya dua kriteria dalam semua contoh di atas. Tetapi tiada apa yang akan menghalang anda daripada memasukkan tiga atau lebih ujian dalam formula IF AND anda selagi ia mematuhi had am Excel ini:

• Dalam Excel 2007 dan lebih tinggi, sehingga 255 argumen boleh digunakan dalam formula, dengan jumlah panjang formula tidak melebihi 8,192 aksara.
• Dalam Excel 2003 dan lebih rendah, tidak lebih daripada 30 argumen dibenarkan, dengan jumlah panjang tidak melebihi 1,024 aksara.

Sebagai contoh berbilang syarat DAN, sila pertimbangkan yang berikut:

• Amaun (B2) hendaklah lebih besar daripada atau sama dengan $100
• Status pesanan (C2) adalah "Ditutup"
• Tarikh penghantaran (D2) adalah dalam bulan semasa

Kini, kami memerlukan penyata IF AND untuk mengenal pasti pesanan yang kesemua 3 syarat adalah BENAR. Dan inilah:

=IF(AND(B2>=100, C2="Closed", MONTH(D2)=MONTH(TODAY())), "x", "")

Memandangkan 'bulan semasa' pada masa penulisan ialah Oktober, formula memberikan hasil di bawah:

Bersarang JIKA DANpernyataan

Apabila bekerja dengan lembaran kerja yang besar, kemungkinan besar anda mungkin dikehendaki menyemak beberapa set kriteria AND yang berbeza pada satu masa. Untuk ini, anda mengambil formula IF bersarang Excel klasik dan melanjutkan ujian logiknya dengan pernyataan AND, seperti ini:

Untuk mendapatkan idea umum, sila lihat contoh berikut.

Andaikan anda ingin menilai perkhidmatan anda berdasarkan kos penghantaran dan anggaran masa penghantaran (ETD):

• Cemerlang : kos penghantaran di bawah $20 dan ETD di bawah 3 hari
• Lemah : kos penghantaran melebihi $30 dan ETD selama 5 hari
• Purata : apa-apa sahaja di antara

Kepada selesaikan, anda menulis dua pernyataan IF AND individu:

IF(AND(B2<20, C2<3), "Excellent", …)

IF(AND(B2>30, C2>5), "Poor", …)

…dan sarangkan satu ke yang lain:

=IF(AND(B2>30, C2>5), "Poor", IF(AND(B2<20, C2<3), "Excellent", "Average"))

Hasilnya akan kelihatan serupa dengan ini:

Lebih banyak contoh formula boleh didapati dalam penyataan IF AND bersarang Excel.

JIKA sensitif huruf besar dan kecil IF AND fungsi dalam Excel

Seperti yang dinyatakan dalam permulaan tutorial ini, formula Excel IF AND tidak membezakan antara aksara besar dan huruf kecil kerana fungsi AND bersifat tidak peka huruf besar dan kecil.

Jika anda menggunakan data sensitif huruf besar/kecil dan ingin menilai keadaan DAN dengan mengambil kira huruf besar kecil, lakukan setiap ujian logik individu di dalam fungsi dan sarang EXACTfungsi tersebut ke dalam pernyataan AND anda:

Untuk contoh ini, kami akan membenderakan pesanan pelanggan tertentu (cth. syarikat bernama Cyberspace ) dengan jumlah melebihi nombor tertentu, katakan $100.

Seperti yang anda boleh lihat dalam tangkapan skrin di bawah, beberapa nama syarikat dalam lajur B kelihatan sama dalam petikan kes aksara, namun mereka adalah syarikat yang berbeza, jadi kami perlu menyemak nama dengan tepat . Jumlah dalam lajur C ialah nombor dan kami menjalankan ujian "lebih besar daripada" biasa untuknya:

=IF(AND(EXACT(B2, "Cyberspace"), C2>100), "x", "")

Untuk menjadikan formula lebih fleksibel, anda boleh memasukkan nama dan amaun pelanggan sasaran dalam dua sel yang berasingan dan merujuk kepada sel tersebut. Cuma ingat untuk mengunci rujukan sel dengan tanda $ ($G$1 dan $G$2 dalam kes kami) supaya ia tidak akan berubah apabila anda menyalin formula ke baris lain:

=IF(AND(EXACT(B2, $G$1), C2>$G$2), "x", "")

Kini, anda boleh menaip sebarang nama dan amaun dalam sel yang dirujuk dan formula akan membenderakan pesanan yang sepadan dalam jadual anda:

JIKA ATAU DAN formula dalam Excel

Dalam formula Excel IF, anda tidak terhad kepada menggunakan hanya satu fungsi logik. Untuk menyemak pelbagai kombinasi berbilang syarat, anda bebas untuk menggabungkan IF, AND, OR dan fungsi lain untuk menjalankan ujian logik yang diperlukan. Berikut ialah contoh formula JIKA DAN ATAU yang menguji beberapaATAU keadaan dalam DAN. Dan sekarang, saya akan menunjukkan kepada anda bagaimana anda boleh melakukan dua atau lebih ujian DAN dalam fungsi OR.

Andainya, anda ingin menandakan pesanan dua pelanggan dengan jumlah yang lebih besar daripada nombor tertentu, katakan $100.

Dalam bahasa Excel, syarat kami dinyatakan dengan cara ini:

OR(AND( Customer1 , Amount >100), AND( Customer2 , Amount >100)

Dengan mengandaikan nama pelanggan berada dalam lajur B, jumlah dalam lajur C, 2 nama sasaran berada dalam G1 dan G2, dan jumlah sasaran adalah dalam G3, anda menggunakan formula ini untuk menandakan pesanan yang sepadan dengan "x":

=IF(OR(AND(B2=$G$1, C2>$G$3), AND(B2=$G$2, C2>$G$3)), "x", "")

Hasil yang sama boleh dicapai dengan lebih sintaks padat:

=IF(AND(OR(B2=$G$1,B2= $G$2), C2>$G$3), "x", "")

Tidak pasti anda memahami sepenuhnya logik formula? Maklumat lanjut boleh didapati dalam Excel IF dengan berbilang syarat AND/OR.

Begitulah anda menggunakan fungsi IF dan AND bersama-sama dalam Excel. Terima kasih kerana membaca dan jumpa lagi minggu hadapan!

Buku kerja latihan

JIKA DAN Excel – contoh formula (fail .xlsx)