Šajā pamācībā ir parādīts, kā programmā Excel izmantot IF kopā ar funkciju AND, lai vienā formulā pārbaudītu vairākus nosacījumus.

Dažas lietas pasaulē ir galīgas, citas - bezgalīgas, un šķiet, ka funkcija IF ir viena no šādām lietām. Mūsu emuārā jau ir izstrādātas vairākas Excel IF pamācības, un mēs katru dienu atklājam jaunus izmantošanas veidus. Šodien mēs aplūkosim, kā var izmantot IF kopā ar funkciju AND, lai vienlaicīgi novērtētu divus vai vairākus nosacījumus.

IF AND paziņojums programmā Excel

Lai izveidotu IF AND paziņojumu, acīmredzot ir jāapvieno IF un AND funkcijas vienā formulā. Lūk, kā to izdarīt:

Tulkojot vienkāršā angļu valodā, formula skan šādi: JA 1. nosacījums ir patiess UN 2. nosacījums ir patiess, veiciet vienu darbību, pretējā gadījumā dariet kaut ko citu.

Piemēram, izveidosim formulu, kas pārbauda, vai B2 ir "piegādāts" un C2 nav tukšs, un atkarībā no rezultāta veic vienu no šīm darbībām:

• Ja abi nosacījumi ir TRUE, atzīmējiet pasūtījumu kā "Slēgts".
• Ja kāds no nosacījumiem ir FALSE vai abi ir FALSE, tiek atgriezta tukša virkne ("").

=IF(AND(B2="piegādāts", C2""), "Slēgts", "")

Tālāk redzamajā ekrānšāviņas attēlā ir parādīta funkcija IF AND programmā Excel:

Ja vēlaties atgriezt kādu vērtību gadījumā, ja loģiskais tests tiek novērtēts kā FALSE, norādiet šo vērtību vienumā value_if_false arguments. Piemēram:

=IF(AND(B2="piegādāts", C2"), "Slēgts", "Atvērts")

Modificētās formulas rezultāts ir "Slēgts", ja ailē B ir "piegādāts" un ailē C ir kāds datums (ne tukšs). Visos pārējos gadījumos formulas rezultāts ir "Atvērts":

Piezīme. Lietojot IF AND formulu programmā Excel, lai novērtētu teksta nosacījumus, paturiet prātā, ka mazie un lielie burti tiek uzskatīti par vienu un to pašu rakstzīmi. Ja meklējat IF AND formulu, kas nosaka mazos un lielos burtus, ietiniet vienu vai vairākus argumentus AND funkcijā EXACT, kā tas ir izdarīts saistītajā piemērā.

Tagad, kad jūs zināt Excel IF AND izteikuma sintaksi, ļaujiet man parādīt, kādus uzdevumus tas var atrisināt.

Excel IF: lielāks par un mazāks par

Iepriekšējā piemērā mēs pārbaudījām divus nosacījumus divās dažādās šūnās. Taču dažreiz var būt nepieciešams veikt divus vai vairākus testus vienā šūnā. Tipisks piemērs ir pārbaude, vai šūnas vērtība ir šāda. starp diviem skaitļiem . To var viegli izdarīt arī ar Excel IF AND funkciju!

Pieņemsim, ka B slejā ir daži pārdošanas skaitļi, un jums tiek prasīts atzīmēt summas, kas lielākas par 50 $, bet mazākas par 100 $. Lai to izdarītu, C2 slejā ievietojiet šo formulu un pēc tam to kopējiet uz leju:

=IF(AND(B2>50, B2<100), "x", "")

Ja jums ir jāiekļauj robežvērtības (50 un 100), izmantojiet mazāks vai vienāds ar operators (<=) un lielāks vai vienāds ar (>=) operators:

=IF(AND(B2>=50, B2<=100), "x", "")

Lai apstrādātu citas robežvērtības, nemainot formulu, ievadiet minimālo un maksimālo skaitli divās atsevišķās šūnās un formulā norādiet uz šīm šūnām. Lai formula pareizi darbotos visās rindās, pārliecinieties, ka robežšūnām (mūsu gadījumā $F$1 un $F$2) tiek izmantotas absolūtās atsauces:

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Izmantojot līdzīgu formulu, varat pārbaudīt, vai datums krīt noteiktā diapazonā .

Piemēram, atzīmēsim datumus no 2018. gada 10. septembra līdz 2018. gada 30. septembrim ieskaitot. Neliels šķērslis ir tas, ka datumus nevar tieši ievadīt loģiskajiem testiem. Lai Excel saprastu datumus, tie jāiekļauj funkcijā DATEVALUE, piemēram, šādi:

=IF(AND(B2>=DATEVALUE("9/10/2018"), B2<=DATEVALUE("9/30/2018")), "x", "")

Vai vienkārši ievadiet No un Uz datumus divās šūnās (šajā piemērā $F$1 un $F$2) un "izvelciet" tos no šīm šūnām, izmantojot jau pazīstamo IF AND formulu:

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Lai iegūtu vairāk informācijas, lūdzu, skatiet Excel IF izteikumu starp diviem skaitļiem vai datumiem.

Ja tas un tas, tad aprēķiniet kaut ko

Papildus iepriekš noteiktu vērtību atdošanai Excel IF AND funkcija var arī veikt dažādus aprēķinus atkarībā no tā, vai norādītie nosacījumi ir TRUE vai FALSE.

Lai demonstrētu šo pieeju, mēs aprēķināsim 5% bonusu par "slēgtajiem" pārdošanas darījumiem, kuru summa ir lielāka vai vienāda ar 100 $.

Pieņemot, ka summa ir B slejā un pasūtījuma statuss ir C slejā, formula ir šāda:

=IF(AND(B2>=100, C2="slēgts"), B2*10%, 0)

Saskaņā ar iepriekš minēto formulu pārējiem rīkojumiem tiek piešķirta nulle ( value_if_false = 0). Ja esat gatavs piešķirt nelielu stimulējošu prēmiju, piemēram, 3 %, pasūtījumiem, kas neatbilst nosacījumiem, iekļaujiet atbilstošo vienādojumu. value_if_false arguments:

=IF(AND(B2>=100, C2="slēgts"), B2*10%, B2*3%)

Vairāki IF AND paziņojumi programmā Excel

Kā jau, iespējams, pamanījāt, visos iepriekš minētajos piemēros mēs esam novērtējuši tikai divus kritērijus. Taču nekas neliedz jums savās IF AND formulās iekļaut trīs un vairāk testu, ja vien tie atbilst šiem vispārīgajiem Excel ierobežojumiem:

• Programmā Excel 2007 un jaunākās versijās formulā var izmantot līdz 255 argumentiem, un kopējais formulas garums nedrīkst pārsniegt 8 192 rakstzīmes.
• Programmā Excel 2003 un jaunākās versijās ir atļauts izmantot ne vairāk kā 30 argumentus, un to kopējais garums nedrīkst pārsniegt 1024 rakstzīmes.

Kā vairāku AND nosacījumu piemēru aplūkojiet šos:

• Summai (B2) jābūt lielākai vai vienādai ar 100 $.
• Pasūtījuma statuss (C2) ir "Slēgts".
• Piegādes datums (D2) ir kārtējā mēnesī.

Tagad mums ir nepieciešams IF AND paziņojums, lai noteiktu pasūtījumus, kuriem visi 3 nosacījumi ir TRUE. Un šeit tas ir:

=IF(AND(B2>=100, C2="Slēgts", MONTH(D2)=MONTH(TODAY())), "x", "")

Ņemot vērā, ka "kārtējais mēnesis" rakstīšanas brīdī bija oktobris, formula sniedz šādus rezultātus:

Iestrādāti IF AND apgalvojumi

Strādājot ar lielām darblapām, ir iespējams, ka vienlaikus būs jāpārbauda vairāki dažādu AND kritēriju komplekti. Šim nolūkam izmantojiet klasisko Excel ieliktu IF formulu un paplašiniet tās loģiskos testus ar AND paziņojumiem, piemēram, šādi:

Lai gūtu vispārēju priekšstatu, aplūkojiet šādu piemēru.

Pieņemsim, ka vēlaties novērtēt savu pakalpojumu, pamatojoties uz sūtījuma izmaksām un paredzamo piegādes laiku (ETD):

• Lielisks : sūtījuma izmaksas zem 20 $ un ETD līdz 3 dienām
• Slikts : sūtījuma izmaksas virs $30 un ETD ilgāk par 5 dienām
• Vidējais : jebkas starp šīm iespējām

Lai to paveiktu, uzrakstiet divus atsevišķus IF AND paziņojumus:

IF(AND(B2<20, C2<3), "Excellent", ...)

IF(AND(B2>30, C2>5), "Slikts", ...)

...un ievietot vienu otrā:

=IF(AND(B2>30, C2>5), "Slikts", IF(AND(B2<20, C2<3), "Lielisks", "Vidējs"))

Rezultāts būs līdzīgs šim:

Vairāk formulas piemēru var atrast Excel ievietotajos IF AND izteikumos.

Lietošanai lietos jutīga IF UN funkcija programmā Excel

Kā minēts šīs pamācības sākumā, Excel IF AND formulas nenošķir lielos un mazos burtus, jo AND funkcija pēc savas būtības nenošķir mazos un lielos burtus.

Ja strādājat ar lielo un mazo izmēru datus un vēlaties novērtēt AND nosacījumus, ņemot vērā teksta gadījumu, veiciet katru atsevišķu loģisko testu EXACT funkcijas iekšienē un ievietojiet šīs funkcijas savā AND izteikumā:

Šajā piemērā mēs atzīmēsim konkrēta klienta pasūtījumus (piem., uzņēmuma ar nosaukumu Kibertelpa ) ar summu, kas pārsniedz noteiktu skaitli, piemēram, $100.

Kā redzams zemāk redzamajā ekrānšāviņas attēlā, daži uzņēmumu nosaukumi B slejā izskatās vienādi ar rakstzīmju burtu izrakstu, tomēr tie ir dažādi uzņēmumi, tāpēc mums ir jāpārbauda nosaukumi. tieši C slejā norādītās summas ir skaitļi, un tām veicam parasto testu "lielāks par":

=IF(AND(EXACT(B2, "Cyberspace"), C2>100), "x", "")

Lai padarītu formulu elastīgāku, varat ievadīt mērķa klienta nosaukumu un summu divās atsevišķās šūnās un atsaukties uz šīm šūnām. Tikai atcerieties bloķēt šūnu atsauces ar $ zīmi (mūsu gadījumā $G$1 un $G$2), lai tās nemainītos, kopējot formulu uz citām rindām:

=IF(AND(EXACT(B2, $G$1), C2>$G$2), "x", "")

Tagad varat ievadīt jebkuru nosaukumu un summu šūnās, uz kurām ir atsauces, un formula atzīmēs atbilstošos pasūtījumus tabulā:

IF VAI UN formula programmā Excel

Excel IF formulās jūs neesat ierobežots, izmantojot tikai vienu loģisko funkciju. Lai pārbaudītu dažādas vairāku nosacījumu kombinācijas, varat brīvi kombinēt IF, AND, OR un citas funkcijas, lai veiktu vajadzīgos loģiskos testus. Šeit ir IF AND OR formulas piemērs, kas pārbauda dažus OR nosacījumus AND ietvaros. Un tagad es jums parādīšu, kā jūs varat veikt divus vai vairākus AND testus OR ietvaros.funkcija.

Pieņemsim, ka vēlaties atzīmēt divu klientu pasūtījumus ar summu, kas lielāka par noteiktu skaitli, piemēram, 100$.

Excel valodā mūsu nosacījumi tiek izteikti šādi:

VAI(UN( Klients1 , Summa >100), AND( Klients2 , Summa >100)

Pieņemot, ka klientu nosaukumi ir B slejā, summas - C slejā, 2 mērķa nosaukumi ir G1 un G2 slejā un mērķa summa ir G3 slejā, jūs izmantojat šo formulu, lai attiecīgos pasūtījumus atzīmētu ar "x":

=IF(OR(AND(B2=$G$1, C2>$G$3), AND(B2=$G$2, C2>$G$3)), "x", "")

Tādus pašus rezultātus var sasniegt ar kompaktāku sintaksi:

=IF(AND(OR(B2=$G$1,B2=$G$2), C2>$G$3), "x", "")

Neesat pārliecināts, ka pilnībā saprotat formulas loģiku? Vairāk informācijas var atrast sadaļā Excel IF ar vairākiem AND/OR nosacījumiem.

Lūk, kā Excel programmā kopā tiek izmantotas funkcijas IF un AND. Paldies, ka izlasījāt, un uz tikšanos nākamnedēļ!

Prakses darba burtnīca

IF UN Excel - formulu piemēri (.xlsx fails)