O'quv qo'llanmada bitta formulada bir nechta shartlarni tekshirish uchun IF dan AND funksiyasi bilan birgalikda Excelda qanday foydalanish ko'rsatilgan.

Dunyodagi ba'zi narsalar cheklangan. Boshqalar cheksizdir va IF funksiyasi shunday narsalardan biri bo'lib tuyuladi. Bizning blogimizda Excel IF bo'yicha bir nechta qo'llanmalar mavjud va ular har kuni yangi foydalanishni kashf etadilar. Bugun biz bir vaqtning o'zida ikki yoki undan ortiq shartlarni baholash uchun IF dan AND funksiyasi bilan qanday foydalanish mumkinligini ko'rib chiqamiz.

Excel'dagi IF AND iborasi

IF AND iborasini yaratish uchun siz IF va VA funksiyalarini bitta formulada birlashtirishingiz kerakligi aniq. Mana shunday:

Oddiy ingliz tiliga tarjima qilinganda formula quyidagicha o'qiladi: IF shart 1 to'g'ri VA 2-shart rost, bitta ishni bajaring, aks holda boshqa ishni bajaring.

Misol sifatida, B2 "etkazib berilgan" va C2 ​​bo'sh emasligini tekshiradigan va natijalarga qarab formula tuzamiz. , quyidagilardan birini bajaradi:

• Agar ikkala shart ham TRUE boʻlsa, tartibni “Yopiq” deb belgilang.
• Agar shartlardan biri YOLGʻON boʻlsa yoki ikkalasi ham FALSE boʻlsa, boʻsh qiymatni qaytaring. string ("").

=IF(AND(B2="delivered", C2""), "Closed", "")

Quyidagi skrinshotda Excelda IF AND funksiyasi ko'rsatilgan:

Agar siz Agar mantiqiy test FALSE deb baholansa, ba'zi qiymatlarni qaytarishni xohlasangiz, ushbu qiymatni value_if_false ga kiriting.dalil. Masalan:

=IF(AND(B2="delivered", C2""), "Closed", "Open")

O'zgartirilgan formuladan "Yopiq" chiqadi, agar B ustuni "etkazib berilgan" bo'lsa va C unda biron bir sana bo'lsa (bo'sh bo'lmagan). Boshqa barcha holatlarda, u "Ochiq" ni qaytaradi:

Eslatma. Matn shartlarini baholash uchun Excelda IF VA formulasidan foydalanganda, kichik va katta harflar bir xil belgi sifatida ishlanishini yodda tuting. Agar siz katta-kichik harflarga sezgir IF VA formulasini izlayotgan bo'lsangiz, bog'langan misolda bajarilganidek AND ning bir yoki bir nechta argumentlarini EXACT funksiyasiga o'rang.

Endi siz Excel IF VA iborasining sintaksisini bilganingizdan so'ng, men sizga qanday vazifalarni hal qilishini ko'rsatib beraman.

Excel IF: kattaroq VA dan kichik

Bo'yicha oldingi misol, biz ikki xil hujayradagi ikkita shartni sinab ko'rdik. Ammo ba'zida bir hujayrada ikki yoki undan ortiq test o'tkazish kerak bo'lishi mumkin. Oddiy misol, katak qiymati ikkita son orasida ekanligini tekshirish. Excel IF AND funksiyasi ham buni osonlik bilan amalga oshirishi mumkin!

Aytaylik, B ustunida sizda savdo raqamlari bor va sizdan $50 dan ortiq, lekin $100 dan kam boʻlgan miqdorlarni belgilash soʻraladi. Buni amalga oshirish uchun ushbu formulani C2 ga kiriting va keyin uni ustunga ko'chiring:

=IF(AND(B2>50, B2<100), "x", "")

Agar siz chegarani kiritishingiz kerak bo'lsa. qiymatlari (50 va 100), kichik yoki teng (<=) va katta yoki teng (>=) operatoridan foydalaning:

=IF(AND(B2>=50, B2<=100), "x", "")

Boshqasini qayta ishlash uchunchegara qiymatlarini formulani o'zgartirmasdan o'zgartiring, ikkita alohida katakchaga minimal va maksimal raqamlarni kiriting va formulangizdagi o'sha kataklarga murojaat qiling. Formulaning barcha qatorlarda to'g'ri ishlashi uchun chegara katakchalari uchun mutlaq havolalardan foydalanishni unutmang (bizning holatlarimizda $F$1 va $F$2):

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Shunga o'xshash formuladan foydalanib, siz sana ning belgilangan diapazonga to'g'ri kelishini tekshirishingiz mumkin.

Masalan, sanalarni 10 gacha belgilaymiz. -2018 yil sentyabr va 2018 yil 30 sentyabr, shu jumladan. Kichkina to'siq shundaki, sanalarni mantiqiy testlarga to'g'ridan-to'g'ri etkazib bo'lmaydi. Excel sanalarni tushunishi uchun ular DATEVALUE funksiyasiga kiritilishi kerak, masalan:

=IF(AND(B2>=DATEVALUE("9/10/2018"), B2<=DATEVALUE("9/30/2018")), "x", "")

Yoki oddiygina Kimdan va Kimga<2 kiriting> ikki katakdagi sanalarni kiriting (bu misolda $F$1 va $F$2) va allaqachon tanish boʻlgan IF VA formulasidan foydalanib, ularni oʻsha kataklardan “tortib oling”:

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Qo'shimcha ma'lumot olish uchun ikki raqam yoki sana orasidagi Excel IF iborasini ko'ring.

Agar bu VA bu, keyin biror narsani hisoblang

Oldindan belgilangan qiymatlarni qaytarishdan tashqari, Excel IF AND funksiyasi belgilangan shartlarning TRUE yoki FALSE ekanligiga qarab turli xil hisob-kitoblarni ham amalga oshirishi mumkin.

Yondoshuvni ko‘rsatish uchun biz “Yopiq” sotuvlar uchun 5% bonusni hisoblab chiqamiz. $100 gacha.

B ustunida summa va C ustunida buyurtma holati bor deb faraz qilsak,formula quyidagicha bo'ladi:

=IF(AND(B2>=100, C2="closed"), B2*10%, 0)

Yuqoridagi formula qolgan buyurtmalar uchun nolni belgilaydi ( value_agar_false = 0) . Agar siz shartlarga javob bermaydigan buyurtmalar uchun kichik rag'batlantiruvchi bonus berishga tayyor bo'lsangiz, aytaylik 3%, tegishli tenglamani value_if_false argumentiga kiriting:

=IF(AND(B2>=100, C2="closed"), B2*10%, B2*3%)

Excel-dagi bir nechta IF VA iboralari

Siz sezganingizdek, biz yuqoridagi barcha misollarda faqat ikkita mezonni baholadik. Ammo Excelning ushbu umumiy cheklovlariga mos kelsa, IF VA formulalaringizga uchta va undan ortiq testlarni kiritishingizga hech narsa to'sqinlik qilmaydi:

• Excel 2007 va undan yuqori versiyalarida 255 tagacha argument. umumiy formula uzunligi 8192 belgidan oshmaydigan formulada ishlatilishi mumkin.
• Excel 2003 va undan pastroq versiyalarda 30 dan ortiq argumentga ruxsat berilmaydi, umumiy uzunligi 1024 belgidan oshmasligi kerak.
• 5>

  Bir nechta VA shartlariga misol sifatida quyidagi shartlarni ko'rib chiqing:

  • Miqdor (B2) $100 dan katta yoki teng bo'lishi kerak
  • Buyurtma holati (C2) "Yopiq"
  • Etkazib berish sanasi (D2) joriy oy ichida

  Endi 3 ta shart TO'G'ri bo'lgan buyurtmalarni aniqlash uchun bizga IF VA bayonoti kerak. Va mana bu:

  =IF(AND(B2>=100, C2="Closed", MONTH(D2)=MONTH(TODAY())), "x", "")

  Yozilish vaqtidagi "joriy oy" oktyabr oyi ekanligini hisobga olsak, formula quyidagi natijalarni beradi:

  

  Ichkarida IF ANDbayonotlar

  Katta ish varaqlari bilan ishlashda sizdan bir vaqtning o'zida bir nechta turli VA mezonlarini tekshirish talab qilinishi mumkin. Buning uchun siz Excelning klassik ichki o'rnatilgan IF formulasini olasiz va uning mantiqiy testlarini AND iboralari bilan kengaytirasiz, masalan:

  IF(VA(…), chiqish1 , IF(VA(...), chiqish2 , IF(VA(…), chiqish3 , chiqish4 )))

  Umumiy fikrni olish uchun quyidagi misolga qarang.

  Xizmatingizni yetkazib berish narxi va taxminiy yetkazib berish vaqti (ETD) asosida baholamoqchi bo'lsangiz:

  • A'lo : yetkazib berish narxi $20 va ETD 3 kundan kamroq
  • Yomon : joʻnatish narxi $30 dan oshadi va 5 kun davomida ETD
  • Oʻrtacha : oʻrtadagi hamma narsa

  To Buni tugatsangiz, ikkita alohida IF VA iborasini yozasiz:

  IF(AND(B2<20, C2<3), "Excellent", …)

  IF(AND(B2>30, C2>5), "Poor", …)

  ...va birini boshqasiga joylashtiring:

  =IF(AND(B2>30, C2>5), "Poor", IF(AND(B2<20, C2<3), "Excellent", "Average"))

  Natija shunga o'xshash bo'ladi:

  

  Ko'proq formula misollarini Excel ichki o'rnatilgan IF VA iboralarida topish mumkin.

  Harf-katta sezgir IF AND Excelda funksiya

  Ushbu qo'llanmaning boshida aytib o'tilganidek, Excel IF VA formulalari katta va kichik harflarni ajratmaydi chunki AND funksiyasi tabiatan katta-kichik harflarni sezmaydi.

  Agar siz katta-kichik harflarni sezgir ma'lumotlari bilan ishlayotgan bo'lsangiz va VA shartlarini matn registrini hisobga olgan holda baholamoqchi bo'lsangiz, har bir alohida mantiqiy testni bajaring. EXACT funktsiyasi va uyasi ichidabu funksiyalarni AND bayonotingizga kiriting:

  AGAR (VA(AN( hujayra ," shart "), EXACT( yacheyka ," shart2 ")), qiymat_agar_true, qiymat_agar_noto'g'ri)

  Ushbu misol uchun biz ma'lum bir mijozning (masalan, Cyberspace deb nomlangan kompaniya) buyurtmalarini ma'lum bir raqamdan oshib ketadigan buyurtmalarini belgilaymiz, deylik $100.

  Quyidagi skrinshotda koʻrib turganingizdek, B ustunidagi baʼzi kompaniya nomlari harflar bilan bir xil koʻrinishga ega va shunga qaramay ular turli kompaniyalardir, shuning uchun biz nomlarni aniq tekshirishimiz kerak. 13>. C ustunidagi summalar raqamlardir va biz ular uchun muntazam "kattaroq" testini o'tkazamiz:

  =IF(AND(EXACT(B2, "Cyberspace"), C2>100), "x", "")

  Formulani yanada moslashuvchan qilish uchun maqsadli mijoz nomi va miqdorini kiritishingiz mumkin. ikkita alohida hujayrada va o'sha hujayralarga murojaat qiling. Yacheyka havolalarini $ belgisi (bizning holatda $G$1 va $G$2) bilan bloklashni unutmang, shunda formulani boshqa qatorlarga nusxalashda ular oʻzgarmaydi:

  =IF(AND(EXACT(B2, $G$1), C2>$G$2), "x", "")

  Endi siz havola qilingan katakchalarga istalgan nom va miqdorni kiritishingiz mumkin va formula jadvalingizdagi tegishli tartiblarni belgilab beradi:

  

  Excelda IF OR AND formula

  Excel IF formulalarida siz faqat bitta mantiqiy funktsiyadan foydalanish bilan cheklanmaysiz. Bir nechta shartlarning turli kombinatsiyalarini tekshirish uchun siz kerakli mantiqiy testlarni bajarish uchun IF, VA, OR va boshqa funktsiyalarni birlashtira olasiz. Mana IF VA OR formulasining bir nechtasini sinab ko'radigan misoliYOKI AND ichidagi shartlar. Endi men sizga OR funksiyasi doirasida ikki yoki undan ortiq AND testlarini qanday bajarishingiz mumkinligini ko'rsataman.

  Aytaylik, siz ikkita mijozning buyurtmalarini ma'lum bir raqamdan kattaroq miqdor bilan belgilashni xohlaysiz, deylik, $100.

  Excel tilida bizning shartlarimiz quyidagicha ifodalangan:

  OR(AND( Customer1 , Amount >100), AND( Customer2 , Amount >100)

  Mijozlarning nomlari B ustunida, summalar C ustunida, 2 ta maqsad nomi. G1 va G2da va maqsadli miqdor G3da bo'lsa, siz ushbu formuladan foydalanib, tegishli buyurtmalarni "x" bilan belgilashingiz mumkin:

  =IF(OR(AND(B2=$G$1, C2>$G$3), AND(B2=$G$2, C2>$G$3)), "x", "")

  Ko'proq bilan bir xil natijalarga erishish mumkin. ixcham sintaksis:

  =IF(AND(OR(B2=$G$1,B2= $G$2), C2>$G$3), "x", "")

  

  Formula mantig'ini to'liq tushunganingizga ishonchingiz komil emasmi? Qo'shimcha ma'lumotni bir nechta VA/YOKI shartlarga ega Excel IF da topish mumkin.

  Mana shunday IF va VA funksiyalaridan Excelda birgalikda foydalanasiz. O'qiganingiz uchun rahmat va keyingi haftada ko'rishguncha!

  Mashq qilish kitobi

  IF VA Excel – formula misollari (.xlsx fayli)

  Shuningdek qarang: Excelda issiqlik xaritasini qanday yaratish mumkin: statik va dinamik