La lernilo montras kiel uzi SE kune kun la funkcio AND en Excel por kontroli plurajn kondiĉojn en unu formulo.

Kelkaj aferoj en la mondo estas finhavaj. Aliaj estas senfinaj, kaj la IF-funkcio ŝajnas esti unu el tiaj aferoj. En nia blogo, ni jam havas manplenon da lerniloj de Excel IF kaj ankoraŭ malkovras novajn uzojn ĉiutage. Hodiaŭ, ni rigardos kiel vi povas uzi IF kune kun la funkcio AND por taksi du aŭ pli da kondiĉoj samtempe.

IF KAJ deklaro en Excel

Por konstrui la deklaron SE KAJ, vi evidente bezonas kombini la funkciojn SE kaj KAJ en unu formulo. Jen kiel:

Tradukita en simplan anglan, la formulo tekstas jene: SE kondiĉo 1 estas vera KAJ kondiĉo 2 estas vera, faru unu aferon, alie faru ion alian.

Ekzemple, ni faru formulon, kiu kontrolas ĉu B2 estas "liverita" kaj C2 ne estas malplena, kaj depende de la rezultoj , faras unu el la jenaj:

• Se ambaŭ kondiĉoj estas VERAJ, marku la ordon kiel "Fermitan".
• Se ĉiu kondiĉo estas MALSA aŭ ambaŭ estas MALSAJ, tiam redonu malplenan. ĉeno ("").

=IF(AND(B2="delivered", C2""), "Closed", "")

La ekrankopio sube montras la funkcion SE KAJ en Excel:

Se vi 'ŝatus redoni iun valoron se la logika testo taksas FALSE, liveru tiun valoron en la valoro_se_falsa argumento. Ekzemple:

=IF(AND(B2="delivered", C2""), "Closed", "Open")

La modifita formulo eligas "Fermita" se kolumno B estas "liverita" kaj C havas ajnan daton en ĝi (ne malplena). En ĉiuj aliaj kazoj, ĝi resendas "Malfermita":

Noto. Kiam vi uzas IF KAJ formulon en Excel por taksi tekstokondiĉojn, bonvolu memori, ke minuskla kaj majuskla estas traktataj kiel la sama signo. Se vi serĉas uskle-distintan IF AND-formulon, envolvu unu aŭ plurajn argumentojn de AND en la EKZAKTAN funkcion kiel ĝi estas farita en la ligita ekzemplo.

Nun kiam vi konas la sintakson de la deklaro de Excel SE KAJ, mi montru al vi kiajn taskojn ĝi povas solvi.

Excel SE: pli granda ol KAJ malpli ol

En la antaŭa ekzemplo, ni testis du kondiĉojn en du malsamaj ĉeloj. Sed foje vi eble bezonos fari du aŭ pli da testoj sur la sama ĉelo. Tipa ekzemplo estas kontroli ĉu ĉelvaloro estas inter du nombroj . La funkcio Excel SE KAJ povas facile fari tion ankaŭ!

Ni diru, ke vi havas kelkajn vendajn nombrojn en kolumno B kaj vi petas marki la kvantojn pli grandajn ol $50 sed malpli ol $100. Por fari ĝin, enigu ĉi tiun formulon en C2 kaj poste kopiu ĝin malsupren en la kolumnon:

=IF(AND(B2>50, B2<100), "x", "")

Se vi bezonas inkluzivi la limon valoroj (50 kaj 100), uzu la operatoron malpli aŭ egala al (<=) kaj pli granda aŭ egala al (>=) operatoro:

=IF(AND(B2>=50, B2<=100), "x", "")

Por prilabori iun alianlimvaloroj sen ŝanĝi la formulon, enigu la minimumajn kaj maksimumajn nombrojn en du apartaj ĉeloj kaj raportu al tiuj ĉeloj en via formulo. Por ke la formulo funkciu ĝuste en ĉiuj vicoj, nepre uzu absolutajn referencojn por la limĉeloj ($F$1 kaj $F$2 en nia kazo):

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Uzante similan formulon, vi povas kontroli ĉu dato falas en difinita intervalo .

Ekzemple, ni marku datojn inter 10 -Sep-2018 kaj 30-Sep-2018, inkluzive. Malgranda obstaklo estas, ke datoj ne povas esti liveritaj rekte al la logikaj testoj. Por ke Excel komprenu la datojn, ili devus esti enfermitaj en la funkcio DATEVALUE, jene:

=IF(AND(B2>=DATEVALUE("9/10/2018"), B2<=DATEVALUE("9/30/2018")), "x", "")

Aŭ simple enigu la De kaj Al datoj en du ĉeloj ($F$1 kaj $F$2 en ĉi tiu ekzemplo) kaj "tiri" ilin el tiuj ĉeloj uzante la jam konatan IF KAJ formulo:

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Por pliaj informoj, bonvolu vidi deklaron de Excel IF inter du nombroj aŭ datoj.

SE ĉi KAJ tio, tiam kalkulu ion

Krom redoni antaŭdifinitajn valorojn, la Excel IF. KAJ funkcio ankaŭ povas fari malsamajn kalkulojn depende de ĉu la specifitaj kondiĉoj estas VERAJ aŭ FALSA.

Por pruvi la aliron, ni kalkulos gratifikon de 5% por "Fermita" vendo kun la kvanto pli granda ol aŭ egala. al $100.

Supozante, ke la kvanto estas en kolumno B kaj la ordostatuso en kolumno C,la formulo iras jene:

=IF(AND(B2>=100, C2="closed"), B2*10%, 0)

La supra formulo asignas nulon al la ceteraj ordoj ( valoro_se_falsa = 0) . Se vi pretas doni malgrandan stimulan gratifikon, diru 3%, al mendoj kiuj ne plenumas la kondiĉojn, inkluzivu la respondan ekvacion en la argumento value_if_false :

=IF(AND(B2>=100, C2="closed"), B2*10%, B2*3%)

Multoblaj IF AND deklaroj en Excel

Kiel vi eble rimarkis, ni taksis nur du kriteriojn en ĉiuj ĉi-supraj ekzemploj. Sed estas nenio, kio malhelpus vin inkluzivi tri kaj pli da testoj en viaj IF KAJ formuloj kondiĉe ke ili konformas al ĉi tiuj ĝeneralaj limigoj de Excel:

• En Excel 2007 kaj pli, ĝis 255 argumentoj. uzeblas en formulo, kun totala longo de formulo ne pli ol 8.192 signoj.
• En Excel 2003 kaj pli malaltaj, ne pli ol 30 argumentoj estas permesitaj, kun totala longo ne superanta 1.024 signoj.

Ekzemplo de multoblaj AND-kondiĉoj, bonvolu konsideri ĉi tiujn:

• Kvanto (B2) devus esti pli granda ol aŭ egala al $100
• Ordostatuso (C2) estas "Fermita"
• Liverdato (D2) estas ene de la nuna monato

Nun, ni bezonas deklaron SE KAJ por identigi la mendojn por kiuj ĉiuj 3 kondiĉoj estas VERAJ. Kaj jen:

=IF(AND(B2>=100, C2="Closed", MONTH(D2)=MONTH(TODAY())), "x", "")

Konsiderante ke la 'nuna monato' en la momento de la skribo estis oktobro, la formulo liveras la subajn rezultojn:

Nestitaj SE KAJdeklaroj

Kiam laboras kun grandaj laborfolioj, eble vi devas kontroli kelkajn arojn de malsamaj KAJ kriterioj samtempe. Por tio, vi prenas klasikan Excel-nestigitan IF-formulon kaj etendas ĝiajn logikajn testojn per KAJ deklaroj, jene:

Por akiri la ĝeneralan ideon, bonvolu rigardi la sekvan ekzemplon.

Supoze, ke vi volas taksi vian servon laŭ la sendokosto kaj laŭtaksa tempo de livero (ETD):

• Bonega : sendokosto malpli ol $20 kaj ETD malpli ol 3 tagoj
• Malbona : sendokosto pli ol 30 USD kaj ETD dum 5 tagoj
• Media : io ajn inter

Al fari ĝin, vi skribas du individuajn IF KAJ deklarojn:

IF(AND(B2<20, C2<3), "Excellent", …)

IF(AND(B2>30, C2>5), "Poor", …)

...kaj nestu unu en la alian:

=IF(AND(B2>30, C2>5), "Poor", IF(AND(B2<20, C2<3), "Excellent", "Average"))

La rezulto aspektos simila al ĉi tio:

Pliaj formulekzemploj troveblas en Excel nestitaj IF KAJ deklaroj.

Majuskkle-distinta IF KAJ funkcio en Excel

Kiel menciite en la komenco de ĉi tiu lernilo, Excel SE KAJ formuloj ne distingas inter majuskloj kaj minuskloj. ĉar la AND-funkcio laŭ naturo estas majuskle-malsentema.

Se vi laboras kun majuskle-distingeblaj datumoj kaj volas taksi AND-kondiĉojn konsiderante la tekstan uskon, faru ĉiun individuan logikan teston ene de la EXACT funkcio kaj nestotiuj funkcioj en vian AND-deklaron:

Por ĉi tiu ekzemplo, ni flagos mendojn de specifa kliento (ekz. la firmao nomita Cyberspace ) kun kvanto superanta certan nombron, ekzemple $100.

Kiel vi povas vidi en la suba ekrankopio, iuj nomoj de kompanioj en kolumno B aspektas same eltiraĵo de la literoj, kaj tamen ili estas malsamaj kompanioj, do ni devas kontroli la nomojn precize . La kvantoj en kolumno C estas nombroj, kaj ni faras regulan "pli grandan ol" teston por ili:

=IF(AND(EXACT(B2, "Cyberspace"), C2>100), "x", "")

Por igi la formulon pli fleksebla, vi povas enigi la cel-klientnomon kaj kvanton. en du apartaj ĉeloj kaj referencas al tiuj ĉeloj. Nur memoru ŝlosi la ĉelreferencojn per $-signo ($G$1 kaj $G$2 en nia kazo) por ke ili ne ŝanĝiĝu kiam vi kopios la formulon al aliaj vicoj:

=IF(AND(EXACT(B2, $G$1), C2>$G$2), "x", "")

Nun vi povas tajpi ajnan nomon kaj kvanton en la referencitaj ĉeloj, kaj la formulo flagos la respondajn ordojn en via tabelo:

SE AŬ KAJ formulo en Excel

En Excel IF-formuloj, vi ne estas limigita uzi nur unu logikan funkcion. Por kontroli diversajn kombinaĵojn de multoblaj kondiĉoj, vi rajtas kombini la SE, KAJ, AŬ kaj aliajn funkciojn por fari la postulatajn logikajn testojn. Jen ekzemplo de SE KAJ AŬ formulo kiu testas kelkajnAŬ kondiĉoj ene de KAJ. Kaj nun, mi montros al vi kiel vi povas fari du aŭ pli da KAJ testoj ene de la OR-funkcio.

Supozi, ke vi volas marki la mendojn de du klientoj kun kvanto pli granda ol certa nombro, diru $100.

En la Excel-lingvo, niaj kondiĉoj estas esprimitaj tiamaniere:

OR(AND( Customer1 , Amount >100), AND( Customer2 , Amount >100)

Suponante, ke la klientnomoj estas en kolumno B, kvantoj en kolumno C, la 2 celnomoj estas en G1 kaj G2, kaj la cela kvanto estas en G3, vi uzas ĉi tiun formulon por marki la respondajn ordojn per "x":

=IF(OR(AND(B2=$G$1, C2>$G$3), AND(B2=$G$2, C2>$G$3)), "x", "")

La samaj rezultoj povas esti atingitaj per pli kompakta sintakso:

=IF(AND(OR(B2=$G$1,B2= $G$2), C2>$G$3), "x", "")

Ne certas, ke vi tute komprenas la logikon de la formulo? Pliaj informoj troveblas en Excel SE kun multoblaj AND/OR-kondiĉoj.

Tiel oni uzas la funkciojn SE kaj KAJ kune en Excel. Dankon pro legado kaj ĝis la venonta semajno!

Praktiku laborlibron

SE KAJ Excel – ekzemploj de formuloj (.xlsx-dosiero)