Tutoriali tregon se si të përdoret IF së bashku me funksionin AND në Excel për të kontrolluar kushte të shumta në një formulë.

Disa gjëra në botë janë të fundme. Të tjerat janë të pafundme dhe funksioni IF duket të jetë një nga këto gjëra. Në blogun tonë, ne tashmë kemi një pjesë të vogël të udhëzimeve të Excel IF dhe ende zbulojmë përdorime të reja çdo ditë. Sot, ne do të shikojmë se si mund të përdorni IF së bashku me funksionin AND për të vlerësuar dy ose më shumë kushte në të njëjtën kohë.

IF AND deklaratë në Excel

Për të ndërtuar deklaratën IF AND, ju duhet të kombinoni funksionet IF dhe AND në një formulë. Ja se si:

E përkthyer në anglisht të thjeshtë, formula lexohet si më poshtë: IF kushti 1 është e vërtetë DHE kushti 2 është i vërtetë, bëni një gjë, përndryshe bëni diçka tjetër.

Si shembull, le të bëjmë një formulë që kontrollon nëse B2 është "dorëzuar" dhe C2 nuk është bosh, dhe në varësi të rezultateve , bën një nga sa vijon:

• Nëse të dyja kushtet janë TRUE, shëno rendin si "Mbyllur".
• Nëse secili kusht është FALSE ose të dyja janë FALSE, atëherë ktheje një bosh string ("").

=IF(AND(B2="delivered", C2""), "Closed", "")

Pastroja më poshtë tregon funksionin IF AND në Excel:

Nëse ju do të doja të kthente një vlerë në rast se testi logjik vlerësohet në FALSE, jepni atë vlerë në value_if_false argument. Për shembull:

=IF(AND(B2="delivered", C2""), "Closed", "Open")

Formula e modifikuar nxjerr "Mbyllur" nëse kolona B është "dorëzuar" dhe C ka ndonjë datë në të (jo bosh). Në të gjitha rastet e tjera, ai kthen "Open":

Shënim. Kur përdorni një formulë IF AND në Excel për të vlerësuar kushtet e tekstit, ju lutemi mbani në mend se shkronjat e vogla dhe të mëdha trajtohen si të njëjtin karakter. Nëse jeni duke kërkuar për një formulë IF AND të ndjeshme ndaj shkronjave, mbështillni një ose më shumë argumente të AND-së në funksionin EXACT siç është bërë në shembullin e lidhur.

Tani që e dini sintaksën e deklaratës Excel IF AND, më lejoni t'ju tregoj se çfarë lloj detyrash mund të zgjidhë.

Excel IF: më e madhe se AND më pak se

Në shembulli i mëparshëm, ne po testonim dy kushte në dy qeliza të ndryshme. Por ndonjëherë mund t'ju duhet të kryeni dy ose më shumë teste në të njëjtën qelizë. Një shembull tipik është kontrollimi nëse një vlerë qelize është midis dy numrave . Funksioni Excel IF AND gjithashtu mund ta bëjë këtë lehtësisht!

Le të themi se keni disa numra shitjesh në kolonën B dhe ju kërkohet të shënoni shumat më të mëdha se $50 por më pak se $100. Për ta bërë këtë, futni këtë formulë në C2 dhe më pas kopjojeni atë në kolonën:

=IF(AND(B2>50, B2<100), "x", "")

Nëse keni nevojë të përfshini kufirin vlerat (50 dhe 100), përdorni operatorin më i vogël ose i barabartë me (<=) dhe më i madh ose i barabartë me (>=):

=IF(AND(B2>=50, B2<=100), "x", "")

Për të përpunuar disa të tjeravlerat kufitare pa ndryshuar formulën, futni numrat minimalë dhe maksimalë në dy qeliza të veçanta dhe referojuni atyre qelizave në formulën tuaj. Që formula të funksionojë si duhet në të gjitha rreshtat, sigurohuni që të përdorni referenca absolute për qelizat kufitare ($F$1 dhe $F$2 në rastin tonë):

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Duke përdorur një formulë të ngjashme, mund të kontrolloni nëse një datë bie brenda një diapazoni të caktuar .

Për shembull, le të flamurojmë datat midis 10 -Shtator-2018 dhe 30-Sep-2018, përfshirëse. Një pengesë e vogël është se datat nuk mund t'i jepen drejtpërdrejt testeve logjike. Që Excel të kuptojë datat, ato duhet të futen në funksionin DATEVALUE, si kjo:

=IF(AND(B2>=DATEVALUE("9/10/2018"), B2<=DATEVALUE("9/30/2018")), "x", "")

Ose thjesht futni Nga dhe To daton në dy qeliza ($F$1 dhe $F$2 në këtë shembull) dhe "tërhiqi" ato nga ato qeliza duke përdorur formulën tashmë të njohur IF AND:

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Për më shumë informacion, ju lutemi shikoni deklaratën Excel IF midis dy numrave ose datave.

Nëse kjo DHE ajo, atëherë llogaritni diçka

Përveç kthimit të vlerave të paracaktuara, Excel IF Funksioni AND gjithashtu mund të kryejë llogaritje të ndryshme në varësi të faktit nëse kushtet e specifikuara janë TË VËRTETA ose E GAME.

Për të demonstruar qasjen, ne do të llogarisim një bonus prej 5% për shitjet "të mbyllura" me shumë më të madhe ose të barabartë në 100 dollarë.

Duke supozuar se shuma është në kolonën B dhe statusi i porosisë në kolonën C,formula shkon si më poshtë:

=IF(AND(B2>=100, C2="closed"), B2*10%, 0)

Formula e mësipërme cakton zero për pjesën tjetër të urdhrave ( value_if_false = 0) . Nëse jeni të gatshëm të jepni një bonus të vogël stimulues, le të themi 3%, për porositë që nuk plotësojnë kushtet, përfshini ekuacionin përkatës në argumentin value_if_false :

=IF(AND(B2>=100, C2="closed"), B2*10%, B2*3%)

Pohime të shumëfishta IF AND në Excel

Siç mund ta keni vënë re, ne kemi vlerësuar vetëm dy kritere në të gjithë shembujt e mësipërm. Por nuk ka asgjë që do t'ju pengonte të përfshini tre ose më shumë teste në formulat tuaja IF AND për sa kohë që ato përputhen me këto kufizime të përgjithshme të Excel:

• Në Excel 2007 dhe më lart, deri në 255 argumente mund të përdoret në një formulë, me një gjatësi totale të formulës jo më shumë se 8,192 karaktere.
• Në Excel 2003 dhe më poshtë, nuk lejohen më shumë se 30 argumente, me një gjatësi totale jo më shumë se 1,024 karaktere.
• 5>

  Si shembull i kushteve të shumta AND, ju lutemi merrni parasysh këto:

  • Shuma (B2) duhet të jetë më e madhe ose e barabartë me 100 $
  • Statusi i porosisë (C2) është "Mbyllur"
  • Data e dorëzimit (D2) është brenda muajit aktual

  Tani, na duhet një deklaratë IF AND për të identifikuar porositë për të cilat të 3 kushtet janë të VËRTETA. Dhe ja ku është:

  =IF(AND(B2>=100, C2="Closed", MONTH(D2)=MONTH(TODAY())), "x", "")

  Duke pasur parasysh që 'muaji aktual' në momentin e shkrimit ishte tetori, formula jep rezultatet e mëposhtme:

  

  Ndodhet IF ANDdeklarata

  Kur punoni me fletë pune të mëdha, ka shumë mundësi që t'ju kërkohet të kontrolloni disa grupe kriteresh DHE të ndryshme në të njëjtën kohë. Për këtë, ju merrni një formulë klasike Excel të mbivendosur IF dhe zgjeroni testet e saj logjike me deklaratat AND, si kjo:

  IF(AND(…), output1 , IF(AND(…), output2 , IF(AND(…), output3 , output4 )))

  Për të marrë idenë e përgjithshme, ju lutemi shikoni shembullin e mëposhtëm.

  Duke supozuar se dëshironi të vlerësoni shërbimin tuaj bazuar në koston e dërgesës dhe kohën e parashikuar të dorëzimit (ETD):

  • Shkëlqyeshëm : kostoja e dërgesës nën $20 dhe ETD nën 3 ditë
  • Dobët : kostoja e dërgesës mbi 30 dollarë dhe ETD për 5 ditë
  • Mesatare : çdo gjë ndërmjet

  Për mbarojeni, shkruani dy pohime individuale IF AND:

  IF(AND(B2<20, C2<3), "Excellent", …)

  IF(AND(B2>30, C2>5), "Poor", …)

  ...dhe vendosni një fole në tjetrën:

  =IF(AND(B2>30, C2>5), "Poor", IF(AND(B2<20, C2<3), "Excellent", "Average"))

  Rezultati do të duket i ngjashëm me këtë:

  

  Më shumë shembuj të formulave mund të gjenden në deklaratat IF AND të ndërlidhura në Excel.

  Nëse dhe të ndjeshme ndaj shkronjave të vogla IF AND funksioni në Excel

  Siç u përmend në fillim të këtij tutoriali, formulat e Excel IF AND nuk bëjnë dallimin midis shkronjave të mëdha dhe të vogla sepse funksioni AND është i pandjeshëm ndaj shkronjave të vogla nga natyra.

  Nëse jeni duke punuar me të dhëna raste të ndjeshme dhe dëshironi të vlerësoni AND kushtet duke marrë parasysh rastin e tekstit, bëni çdo test logjik individual brenda funksionit dhe folesë EXACTato funksione në deklaratën tuaj AND:

  IF(AND(EXACT( qeliza ," kushti1 "), EXACT( qeliza ," kushti2 ")), value_if_true, value_if_false)

  Për këtë shembull, ne do të raportojmë porositë e një klienti specifik (p.sh. kompania e quajtur Cyberspace ) me një shumë që tejkalon një numër të caktuar, të themi 100 dollarë.

  Siç mund ta shihni në pamjen e mëposhtme të ekranit, disa emra kompanish në kolonën B duken të njëjtat fragmente nga rasti i personazheve, dhe megjithatë ato janë kompani të ndryshme, kështu që ne duhet t'i kontrollojmë emrat saktësisht . Shumat në kolonën C janë numra dhe ne kryejmë një test të rregullt "më të madh se" për to:

  =IF(AND(EXACT(B2, "Cyberspace"), C2>100), "x", "")

  Për ta bërë formulën më fleksibël, mund të futni emrin dhe shumën e klientit të synuar në dy qeliza të veçanta dhe referojuni atyre qelizave. Vetëm mos harroni të kyçni referencat e qelizave me shenjën $ ($G$1 dhe $G$2 në rastin tonë) në mënyrë që ato të mos ndryshojnë kur të kopjoni formulën në rreshtat e tjerë:

  =IF(AND(EXACT(B2, $G$1), C2>$G$2), "x", "")

  Tani, mund të shkruani çdo emër dhe shumë në qelizat e referuara dhe formula do të shënjojë porositë përkatëse në tabelën tuaj:

  

  IF OSE DHE formulë në Excel

  Në formulat Excel IF, nuk jeni të kufizuar në përdorimin e vetëm një funksioni logjik. Për të kontrolluar kombinime të ndryshme të kushteve të shumta, jeni i lirë të kombinoni IF, AND, OR dhe funksione të tjera për të ekzekutuar testet e kërkuara logjike. Këtu është një shembull i formulës NËSE DHE OSE që teston disaOSE kushtet brenda DHE. Dhe tani, unë do t'ju tregoj se si mund të bëni dy ose më shumë teste DHE brenda funksionit OR.

  Supozojmë se dëshironi të shënoni porositë e dy klientëve me një shumë më të madhe se një numër i caktuar, le të themi 100 dollarë.

  Në gjuhën Excel, kushtet tona shprehen në këtë mënyrë:

  OR(AND( Customer1 , Amount >100), AND( Customer2 , Amount >100)

  Duke supozuar se emrat e klientëve janë në kolonën B, shumat në kolonën C, 2 emrat e synuar janë në G1 dhe G2, dhe shuma e synuar është në G3, ju përdorni këtë formulë për të shënuar porositë përkatëse me "x":

  =IF(OR(AND(B2=$G$1, C2>$G$3), AND(B2=$G$2, C2>$G$3)), "x", "")

  Të njëjtat rezultate mund të arrihen me më shumë sintaksë kompakte:

  =IF(AND(OR(B2=$G$1,B2= $G$2), C2>$G$3), "x", "")

  

  Nuk jeni të sigurt që e kuptoni plotësisht logjikën e formulës? Më shumë informacion mund të gjenden në Excel IF me kushte të shumta DHE/OR.

  Kjo është mënyra se si i përdorni funksionet IF dhe AND së bashku në Excel. Faleminderit që lexuat dhe shihemi javën tjetër!

  Praktikoni librin e punës

  IF DHE Excel – shembuj formulash (skedari .xlsx)