Энэ заавар нь Excel-ийн AND функцийн хамт IF-ийг хэрхэн нэг томьёоны доторх олон нөхцөлийг шалгахын тулд хэрхэн ашиглахыг харуулж байна.

Дэлхий дээрх зарим зүйл хязгаарлагдмал байдаг. Бусад нь хязгааргүй бөгөөд IF функц нь ийм зүйлсийн нэг юм шиг санагддаг. Манай блог дээр Excel IF-ийн цөөн хэдэн хичээл байгаа бөгөөд өдөр бүр шинэ хэрэглээг олж мэдсээр байна. Өнөөдөр бид хоёр ба түүнээс дээш нөхцөлийг нэгэн зэрэг үнэлэхийн тулд IF функцийг AND функцтэй хэрхэн ашиглах талаар авч үзэх болно.

Excel дээрх IF AND мэдэгдлийг

IF AND хэллэгийг бүтээхийн тулд та IF болон AND функцуудыг нэг томьёонд нэгтгэх хэрэгтэй. Үүнд:

Энгийн англи хэл рүү хөрвүүлсэн бол томьёог дараах байдлаар уншина: IF нөхцөл 1 үнэн БА Нөхцөл 2 нь үнэн бол нэг зүйл хий, үгүй ​​бол өөр зүйл хий.

Жишээ нь B2 "хүргэгдсэн", C2 хоосон биш, үр дүнгээс хамааран шалгадаг томьёо хийцгээе. , дараах зүйлсийн аль нэгийг хийнэ:

• Хэрэв хоёр нөхцөл ҮНЭН бол дарааллыг "Хаалттай" гэж тэмдэглэнэ үү.
• Хэрэв аль нэг нөхцөл ХУДАЛ эсвэл хоёулаа ХУДАЛ бол хоосон буцаана. string ("").

=IF(AND(B2="delivered", C2""), "Closed", "")

Доорх дэлгэцийн агшинд Excel-ийн IF AND функцийг харуулав:

Хэрэв та Логик тест ХУДАЛ гэж үнэлэгдсэн тохиолдолд зарим утгыг буцаахыг хүсэж байгаа бол энэ утгыг хэрэв_худал_утга хэсэгт оруулна уу.маргаан. Жишээ нь:

=IF(AND(B2="delivered", C2""), "Closed", "Open")

Өөрчлөгдсөн томьёо нь В баганад "хүргэгдсэн" ба С-д ямар нэгэн огноо (хоосон биш) байвал "Хаалттай" гарна. Бусад бүх тохиолдолд "Нээлттэй" гэж буцаана:

Тайлбар. Текстийн нөхцөлийг үнэлэхийн тулд Excel-д IF AND томьёог ашиглахдаа жижиг ба том үсгийг ижил тэмдэгт гэж үзнэ гэдгийг санаарай. Хэрэв та том жижиг жижиг IF AND томьёог хайж байгаа бол AND-ын нэг буюу хэд хэдэн аргументыг холбосон жишээн дээр хийгдэж байгаа шиг EXACT функцэд боож өгнө үү.

Одоо та Excel IF AND мэдэгдлийн синтаксийг мэдэж байгаа тул энэ нь ямар төрлийн даалгавруудыг шийдэж болохыг танд харуулъя.

Excel IF: их ба түүнээс бага

Өмнөх жишээнд бид хоёр өөр нүдэнд хоёр нөхцөлийг туршиж үзсэн. Гэхдээ заримдаа нэг нүдэн дээр хоёр ба түүнээс дээш тест хийх шаардлагатай болдог. Энгийн жишээ бол нүдний утга хоёр тооны хооронд байгаа эсэхийг шалгах явдал юм. Excel IF AND функц нь үүнийг хялбархан хийж чадна!

Та В баганад борлуулалтын дугаар байгаа бөгөөд 50 доллараас дээш боловч 100 доллараас бага дүнг тэмдэглэхийг хүссэн гэж бодъё. Үүнийг хийхийн тулд энэ томьёог C2-д оруулаад, дараа нь баганад хуулж аваарай:

=IF(AND(B2>50, B2<100), "x", "")

Хэрэв та хязгаарыг оруулах шаардлагатай бол утгууд (50 ба 100), бага буюу тэнцүү оператор (<=) ба илүү их буюу тэнцүү (>=) операторыг ашиглана:

=IF(AND(B2>=50, B2<=100), "x", "")

Өөрийг боловсруулахтомъёог өөрчлөхгүйгээр хилийн утгыг оруулахын тулд хоёр тусдаа нүдэнд хамгийн бага ба хамгийн их тоог оруулаад томъёоныхоо тэдгээр нүднүүдийг харна уу. Томъёо бүх мөрөнд зөв ажиллахын тулд хилийн нүднүүдэд үнэмлэхүй лавлагаа ашиглахаа мартуузай (бидний тохиолдолд $F$1 ба $F$2):

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Ижил төстэй томъёог ашигласнаар та огноо нь заасан мужид багтаж байгаа эсэхийг шалгаж болно.

Жишээ нь 10-ын хоорондох огноог тэмдэглэе. -2018 оны 9-р сар, 2018 оны 9-р сарын 30-ны өдрийг багтаасан. Жижиг саад бэрхшээл бол огноог логик тестүүдэд шууд оруулах боломжгүй юм. Excel-д огноог ойлгохын тулд тэдгээрийг DATEVALUE функцэд дараах байдлаар хавсаргах хэрэгтэй:

=IF(AND(B2>=DATEVALUE("9/10/2018"), B2<=DATEVALUE("9/30/2018")), "x", "")

Эсвэл зүгээр л From болон To<2-г оруулна уу> огноог хоёр нүдэнд (энэ жишээнд $F$1 ба $F$2) оруулаад аль хэдийн танил болсон IF AND томьёог ашиглан тэдгээрийг эдгээр нүднүүдээс "татан авна уу":

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Дэлгэрэнгүй мэдээлэл авахыг хүсвэл хоёр тоо эсвэл огнооны хоорондох Excel IF мэдэгдлийг харна уу.

ХЭРэв энэ ба тэр бол ямар нэг зүйлийг тооцоолно уу

Урьдчилан тодорхойлсон утгыг буцаахаас гадна Excel IF Мөн AND функц нь заасан нөхцөлүүд нь ҮНЭН эсвэл ХУДАЛ байгаа эсэхээс хамаарч өөр өөр тооцоолол хийж болно.

Аргыг харуулахын тулд бид "Хаалттай" борлуулалтаас дээш буюу тэнцүү дүнтэй 5%-ийн урамшуулал тооцох болно. $100 хүртэл.

Б баганад үнийн дүн, С баганад захиалгын төлөв байна гэж үзвэл,томъёо дараах байдалтай байна:

=IF(AND(B2>=100, C2="closed"), B2*10%, 0)

Дээрх томьёо нь бусад захиалгад тэг онооно ( утга_худал = 0) . Хэрэв та нөхцөлийг хангаагүй захиалгад 3% гэх мэт өчүүхэн урамшуулал өгөхөд бэлэн байгаа бол харгалзах тэгшитгэлийг худал_хэрэв_утга аргументад оруулна:

=IF(AND(B2>=100, C2="closed"), B2*10%, B2*3%)

Excel дэх олон IF AND мэдэгдлүүд

Таны анзаарсанчлан бид дээрх бүх жишээн дээр зөвхөн хоёр шалгуурыг үнэллээ. Гэхдээ Excel-ийн эдгээр ерөнхий хязгаарлалттай нийцэж байгаа тохиолдолд IF AND томьёодоо гурав ба түүнээс дээш тест оруулахад юу ч саад болохгүй:

• Excel 2007 болон түүнээс дээш хувилбарт 255 хүртэлх аргумент томьёоны нийт урт нь 8192 тэмдэгтээс ихгүй томьёонд ашиглагдаж болно.
• Excel 2003 болон түүнээс доош хувилбарт 30-аас илүүгүй аргумент зөвшөөрөгдөх бөгөөд нийт урт нь 1024 тэмдэгтээс ихгүй байна.

Олон AND нөхцлийн жишээ болгон эдгээр нөхцлүүдийг авч үзье:

• Дэм (B2) нь $100-аас их буюу тэнцүү байх ёстой
• Захиалгын төлөв (C2) "Хаалттай"
• Хүргэх огноо (D2) нь тухайн сард багтаж байна

Одоо бидэнд 3 нөхцөл ҮНЭН байгаа захиалгыг тодорхойлохын тулд IF AND мэдэгдэл хэрэгтэй. Энд байна:

=IF(AND(B2>=100, C2="Closed", MONTH(D2)=MONTH(TODAY())), "x", "")

Бичиж байх үеийн "одоогийн сар" нь 10-р сар байсан тул томъёо нь дараах үр дүнг өгдөг:

Хэрэв AND бол үүрлэсэнмэдэгдлүүд

Том ажлын хуудастай ажиллахдаа нэг удаад та өөр өөр AND шалгуурын хэд хэдэн багцыг шалгах шаардлагатай болж магадгүй юм. Үүний тулд та Excel-ийн сонгодог IF томъёог авч, түүний логик тестүүдийг AND хэллэгээр өргөтгөх хэрэгтэй:

Ерөнхий санааг авахын тулд дараах жишээг харна уу.

Та үйлчилгээгээ тээвэрлэлтийн зардал болон хүргэх тооцоолсон хугацаанд (ETD) үндэслэн үнэлэхийг хүсэж байна гэж бодъё:

• Маш сайн : тээвэрлэлтийн зардал 20 доллараас бага, ETD 3 хоногоос бага
• Муу : тээвэрлэлтийн зардал $30-аас дээш, 5 өдрийн ETD
• Дундаж : хоорондын бүх зүйл

Хүртэл Үүнийг дуусгахын тулд та хоёр тусдаа IF AND мэдэгдлийг бичнэ үү:

IF(AND(B2<20, C2<3), "Excellent", …)

IF(AND(B2>30, C2>5), "Poor", …)

...мөн нэгийг нөгөө рүү нь оруулаарай:

=IF(AND(B2>30, C2>5), "Poor", IF(AND(B2<20, C2<3), "Excellent", "Average"))

Үр дүн нь үүнтэй төстэй харагдах болно:

Илүү томьёоны жишээг Excel-ийн үүрлэсэн IF AND хэллэгүүдээс олж болно.

Үр томьёоны жижиг үсгийг мэдэрдэг IF AND Excel-ийн функц

Энэ гарын авлагын эхэнд дурдсанчлан Excel IF AND томьёо нь том, жижиг үсгийн хооронд ялгаагүй Учир нь AND функц нь том жижиг жижиг жижиг жижиг үсэг мэдрэгддэггүй.

Хэрэв та үсгийн том үсэг мэдэрдэг өгөгдөлтэй ажиллаж байгаа бөгөөд текстийн том жижиг үсгийг харгалзан AND нөхцөлийг үнэлэхийг хүсвэл логик тест бүрийг тус тусад нь хийнэ үү. EXACT функц болон үүр доторэдгээр функцийг таны AND мэдэгдэлд оруулна:

Энэ жишээний хувьд бид тодорхой харилцагчийн (жишээ нь: Цахим орон зай нэртэй компани) тодорхой тооноос давсан үнийн дүн бүхий захиалгыг дарцаглах гэж байна. $100.

Доорх дэлгэцийн агшинд харж байгаачлан В баганад байгаа зарим компанийн нэрс нь үсгийн жижиг үсэгтэй ижил, гэхдээ тэдгээр нь өөр компани тул бид нэрсийг яг шалгах хэрэгтэй 13>. С баганад байгаа дүн нь тоо бөгөөд бид тэдгээрт "илүү" гэсэн шалгалтыг тогтмол хийдэг:

=IF(AND(EXACT(B2, "Cyberspace"), C2>100), "x", "")

Томьёог илүү уян хатан болгохын тулд та зорилтот хэрэглэгчийн нэр болон дүнг оруулах боломжтой. хоёр тусдаа нүдэнд байх ба тэдгээр нүдийг хэлнэ. Нүдний лавлагааг $ тэмдгээр (манай тохиолдолд $G$1 ба $G$2) түгжихээ санаарай, ингэснээр томьёог бусад мөр рүү хуулах үед тэдгээр нь өөрчлөгдөхгүй:

=IF(AND(EXACT(B2, $G$1), C2>$G$2), "x", "")

Одоо та лавласан нүднүүдэд дурын нэр, дүнг бичих боломжтой бөгөөд томьёо нь таны хүснэгтийн харгалзах дарааллыг тэмдэглэнэ:

Excel-д IF OR AND томъёо

Excel IF томьёонд та зөвхөн нэг логик функц ашиглахаар хязгаарлагдахгүй. Олон нөхцлийн янз бүрийн хослолыг шалгахын тулд та IF, AND, OR болон бусад функцуудыг нэгтгэж, шаардлагатай логик тестүүдийг ажиллуулж болно. Энд хэд хэдэн тест хийдэг IF AND OR томъёоны жишээг үзүүлэвOR AND доторх нөхцөл. Одоо би танд OR функцийн хүрээнд хоёр ба түүнээс дээш AND тестийг хэрхэн хийж болохыг харуулах болно.

Та хоёр харилцагчийн захиалгыг 100 доллар гэж тодорхой тооноос их хэмжээгээр тэмдэглэхийг хүсч байна гэж бодъё.

Excel хэл дээр бидний нөхцөл дараах байдлаар илэрхийлэгдэнэ:

OR(AND( Customer1 , Amount >100), AND( Customer2 , Amount >100)

Үйлчлүүлэгчийн нэрийг В баганад, дүнг C баганад, 2 зорилтот нэр гэж үзвэл. G1 ба G2-д байгаа бөгөөд зорилтот хэмжээ нь G3-д байгаа бол та энэ томьёог ашиглан харгалзах захиалгыг "x"-ээр тэмдэглэнэ үү:

=IF(OR(AND(B2=$G$1, C2>$G$3), AND(B2=$G$2, C2>$G$3)), "x", "")

Ижил үр дүнд илүү их хэмжээгээр хүрч болно. авсаархан синтакс:

=IF(AND(OR(B2=$G$1,B2= $G$2), C2>$G$3), "x", "")

Та томьёоны логикийг бүрэн ойлгосон гэдэгтээ итгэлтэй байна уу? Дэлгэрэнгүй мэдээллийг Excel-ийн олон БА/ЭСВЭЛ нөхцөлтэй IF програмаас авах боломжтой.

Ингэж та IF болон AND функцийг Excel-д хамтад нь ашигладаг. Уншсан танд баярлалаа, дараа долоо хоногт уулзацгаая!

Дасгал хийх ном

IF AND Excel – томъёоны жишээнүүд (.xlsx файл)