ટ્યુટોરીયલ બતાવે છે કે કેવી રીતે એક્સેલમાં AND ફંક્શન સાથે IF નો ઉપયોગ એક ફોર્મ્યુલામાં બહુવિધ પરિસ્થિતિઓને તપાસવા માટે થાય છે.

વિશ્વમાં કેટલીક વસ્તુઓ મર્યાદિત છે. અન્ય અનંત છે, અને IF ફંક્શન આવી વસ્તુઓમાંથી એક હોવાનું જણાય છે. અમારા બ્લોગ પર, અમારી પાસે પહેલેથી જ મુઠ્ઠીભર Excel IF ટ્યુટોરિયલ્સ છે અને હજુ પણ દરરોજ નવા ઉપયોગો શોધીએ છીએ. આજે, અમે એક જ સમયે બે અથવા વધુ સ્થિતિઓનું મૂલ્યાંકન કરવા માટે તમે AND ફંક્શન સાથે IF નો ઉપયોગ કેવી રીતે કરી શકો તે જોવા જઈ રહ્યા છીએ.

Excel માં IF AND સ્ટેટમેન્ટ

IF AND સ્ટેટમેન્ટ બનાવવા માટે, તમારે દેખીતી રીતે IF અને AND ફંક્શનને એક સૂત્રમાં જોડવાની જરૂર છે. અહીં કેવી રીતે છે:

સાદા અંગ્રેજીમાં અનુવાદિત, સૂત્ર નીચે પ્રમાણે વાંચે છે: IF શરત 1 સાચું છે અને શરત 2 સાચું છે, એક કામ કરો, અન્યથા કંઈક બીજું કરો.

ઉદાહરણ તરીકે, ચાલો એક ફોર્મ્યુલા બનાવીએ જે તપાસે છે કે B2 "વિતરિત" છે કે કેમ અને C2 ખાલી નથી, અને પરિણામો પર આધાર રાખીને , નીચેનામાંથી એક કરે છે:

• જો બંને શરતો સાચી હોય, તો ઓર્ડરને "બંધ" તરીકે ચિહ્નિત કરો.
• જો બેમાંથી એક શરત FALSE હોય અથવા બંને FALSE હોય, તો ખાલી પરત કરો. શબ્દમાળા ("").

=IF(AND(B2="delivered", C2""), "Closed", "")

નીચેનો સ્ક્રીનશોટ Excel માં IF AND ફંક્શન બતાવે છે:

જો તમે જો લોજિકલ ટેસ્ટનું મૂલ્યાંકન FALSE પર થાય તો કેટલાક મૂલ્ય પરત કરવા માગો છો, તે મૂલ્ય value_if_false માં આપોદલીલ ઉદાહરણ તરીકે:

=IF(AND(B2="delivered", C2""), "Closed", "Open")

જો કૉલમ B "વિતરિત" હોય અને C માં કોઈપણ તારીખ હોય તો સંશોધિત ફોર્મ્યુલા "બંધ" આઉટપુટ કરે છે (ખાલી સિવાય). અન્ય તમામ કેસોમાં, તે "ઓપન":

નોંધ પરત કરે છે. ટેક્સ્ટની સ્થિતિનું મૂલ્યાંકન કરવા માટે Excel માં IF AND ફોર્મ્યુલાનો ઉપયોગ કરતી વખતે, કૃપા કરીને ધ્યાનમાં રાખો કે લોઅરકેસ અને અપરકેસને સમાન અક્ષર તરીકે ગણવામાં આવે છે. જો તમે કેસ-સંવેદનશીલ IF AND ફોર્મ્યુલા શોધી રહ્યાં છો, તો AND ની એક અથવા વધુ દલીલોને EXACT ફંક્શનમાં લપેટો કારણ કે તે લિંક કરેલ ઉદાહરણમાં કરવામાં આવ્યું છે.

હવે તમે Excel IF AND સ્ટેટમેન્ટનું વાક્યરચના જાણો છો, ચાલો હું તમને બતાવું કે તે કયા પ્રકારનાં કાર્યોને હલ કરી શકે છે.

Excel IF: કરતાં વધુ અને તેનાથી ઓછું

માં અગાઉના ઉદાહરણ, અમે બે અલગ અલગ કોષોમાં બે સ્થિતિઓનું પરીક્ષણ કરી રહ્યા હતા. પરંતુ કેટલીકવાર તમારે એક જ કોષ પર બે અથવા વધુ પરીક્ષણો ચલાવવાની જરૂર પડી શકે છે. એક લાક્ષણિક ઉદાહરણ એ તપાસી રહ્યું છે કે કોષની કિંમત બે સંખ્યાઓ વચ્ચે છે કે કેમ. Excel IF AND ફંક્શન પણ તે સરળતાથી કરી શકે છે!

ચાલો કહીએ કે તમારી પાસે કૉલમ Bમાં કેટલાક વેચાણ નંબરો છે અને તમને $50 કરતાં વધુ પરંતુ $100 કરતાં ઓછી રકમને ફ્લેગ કરવાની વિનંતી કરવામાં આવે છે. તે પૂર્ણ કરવા માટે, આ ફોર્મ્યુલાને C2 માં દાખલ કરો અને પછી તેને કૉલમ નીચે કૉપિ કરો:

=IF(AND(B2>50, B2<100), "x", "")

જો તમારે સીમા શામેલ કરવાની જરૂર હોય મૂલ્યો (50 અને 100), ઓપરેટર (<=) થી ઓછા અથવા તેના સમાન ઓપરેટર (<=) અને થી વધુ અથવા તેનાથી વધુ (>=) ઓપરેટરનો ઉપયોગ કરો:

=IF(AND(B2>=50, B2<=100), "x", "")

કોઈ અન્ય પર પ્રક્રિયા કરવા માટેસૂત્ર બદલ્યા વિના સીમા મૂલ્યો, બે અલગ કોષોમાં લઘુત્તમ અને મહત્તમ સંખ્યાઓ દાખલ કરો અને તમારા સૂત્રમાં તે કોષોનો સંદર્ભ લો. બધી પંક્તિઓમાં ફોર્મ્યુલા યોગ્ય રીતે કામ કરે તે માટે, સીમા કોષો માટે ચોક્કસ સંદર્ભોનો ઉપયોગ કરવાનું સુનિશ્ચિત કરો (અમારા કિસ્સામાં $F$1 અને $F$2):

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

સમાન ફોર્મ્યુલાનો ઉપયોગ કરીને, તમે તપાસ કરી શકો છો કે શું તારીખ નિર્દિષ્ટ રેન્જમાં આવે છે .

ઉદાહરણ તરીકે, ચાલો 10 ની વચ્ચેની તારીખોને ફ્લેગ કરીએ -સપ્ટે.-2018 અને 30-સપ્ટે.-2018, સહિત. એક નાની અડચણ એ છે કે તાર્કિક પરીક્ષણોને સીધી તારીખો આપી શકાતી નથી. એક્સેલ તારીખો સમજવા માટે, તે DATEVALUE ફંક્શનમાં આ રીતે બંધ હોવું જોઈએ:

=IF(AND(B2>=DATEVALUE("9/10/2018"), B2<=DATEVALUE("9/30/2018")), "x", "")

અથવા ફક્ત માંથી અને પ્રતિ<2 ઇનપુટ કરો> બે કોષોમાં તારીખો (આ ઉદાહરણમાં $F$1 અને $F$2) અને પહેલાથી જ પરિચિત IF AND ફોર્મ્યુલાનો ઉપયોગ કરીને તેમને તે કોષોમાંથી "ખેંચો":

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

વધુ માહિતી માટે, કૃપા કરીને બે નંબરો અથવા તારીખો વચ્ચેનું એક્સેલ IF સ્ટેટમેન્ટ જુઓ.

જો આ અને તે, તો પછી કંઈક ગણતરી કરો

પૂર્વવ્યાખ્યાયિત મૂલ્યો પરત કરવા સિવાય, એક્સેલ IF AND ફંક્શન નિર્દિષ્ટ શરતો સાચી છે કે ખોટી છે તેના આધારે અલગ અલગ ગણતરીઓ પણ કરી શકે છે.

અભિગમ દર્શાવવા માટે, અમે "બંધ" વેચાણ માટે 5% ના બોનસની ગણતરી કરીશું જેનાથી વધુ અથવા સમાન રકમ સાથે $100 સુધી.

માની લઈએ કે રકમ કૉલમ B માં છે અને કૉલમ C માં ઓર્ડરની સ્થિતિ,સૂત્ર નીચે પ્રમાણે જાય છે:

=IF(AND(B2>=100, C2="closed"), B2*10%, 0)

ઉપરનું સૂત્ર બાકીના ઓર્ડરને શૂન્ય સોંપે છે ( મૂલ્ય_જો_ખોટું = 0) . જો તમે એક નાનું ઉત્તેજક બોનસ આપવા તૈયાર છો, તો 3% કહો, જે ઑર્ડર શરતોને પૂર્ણ કરતા નથી, અનુરૂપ સમીકરણને મૂલ્ય_જો_ખોટું દલીલમાં શામેલ કરો:

=IF(AND(B2>=100, C2="closed"), B2*10%, B2*3%)

એક્સેલમાં બહુવિધ IF AND સ્ટેટમેન્ટ

તમે નોંધ્યું હશે કે, અમે ઉપરના તમામ ઉદાહરણોમાં માત્ર બે માપદંડોનું મૂલ્યાંકન કર્યું છે. પરંતુ એવું કંઈ નથી જે તમને તમારા IF AND ફોર્મ્યુલામાં ત્રણ અને વધુ પરીક્ષણોનો સમાવેશ કરતા અટકાવે જ્યાં સુધી તેઓ Excel ની આ સામાન્ય મર્યાદાઓનું પાલન કરે છે:

• Excel 2007 અને ઉચ્ચમાં, 255 દલીલો સુધી ફોર્મ્યુલામાં ઉપયોગ કરી શકાય છે, જેમાં કુલ ફોર્મ્યુલાની લંબાઈ 8,192 અક્ષરોથી વધુ ન હોય.
• એક્સેલ 2003 અને તેનાથી નીચેના ભાગમાં, કુલ લંબાઈ 1,024 અક્ષરોથી વધુ ન હોય તેવી 30 થી વધુ દલીલોને મંજૂરી નથી.

મલ્ટિપલ AND શરતોના ઉદાહરણ તરીકે, કૃપા કરીને આનો વિચાર કરો:

• રકમ (B2) $100 કરતાં વધુ અથવા તેની બરાબર હોવી જોઈએ
• ઓર્ડર સ્થિતિ (C2) "બંધ" છે
• ડિલિવરીની તારીખ (D2) વર્તમાન મહિનાની અંદર છે

હવે, અમને ઓર્ડર ઓળખવા માટે IF AND સ્ટેટમેન્ટની જરૂર છે જેના માટે તમામ 3 શરતો સાચી છે. અને તે અહીં છે:

=IF(AND(B2>=100, C2="Closed", MONTH(D2)=MONTH(TODAY())), "x", "")

લખવાની ક્ષણે 'વર્તમાન મહિનો' ઓક્ટોબર હતો તે જોતાં, સૂત્ર નીચેના પરિણામો આપે છે:

નેસ્ટેડ IF ANDનિવેદનો

મોટી વર્કશીટ્સ સાથે કામ કરતી વખતે, સંભવ છે કે તમારે એક સમયે અલગ-અલગ અને માપદંડોના થોડા સેટ તપાસવાની જરૂર પડી શકે છે. આ માટે, તમે ક્લાસિક એક્સેલ નેસ્ટેડ IF ફોર્મ્યુલા લો અને તેના લોજિકલ ટેસ્ટને AND સ્ટેટમેન્ટ્સ સાથે વિસ્તૃત કરો, જેમ કે:

સામાન્ય વિચાર મેળવવા માટે, કૃપા કરીને નીચેના ઉદાહરણને જુઓ.

થી તે પૂર્ણ કરો, તમે બે વ્યક્તિગત IF AND સ્ટેટમેન્ટ લખો:

IF(AND(B2<20, C2<3), "Excellent", …)

IF(AND(B2>30, C2>5), "Poor", …)

…અને એકને બીજામાં નેસ્ટ કરો:

=IF(AND(B2>30, C2>5), "Poor", IF(AND(B2<20, C2<3), "Excellent", "Average"))

પરિણામ આના જેવું જ દેખાશે:

વધુ ફોર્મ્યુલા ઉદાહરણો Excel નેસ્ટેડ IF AND સ્ટેટમેન્ટમાં મળી શકે છે.

કેસ-સંવેદનશીલ IF AND એક્સેલમાં ફંક્શન

આ ટ્યુટોરીયલની શરૂઆતમાં જણાવ્યા મુજબ, એક્સેલ IF અને ફોર્મ્યુલા અપરકેસ અને લોઅરકેસ અક્ષરો વચ્ચે ભેદ પાડતા નથી કારણ કે AND ફંક્શન પ્રકૃતિ દ્વારા કેસ-સંવેદનશીલ છે.

જો તમે કેસ-સેન્સિટિવ ડેટા સાથે કામ કરી રહ્યાં છો અને ટેક્સ્ટ કેસને ધ્યાનમાં લઈને અને શરતોનું મૂલ્યાંકન કરવા માંગો છો, તો દરેક વ્યક્તિગત લોજિકલ પરીક્ષણ કરો ચોક્કસ કાર્ય અને માળખાની અંદરતમારા AND સ્ટેટમેન્ટમાં તે કાર્યો:

આ ઉદાહરણ માટે, અમે ચોક્કસ ગ્રાહક (દા.ત. સાયબરસ્પેસ નામની કંપની)ના ઓર્ડરને ચોક્કસ સંખ્યા કરતાં વધુ રકમ સાથે ફ્લેગ કરવા જઈ રહ્યા છીએ, કહો $100.

જેમ તમે નીચેના સ્ક્રીનશૉટમાં જોઈ શકો છો, કૉલમ B માં કેટલીક કંપનીના નામો અક્ષરોના કેસમાં સમાન અંશો દેખાય છે, અને તેમ છતાં તે જુદી જુદી કંપનીઓ છે, તેથી અમારે નામ ચોક્કસપણે તપાસવું પડશે. 13>. કૉલમ C માં રકમો સંખ્યાઓ છે, અને અમે તેમના માટે નિયમિત "મોટા" પરીક્ષણ ચલાવીએ છીએ:

=IF(AND(EXACT(B2, "Cyberspace"), C2>100), "x", "")

ફોર્મ્યુલાને વધુ લવચીક બનાવવા માટે, તમે લક્ષ્ય ગ્રાહકનું નામ અને રકમ ઇનપુટ કરી શકો છો. બે અલગ કોષોમાં અને તે કોષોનો સંદર્ભ લો. ફક્ત સેલ સંદર્ભોને $ ચિહ્ન ($G$1 અને $G$2 અમારા કિસ્સામાં) સાથે લૉક કરવાનું યાદ રાખો જેથી જ્યારે તમે ફોર્મ્યુલાને અન્ય પંક્તિઓમાં કૉપિ કરો ત્યારે તેઓ બદલાશે નહીં:

=IF(AND(EXACT(B2, $G$1), C2>$G$2), "x", "")

હવે, તમે સંદર્ભિત કોષોમાં કોઈપણ નામ અને રકમ ટાઈપ કરી શકો છો, અને સૂત્ર તમારા કોષ્ટકમાં અનુરૂપ ઓર્ડરને ફ્લેગ કરશે:

એક્સેલમાં જો અથવા અને સૂત્ર

એક્સેલ IF ફોર્મ્યુલામાં, તમે માત્ર એક લોજિકલ ફંક્શનનો ઉપયોગ કરવા માટે મર્યાદિત નથી. બહુવિધ શરતોના વિવિધ સંયોજનોને તપાસવા માટે, તમે જરૂરી લોજિકલ પરીક્ષણો ચલાવવા માટે IF, AND, OR અને અન્ય કાર્યોને જોડવા માટે મુક્ત છો. અહીં IF AND OR ફોર્મ્યુલાનું ઉદાહરણ છે જે એક દંપતિનું પરીક્ષણ કરે છેઅથવા AND ની અંદર શરતો. અને હવે, હું તમને બતાવીશ કે તમે OR ફંક્શનમાં બે કે તેથી વધુ અને પરીક્ષણો કેવી રીતે કરી શકો છો.

ધારો કે, તમે બે ગ્રાહકોના ઓર્ડરને ચોક્કસ સંખ્યા કરતાં વધુ રકમ સાથે ચિહ્નિત કરવા માંગો છો, કહો કે $100.

એક્સેલ ભાષામાં, અમારી શરતો આ રીતે વ્યક્ત કરવામાં આવે છે:

OR(AND( Customer1 , Amount >100), AND( Customer2 , Amount >100)

ધારી લઈએ કે ગ્રાહકના નામ કૉલમ B માં છે, કૉલમ C માં રકમ, 2 લક્ષ્ય નામો G1 અને G2 માં છે, અને લક્ષ્ય રકમ G3 માં છે, તમે અનુરૂપ ઓર્ડરને "x" સાથે ચિહ્નિત કરવા માટે આ સૂત્રનો ઉપયોગ કરો છો:

=IF(OR(AND(B2=$G$1, C2>$G$3), AND(B2=$G$2, C2>$G$3)), "x", "")

તે જ પરિણામો વધુ સાથે પ્રાપ્ત કરી શકાય છે સંક્ષિપ્ત વાક્યરચના:

=IF(AND(OR(B2=$G$1,B2= $G$2), C2>$G$3), "x", "")

તમે સૂત્રના તર્કને સંપૂર્ણપણે સમજો છો તેની ખાતરી નથી? એક્સેલ IF માં બહુવિધ AND/OR શરતો સાથે વધુ માહિતી મળી શકે છે.

આ રીતે તમે Excel માં IF અને AND ફંક્શનનો એકસાથે ઉપયોગ કરો છો. વાંચવા બદલ આભાર અને આવતા અઠવાડિયે મળીશું!

પ્રેક્ટિસ વર્કબુક

IF AND Excel – ફોર્મ્યુલા ઉદાહરણો (.xlsx ફાઇલ)