Tutorialak IF eta Excel funtzioarekin batera nola erabili erakusten du formula bakarrean hainbat baldintza egiaztatzeko.

Munduko gauza batzuk finituak dira. Beste batzuk infinituak dira, eta IF funtzioa horrelako gauzetako bat dela dirudi. Gure blogean, Excel IF tutorial gutxi batzuk ditugu dagoeneko eta oraindik erabilera berriak deskubritzen ditugu egunero. Gaur, ETA funtzioarekin batera nola erabil dezakezun aztertuko dugu bi baldintza edo gehiago aldi berean ebaluatzeko.

IF AND adierazpena Excel-en

IF AND sententzia eraikitzeko, jakina, IF eta AND funtzioak formula batean konbinatu behar dituzu. Hona hemen nola:

Ingeles arruntera itzulita, formula honela dio: IF baldintza 1 egia da ETA 2 baldintza egia da, egin gauza bat, bestela egin beste zerbait.

Adibide gisa, egin dezagun B2 "entregatu" den eta C2 hutsik ez dagoen egiaztatzen duen formula bat, eta emaitzen arabera. , hauetako bat egiten du:

• Bi baldintzak EGIA badira, markatu ordena "Itxita".
• Baldintza bat GEZURRA bada edo biak GEZURRA badira, itzuli hutsik. katea ("").

=IF(AND(B2="delivered", C2""), "Closed", "")

Beheko pantaila-argazkiak IF AND funtzioa erakusten du Excel-en:

Badazu Balioren bat itzuli nahiko nuke proba logikoak FALSE balioesten badu, eman balio hori value_if_false ataleanargumentua. Adibidez:

=IF(AND(B2="delivered", C2""), "Closed", "Open")

Aldatutako formulak "Itxita" ateratzen du B zutabea "entregatu" bada eta C-k edozein data badu (ez dago hutsik). Gainerako kasuetan, "Ireki" itzultzen du:

Oharra. Excel-en IF AND formula bat erabiltzean testu-baldintzak ebaluatzeko, kontuan izan minuskulak eta maiuskulak karaktere berdin gisa tratatzen direla. Maiuskulak eta minuskulak bereizten dituen formula bat bilatzen ari bazara, sartu ETA-ren argumentu bat edo gehiago ZEHAZ funtzioan, estekatutako adibidean egiten den moduan.

Orain, Excel IF AND sententziaren sintaxia ezagutzen duzunez, utz iezadazu zer-nolako zereginak ebatzi ditzakeen erakusten.

Excel IF: handiagoa ETA baino txikiagoa

En aurreko adibidea, bi baldintza bi zelula ezberdinetan probatzen ari ginen. Baina batzuetan zelula berean bi proba edo gehiago egin beharko dituzu. Adibide arrunt bat gelaxka-balio bat bi zenbakiren artean dagoen egiaztatzea da. Excel IF AND funtzioak ere erraz egin dezake hori!

Demagun B zutabean salmenta-zenbaki batzuk dituzula eta 50 $ baino handiagoak baina 100 $ baino txikiagoak diren zenbatekoak markatzeko eskatzen zaizula. Hori egiteko, sartu formula hau C2-n eta kopiatu zutabean behera:

=IF(AND(B2>50, B2<100), "x", "")

muga sartu behar baduzu balioak (50 eta 100), erabili baino txikiagoa edo berdina (<=) eta baino handiagoa edo berdina (>=) eragilea:

=IF(AND(B2>=50, B2<=100), "x", "")

Beste batzuk prozesatzekomuga-balioak formula aldatu gabe, idatzi gutxieneko eta gehienezko zenbakiak bi gelaxka bereizietan eta erreferentzia zure formulako gelaxka horiei. Formulak errenkada guztietan behar bezala funtziona dezan, ziurtatu muga-gelaxketarako erreferentzia absolutuak erabiltzen dituzula ($F$1 eta $F$2 gure kasuan):

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Antzeko formula bat erabiliz, egiazta dezakezu data bat zehaztutako barruti baten barruan dagoen .

Adibidez, markatu ditzagun 10 arteko datak. -2018-iraila eta 2018-iraila-30a, biak barne. Oztopo txiki bat da proba logikoei datak ezin zaizkiela zuzenean eman. Excel-ek datak ulertzeko, DATEVALUE funtzioan sartu behar dira, honela:

=IF(AND(B2>=DATEVALUE("9/10/2018"), B2<=DATEVALUE("9/30/2018")), "x", "")

Edo besterik gabe sartu From eta To datak bi gelaxketan ($F$1 eta $F$2 adibide honetan) eta "erara" itzazu gelaxka horietatik jada ezaguna IF AND formula erabiliz:

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Informazio gehiago lortzeko, ikusi Excel IF adierazpena bi zenbaki edo daten artean.

HAU ETA HORI BADUZ, orduan kalkulatu zerbait

Aurrez definitutako balioak itzultzeaz gain, Excel IF ETA funtzioak kalkulu desberdinak ere egin ditzake zehaztutako baldintzak EGIA edo GEZURRA diren ala ez.

Hurbilketa erakusteko, % 5eko hobaria kalkulatuko dugu "Itxitako" salmentetarako zenbatekoa baino handiagoa edo berdina duena. 100 $-ra.

Kopurua B zutabean eta eskaeraren egoera C zutabean dagoela suposatuz,formula honela doa:

=IF(AND(B2>=100, C2="closed"), B2*10%, 0)

Goiko formulak zero esleitzen die gainerako aginduei ( value_if_false = 0) . Baldintzak betetzen ez dituzten eskaerei suspergarri txiki bat emateko prest bazaude, demagun % 3, sartu dagokion ekuazioa value_if_false argumentuan:

=IF(AND(B2>=100, C2="closed"), B2*10%, B2*3%)

IF AND adierazpen anitz Excel-en

Ohartuko zinen bezala, goiko adibide guztietan bi irizpide baino ez ditugu ebaluatu. Baina ez dago ezer eragotziko dizun hiru proba edo gehiago zure IF AND formuletan, betiere Excel-en muga orokor hauek betetzen badituzte:

• Excel 2007 eta bertsio berriagoetan, 255 argumentu arte. formula batean erabil daiteke, formula osoaren luzera 8.192 karaktere baino gehiagokoa izan gabe.
• Excel 2003-n eta bertsio txikiagoan, ezin dira 30 argumentu baino gehiago onartzen, guztira 1.024 karaktere baino gehiago ez dutenak.

AND baldintza anitzen adibide gisa, kontuan hartu hauek:

• Zenbatekoak (B2) $100 baino handiagoa edo berdina izan behar du
• Eskaeraren egoera (C2) "Itxita" da
• Bidalketa-data (D2) uneko hilabetearen barruan dago

Orain, IF AND adierazpena behar dugu 3 baldintzak EGIA diren eskaerak identifikatzeko. Eta hona hemen:

=IF(AND(B2>=100, C2="Closed", MONTH(D2)=MONTH(TODAY())), "x", "")

Idazteko unean 'uneko hilabetea' urria zela kontuan hartuta, formulak beheko emaitzak ematen ditu:

Habiatua IF ANDadierazpenak

Fitxa handiekin lan egiten duzunean, baliteke aldi berean ETA irizpide ezberdinen multzo batzuk egiaztatzea eskatzea. Horretarako, Excel habiaratutako IF formula klasiko bat hartu eta bere proba logikoak ETA adierazpenekin zabaltzen dituzu, honela:

Ideia orokorra lortzeko, begiratu hurrengo adibidea.

Demagun zure zerbitzua bidalketa-kostuaren eta entrega-denboraren (ETD) arabera baloratu nahi duzula:

• Bikaina : bidalketa kostua 20 $ baino gutxiagokoa eta ETDa 3 egun baino gutxiagokoa.
• Eskaria : bidalketa kostua 30 $ baino gehiago eta ETD 5 egunetan zehar
• Batezbestekoa : tarteko edozer gauza

Horretarako amaitu, bi banakako IF AND adierazpenak idatziko dituzu:

IF(AND(B2<20, C2<3), "Excellent", …)

IF(AND(B2>30, C2>5), "Poor", …)

…eta bata bestean habiatu:

=IF(AND(B2>30, C2>5), "Poor", IF(AND(B2<20, C2<3), "Excellent", "Average"))

Emaitza honen antzekoa izango da:

Formula adibide gehiago aurki daitezke IF AND habiaratu diren Excel-en.

Mauskulak eta minuskulak bereizten dituzte IF AND. funtzioa Excel-en

Tutorial honen hasieran aipatu bezala, Excel IF AND formulek ez dituzte letra larriak eta minuskulak bereizten ETA funtzioak maiuskulak eta minuskulak bereizten dituelako berez.

maiuskulak eta minuskulak bereizten dituen datuekin lanean ari bazara eta ETA baldintzak testuaren maiuskulak eta minuskulak kontuan hartuta ebaluatu nahi badituzu, egin proba logiko bakoitza. EXACT funtzioaren eta habia barruanfuntzio horiek zure AND adierazpenean:

Adibide honetarako, bezero zehatz baten eskaerak markatuko ditugu (adibidez, Ziberespazioa izeneko enpresa) kopuru jakin bat gainditzen duen kopuru batekin, demagun. 100 $.

Beheko pantaila-argazkian ikus dezakezun bezala, B zutabeko enpresa-izen batzuek karaktereen maiuskularen zati berdina dute, eta, hala ere, enpresa desberdinak dira, beraz, izenak zehazki . C zutabeko zenbatekoak zenbakiak dira, eta ohiko "baino handiagoa" proba bat egiten dugu haientzat:

=IF(AND(EXACT(B2, "Cyberspace"), C2>100), "x", "")

Formula malguagoa izan dadin, helburuko bezeroaren izena eta zenbatekoa sar ditzakezu. bi gelaxka bereizi eta zelula horiei erreferentzia egin. Gogoratu gelaxken erreferentziak $ zeinuarekin blokeatzea ($G$1 eta $G$2 gure kasuan), formula beste errenkada batzuetara kopiatzen duzunean aldatuko ez daitezen:

=IF(AND(EXACT(B2, $G$1), C2>$G$2), "x", "")

Orain, edozein izen eta zenbatekoa idatz dezakezu erreferentziako gelaxketan, eta formulak zure taulan dagozkien aginduak markatuko ditu:

IF OR AND formula Excel-en

Excel IF formuletan, ez zara funtzio logiko bakarra erabiltzera mugatzen. Baldintza anitzen konbinazio desberdinak egiaztatzeko, librea zara IF, AND, OR eta beste funtzio batzuk konbinatzeko beharrezko proba logikoak egiteko. Hona hemen IF AND OR formularen adibide bat, pare bat probatzen dituenaEDO baldintzak AND barruan. Eta orain, EDO funtzioaren barruan bi ETA proba edo gehiago nola egin ditzakezun erakutsiko dizut.

Demagun, bi bezeroren eskaerak kopuru jakin bat baino zenbateko handiagoarekin markatu nahi dituzula, demagun 100 $.

Excel hizkuntzan, gure baldintzak honela adierazten dira:

OR(AND( Customer1 , Amount >100), AND( Customer2 , Amount >100)

Bezeroen izenak B zutabean daudela suposatuz, zenbatekoak C zutabean, 2 xede-izenak. G1 eta G2-n daude, eta xede-kopurua G3-n dago, formula hau erabiltzen duzu dagozkien aginduak "x"-rekin markatzeko:

=IF(OR(AND(B2=$G$1, C2>$G$3), AND(B2=$G$2, C2>$G$3)), "x", "")

Emaitza berdinak lor daitezke gehiagorekin. sintaxi trinkoa:

=IF(AND(OR(B2=$G$1,B2= $G$2), C2>$G$3), "x", "")

Ez al zaude ziur formularen logika guztiz ulertzen duzula? Informazio gehiago Excel-en aurki dezakezu ETA/EDO baldintza anitzekin.

Horrela erabiltzen dituzu IF eta ETA funtzioak elkarrekin Excel-en. Eskerrik asko irakurtzeagatik eta datorren astean arte!

Lan koadernoa

IF AND Excel – formula adibideak (.xlsx fitxategia)