Das Tutorial zeigt, wie man IF zusammen mit der AND-Funktion in Excel verwendet, um mehrere Bedingungen in einer Formel zu überprüfen.

Manche Dinge in der Welt sind endlich, andere sind unendlich, und die IF-Funktion scheint eines dieser Dinge zu sein. In unserem Blog haben wir bereits eine Handvoll Excel IF-Tutorials und entdecken immer noch jeden Tag neue Anwendungsmöglichkeiten. Heute werden wir uns ansehen, wie Sie IF zusammen mit der AND-Funktion verwenden können, um zwei oder mehr Bedingungen gleichzeitig auszuwerten.

IF AND-Anweisung in Excel

Um die IF AND-Anweisung zu erstellen, müssen Sie natürlich die IF- und AND-Funktionen in einer Formel kombinieren, und zwar folgendermaßen

In einfaches Englisch übersetzt lautet die Formel wie folgt: WENN Bedingung 1 wahr ist UND Bedingung 2 wahr ist, tue eine Sache, ansonsten tue etwas anderes.

Nehmen wir als Beispiel eine Formel, die prüft, ob B2 "geliefert" und C2 nicht leer ist, und je nach Ergebnis eine der folgenden Aktionen ausführt:

• Wenn beide Bedingungen WAHR sind, kennzeichnen Sie den Auftrag als "abgeschlossen".
• Wenn eine der beiden Bedingungen FALSCH ist oder beide FALSCH sind, wird eine leere Zeichenkette ("") zurückgegeben.

=IF(AND(B2="geliefert", C2""), "Geschlossen", "")

Die folgende Abbildung zeigt die Funktion IF AND in Excel:

Wenn Sie einen Wert zurückgeben möchten, falls der logische Test FALSE ergibt, geben Sie diesen Wert in der wert_wenn_false Zum Beispiel:

=IF(AND(B2="geliefert", C2""), "Geschlossen", "Offen")

Die geänderte Formel gibt "Geschlossen" aus, wenn Spalte B "geliefert" ist und C ein beliebiges Datum enthält (nicht leer), in allen anderen Fällen wird "Offen" ausgegeben:

Hinweis: Wenn Sie eine WENN-UND-Formel in Excel verwenden, um Textbedingungen auszuwerten, beachten Sie bitte, dass Klein- und Großbuchstaben als dasselbe Zeichen behandelt werden. Wenn Sie eine WENN-UND-Formel suchen, bei der die Groß-/Kleinschreibung beachtet wird, schließen Sie ein oder mehrere Argumente von AND in die EXACT-Funktion ein, wie es im verlinkten Beispiel gemacht wird.

Nachdem Sie nun die Syntax der Excel-Anweisung IF AND kennen, möchte ich Ihnen zeigen, welche Art von Aufgaben damit gelöst werden können.

Excel IF: größer als UND kleiner als

Im vorigen Beispiel haben wir zwei Bedingungen in zwei verschiedenen Zellen getestet. Manchmal müssen Sie jedoch zwei oder mehr Tests für dieselbe Zelle durchführen. Ein typisches Beispiel ist die Prüfung, ob ein Zellwert zwischen zwei Zahlen Die Excel-Funktion WENN UND kann dies ebenfalls problemlos tun!

Angenommen, Sie haben einige Verkaufszahlen in Spalte B und möchten die Beträge, die größer als 50 $, aber kleiner als 100 $ sind, kennzeichnen. Dazu fügen Sie diese Formel in C2 ein und kopieren sie dann in die Spalte:

=IF(AND(B2>50, B2<100), "x", "")

Wenn Sie die Grenzwerte (50 und 100), verwenden Sie die kleiner als oder gleich Operator (<=) und größer als oder gleich (>=)-Operator:

=IF(AND(B2>=50, B2<=100), "x", "")

Um andere Grenzwerte zu verarbeiten, ohne die Formel zu ändern, geben Sie die Mindest- und Höchstwerte in zwei separate Zellen ein und beziehen sich in Ihrer Formel auf diese Zellen. Damit die Formel in allen Zeilen korrekt funktioniert, müssen Sie für die Grenzzellen (in unserem Fall $F$1 und $F$2) absolute Referenzen verwenden:

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Mit einer ähnlichen Formel können Sie prüfen, ob eine Datum fällt innerhalb eines bestimmten Bereichs .

Ein Beispiel: Wir wollen Daten zwischen 10-Sep-2018 und 30-Sep-2018 markieren. Eine kleine Hürde besteht darin, dass Datumsangaben nicht direkt in die logischen Tests eingegeben werden können. Damit Excel die Datumsangaben versteht, müssen sie in die DATEVALUE-Funktion eingeschlossen werden, etwa so:

=IF(AND(B2>=DATEVALUE("9/10/2018"), B2<=DATEVALUE("9/30/2018")), "x", "")

Oder geben Sie einfach die Von und An Daten in zwei Zellen ($F$1 und $F$2 in diesem Beispiel) und "ziehen" sie aus diesen Zellen, indem Sie die bereits bekannte WENN UND-Formel verwenden:

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Weitere Informationen finden Sie unter Excel IF-Anweisung zwischen zwei Zahlen oder Daten.

WENN dies UND das, dann etwas berechnen

Die Excel-Funktion WENN UND kann nicht nur vordefinierte Werte zurückgeben, sondern auch unterschiedliche Berechnungen durchführen, je nachdem, ob die angegebenen Bedingungen WAHR oder FALSCH sind.

Zur Veranschaulichung des Ansatzes werden wir einen Bonus von 5 % für "abgeschlossene" Verkäufe mit einem Betrag von mindestens 100 $ berechnen.

Angenommen, der Betrag steht in Spalte B und der Auftragsstatus in Spalte C, so lautet die Formel wie folgt:

=IF(AND(B2>=100, C2="geschlossen"), B2*10%, 0)

Die obige Formel weist den übrigen Aufträgen den Wert Null zu ( wert_wenn_false = Wenn Sie bereit sind, einen kleinen stimulierenden Bonus, z.B. 3%, für Aufträge zu gewähren, die die Bedingungen nicht erfüllen, fügen Sie die entsprechende Gleichung in die wert_wenn_false Argument:

=IF(AND(B2>=100, C2="geschlossen"), B2*10%, B2*3%)

Mehrere IF AND-Anweisungen in Excel

Wie Sie vielleicht bemerkt haben, haben wir in allen obigen Beispielen nur zwei Kriterien ausgewertet. Es gibt jedoch nichts, was Sie daran hindern würde, drei und mehr Tests in Ihre WENN UND-Formeln aufzunehmen, solange sie diese allgemeinen Einschränkungen von Excel einhalten:

• In Excel 2007 und höher können bis zu 255 Argumente in einer Formel verwendet werden, wobei die Gesamtlänge der Formel 8.192 Zeichen nicht überschreiten darf.
• In Excel 2003 und niedrigeren Versionen sind nicht mehr als 30 Argumente zulässig, wobei die Gesamtlänge 1.024 Zeichen nicht überschreiten darf.

Als Beispiel für mehrere UND-Bedingungen seien diese genannt:

• Der Betrag (B2) sollte größer oder gleich $100 sein.
• Auftragsstatus (C2) ist "Geschlossen".
• Das Lieferdatum (D2) liegt innerhalb des laufenden Monats

Jetzt brauchen wir eine IF AND-Anweisung, um die Aufträge zu identifizieren, für die alle 3 Bedingungen WAHR sind, und hier ist sie:

=IF(AND(B2>=100, C2="Geschlossen", MONTH(D2)=MONTH(TODAY())), "x", "")

Da der "aktuelle Monat" zum Zeitpunkt der Erstellung dieses Berichts der Oktober war, liefert die Formel die folgenden Ergebnisse:

Verschachtelte IF AND-Anweisungen

Wenn Sie mit großen Arbeitsblättern arbeiten, kann es vorkommen, dass Sie mehrere Sätze verschiedener UND-Kriterien gleichzeitig überprüfen müssen. Dazu nehmen Sie eine klassische verschachtelte WENN-Formel von Excel und erweitern ihre logischen Tests mit UND-Anweisungen, etwa so:

Um sich einen Überblick zu verschaffen, sehen Sie sich bitte das folgende Beispiel an.

Angenommen, Sie möchten Ihre Dienstleistung auf der Grundlage der Versandkosten und der geschätzten Lieferzeit (ETD) bewerten:

• Ausgezeichnet : Versandkosten unter $20 und ETD unter 3 Tagen
• Schlecht : Versandkosten über $30 und ETD über 5 Tage
• Durchschnitt : alles was dazwischen liegt

Um dies zu erreichen, schreiben Sie zwei einzelne IF AND-Anweisungen:

IF(AND(B2<20, C2<3), "Ausgezeichnet", ...)

IF(AND(B2>30, C2>5), "Schlecht", ...)

...und ineinander verschachteln:

=IF(AND(B2<30, C2<5), "Schlecht", IF(AND(B2<20, C2<3), "Ausgezeichnet", "Durchschnitt"))

Das Ergebnis sieht in etwa so aus:

Weitere Beispiele für Formeln finden Sie in Excel verschachtelte IF AND-Anweisungen.

Groß- und Kleinschreibung beachtende IF AND-Funktion in Excel

Wie bereits zu Beginn dieses Tutorials erwähnt, unterscheiden Excel-WENN-UND-Formeln nicht zwischen Groß- und Kleinbuchstaben, da die UND-Funktion von Natur aus nicht zwischen Groß- und Kleinschreibung unterscheidet.

Wenn Sie arbeiten mit Groß- und Kleinschreibung Daten haben und AND-Bedingungen unter Berücksichtigung der Groß- und Kleinschreibung auswerten wollen, führen Sie jeden einzelnen logischen Test innerhalb der EXACT-Funktion durch und verschachteln diese Funktionen in Ihre AND-Anweisung:

In diesem Beispiel werden wir die Bestellungen eines bestimmten Kunden (z.B. die Firma namens Cyberspace ) mit einem Betrag, der eine bestimmte Zahl übersteigt, z. B. 100 $.

Wie Sie auf dem folgenden Screenshot sehen können, sehen einige Firmennamen in Spalte B gleich aus, obwohl es sich um verschiedene Firmen handelt, so dass wir die Namen überprüfen müssen genau Die Beträge in Spalte C sind Zahlen, für die wir einen normalen "größer als"-Test durchführen:

=IF(AND(EXACT(B2, "Cyberspace"), C2>100), "x", "")

Um die Formel flexibler zu gestalten, können Sie den Namen des Zielkunden und den Betrag in zwei separate Zellen eingeben und auf diese Zellen verweisen. Denken Sie nur daran, die Zellverweise mit dem $-Zeichen zu sperren (in unserem Fall $G$1 und $G$2), damit sie sich nicht ändern, wenn Sie die Formel in andere Zeilen kopieren:

=IF(AND(EXACT(B2, $G$1), C2>$G$2), "x", "")

Nun können Sie einen beliebigen Namen und Betrag in die referenzierten Zellen eingeben, und die Formel markiert die entsprechenden Aufträge in Ihrer Tabelle:

IF OR AND-Formel in Excel

In den WENN-Formeln von Excel sind Sie nicht auf die Verwendung einer einzigen logischen Funktion beschränkt. Um verschiedene Kombinationen mehrerer Bedingungen zu prüfen, können Sie die WENN-, UND-, ODER- und andere Funktionen kombinieren, um die erforderlichen logischen Tests durchzuführen. Hier ist ein Beispiel für eine WENN- UND ODER-Formel, die mehrere ODER-Bedingungen innerhalb von UND prüft. Und nun zeige ich Ihnen, wie Sie zwei oder mehr UND-Tests innerhalb von ODER durchführen könnenFunktion.

Angenommen, Sie möchten die Bestellungen von zwei Kunden mit einem Betrag größer als eine bestimmte Zahl, z. B. 100 $, kennzeichnen.

In der Excel-Sprache werden unsere Bedingungen auf diese Weise ausgedrückt:

OR(AND( Kunde1 , Betrag >100), AND( Kunde2 , Betrag >100)

Angenommen, die Kundennamen stehen in Spalte B, die Beträge in Spalte C, die beiden Zielnamen stehen in G1 und G2 und der Zielbetrag in G3, dann verwenden Sie diese Formel, um die entsprechenden Aufträge mit "x" zu markieren:

=IF(OR(AND(B2=$G$1, C2>$G$3), AND(B2=$G$2, C2>$G$3)), "x", "")

Die gleichen Ergebnisse können mit einer kompakteren Syntax erzielt werden:

=IF(AND(OR(B2=$G$1,B2= $G$2), C2>$G$3), "x", "")

Wenn Sie die Logik der Formel nicht ganz verstanden haben, finden Sie weitere Informationen in Excel IF with multiple AND/OR conditions.

So verwenden Sie die Funktionen WENN und UND zusammen in Excel. Vielen Dank für die Lektüre und bis nächste Woche!

Arbeitsbuch für die Praxis

IF AND Excel - Formelbeispiele (.xlsx Datei)