Təlimat bir düsturda çoxlu şərtləri yoxlamaq üçün IF-dən AND funksiyası ilə birlikdə Excel-də necə istifadə olunacağını göstərir.

Dünyada bəzi şeylər məhduddur. Digərləri sonsuzdur və IF funksiyası belə şeylərdən biri kimi görünür. Bloqumuzda artıq bir neçə Excel IF dərsliyi var və hələ də hər gün yeni istifadələr kəşf edirik. Bu gün biz eyni zamanda iki və ya daha çox şərti qiymətləndirmək üçün AND funksiyası ilə birlikdə IF-dən necə istifadə edə biləcəyinizi nəzərdən keçirəcəyik.

Excel-də IF AND ifadəsi

ƏGƏR VƏ ifadəsini qurmaq üçün siz açıq-aydın IF və AND funksiyalarını bir düsturda birləşdirməlisiniz. Budur:

Adi ingilis dilinə tərcümə olunub, düstur aşağıdakı kimi oxunur: ƏGƏR şərt 1 doğrudur VƏ şərt 2 doğrudur, bir şeyi edin, əks halda başqa bir şey edin.

Nümunə olaraq, B2-nin "çatdırıldığını" və C2-nin boş olmadığını yoxlayan və nəticələrdən asılı olaraq bir düstur yaradaq. , aşağıdakılardan birini yerinə yetirir:

• Hər iki şərt DOĞRU olarsa, sıranı "Qapalı" kimi qeyd edin.
• Əgər hər iki şərt YANLIŞ və ya hər ikisi YANLIŞdırsa, boş qaytarın string ("").

=IF(AND(B2="delivered", C2""), "Closed", "")

Aşağıdakı ekran görüntüsü Excel-də IF AND funksiyasını göstərir:

Əgər siz 'məntiqi testin YANLIŞ olaraq qiymətləndirilməsi halında bəzi dəyəri qaytarmaq istərdim, bu dəyəri value_if_false -də təqdim edinarqument. Məsələn:

=IF(AND(B2="delivered", C2""), "Closed", "Open")

Dəyişdirilmiş düstur B sütunu "çatdırılıbsa" və C-də hər hansı bir tarix varsa (boş deyilsə) "Qapalı" verir. Bütün digər hallarda, o, "Açıq" qaytarır:

Qeyd. Mətn şərtlərini qiymətləndirmək üçün Excel-də ƏGƏR VƏ düsturundan istifadə edərkən, kiçik və böyük hərflərin eyni simvol kimi qəbul edildiyini unutmayın. Əgər siz hərflərə həssas ƏGƏR VƏ düsturu axtarırsınızsa, bir və ya bir neçə AND arqumentini əlaqəli nümunədə olduğu kimi DƏMƏK funksiyasına sarın.

İndi siz Excel ƏGƏR VƏ ifadəsinin sintaksisini bildiyiniz üçün icazə verin, sizə onun hansı tapşırıqları həll edə biləcəyini göstərim.

Excel IF: böyük VƏ kiçik

İşdə əvvəlki misalda iki fərqli hüceyrədə iki şərti sınaqdan keçirirdik. Ancaq bəzən eyni hüceyrədə iki və ya daha çox test keçirməli ola bilərsiniz. Tipik bir nümunə, hüceyrə dəyərinin iki ədəd arasında olub olmadığını yoxlamaqdır. Excel IF AND funksiyası da bunu asanlıqla edə bilər!

Təsəvvür edək ki, B sütununda bəzi satış nömrələriniz var və sizdən $50-dən çox, lakin $100-dan az olan məbləğləri qeyd etməyiniz xahiş olunur. Bunu etmək üçün bu düsturu C2-yə daxil edin və sonra onu sütunun aşağısına köçürün:

=IF(AND(B2>50, B2<100), "x", "")

Əgər sərhədi daxil etmək lazımdırsa dəyərləri (50 və 100), kiçik və ya bərabər operatorundan (<=) və böyük və ya ona bərabər (>=) operatorundan istifadə edin:

=IF(AND(B2>=50, B2<=100), "x", "")

Başqasını emal etmək üçündüsturu dəyişmədən sərhəd dəyərləri üçün minimum və maksimum ədədləri iki ayrı xanaya daxil edin və düsturunuzda həmin xanalara müraciət edin. Düsturun bütün sətirlərdə düzgün işləməsi üçün sərhəd xanaları üçün mütləq istinadlardan istifadə etdiyinizə əmin olun (bizim halda $F$1 və $F$2):

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Oxşar düsturdan istifadə etməklə, siz tarixin -ün müəyyən edilmiş diapazona düşdüyünü yoxlaya bilərsiniz.

Məsələn, tarixləri 10 arasında qeyd edək. -Sentyabr 2018 və 30 Sentyabr 2018 daxil olmaqla. Kiçik bir maneə odur ki, tarixlər birbaşa məntiqi testlərə verilə bilməz. Excel-in tarixləri başa düşməsi üçün onlar TARİXVALUE funksiyasına əlavə edilməlidir, məsələn:

=IF(AND(B2>=DATEVALUE("9/10/2018"), B2<=DATEVALUE("9/30/2018")), "x", "")

Və ya sadəcə olaraq From və To<2 daxil edin> iki xanadakı tarixləri (bu nümunədə $F$1 və $F$2) daxil edin və artıq tanış IF AND düsturundan istifadə edərək onları həmin xanalardan "çəkin":

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Ətraflı məlumat üçün lütfən, iki rəqəm və ya tarix arasındakı Excel IF ifadəsinə baxın.

Əgər bu VƏ belədirsə, onda bir şey hesablayın

Öncədən təyin edilmiş dəyərləri qaytarmaqdan başqa, Excel IF AND funksiyası həmçinin göstərilən şərtlərin DOĞRU və ya YANLIŞ olmasından asılı olaraq müxtəlif hesablamalar həyata keçirə bilər.

Yanışmanı nümayiş etdirmək üçün biz məbləğdən çox və ya ona bərabər olan "Qapalı" satışlar üçün 5% bonus hesablayacağıq. $100-ə qədər.

Məbləğin B sütununda və sifariş statusunun C sütununda olduğunu fərz etsək,düstur aşağıdakı kimidir:

=IF(AND(B2>=100, C2="closed"), B2*10%, 0)

Yuxarıdakı düstur qalan sifarişlərə sıfır təyin edir ( value_if_false = 0) . Şərtlərə cavab verməyən sifarişlərə kiçik stimullaşdırıcı bonus, məsələn, 3% vermək istəyirsinizsə, müvafiq tənliyi value_if_false arqumentinə daxil edin:

=IF(AND(B2>=100, C2="closed"), B2*10%, B2*3%)

Excel-də çoxlu ƏGƏR VƏ ifadələri

Baxdığınız kimi, biz yuxarıda göstərilən bütün nümunələrdə yalnız iki meyarı qiymətləndirmişik. Lakin Excel-in bu ümumi məhdudiyyətlərinə uyğun olduğu müddətcə İF VƏ düsturlarınıza üç və ya daha çox testi daxil etməyə heç nə mane ola bilməz:

• Excel 2007 və daha yüksək versiyalarda 255-ə qədər arqument düsturun ümumi uzunluğu 8192 simvoldan çox olmayan düsturda istifadə edilə bilər.
• Excel 2003 və daha aşağı versiyalarda ümumi uzunluğu 1024 simvoldan çox olmayan 30-dan çox arqumentə icazə verilmir.
• 5>

  Birdən çox VƏ şərtlərinə misal olaraq bunları nəzərdən keçirin:

  • Məbləğ (B2) 100$-dan çox və ya ona bərabər olmalıdır
  • Sifariş statusu (C2) "Bağlıdır"
  • Çatdırılma tarixi (D2) cari ay ərzindədir

  İndi bizə hər 3 şərtin DOĞRU olan sifarişləri müəyyən etmək üçün ƏGƏR VƏ ifadəsinə ehtiyacımız var. Və budur:

  =IF(AND(B2>=100, C2="Closed", MONTH(D2)=MONTH(TODAY())), "x", "")

  Yazılan anda 'cari ay' oktyabr olduğunu nəzərə alsaq, formula aşağıdakı nəticələri verir:

  

  ƏGƏR VƏ OLARAQ iç içəbəyanatlar

  Böyük iş vərəqləri ilə işləyərkən, sizdən eyni anda bir neçə fərqli VƏ meyar dəstini yoxlamaq tələb oluna bilər. Bunun üçün siz klassik Excel daxili IF düsturunu götürürsünüz və onun məntiqi testlərini VƏ ifadələri ilə genişləndirirsiniz, məsələn:

  IF(AND(…), output1 , IF(AND(…), output2 , IF(AND(…), output3 , output4 )))

  Ümumi fikir əldə etmək üçün lütfən, aşağıdakı nümunəyə baxın.

  Fərz edək ki, siz göndərmə dəyərinə və təxmini çatdırılma vaxtına (ETD) əsasən xidmətinizi qiymətləndirmək istəyirsiniz:

  • Əla : daşınma dəyəri $20 və ETD 3 gündən azdır
  • Zəif : daşınma qiyməti 30$-dan yuxarı və 5 gün ərzində ETD
  • Orta : arasında hər şey

  bunu tamamlayın, siz iki fərdi ƏGƏR VƏ ifadəsini yazın:

  IF(AND(B2<20, C2<3), "Excellent", …)

  IF(AND(B2>30, C2>5), "Poor", …)

  ...və birini digərinə yerləşdirin:

  =IF(AND(B2>30, C2>5), "Poor", IF(AND(B2<20, C2<3), "Excellent", "Average"))

  Nəticə buna bənzəyəcək:

  

  Daha çox düstur nümunələri Excel daxili IF AND ifadələrində tapıla bilər.

  Hərf hərfinə həssas IF AND Excel-də funksiya

  Bu dərsliyin əvvəlində qeyd edildiyi kimi, Excel IF VƏ düsturları böyük və kiçik hərflər arasında fərq qoymur çünki AND funksiyası təbiətcə böyük hərflərə həssasdır.

  Əgər siz həssas verilənlərlə işləyirsinizsə və mətn registrini nəzərə alaraq VƏ şərtlərini qiymətləndirmək istəyirsinizsə, hər bir fərdi məntiqi testi yerinə yetirin. EXACT funksiyası və yuvası daxilindəbu funksiyaları AND ifadənizdə yerləşdirin:

  IF(VƏ(EXACT( xana ," şərt1 "), EXACT( xana ," şərt2 ")), dəyər_əgər_doğru, dəyər_əgər_yanlış)

  Bu misal üçün biz konkret müştərinin (məsələn, Cyberspace adlı şirkətin) məbləği müəyyən rəqəmi aşan sifarişlərini qeyd edəcəyik. $100.

  Aşağıdakı skrinşotda gördüyünüz kimi, B sütununda bəzi şirkət adları simvolların hərfindən eyni çıxarış kimi görünür və buna baxmayaraq, onlar fərqli şirkətlərdir, ona görə də biz adları dəqiq olaraq yoxlamalıyıq . C sütunundakı məbləğlər rəqəmlərdir və biz onlar üçün müntəzəm olaraq "böyük" testi keçiririk:

  =IF(AND(EXACT(B2, "Cyberspace"), C2>100), "x", "")

  Düsulu daha çevik etmək üçün siz hədəf müştəri adını və məbləği daxil edə bilərsiniz. iki ayrı hüceyrədə və həmin hüceyrələrə istinad edin. Yalnız xana istinadlarını $ işarəsi ilə (bizim halda $G$1 və $G$2) kilidləməyi unutmayın ki, formulanı digər sətirlərə köçürəndə onlar dəyişməsin:

  =IF(AND(EXACT(B2, $G$1), C2>$G$2), "x", "")

  İndi siz istinad edilən xanalara istənilən ad və məbləği daxil edə bilərsiniz və düstur cədvəlinizdə müvafiq sıraları işarələyəcək:

  

  Excel-də ƏGƏR OR AND düsturu

  Excel IF düsturlarında siz yalnız bir məntiqi funksiyadan istifadə etməklə məhdudlaşmırsınız. Çoxsaylı şərtlərin müxtəlif kombinasiyalarını yoxlamaq üçün tələb olunan məntiqi testləri yerinə yetirmək üçün IF, AND, OR və digər funksiyaları birləşdirə bilərsiniz. Burada bir neçə sınayan IF AND OR formula nümunəsidirVƏ ya AND daxilində şərtlər. İndi isə mən sizə OR funksiyası daxilində iki və ya daha çox AND testini necə edə biləcəyinizi göstərəcəyəm.

  Fərz edək ki, siz iki müştərinin sifarişlərini müəyyən sayda, məsələn, 100 dollardan çox məbləğlə qeyd etmək istəyirsiniz.

  Excel dilində şərtlərimiz bu şəkildə ifadə edilir:

  OR(AND( Customer1 , Amount >100), AND( Customer2 , Amount >100)

  Müştəri adlarının B sütununda, məbləğlərin C sütununda, 2 hədəf adı olduğunu fərz etsək G1 və G2-də və hədəf məbləğ G3-dədir, siz müvafiq sifarişləri "x" ilə qeyd etmək üçün bu düsturdan istifadə edirsiniz:

  =IF(OR(AND(B2=$G$1, C2>$G$3), AND(B2=$G$2, C2>$G$3)), "x", "")

  Eyni nəticələr daha çox istifadə etməklə əldə edilə bilər. yığcam sintaksis:

  =IF(AND(OR(B2=$G$1,B2= $G$2), C2>$G$3), "x", "")

  

  Düsturun məntiqini tam başa düşdüyünüzə əmin deyilsiniz? Ətraflı məlumatı çoxlu VƏ/VƏ ya şərtləri olan Excel IF-də tapa bilərsiniz.

  Siz Excel-də ƏGƏR və VƏ funksiyalarından belə istifadə edirsiniz. Oxuduğunuz üçün təşəkkür edirik və gələn həftə görüşərik!

  İş dəftərini məşq edin

  IF VƏ Excel – düstur nümunələri (.xlsx faylı)