Die tutoriaal wys hoe om IF saam met die EN-funksie in Excel te gebruik om verskeie toestande in een formule na te gaan.

Sommige dinge in die wêreld is eindig. Ander is oneindig, en die IF-funksie blyk een van sulke dinge te wees. Op ons blog het ons reeds 'n handvol Excel IF-tutoriale en ontdek steeds elke dag nuwe gebruike. Vandag gaan ons kyk hoe jy IF saam met die EN-funksie kan gebruik om twee of meer toestande gelyktydig te evalueer.

IF EN-stelling in Excel

Om die IF EN-stelling te bou, moet jy natuurlik die IF- en EN-funksies in een formule kombineer. Hier is hoe:

Vertaal in gewone Engels, lees die formule soos volg: INDIEN voorwaarde 1 is waar EN voorwaarde 2 is waar, doen een ding, anders doen iets anders.

As voorbeeld, kom ons maak 'n formule wat kontroleer of B2 "afgelewer" is en C2 nie leeg is nie, en afhangende van die resultate , doen een van die volgende:

• As beide voorwaardes WAAR is, merk die bestelling as "Geslote".
• As een van die voorwaardes ONWAAR is of albei ONWAAR is, gee dan 'n leë string ("").

=IF(AND(B2="delivered", C2""), "Closed", "")

Die skermkiekie hieronder wys die IF EN-funksie in Excel:

As jy wil graag 'n waarde terugstuur indien die logiese toets na ONWAAR evalueer, verskaf daardie waarde in die waarde_as_vals argument. Byvoorbeeld:

=IF(AND(B2="delivered", C2""), "Closed", "Open")

Die gewysigde formule voer "Geslote" uit as kolom B "afgelewer" is en C enige datum in het (nie-leë). In alle ander gevalle gee dit "Oop" terug:

Let wel. Wanneer 'n IF EN-formule in Excel gebruik word om tekstoestande te evalueer, hou asseblief in gedagte dat kleinletters en hoofletters as dieselfde karakter hanteer word. As jy op soek is na 'n hooflettersensitiewe IF EN-formule, draai een of meer argumente van EN in die EXACT-funksie soos dit in die gekoppelde voorbeeld gedoen word.

Nou dat jy die sintaksis van die Excel IF AND-stelling ken, laat ek jou wys watter soort take dit kan oplos.

Excel IF: groter as EN minder as

In die vorige voorbeeld, ons het twee toestande in twee verskillende selle getoets. Maar soms moet jy dalk twee of meer toetse op dieselfde sel uitvoer. 'n Tipiese voorbeeld is om te kyk of 'n selwaarde tussen twee getalle is. Die Excel IF EN-funksie kan dit ook maklik doen!

Kom ons sê jy het 'n paar verkoopsnommers in kolom B en jy word versoek om die bedrae groter as $50 maar minder as $100 te vlag. Om dit te laat doen, voeg hierdie formule in C2 in en kopieer dit dan in die kolom af:

=IF(AND(B2>50, B2<100), "x", "")

As jy die grens moet insluit waardes (50 en 100), gebruik die minder as of gelyk aan operateur (<=) en groter as of gelyk aan (>=) operateur:

=IF(AND(B2>=50, B2<=100), "x", "")

Om 'n ander te verwerkgrenswaardes sonder om die formule te verander, voer die minimum en maksimum getalle in twee aparte selle in en verwys na daardie selle in jou formule. Vir die formule om korrek in al die rye te werk, maak seker dat jy absolute verwysings vir die grensselle gebruik ($F$1 en $F$2 in ons geval):

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Deur 'n soortgelyke formule te gebruik, kan jy kyk of 'n datum binne 'n gespesifiseerde reeks val .

Kom ons vlag byvoorbeeld datums tussen 10 -Sep-2018 en 30-Sep-2018, ingesluit. 'n Klein struikelblok is dat datums nie direk aan die logiese toetse verskaf kan word nie. Vir Excel om die datums te verstaan, moet hulle in die DATUMWAARDE-funksie ingesluit word, soos volg:

=IF(AND(B2>=DATEVALUE("9/10/2018"), B2<=DATEVALUE("9/30/2018")), "x", "")

Of voer eenvoudig die Van en Tot<2 in> datums in twee selle ($F$1 en $F$2 in hierdie voorbeeld) en "trek" hulle uit daardie selle deur die reeds bekende IF EN formule te gebruik:

=IF(AND(B2>=$F$1, B2<=$F$2), "x", "")

Vir meer inligting, sien asseblief Excel IF-stelling tussen twee getalle of datums.

AS dit EN dat, bereken dan iets

Behalwe om voorafbepaalde waardes terug te gee, is die Excel IF AND-funksie kan ook verskillende berekeninge uitvoer afhangende van of die gespesifiseerde voorwaardes WAAR of ONWAAR is.

Om die benadering te demonstreer, sal ons 'n bonus van 5% vir "Geslote" verkope met die bedrag groter as of gelyk bereken tot $100.

Gestel die bedrag is in kolom B en die bestellingstatus in kolom C,die formule gaan soos volg:

=IF(AND(B2>=100, C2="closed"), B2*10%, 0)

Bogenoemde formule ken nul toe aan die res van die bestellings ( waarde_as_vals = 0) . As jy bereid is om 'n klein stimulerende bonus, sê 3%, te gee aan bestellings wat nie aan die voorwaardes voldoen nie, sluit die ooreenstemmende vergelyking in die waarde_as_vals argument in:

=IF(AND(B2>=100, C2="closed"), B2*10%, B2*3%)

Veelvuldige IF EN-stellings in Excel

Soos jy dalk opgemerk het, het ons slegs twee kriteria in al die bogenoemde voorbeelde geëvalueer. Maar daar is niks wat jou sal verhoed om drie en meer toetse in jou IF EN formules in te sluit solank dit aan hierdie algemene beperkings van Excel voldoen nie:

• In Excel 2007 en hoër, tot 255 argumente kan in 'n formule gebruik word, met 'n totale formulelengte wat nie 8 192 karakters oorskry nie.
• In Excel 2003 en laer word nie meer as 30 argumente toegelaat nie, met 'n totale lengte van hoogstens 1 024 karakters.

As 'n voorbeeld van veelvuldige EN voorwaardes, oorweeg asseblief hierdie:

• Bedrag (B2) moet groter as of gelyk aan $100 wees
• Bestellingstatus (C2) is "Gesluit"
• Afleweringsdatum (D2) is binne die huidige maand

Nou het ons 'n IF EN-stelling nodig om die bestellings te identifiseer waarvoor al 3 voorwaardes WAAR is. En hier is dit:

=IF(AND(B2>=100, C2="Closed", MONTH(D2)=MONTH(TODAY())), "x", "")

Gegewe dat die 'huidige maand' op die oomblik van skryf Oktober was, lewer die formule die onderstaande resultate:

Geneste INDIEN ENstellings

Wanneer jy met groot werkkaarte werk, is die kans goed dat jy dalk vereis word om 'n paar stelle verskillende EN kriteria op 'n slag na te gaan. Hiervoor neem jy 'n klassieke Excel geneste IF-formule en brei sy logiese toetse uit met EN-stellings, soos hierdie:

Om die algemene idee te kry, kyk asseblief na die volgende voorbeeld.

Gestel jy wil jou diens beoordeel op grond van die versendingskoste en geskatte afleweringstyd (ETD):

• Uitstekend : versendingskoste onder $20 en ETD onder 3 dae
• Swak : versending kos meer as $30 en ETD oor 5 dae
• Gemiddeld : enigiets tussenin

Tot kry dit klaar, skryf jy twee individuele IF EN-stellings:

IF(AND(B2<20, C2<3), "Excellent", …)

IF(AND(B2>30, C2>5), "Poor", …)

...en nes die een in die ander:

=IF(AND(B2>30, C2>5), "Poor", IF(AND(B2<20, C2<3), "Excellent", "Average"))

Die resultaat sal soortgelyk soos hierdie lyk:

Meer formule-voorbeelde kan gevind word in Excel geneste IF EN-stellings.

Kleinlettergevoelig IF EN funksie in Excel

Soos genoem in die begin van hierdie tutoriaal, onderskei Excel IF EN formules nie tussen hoofletters en kleinletters nie omdat die EN-funksie van nature hoofletter-onsensitief is.

As jy met hooflettergevoelig data werk en EN-toestande wil evalueer met inagneming van die teksgeval, doen elke individuele logiese toets binne die PRESIESE funksie en nesdaardie funksies in jou EN-stelling:

Vir hierdie voorbeeld gaan ons bestellings van 'n spesifieke kliënt (bv. die maatskappy genaamd Cyberspace ) vlag met 'n bedrag wat 'n sekere getal oorskry, sê $100.

Soos jy in die skermkiekie hieronder kan sien, lyk sommige maatskappyname in kolom B dieselfde uittreksel as die karakters, en nietemin is hulle verskillende maatskappye, so ons moet die name presies . Die bedrae in kolom C is getalle, en ons voer 'n gereelde "groter as"-toets daarvoor uit:

=IF(AND(EXACT(B2, "Cyberspace"), C2>100), "x", "")

Om die formule meer buigsaam te maak, kan jy die teikenkliëntnaam en -bedrag invoer in twee afsonderlike selle en verwys na daardie selle. Onthou net om die selverwysings met $-teken te sluit ($G$1 en $G$2 in ons geval) sodat hulle nie sal verander wanneer jy die formule na ander rye kopieer nie:

=IF(AND(EXACT(B2, $G$1), C2>$G$2), "x", "")

Nou kan jy enige naam en bedrag in die verwysde selle tik, en die formule sal die ooreenstemmende bestellings in jou tabel vlag:

IF OF EN formule in Excel

In Excel IF-formules is jy nie beperk tot die gebruik van slegs een logiese funksie nie. Om verskeie kombinasies van veelvuldige toestande na te gaan, is dit jou vry om die IF, EN, OF en ander funksies te kombineer om die vereiste logiese toetse uit te voer. Hier is 'n voorbeeld van IF EN OF formule wat 'n paar toetsOF voorwaardes binne EN. En nou sal ek jou wys hoe jy twee of meer EN-toetse binne die OF-funksie kan doen.

Gestel jy wil die bestellings van twee kliënte met 'n bedrag groter as 'n sekere getal merk, sê $100.

In die Excel-taal word ons voorwaardes soos volg uitgedruk:

OR(AND( Customer1 , Amount >100), AND( Customer2 , Amount >100)

Aangesien die klantname is in kolom B, bedrae in kolom C, die 2 teikenname is in G1 en G2, en die teikenbedrag is in G3, gebruik jy hierdie formule om die ooreenstemmende bestellings met "x" te merk:

=IF(OR(AND(B2=$G$1, C2>$G$3), AND(B2=$G$2, C2>$G$3)), "x", "")

Dieselfde resultate kan bereik word met 'n meer kompakte sintaksis:

=IF(AND(OR(B2=$G$1,B2= $G$2), C2>$G$3), "x", "")

Nie seker jy verstaan ​​die formule se logika heeltemal nie? Meer inligting kan gevind word in Excel IF met veelvuldige EN/OF voorwaardes.

Dis hoe jy die IF en EN funksies saam in Excel gebruik. Dankie dat jy gelees het en sien jou volgende week!

Oefenwerkboek

IF EN Excel – formulevoorbeelde (.xlsx-lêer)