Το σεμινάριο δείχνει πώς να χρησιμοποιήσετε τη συνάρτηση MAXIFS στο Excel για να λάβετε τη μέγιστη τιμή με όρους.

Παραδοσιακά, όταν χρειαζόταν ποτέ να βρείτε την υψηλότερη τιμή με συνθήκες στο Excel, έπρεπε να φτιάξετε τον δικό σας τύπο MAX IF. Αν και δεν είναι κάτι σημαντικό για τους έμπειρους χρήστες, αυτό μπορεί να παρουσιάζει ορισμένες δυσκολίες για τους αρχάριους, επειδή, πρώτον, θα πρέπει να θυμάστε τη σύνταξη του τύπου και, δεύτερον, θα πρέπει να γνωρίζετε πώς να εργάζεστε με τύπους συστοιχιών. Ευτυχώς, η Microsoft εισήγαγε πρόσφατα μια νέασυνάρτηση που μας επιτρέπει να κάνουμε conditional max με εύκολο τρόπο!

Λειτουργία MAXIFS του Excel

Η συνάρτηση MAXIFS επιστρέφει τη μεγαλύτερη αριθμητική τιμή στο καθορισμένο εύρος τιμών με βάση ένα ή περισσότερα κριτήρια.

Η σύνταξη της συνάρτησης MAXIFS έχει ως εξής:

Πού:

• Max_range (υποχρεωτικό) - η περιοχή κελιών όπου θέλετε να βρείτε τη μέγιστη τιμή.
• Criteria_range1 (απαιτείται) - το πρώτο εύρος που θα αξιολογηθεί με κριτήρια1 .
• Κριτήρια1 - η συνθήκη που θα χρησιμοποιηθεί στην πρώτη περιοχή. Μπορεί να αναπαρασταθεί με αριθμό, κείμενο ή έκφραση.
• Criteria_range2 / κριτήρια2 , ...(προαιρετικά) - πρόσθετες περιοχές και τα σχετικά τους κριτήρια. Υποστηρίζονται έως και 126 ζεύγη περιοχών/κριτηρίων.

Αυτή η συνάρτηση MAXIFS είναι διαθέσιμη στο Excel 2019, Excel 2021 και Excel for Microsoft 365 σε Windows και Mac.

Ως παράδειγμα, ας βρούμε τον ψηλότερο ποδοσφαιριστή του τοπικού μας σχολείου. Υποθέτοντας ότι το ύψος των μαθητών βρίσκεται στα κελιά D2:D11 (max_range) και τα αθλήματα στα κελιά B2:B11 (criteria_range1), χρησιμοποιήστε τη λέξη "ποδόσφαιρο" ως κριτήριο1 και θα έχετε αυτόν τον τύπο:

=MAXIFS(D2:D11, B2:B11, "ποδόσφαιρο")

Για να κάνετε τον τύπο πιο ευέλικτο, μπορείτε να εισαγάγετε το άθλημα-στόχο σε κάποιο κελί (π.χ. G1) και να συμπεριλάβετε την αναφορά του κελιού στο κριτήρια1 επιχείρημα:

=MAXIFS(D2:D11, B2:B11, G1)

Σημείωση. max_range και criteria_range τα ορίσματα πρέπει να έχουν το ίδιο μέγεθος και σχήμα, δηλαδή να περιέχουν τον ίδιο αριθμό γραμμών και στηλών, διαφορετικά επιστρέφεται το σφάλμα #VALUE!.

Πώς να χρησιμοποιήσετε τη συνάρτηση MAXIFS στο Excel - παραδείγματα τύπων

Όπως μόλις είδατε, το MAXIFS του Excel είναι αρκετά απλό και εύκολο στη χρήση. Ωστόσο, έχει μερικές μικρές αποχρώσεις που κάνουν μεγάλη διαφορά. Στα παρακάτω παραδείγματα, θα προσπαθήσουμε να αξιοποιήσουμε στο έπακρο το conditional max στο Excel.

Εύρεση μέγιστης τιμής με βάση πολλαπλά κριτήρια

Στο πρώτο μέρος αυτού του σεμιναρίου, δημιουργήσαμε έναν τύπο MAXIFS στην απλούστερη μορφή του για να λάβουμε τη μέγιστη τιμή με βάση μία συνθήκη. Τώρα, θα προχωρήσουμε αυτό το παράδειγμα περαιτέρω και θα αξιολογήσουμε δύο διαφορετικά κριτήρια.

Ας υποθέσουμε ότι θέλετε να βρείτε τον ψηλότερο παίκτη του μπάσκετ στο γυμνάσιο. Για να το κάνετε αυτό, ορίστε τα ακόλουθα επιχειρήματα:

• Max_range - μια σειρά κελιών που περιέχουν ύψη - D2:D11.
• Criteria_range1 - ένα εύρος κελιών που περιέχει αθλητικά - B2:B11.
• Κριτήρια1 - "μπάσκετ", η οποία εισάγεται στο κελί G1.
• Criteria_range2 - μια σειρά κελιών που καθορίζουν τον τύπο του σχολείου - C2:C11.
• Κριτήρια2 - "junior", η οποία εισάγεται στο κελί G2.

Συνδυάζοντας τα επιχειρήματα, έχουμε αυτούς τους τύπους:

Με "σκληρά κωδικοποιημένα" κριτήρια:

=MAXIFS(D2:D11, B2:B11, "basketball", C2:C11, "junior")

Με κριτήρια σε προκαθορισμένα κελιά:

=MAXIFS(D2:D11, B2:B11, G1, C2:C11, G2)

Σημειώστε ότι η συνάρτηση MAXIFS στο Excel είναι case-insensitive , οπότε δεν χρειάζεται να ανησυχείτε για την πεζότητα των γραμμάτων στα κριτήριά σας.

Σε περίπτωση που σκοπεύετε να χρησιμοποιήσετε τον τύπο σας σε πολλαπλά κελιά, φροντίστε να κλειδώσετε όλες τις περιοχές με απόλυτες αναφορές κελιών, ως εξής:

=MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2)

Αυτό θα διασφαλίσει ότι ο τύπος αντιγράφεται σωστά σε άλλα κελιά - οι αναφορές κριτηρίων αλλάζουν με βάση τη σχετική θέση του κελιού όπου αντιγράφεται ο τύπος, ενώ οι περιοχές παραμένουν αμετάβλητες:

Ως επιπλέον μπόνους, θα σας δείξω έναν γρήγορο τρόπο για να εξάγετε μια τιμή από ένα άλλο κελί που σχετίζεται με την τιμή max. Στην περίπτωσή μας, αυτό θα είναι το όνομα του ψηλότερου ατόμου. Για το σκοπό αυτό, θα χρησιμοποιήσουμε τον κλασικό τύπο INDEX MATCH και θα φωλιάσουμε MAXIFS στο πρώτο όρισμα του MATCH ως τιμή αναζήτησης:

=INDEX($A$2:$A$11, MATCH(MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2), $D$2:$D$11, 0))

Ο τύπος μας λέει ότι το όνομα του ψηλότερου παίκτη του μπάσκετ στο γυμνάσιο είναι Λίαμ:

Excel MAXIFS με λογικούς τελεστές

Σε περίπτωση που πρέπει να αξιολογήσετε αριθμητικά κριτήρια, χρησιμοποιήστε λογικούς τελεστές όπως:

• μεγαλύτερο από (>)
• λιγότερο από (<)
• μεγαλύτερο ή ίσο από (>=)
• μικρότερο ή ίσο από (<=)
• όχι ίσο με ()

Ο τελεστής "ίσο με" (=) μπορεί να παραλειφθεί στις περισσότερες περιπτώσεις.

Συνήθως, η επιλογή ενός τελεστή δεν αποτελεί πρόβλημα, το πιο δύσκολο κομμάτι είναι να δημιουργήσετε κριτήρια με τη σωστή σύνταξη. Ακολουθεί ο τρόπος:

• Ένας λογικός τελεστής που ακολουθείται από έναν αριθμό ή ένα κείμενο πρέπει να περικλείεται σε διπλά εισαγωγικά όπως ">=14" ή "running".
• Σε περίπτωση αναφοράς κελιού ή άλλης συνάρτησης, χρησιμοποιήστε τα εισαγωγικά για να ξεκινήσετε μια συμβολοσειρά και ένα ampersand για να συνδέσετε την αναφορά και να ολοκληρώσετε τη συμβολοσειρά, π.χ. ">"&B1 ή "<"&TODAY().

Για να δούμε πώς λειτουργεί στην πράξη, ας προσθέσουμε τη στήλη Ηλικία (στήλη C) στον πίνακα του δείγματός μας και ας βρούμε το μέγιστο ύψος μεταξύ των αγοριών ηλικίας μεταξύ 13 και 14. Αυτό μπορεί να γίνει με τα ακόλουθα κριτήρια:

Κριτήριο1: ">=13"

Κριτήριο2: "<=14"

Επειδή συγκρίνουμε τους αριθμούς στην ίδια στήλη, το criteria_range και στις δύο περιπτώσεις είναι το ίδιο (C2:C11):

=MAXIFS(D2:D11, C2:C11, ">=13", C2:C11, "<=14")

Εάν δεν θέλετε να καταχωρίσετε τα κριτήρια στον τύπο, εισαγάγετε τα κριτήρια σε ξεχωριστά κελιά (π.χ. G1 και H1) και χρησιμοποιήστε την ακόλουθη σύνταξη:

=MAXIFS(D2:D11, C2:C11, ">="&G1, C2:C11, "<="&H1)

Το παρακάτω στιγμιότυπο οθόνης δείχνει το αποτέλεσμα:

Εκτός από τους αριθμούς, οι λογικοί τελεστές μπορούν επίσης να λειτουργήσουν με κριτήρια κειμένου. Ειδικότερα, ο τελεστής "μη ίσο με" είναι χρήσιμος όταν θέλετε να αποκλείσετε κάτι από τους υπολογισμούς σας. Για παράδειγμα, για να βρείτε τον ψηλότερο μαθητή σε όλα τα αθλήματα εκτός από το βόλεϊ, χρησιμοποιήστε τον ακόλουθο τύπο:

=MAXIFS(D2:D11, B2:B11, "volleyball")

Ή αυτό εδώ, όπου το G1 είναι το αποκλεισμένο άθλημα:

=MAXIFS(D2:D11, B2:B11, ""&G1)

Τύποι MAXIFS με χαρακτήρες μπαλαντέρ (μερική αντιστοίχιση)

Για να αξιολογήσετε μια συνθήκη που περιέχει ένα συγκεκριμένο κείμενο ή χαρακτήρα, συμπεριλάβετε έναν από τους ακόλουθους χαρακτήρες μπαλαντέρ στα κριτήριά σας:

• Ερωτηματικό (?) για να ταιριάζει με οποιονδήποτε μεμονωμένο χαρακτήρα.
• Αστερίσκος (*) για να ταιριάζει με οποιαδήποτε ακολουθία χαρακτήρων.

Για αυτό το παράδειγμα, ας βρούμε τον ψηλότερο άντρα στα αθλήματα παιχνιδιών. Επειδή τα ονόματα όλων των αθλημάτων παιχνιδιών στο σύνολο δεδομένων μας τελειώνουν με τη λέξη "ball", συμπεριλαμβάνουμε αυτή τη λέξη στα κριτήρια και χρησιμοποιούμε έναν αστερίσκο για να ταιριάξουμε τυχόν προηγούμενους χαρακτήρες:

=MAXIFS(D2:D11, B2:B11, "*ball")

Μπορείτε επίσης να πληκτρολογήσετε "μπάλα" σε κάποιο κελί, π.χ. G1, και να συνδέσετε τον χαρακτήρα μπαλαντέρ με την αναφορά του κελιού:

=MAXIFS(D2:D11, B2:B11, "*"&G1)

Το αποτέλεσμα θα έχει ως εξής:

Λήψη μέγιστης τιμής σε ένα εύρος ημερομηνιών

Επειδή οι ημερομηνίες αποθηκεύονται ως αύξοντες αριθμοί στο εσωτερικό σύστημα του Excel, εργάζεστε με τα κριτήρια των ημερομηνιών με τον ίδιο τρόπο που εργάζεστε με τους αριθμούς.

Για να το δείξουμε αυτό, θα αντικαταστήσουμε το Ηλικία στήλη με Ημερομηνία γέννησης και να προσπαθήσουμε να βρούμε το μέγιστο ύψος μεταξύ των αγοριών που γεννήθηκαν σε ένα συγκεκριμένο έτος, ας πούμε το 2004. Για να επιτύχουμε αυτό το έργο, πρέπει να "φιλτράρουμε" τις ημερομηνίες γέννησης που είναι μεγαλύτερες ή ίσες με την 1η Ιανουαρίου 2004 και μικρότερες ή ίσες με την 31η Δεκεμβρίου 2004.

Κατά τη δημιουργία των κριτηρίων σας, είναι σημαντικό να παρέχετε τις ημερομηνίες σε μορφή που μπορεί να κατανοήσει το Excel:

=MAXIFS(D2:D11, C2:C11, ">=1-Jan-2004", C2:C11, "<=31-Dec-2004")

Ή

=MAXIFS(D2:D11, C2:C11, ">=1/1/2004", C2:C11, "<=31/12/2004")

Για την αποφυγή παρερμηνειών, είναι λογικό να χρησιμοποιείτε τη συνάρτηση DATE:

=MAXIFS(D2:D11, C2:C11, ">="&DATE(2004,1,1), C2:C11, "<="&DATE(2004,12,31))

Για αυτό το παράδειγμα, θα πληκτρολογήσουμε το έτος-στόχο στο G1 και στη συνέχεια θα χρησιμοποιήσουμε τη συνάρτηση DATE για να παρέχουμε τις ημερομηνίες:

=MAXIFS(D2:D11, C2:C11, ">="&DATE(G1,1,1), C2:C11, "<="&DATE(G1,12,31))

Σημείωση. Σε αντίθεση με τους αριθμούς, οι ημερομηνίες πρέπει να μπαίνουν σε εισαγωγικά όταν χρησιμοποιούνται στα κριτήρια μόνες τους. Για παράδειγμα:

=MAXIFS(D2:D11, C2:C11, "10/5/2005")

Εύρεση μέγιστης τιμής με βάση πολλαπλά κριτήρια με λογική OR

Η συνάρτηση MAXIFS του Excel έχει σχεδιαστεί για να ελέγχει τις συνθήκες με τη λογική AND - δηλαδή επεξεργάζεται μόνο τους αριθμούς που βρίσκονται στο max_range Σε ορισμένες περιπτώσεις, ωστόσο, μπορεί να χρειαστεί να αξιολογήσετε τις συνθήκες με τη λογική Ή - δηλαδή να επεξεργαστείτε όλους τους αριθμούς για τους οποίους κάποιο από τα καθορισμένα κριτήρια είναι ΑΛΗΘΙΝΟ.

Για να γίνουν τα πράγματα πιο κατανοητά, αναλογιστείτε το ακόλουθο παράδειγμα. Ας υποθέσουμε ότι θέλετε να βρείτε το μέγιστο ύψος των παιδιών που παίζουν είτε μπάσκετ είτε ποδόσφαιρο. Πώς θα το κάνετε αυτό; Η χρήση του "μπάσκετ" ως κριτήριο1 και του "ποδοσφαίρου" ως κριτήριο2 δεν θα λειτουργήσει, επειδή το Excel θα υποθέσει ότι και τα δύο κριτήρια θα πρέπει να αποτιμηθούν σε TRUE.

Η λύση είναι να φτιάξετε 2 ξεχωριστούς τύπους MAXIFS, έναν για κάθε άθλημα, και στη συνέχεια να χρησιμοποιήσετε την παλιά καλή συνάρτηση MAX για να επιστρέψετε έναν υψηλότερο αριθμό:

=MAX(MAXIFS(C2:C11, B2:B11, "basketball"), MAXIFS(C2:C11, B2:B11, "football"))

Το παρακάτω στιγμιότυπο οθόνης δείχνει αυτόν τον τύπο, αλλά με τα κριτήρια σε προκαθορισμένα κελιά εισόδου, F1 και H1:

Ένας άλλος τρόπος είναι να χρησιμοποιήσετε έναν τύπο MAX IF με λογική OR.

7 πράγματα που πρέπει να θυμάστε για το Excel MAXIFS

Παρακάτω θα βρείτε μερικές παρατηρήσεις που θα σας βοηθήσουν να βελτιώσετε τους τύπους σας και να αποφύγετε τα συνήθη λάθη. Ορισμένες από αυτές τις παρατηρήσεις έχουν ήδη συζητηθεί ως συμβουλές και σημειώσεις στα παραδείγματά μας, αλλά ίσως είναι χρήσιμο να πάρετε μια σύντομη περίληψη αυτών που έχετε ήδη μάθει:

1. Η συνάρτηση MAXIFS στο Excel μπορεί να πάρει την υψηλότερη τιμή με βάση ένα ή πολλαπλά κριτήρια .
2. Από προεπιλογή, το Excel MAXIFS λειτουργεί με το Λογική AND , δηλαδή επιστρέφει τον μέγιστο αριθμό που πληροί όλες τις καθορισμένες συνθήκες.
3. Για να λειτουργήσει η συνάρτηση, το εύρος max και τα κριτήρια πρέπει να έχουν την τιμή ίδιο μέγεθος και σχήμα .
4. Η συνάρτηση SUMIF είναι case-insensitive , δηλαδή δεν αναγνωρίζει την πεζότητα των γραμμάτων στα κριτήρια κειμένου.
5. Όταν γράφετε έναν τύπο MAXIFS για πολλαπλά κελιά, θυμηθείτε να κλειδώστε τις σειρές με απόλυτες αναφορές κελιών για να αντιγραφεί σωστά ο τύπος.
6. Mind the σύνταξη των κριτηρίων σας Ακολουθούν οι βασικοί κανόνες:
   • Όταν χρησιμοποιούνται μόνα τους, το κείμενο και οι ημερομηνίες θα πρέπει να περικλείονται σε εισαγωγικά, ενώ οι αριθμοί και οι αναφορές σε κελιά δεν θα πρέπει.
   • Όταν ένας αριθμός, μια ημερομηνία ή ένα κείμενο χρησιμοποιείται με έναν λογικό τελεστή, ολόκληρη η έκφραση πρέπει να περικλείεται σε διπλά εισαγωγικά όπως ">=10"- οι αναφορές κελιών και άλλες συναρτήσεις πρέπει να συνδέονται μεταξύ τους με τη χρήση μιας τελείας όπως ">"&G1.
7. Η λειτουργία MAXIFS είναι διαθέσιμη μόνο στο Excel 2019 και στο Excel για το Office 365. Σε προηγούμενες εκδόσεις, αυτή η λειτουργία δεν είναι διαθέσιμη.

Έτσι μπορείτε να βρείτε τη μέγιστη τιμή στο Excel με συνθήκες. Σας ευχαριστώ για την ανάγνωση και ελπίζω να σας δω σύντομα στο blog μας!

Κατεβάστε το βιβλίο ασκήσεων:

Παραδείγματα τύπων MAXIFS του Excel (.xlsx αρχείο)