გაკვეთილი გვიჩვენებს, თუ როგორ გამოვიყენოთ IF AND ფუნქციასთან ერთად Excel-ში რამდენიმე პირობის შესამოწმებლად ერთ ფორმულაში.

ზოგიერთი რამ მსოფლიოში სასრულია. სხვები უსასრულოა და IF ფუნქცია ერთ-ერთი ასეთია. ჩვენს ბლოგზე, ჩვენ უკვე გვაქვს Excel IF-ის რამდენიმე გაკვეთილი და კვლავ აღმოვაჩენთ ახალ გამოყენებას ყოველდღე. დღეს ჩვენ განვიხილავთ, თუ როგორ შეგიძლიათ გამოიყენოთ IF AND ფუნქციასთან ერთად ორი ან მეტი პირობის ერთდროულად შესაფასებლად.

IF AND განცხადება Excel-ში

იმისთვის, რომ ააგოთ IF AND განცხადება, თქვენ აშკარად გჭირდებათ IF და AND ფუნქციების გაერთიანება ერთ ფორმულაში. აი, როგორ:

თარგმნილია უბრალო ინგლისურად, ფორმულა ასე იკითხება: IF პირობა 1 არის ჭეშმარიტი და პირობა 2 არის ჭეშმარიტი, გააკეთე ერთი რამ, თორემ სხვა რამ.

მაგალითად, შევქმნათ ფორმულა, რომელიც ამოწმებს, არის თუ არა B2 „მიწოდებული“ და C2 ცარიელი და ეს დამოკიდებულია შედეგებზე , აკეთებს ერთ-ერთ შემდეგს:

• თუ ორივე პირობა არის TRUE, მონიშნეთ ბრძანება როგორც "დახურული".
• თუ რომელიმე პირობა არის FALSE ან ორივე FALSE, მაშინ დააბრუნეთ ცარიელი string ("").

=IF(AND(B2="delivered", C2""), "Closed", "")

ქვემოთ სკრინშოტი აჩვენებს IF და ფუნქციას Excel-ში:

თუ თქვენ მინდა დააბრუნოს გარკვეული მნიშვნელობა იმ შემთხვევაში, თუ ლოგიკური ტესტი შეფასდება FALSE-ზე, მიაწოდეთ ეს მნიშვნელობა value_if_false არგუმენტი. მაგალითად:

=IF(AND(B2="delivered", C2""), "Closed", "Open")

შეცვლილი ფორმულა გამოაქვს "დახურულია", თუ სვეტი B არის "მიწოდებული" და C აქვს მასში რაიმე თარიღი (არა ცარიელი). ყველა სხვა შემთხვევაში, ის აბრუნებს "Open"-ს:

შენიშვნა. Excel-ში IF AND ფორმულის გამოყენებისას ტექსტის პირობების შესაფასებლად, გთხოვთ, გახსოვდეთ, რომ მცირე და დიდი რეგისტრი განიხილება, როგორც ერთი და იგივე სიმბოლო. თუ თქვენ ეძებთ IF AND ფორმულას, რომელიც მგრძნობიარეა რეგისტრის მიმართ, გადაიტანეთ AND-ის ერთი ან მეტი არგუმენტი EXACT ფუნქციაში, როგორც ეს კეთდება დაკავშირებულ მაგალითში.

ახლა, როცა იცით Excel IF AND-ის განცხადების სინტაქსი, ნება მიბოძეთ გაჩვენოთ, რა სახის ამოცანების გადაჭრა შეუძლია მას.

Excel IF: მეტი ვიდრე AND

წინა მაგალითი, ჩვენ ვამოწმებდით ორ მდგომარეობას ორ სხვადასხვა უჯრედში. მაგრამ ზოგჯერ შეიძლება დაგჭირდეთ ორი ან მეტი ტესტის ჩატარება ერთსა და იმავე უჯრედზე. ტიპიური მაგალითია იმის შემოწმება, არის თუ არა უჯრედის მნიშვნელობა ორ რიცხვს შორის . Excel IF AND ფუნქციასაც ადვილად შეუძლია ამის გაკეთება!

ვთქვათ, რომ თქვენ გაქვთ გაყიდვების ნომრები B სვეტში და მოგეთხოვებათ მონიშნოთ 50$-ზე მეტი, მაგრამ 100$-ზე ნაკლები თანხები. ამის შესასრულებლად, ჩადეთ ეს ფორმულა C2-ში და შემდეგ დააკოპირეთ იგი სვეტში:

=IF(AND(B2>50, B2<100), "x", "")

თუ გჭირდებათ საზღვრის ჩასმა მნიშვნელობები (50 და 100), გამოიყენეთ მცირე ან ტოლი ოპერატორი (<=) და უმეტეს ან ტოლია (>=) ოპერატორი:

=IF(AND(B2>=50, B2<=100), "x", "")

სხვა დასამუშავებლადსასაზღვრო მნიშვნელობები ფორმულის შეცვლის გარეშე, შეიყვანეთ მინიმალური და მაქსიმალური რიცხვები ორ ცალკეულ უჯრედში და მიუთითეთ ეს უჯრედები თქვენს ფორმულაში. იმისათვის, რომ ფორმულა სწორად იმუშაოს ყველა მწკრივში, დარწმუნდით, რომ გამოიყენეთ აბსოლუტური მითითებები სასაზღვრო უჯრედებისთვის ($F$1 და $F$2 ჩვენს შემთხვევაში):

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

მსგავსი ფორმულის გამოყენებით შეგიძლიათ შეამოწმოთ, თუ თარიღი ეცემა მითითებულ დიაპაზონში .

მაგალითად, მონიშნეთ თარიღები 10 შორის. -სექ-2018 და 30-სექ-2018 ჩათვლით. მცირე დაბრკოლება ის არის, რომ თარიღები არ შეიძლება მიეწოდოს უშუალოდ ლოგიკურ ტესტებს. იმისათვის, რომ Excel-მა გაიგოს თარიღები, ისინი უნდა იყოს ჩასმული DATEVALUE ფუნქციაში, შემდეგნაირად:

=IF(AND(B2>=DATEVALUE("9/10/2018"), B2<=DATEVALUE("9/30/2018")), "x", "")

ან უბრალოდ შეიყვანეთ From და To თარიღდება ორ უჯრედში ($F$1 და $F$2 ამ მაგალითში) და „ამოიღეთ“ ისინი ამ უჯრედებიდან უკვე ნაცნობი IF და ფორმულის გამოყენებით:

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

დამატებითი ინფორმაციისთვის იხილეთ Excel IF განცხადება ორ რიცხვს ან თარიღს შორის.

თუ ეს და ეს, მაშინ გამოთვალეთ რაღაც

გარდა წინასწარ განსაზღვრული მნიშვნელობების დაბრუნებისა, Excel IF AND ფუნქციას ასევე შეუძლია შეასრულოს სხვადასხვა გამოთვლები იმისდა მიხედვით, მითითებული პირობები არის TRUE ან FALSE.

მიდგომის დემონსტრირებისთვის, ჩვენ გამოვთვლით ბონუსს 5% "დახურულ" გაყიდვებზე მეტი ან ტოლი თანხით. $100-მდე.

თუ ვივარაუდებთ, რომ თანხა არის B სვეტში და შეკვეთის სტატუსი სვეტში C,ფორმულა შემდეგია:

=IF(AND(B2>=100, C2="closed"), B2*10%, 0)

ზემოხსენებული ფორმულა ანიჭებს ნულს დანარჩენ ბრძანებებს ( value_if_false = 0) . თუ თქვენ მზად ხართ მისცეთ მცირე მასტიმულირებელი ბონუსი, ვთქვათ 3%, შეკვეთებზე, რომლებიც არ აკმაყოფილებენ პირობებს, შეიტანეთ შესაბამისი განტოლება value_if_false არგუმენტში:

=IF(AND(B2>=100, C2="closed"), B2*10%, B2*3%)

Multiple IF AND განცხადებები Excel-ში

როგორც თქვენ შენიშნეთ, ჩვენ შევაფასეთ მხოლოდ ორი კრიტერიუმი ყველა ზემოთ მოყვანილ მაგალითში. მაგრამ არაფერი შეგიშლით ხელს სამი და მეტი ტესტის თქვენს IF AND ფორმულებში ჩართვაში, თუ ისინი შეესაბამება Excel-ის ამ ზოგად შეზღუდვებს:

• Excel 2007 და უფრო მაღალი, 255-მდე არგუმენტი შეიძლება გამოყენებულ იქნას ფორმულაში, რომლის ჯამური ფორმულის სიგრძე არ აღემატება 8192 სიმბოლოს.
• Excel 2003 და უფრო დაბალი, არაუმეტეს 30 არგუმენტი დაშვებულია, რომელთა საერთო სიგრძე არ აღემატება 1024 სიმბოლოს.
• 5>

  როგორც მრავალი AND პირობების მაგალითი, გთხოვთ, განიხილოთ შემდეგი:

  • თანხა (B2) უნდა იყოს $100-ზე მეტი ან ტოლი
  • შეკვეთის სტატუსი (C2) არის "დახურული"
  • მიწოდების თარიღი (D2) არის მიმდინარე თვეში

  ახლა, ჩვენ გვჭირდება IF და განცხადება, რათა განვსაზღვროთ შეკვეთები, რომლებისთვისაც სამივე პირობა არის TRUE. და აი:

  =IF(AND(B2>=100, C2="Closed", MONTH(D2)=MONTH(TODAY())), "x", "")

  იმის გათვალისწინებით, რომ „მიმდინარე თვე“ დაწერის მომენტში იყო ოქტომბერი, ფორმულა იძლევა შემდეგ შედეგებს:

  

  ჩადგმული IF დაგანცხადებები

  დიდი სამუშაო ფურცლებთან მუშაობისას, დიდი ალბათობით, შეიძლება დაგჭირდეთ ერთდროულად შეამოწმოთ სხვადასხვა და კრიტერიუმების რამდენიმე ნაკრები. ამისათვის თქვენ იღებთ კლასიკურ Excel-ის ჩადგმულ IF ფორმულას და აფართოებთ მის ლოგიკურ ტესტებს AND განცხადებებით, როგორიცაა:

  Იხილეთ ასევე: მონაცემთა დადასტურება Excel-ში: როგორ დავამატოთ, გამოიყენოთ და წაშალოთ
  IF(AND(…), output1 , IF(AND(…), output2 , IF(AND(…), output3 , output4 )))

  ზოგადი იდეის მისაღებად, გთხოვთ გადახედოთ შემდეგ მაგალითს.

  დაუშვათ, რომ გსურთ შეაფასოთ თქვენი სერვისი გადაზიდვის ღირებულებისა და მიწოდების სავარაუდო დროის მიხედვით (ETD):

  • შესანიშნავი : გადაზიდვის ღირებულება 20$-ზე ნაკლები და ETD 3 დღეზე ნაკლები
  • ცუდი : გადაზიდვის ღირებულება 30$-ზე მეტი და ETD 5 დღის განმავლობაში
  • საშუალო : არაფერი შორის

  დაასრულეთ, ჩაწერეთ ორი ინდივიდუალური IF და განცხადება:

  IF(AND(B2<20, C2<3), "Excellent", …)

  IF(AND(B2>30, C2>5), "Poor", …)

  …და ჩადეთ ერთი მეორეში:

  =IF(AND(B2>30, C2>5), "Poor", IF(AND(B2<20, C2<3), "Excellent", "Average"))

  შედეგი ასე გამოიყურება:

  

  ფორმულების მეტი მაგალითები შეგიძლიათ იხილოთ Excel-ში ჩასმული IF AND განცხადებებში.

  Rese-sensitive IF AND ფუნქცია Excel-ში

  როგორც აღინიშნა ამ გაკვეთილის დასაწყისში, Excel IF ფორმულები არ განასხვავებენ დიდ და პატარა ასოებს შორის რადგან AND ფუნქცია ბუნებით არ არის მგრძნობიარე რეგისტრის მიმართ.

  თუ თქვენ მუშაობთ რეზერვებზე მგრძნობიარე მონაცემებთან და გსურთ შეაფასოთ AND პირობები ტექსტის ქეისის გათვალისწინებით, გააკეთეთ თითოეული ინდივიდუალური ლოგიკური ტესტი EXACT ფუნქციისა და ბუდის შიგნითეს ფუნქციები თქვენს AND განცხადებაში:

  IF(AND(EXACT( უჯრედ ," პირობა1 "), EXACT( უჯრედ ," პირობა2 ")), value_if_true, value_if_false)

  ამ მაგალითად, ჩვენ ვაპირებთ დროშის მონიშვნას კონკრეტული მომხმარებლის (მაგ. კომპანიის სახელით კიბერსივრცე ) შეკვეთებზე, რომლის ოდენობა აღემატება გარკვეულ რაოდენობას, ვთქვათ $100.

  როგორც ხედავთ ქვემოთ მოცემულ ეკრანის სურათზე, B სვეტის ზოგიერთი კომპანიის სახელი იდენტურია სიმბოლოების ასოების ამონარიდიდან და, მიუხედავად ამისა, ისინი სხვადასხვა კომპანიებია, ამიტომ ჩვენ უნდა შევამოწმოთ სახელები ზუსტად . C სვეტის თანხები არის რიცხვები და ჩვენ ვაწარმოებთ მათ რეგულარულ ტესტს "უმეტესზე":

  =IF(AND(EXACT(B2, "Cyberspace"), C2>100), "x", "")

  ფორმულა უფრო მოქნილი რომ გახადოთ, შეგიძლიათ შეიყვანოთ სამიზნე მომხმარებლის სახელი და თანხა. ორ ცალკეულ უჯრედში და მიუთითეთ ეს უჯრედები. უბრალოდ დაიმახსოვრეთ, რომ დაბლოკოთ უჯრედის მითითებები $ ნიშნით ($G$1 და $G$2 ჩვენს შემთხვევაში), რათა არ შეიცვალოს ფორმულის სხვა რიგებში კოპირებისას:

  =IF(AND(EXACT(B2, $G$1), C2>$G$2), "x", "")

  ახლა თქვენ შეგიძლიათ აკრიფოთ ნებისმიერი სახელი და თანხა მითითებულ უჯრედებში და ფორმულა მონიშნავს შესაბამის ბრძანებებს თქვენს ცხრილში:

  Იხილეთ ასევე: როგორ ჩავსვათ გვერდის წყვეტები Excel-ში; ამოიღეთ ან დამალეთ შესვენების ხაზები

  

  IF OR AND ფორმულა Excel-ში

  Excel IF ფორმულებში თქვენ არ შემოიფარგლებით მხოლოდ ერთი ლოგიკური ფუნქციის გამოყენებით. მრავალი პირობის სხვადასხვა კომბინაციის შესამოწმებლად, თქვენ თავისუფლად შეგიძლიათ დააკავშიროთ IF, AND, OR და სხვა ფუნქციები საჭირო ლოგიკური ტესტების გასაშვებად. აქ არის IF AND OR ფორმულის მაგალითი, რომელიც ამოწმებს რამდენიმეან პირობები AND-ის ფარგლებში. ახლა კი მე გაჩვენებთ, თუ როგორ შეგიძლიათ გააკეთოთ ორი ან მეტი AND ტესტი OR ფუნქციის ფარგლებში.

  დავარაუდოთ, რომ გსურთ მონიშნოთ ორი კლიენტის შეკვეთები გარკვეულ რაოდენობაზე მეტი ოდენობით, ვთქვათ $100.

  Excel-ის ენაში, ჩვენი პირობები გამოიხატება ასე:

  OR(AND( Customer1 , Amount >100), AND( Customer2 , Amount >100)

  დავარაუდეთ, რომ კლიენტების სახელები არის სვეტში B, თანხები სვეტში C, 2 სამიზნე სახელი. არის G1-ში და G2-ში, ხოლო სამიზნე თანხა არის G3-ში, თქვენ იყენებთ ამ ფორმულას შესაბამისი ბრძანებების აღსანიშნავად "x"-ით:

  =IF(OR(AND(B2=$G$1, C2>$G$3), AND(B2=$G$2, C2>$G$3)), "x", "")

  იგივე შედეგების მიღწევა შესაძლებელია მეტი კომპაქტური სინტაქსი:

  =IF(AND(OR(B2=$G$1,B2= $G$2), C2>$G$3), "x", "")

  

  დარწმუნებული არ ხართ, რომ სრულად გესმით ფორმულის ლოგიკა? მეტი ინფორმაცია შეგიძლიათ იხილოთ Excel IF-ში მრავალი AND/OR პირობებით.

  ასე იყენებთ IF და AND ფუნქციებს ერთად Excel-ში. გმადლობთ, რომ წაიკითხეთ და შევხვდებით მომავალ კვირას!

  სავარჯიშო სამუშაო წიგნი

  IF და Excel – ფორმულების მაგალითები (.xlsx ფაილი)