Ուսուցումը ցույց է տալիս, թե ինչպես օգտագործել IF-ը Excel-ում AND ֆունկցիայի հետ միասին՝ մեկ բանաձևով մի քանի պայմաններ ստուգելու համար:

Աշխարհում որոշ բաներ վերջավոր են: Մյուսները անսահման են, և IF ֆունկցիան կարծես այդպիսի բաներից մեկն է: Մեր բլոգում մենք արդեն ունենք մի քանի Excel IF ձեռնարկներ և դեռևս ամեն օր բացահայտում ենք նոր կիրառումներ: Այսօր մենք պատրաստվում ենք տեսնել, թե ինչպես կարող եք օգտագործել IF-ը AND ֆունկցիայի հետ միասին՝ միաժամանակ երկու կամ ավելի պայմաններ գնահատելու համար:

IF AND հայտարարությունը Excel-ում

ԵԹԵ ԵՎ հայտարարությունը կառուցելու համար ակնհայտորեն պետք է միավորել IF և AND ֆունկցիաները մեկ բանաձևում: Ահա թե ինչպես.

Թարգմանված պարզ անգլերենի, բանաձևը հետևյալն է. ԵԹԵ պայման 1 ճշմարիտ է ԵՎ 2-րդ պայմանը ճշմարիտ է, արեք մի բան, հակառակ դեպքում արեք այլ բան:

Որպես օրինակ կազմենք մի բանաձև, որը ստուգում է, արդյոք B2-ը «առաքվում է», իսկ C2-ը դատարկ չէ, և կախված արդյունքներից. , կատարում է հետևյալներից մեկը.

• Եթե երկու պայմաններն էլ ճշմարիտ են, ապա նշեք կարգը որպես «Փակ»:
• Եթե որևէ պայման FALSE է կամ երկուսն էլ FALSE, ապա վերադարձրեք դատարկը: տող (""):

=IF(AND(B2="delivered", C2""), "Closed", "")

Սքրինշոթը ստորև ցույց է տալիս IF AND ֆունկցիան Excel-ում.

Եթե դուք «Կցանկանայի վերադարձնել որոշ արժեք, եթե տրամաբանական թեստը գնահատվի FALSE, այդ արժեքը տրամադրեք value_if_false փաստարկ. Օրինակ՝

=IF(AND(B2="delivered", C2""), "Closed", "Open")

Փոփոխված բանաձևը թողարկում է «Փակ», եթե B սյունակը «առաքվում է», իսկ C-ն ունի որևէ ամսաթիվ (ոչ դատարկ): Մնացած բոլոր դեպքերում այն ​​վերադարձնում է «Open»:

Նշում. Տեքստի պայմանները գնահատելու համար Excel-ում ԵԹԵ ԵՎ բանաձև օգտագործելիս, խնդրում ենք նկատի ունենալ, որ փոքրատառերն ու մեծատառերը համարվում են նույն նիշը: Եթե ​​փնտրում եք մեծատառերի զգայուն ԵԹԵ ԵՎ բանաձև, ապա փաթեթավորեք AND-ի մեկ կամ մի քանի արգումենտ EXACT ֆունկցիայի մեջ, ինչպես դա արվում է կապված օրինակում:

Այժմ, երբ դուք գիտեք Excel IF AND հայտարարության շարահյուսությունը, թույլ տվեք ցույց տալ ձեզ, թե ինչպիսի խնդիրներ կարող է լուծել այն:

Excel IF. Նախորդ օրինակը, մենք փորձարկում էինք երկու պայման երկու տարբեր բջիջներում: Բայց երբեմն ձեզ կարող է անհրաժեշտ լինել նույն խցում երկու կամ ավելի թեստ անցկացնել: Տիպիկ օրինակ է ստուգել, ​​թե արդյոք բջիջի արժեքը երկու թվերի միջև է : Excel IF AND ֆունկցիան նույնպես կարող է հեշտությամբ դա անել:

Ենթադրենք, դուք ունեք վաճառքի որոշ թվեր սյունակ B-ում, և ձեզնից խնդրում են նշել 50 դոլարից ավելի, բայց 100 դոլարից պակաս գումարները: Դա անելու համար տեղադրեք այս բանաձևը C2-ում և այնուհետև պատճենեք այն սյունակում.

=IF(AND(B2>50, B2<100), "x", "")

Եթե Ձեզ անհրաժեշտ է ներառել սահմանը: արժեքներ (50 և 100), օգտագործեք փոքր կամ հավասար օպերատորը (<=) և մեծ կամ հավասար (>=) օպերատորը.

=IF(AND(B2>=50, B2<=100), "x", "")

Մի այլ բան մշակելու համարսահմանային արժեքները՝ առանց բանաձևը փոխելու, մուտքագրեք նվազագույն և առավելագույն թվերը երկու առանձին բջիջներում և նշեք ձեր բանաձևի այդ բջիջները: Որպեսզի բանաձևը ճիշտ աշխատի բոլոր տողերում, համոզվեք, որ օգտագործեք բացարձակ հղումներ սահմանային բջիջների համար ($F$1 և $F$2 մեր դեպքում):

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Օգտագործելով նմանատիպ բանաձև՝ կարող եք ստուգել, ​​թե արդյոք ամսաթիվը ընկնում է նշված տիրույթում ։

Օրինակ, եկեք նշենք ամսաթվերը 10-ի միջև։ -Սեպ-2018 և 30-Սեպ-2018 ներառյալ: Փոքր խոչընդոտն այն է, որ ամսաթվերը չեն կարող ուղղակիորեն տրամադրվել տրամաբանական թեստերին: Որպեսզի Excel-ը հասկանա ամսաթվերը, դրանք պետք է կցվեն DATEVALUE ֆունկցիայի մեջ, այսպես.

=IF(AND(B2>=DATEVALUE("9/10/2018"), B2<=DATEVALUE("9/30/2018")), "x", "")

Կամ պարզապես մուտքագրեք From և To<2:> ամսաթվերը երկու բջիջներում ($F$1 և $F$2 այս օրինակում) և «քաշեք» դրանք այդ բջիջներից` օգտագործելով արդեն ծանոթ ԵԹԵ ԵՎ բանաձևը.

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Լրացուցիչ տեղեկությունների համար տե՛ս Excel IF հայտարարությունը երկու թվերի կամ ամսաթվերի միջև:

Եթե սա ԵՎ այն, ապա հաշվարկեք ինչ-որ բան

Բացի նախապես սահմանված արժեքները վերադարձնելուց, Excel IF-ը AND ֆունկցիան կարող է նաև կատարել տարբեր հաշվարկներ՝ կախված նշված պայմանների ճշմարիտ կամ սխալ լինելուց:

Մոտեցումը ցույց տալու համար մենք կհաշվարկենք 5% բոնուս «Փակ» վաճառքի համար՝ մեծ կամ հավասար գումարով: մինչև $100:

Ենթադրելով, որ գումարը գտնվում է B սյունակում, իսկ պատվերի կարգավիճակը՝ C սյունակում,բանաձևը հետևյալն է.

=IF(AND(B2>=100, C2="closed"), B2*10%, 0)

Վերոնշյալ բանաձևը զրո է վերագրում մնացած պատվերներին ( value_if_false = 0) . Եթե ​​դուք ցանկանում եք տալ փոքր խթանող բոնուս, ասենք 3%, այն պատվերներին, որոնք չեն համապատասխանում պայմաններին, ներառեք համապատասխան հավասարումը value_if_false արգումենտում՝

=IF(AND(B2>=100, C2="closed"), B2*10%, B2*3%)

Բազմաթիվ IF AND հայտարարություններ Excel-ում

Ինչպես նկատեցիք, վերը նշված բոլոր օրինակներում մենք գնահատել ենք միայն երկու չափանիշ: Բայց չկա ոչինչ, որը կխանգարի ձեզ երեք և ավելի թեստեր ներառել ձեր ԵԹԵ ԵՎ բանաձևերում, քանի դեռ դրանք համապատասխանում են Excel-ի այս ընդհանուր սահմանափակումներին. կարող է օգտագործվել 8192 նիշից չգերազանցող բանաձևով բանաձևի մեջ:

Որպես բազմաթիվ AND պայմանների օրինակ՝ խնդրում ենք հաշվի առնել հետևյալը.

• Գումարը (B2) պետք է լինի $100-ից մեծ կամ հավասար
• Պատվերի կարգավիճակը (C2) «Փակ է»
• Առաքման ամսաթիվը (D2) ընթացիկ ամսվա ընթացքում է

Այժմ մեզ անհրաժեշտ է ԵԹԵ ԵՎ հայտարարություն՝ պարզելու այն պատվերները, որոնց համար բոլոր 3 պայմանները ՃՇՄԱՐՏ են: Եվ ահա.

=IF(AND(B2>=100, C2="Closed", MONTH(D2)=MONTH(TODAY())), "x", "")

Հաշվի առնելով, որ «ընթացիկ ամիսը» գրելու պահին հոկտեմբերն էր, բանաձևը տալիս է հետևյալ արդյունքները.

Ներդրված ԵԹԵ ԵՎհայտարարություններ

Մեծ աշխատաթերթերի հետ աշխատելիս, հավանական է, որ ձեզանից պահանջվի միաժամանակ ստուգել տարբեր ԵՎ չափանիշների մի քանի հավաքածու: Դրա համար դուք վերցնում եք դասական Excel-ի մեջ տեղադրված IF բանաձևը և ընդլայնում դրա տրամաբանական թեստերը AND հայտարարություններով, այսպես՝

Ընդհանուր պատկերացում կազմելու համար խնդրում ենք դիտել հետևյալ օրինակը:

Ենթադրենք, որ ցանկանում եք գնահատել ձեր ծառայությունը` հիմնվելով առաքման արժեքի և առաքման գնահատված ժամանակի վրա (ETD).

• Գերազանց . առաքման արժեքը $20-ից ցածր և ETD-ն` մինչև 3 օր:
• Վատ . առաքման արժեքը գերազանցում է $30-ը և ETD-ն 5 օրվա ընթացքում
• Միջին . ամեն ինչ միջև

մինչև ավարտեք այն, դուք գրում եք երկու առանձին IF AND հայտարարություն՝

IF(AND(B2<20, C2<3), "Excellent", …)

IF(AND(B2>30, C2>5), "Poor", …)

…և տեղադրեք մեկը մյուսի մեջ՝

=IF(AND(B2>30, C2>5), "Poor", IF(AND(B2<20, C2<3), "Excellent", "Average"))

Արդյունքը նման կլինի հետևյալին.

Ավելի շատ բանաձևերի օրինակներ կարելի է գտնել Excel-ի մեջ տեղադրված IF AND հայտարարություններում:

Փորձերի զգայուն IF AND ֆունկցիա Excel-ում

Ինչպես նշվեց այս ձեռնարկի սկզբում, Excel IF AND բանաձևերը չեն տարբերում մեծատառ և փոքրատառ նիշերը քանի որ AND ֆունկցիան իր բնույթով մեծատառերի նկատմամբ զգայուն չէ:

Եթե դուք աշխատում եք գործերի զգայուն տվյալների հետ և ցանկանում եք գնահատել AND պայմանները` հաշվի առնելով տեքստի տառերը, կատարեք յուրաքանչյուր առանձին տրամաբանական թեստ: EXACT ֆունկցիայի և բույնի ներսումայդ գործառույթները ձեր AND հայտարարության մեջ.

Այս օրինակի համար մենք պատրաստվում ենք նշել որոշակի հաճախորդի պատվերները (օրինակ՝ Կիբերտարածություն անունով ընկերության) որոշակի քանակից ավելի մեծ գումարով, ասենք. $100:

Ինչպես կարող եք տեսնել ստորև ներկայացված սքրինշոթում, B սյունակում որոշ ընկերությունների անունները նույն տեսքն ունեն, և, այնուամենայնիվ, դրանք տարբեր ընկերություններ են, ուստի մենք պետք է ստուգենք անունները ճիշտ . Գ սյունակի գումարները թվեր են, և մենք դրանց համար սովորական «ավելի մեծ» թեստ ենք անցկացնում.

=IF(AND(EXACT(B2, "Cyberspace"), C2>100), "x", "")

Բանաձևն ավելի ճկուն դարձնելու համար կարող եք մուտքագրել թիրախային հաճախորդի անունը և գումարը: երկու առանձին բջիջներում և վերաբերում են այդ բջիջներին: Պարզապես հիշեք, որ բջջային հղումները կողպեք $ նշանով ($G$1 և $G$2 մեր դեպքում), որպեսզի դրանք չփոխվեն, երբ դուք պատճենեք բանաձևը այլ տողերում.

=IF(AND(EXACT(B2, $G$1), C2>$G$2), "x", "")

Այժմ դուք կարող եք մուտքագրել ցանկացած անուն և գումար նշված բջիջներում, և բանաձևը ձեր աղյուսակում կնշի համապատասխան պատվերները.

Excel IF բանաձեւերում դուք չեք սահմանափակվում միայն մեկ տրամաբանական ֆունկցիայի օգտագործմամբ: Բազմաթիվ պայմանների տարբեր համակցություններ ստուգելու համար դուք ազատ եք համատեղել ԵԹԵ, ԵՎ, ԿԱՄ և այլ գործառույթները՝ պահանջվող տրամաբանական թեստերն իրականացնելու համար: Ահա ԵԹԵ ԵՎ ԿԱՄ բանաձևի օրինակ, որը ստուգում է մի քանի բանԿԱՄ պայմանները AND-ի շրջանակներում: Եվ հիմա ես ձեզ ցույց կտամ, թե ինչպես կարող եք կատարել երկու կամ ավելի AND թեստեր OR ֆունկցիայի շրջանակներում:

Ենթադրենք, որ ցանկանում եք նշել երկու հաճախորդների պատվերները որոշակի թվից ավելի մեծ գումարով, ասենք $100:

Excel լեզվում մեր պայմաններն արտահայտվում են այսպես.

OR(AND( Customer1 , Amount >100), AND( Customer2 , Amount >100)

Ենթադրենք, որ հաճախորդների անունները գտնվում են B սյունակում, գումարները` սյունակում, 2 թիրախային անունները: գտնվում են G1-ում և G2-ում, իսկ նպատակային գումարը G3-ում է, դուք օգտագործում եք այս բանաձևը՝ համապատասխան պատվերները «x»-ով նշելու համար.

=IF(OR(AND(B2=$G$1, C2>$G$3), AND(B2=$G$2, C2>$G$3)), "x", "")

Նույն արդյունքները կարելի է ձեռք բերել ավելի շատ կոմպակտ շարահյուսություն.

=IF(AND(OR(B2=$G$1,B2= $G$2), C2>$G$3), "x", "")

Վստահ չե՞ք, որ լիովին հասկանում եք բանաձևի տրամաբանությունը: Լրացուցիչ տեղեկություններ կարելի է գտնել Excel IF-ում մի քանի AND/OR պայմաններով:

Այսպես եք օգտագործում IF և AND գործառույթները միասին Excel-ում: Շնորհակալություն կարդալու համար և կհանդիպենք հաջորդ շաբաթ:

Զբաղվեք աշխատանքային գրքույկով

IF AND Excel – բանաձեւերի օրինակներ (.xlsx ֆայլ)