Tutorial menunjukkan cara menggunakan fungsi MAXIFS dalam Excel untuk mendapatkan nilai maksimum dengan syarat.

Secara tradisinya, apabila anda perlu mencari nilai tertinggi dengan syarat dalam Excel, anda terpaksa membina formula MAX IF anda sendiri. Walaupun bukan masalah besar untuk pengguna berpengalaman, itu mungkin menimbulkan kesukaran tertentu untuk orang baru kerana, pertama, anda harus mengingati sintaks formula dan, kedua, anda perlu tahu cara bekerja dengan formula tatasusunan. Nasib baik, Microsoft baru-baru ini telah memperkenalkan fungsi baharu yang membolehkan kami melakukan maks bersyarat dengan cara yang mudah!

Fungsi Excel MAXIFS

Fungsi MAXIFS mengembalikan nilai angka terbesar dalam julat yang ditentukan berdasarkan satu atau lebih kriteria.

Sintaks fungsi MAXIFS adalah seperti berikut:

Di mana:

• Julat_Maks (diperlukan) - julat sel yang anda mahu cari nilai maksimum.
• Julat_Kriteria1 (diperlukan) - julat pertama untuk dinilai dengan kriteria1 .
• Kriteria1 - syarat untuk digunakan pada julat pertama. Ia boleh diwakili dengan nombor, teks atau ungkapan.
• Kriteria_julat2 / kriteria2 , …(pilihan) - julat tambahan dan kriteria berkaitannya. Sehingga 126 pasangan julat/kriteria disokong.

Fungsi MAXIFS ini tersedia dalam Excel 2019, Excel 2021 danExcel untuk Microsoft 365 pada Windows dan Mac.

Sebagai contoh, mari cari pemain bola sepak tertinggi di sekolah tempatan kita. Dengan mengandaikan ketinggian pelajar berada dalam sel D2:D11 (julat_maks) dan sukan berada dalam B2:B11 (julat_kriteria1), gunakan perkataan "bola sepak" sebagai kriteria1 dan anda akan mendapat formula ini:

=MAXIFS(D2:D11, B2:B11, "football")

Untuk menjadikan formula lebih serba boleh, anda boleh memasukkan sukan sasaran dalam beberapa sel (katakan, G1) dan memasukkan rujukan sel dalam hujah kriteria1 :

=MAXIFS(D2:D11, B2:B11, G1)

Nota. Argumen julat_maks dan julat_kriteria mestilah mempunyai saiz dan bentuk yang sama, iaitu mengandungi bilangan baris dan lajur yang sama, jika tidak, #VALUE! ralat dikembalikan.

Cara menggunakan fungsi MAXIFS dalam Excel - contoh formula

Seperti yang baru anda lihat, Excel MAXIFS agak mudah dan mudah digunakan. Walau bagaimanapun, ia mempunyai beberapa nuansa kecil yang membuat perbezaan besar. Dalam contoh di bawah, kami akan cuba memanfaatkan maksimum bersyarat dalam Excel.

Cari nilai maksimum berdasarkan berbilang kriteria

Dalam bahagian pertama tutorial ini, kami mencipta formula MAXIFS dalam bentuk yang paling mudah untuk mendapatkan nilai maksimum berdasarkan satu syarat. Sekarang, kita akan mengambil contoh itu dengan lebih lanjut dan menilai dua kriteria berbeza.

Andaikata, anda ingin mencari pemain bola keranjang tertinggi di sekolah rendah. Untuk melakukannya, tentukan perkara berikutargumen:

• Julat_Max - julat sel yang mengandungi ketinggian - D2:D11.
• Julat_Kriteria1 - julat sel yang mengandungi sukan - B2:B11.
• Kriteria1 - "bola keranjang", yang merupakan input dalam sel G1.
• Julat_Kriteria2 - julat sel yang mentakrifkan jenis sekolah - C2:C11.
• Kriteria2 - "junior", yang merupakan input dalam sel G2.

Menggabungkan argumen, kita mendapat formula ini :

Dengan kriteria "hardcoded":

=MAXIFS(D2:D11, B2:B11, "basketball", C2:C11, "junior")

Dengan kriteria dalam sel pratakrif:

=MAXIFS(D2:D11, B2:B11, G1, C2:C11, G2)

Sila ambil perhatian bahawa MAXIFS fungsi dalam Excel adalah tidak sensitif huruf besar , jadi anda tidak perlu risau tentang huruf besar dalam kriteria anda.

Sekiranya anda bercadang untuk menggunakan anda formula pada berbilang sel, pastikan anda mengunci semua julat dengan rujukan sel mutlak, seperti ini:

=MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2)

Ini akan memastikan formula menyalin ke sel lain dengan betul - rujukan kriteria berubah berdasarkan pada kedudukan relatif sel di mana formula disalin semasa t julatnya kekal tidak berubah:

Sebagai bonus tambahan, saya akan menunjukkan kepada anda cara cepat untuk mengekstrak nilai daripada sel lain yang dikaitkan dengan nilai maksimum. Dalam kes kami, itu akan menjadi nama orang yang paling tinggi. Untuk ini, kami akan menggunakan formula INDEX MATCH klasik dan sarang MAXIFS dalam argumen pertama MATCH sebagai nilai carian:

=INDEX($A$2:$A$11, MATCH(MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2), $D$2:$D$11, 0))

Formula memberitahu kami bahawa namadaripada pemain bola keranjang tertinggi di sekolah rendah ialah Liam:

Excel MAXIFS dengan operator logik

Dalam situasi apabila anda perlu menilai kriteria angka, gunakan operator logik seperti:

• lebih besar daripada (>)
• kurang daripada (<)
• lebih besar daripada atau sama dengan (>=)
• kurang daripada atau sama dengan (<=)
• tidak sama dengan ()

Pengendali "sama dengan" (=) boleh diabaikan dalam kebanyakan kes.

Biasanya, memilih operator tidak menjadi masalah, bahagian yang paling rumit ialah membina kriteria dengan sintaks yang betul. Begini caranya:

• Pengendali logik yang diikuti dengan nombor atau teks mesti disertakan dalam petikan berganda seperti ">=14" atau "berjalan".
• Sekiranya sel rujukan atau fungsi lain, gunakan petikan untuk memulakan rentetan dan ampersand untuk menggabungkan rujukan dan menamatkan rentetan itu, mis. ">"&B1 atau "<"&TODAY().

Untuk melihat cara ia berfungsi dalam amalan, mari tambah lajur Umur (lajur C) pada jadual sampel kami dan cari ketinggian maksimum dalam kalangan kanak-kanak lelaki berumur antara 13 dan 14. Ini boleh dilakukan dengan kriteria berikut:

Kriteria1: ">=13"

Kriteria2: "<=14"

Oleh kerana kami membandingkan nombor dalam lajur yang sama, julat_kriteria dalam kedua-dua kes adalah sama (C2:C11):

=MAXIFS(D2:D11, C2:C11, ">=13", C2:C11, "<=14")

Jika anda tidak mahu kod keras kriteria dalam formula, masukkannya dalam sel berasingan (cth. G1 dan H1) dan gunakan yang berikutsintaks:

=MAXIFS(D2:D11, C2:C11, ">="&G1, C2:C11, "<="&H1)

Tangkapan skrin di bawah menunjukkan keputusan:

Selain nombor, pengendali logik juga boleh berfungsi dengan kriteria teks. Khususnya, pengendali "tidak sama dengan" berguna apabila anda ingin mengecualikan sesuatu daripada pengiraan anda. Contohnya, untuk mencari pelajar tertinggi dalam semua sukan tidak termasuk bola tampar, gunakan formula berikut:

=MAXIFS(D2:D11, B2:B11, "volleyball")

Atau yang ini, dengan G1 ialah sukan yang dikecualikan:

=MAXIFS(D2:D11, B2:B11, ""&G1)

Formula MAXIFS dengan aksara kad bebas (separa padanan)

Untuk menilai keadaan yang mengandungi teks atau aksara tertentu, masukkan salah satu daripada aksara kad bebas berikut dalam kriteria anda:

• Tanda soal (?) untuk memadankan mana-mana aksara tunggal.
• Asterisk (*) untuk memadankan mana-mana jujukan aksara.

Untuk contoh ini, mari kita ketahui lelaki paling tinggi dalam sukan permainan. Oleh kerana nama semua sukan permainan dalam set data kami berakhir dengan perkataan "bola", kami memasukkan perkataan ini dalam kriteria dan menggunakan asterisk untuk memadankan mana-mana aksara sebelumnya:

=MAXIFS(D2:D11, B2:B11, "*ball")

Anda boleh taip juga "bola" dalam beberapa sel, cth. G1 dan gabungkan aksara kad bebas dengan rujukan sel:

=MAXIFS(D2:D11, B2:B11, "*"&G1)

Hasilnya akan kelihatan seperti berikut:

Dapatkan nilai maksimum dalam julat tarikh

Oleh kerana tarikh disimpan sebagai nombor siri dalam sistem Excel dalaman, anda bekerja dengan kriteria tarikh dengan cara yang sama seperti anda bekerja dengan nombor.

Untukmenggambarkan ini, kami akan menggantikan lajur Umur dengan Tarikh Lahir dan cuba menentukan ketinggian maksimum dalam kalangan kanak-kanak lelaki yang lahir pada tahun tertentu, katakan pada tahun 2004. Untuk menyelesaikan tugasan ini , kita perlu "menapis" tarikh lahir yang lebih besar daripada atau sama dengan 1-Jan-2004 dan kurang daripada atau sama dengan 31-Dis-2004.

Apabila membina kriteria anda, adalah penting untuk anda berikan tarikh dalam format yang Excel boleh fahami:

=MAXIFS(D2:D11, C2:C11, ">=1-Jan-2004", C2:C11, "<=31-Dec-2004")

Atau

=MAXIFS(D2:D11, C2:C11, ">=1/1/2004", C2:C11, "<=12/31/2004")

Untuk mengelakkan salah tafsir, adalah wajar untuk menggunakan fungsi DATE :

=MAXIFS(D2:D11, C2:C11, ">="&DATE(2004,1,1), C2:C11, "<="&DATE(2004,12,31))

Untuk contoh ini, kami akan menaip tahun sasaran dalam G1, dan kemudian menggunakan fungsi DATE untuk membekalkan tarikh:

=MAXIFS(D2:D11, C2:C11, ">="&DATE(G1,1,1), C2:C11, "<="&DATE(G1,12,31))

Nota. Tidak seperti nombor, tarikh hendaklah disertakan dalam tanda petikan apabila digunakan dalam kriteria sendiri. Contohnya:

=MAXIFS(D2:D11, C2:C11, "10/5/2005")

Cari nilai maksimum berdasarkan berbilang kriteria dengan logik OR

Fungsi Excel MAXIFS direka untuk menguji keadaan dengan logik AND - iaitu ia memproses nombor tersebut sahaja dalam julat_maks yang mana semua kriterianya adalah BENAR. Walau bagaimanapun, dalam sesetengah situasi, anda mungkin perlu menilai keadaan dengan logik OR - iaitu memproses semua nombor yang mana mana-mana kriteria yang dinyatakan adalah BENAR.

Untuk memudahkan perkara difahami, sila pertimbangkan perkara berikut contoh. Andaikan anda ingin mencari ketinggian maksimum lelaki yang bermain bola keranjang ataubola sepak. Bagaimana anda akan melakukannya? Menggunakan "bola keranjang" sebagai kriteria1 dan sebagai kriteria "bola sepak"2 tidak akan berfungsi, kerana Excel akan menganggap bahawa kedua-dua kriteria harus dinilai kepada BENAR.

Penyelesaian adalah untuk membuat 2 formula MAXIFS berasingan, satu untuk setiap sukan, dan kemudian gunakan fungsi MAX lama yang baik untuk mengembalikan nombor yang lebih tinggi:

=MAX(MAXIFS(C2:C11, B2:B11, "basketball"), MAXIFS(C2:C11, B2:B11, "football"))

Tangkapan skrin di bawah menunjukkan formula ini tetapi dengan kriteria dalam sel input yang dipratentukan, F1 dan H1:

Cara lain ialah menggunakan formula MAX IF dengan logik ATAU.

7 perkara yang perlu diingat tentang Excel MAXIFS

Di bawah anda akan menemui beberapa kenyataan yang akan membantu untuk menambah baik formula anda dan mengelakkan ralat biasa. Beberapa pemerhatian ini telah pun dibincangkan sebagai petua dan nota dalam contoh kami, tetapi mungkin berguna untuk mendapatkan ringkasan ringkas tentang perkara yang telah anda pelajari:

1. Fungsi MAXIFS dalam Excel boleh mendapatkan nilai tertinggi berdasarkan satu atau berbilang kriteria .
2. Secara lalai, Excel MAXIFS berfungsi dengan DAN logik , iaitu mengembalikan nombor maksimum yang memenuhi semua syarat yang ditentukan.
3. Untuk fungsi berfungsi, julat maks dan julat kriteria mesti mempunyai saiz dan bentuk yang sama.
4. Fungsi SUMIF adalah tidak peka huruf besar-kecil , iaitu ia tidak mengecam huruf besar dalam kriteria teks.
5. Apabila menulis formula MAXIFS untuk berbilang sel, ingat untuk kunci julat denganrujukan sel mutlak untuk formula disalin dengan betul.
6. Perhatikan sintaks kriteria anda ! Berikut ialah peraturan utama:
   • Apabila digunakan sendiri, teks dan tarikh hendaklah disertakan dalam tanda petikan, nombor dan rujukan sel tidak sepatutnya.
   • Apabila nombor, tarikh atau teks digunakan dengan pengendali logik, keseluruhan ungkapan mesti disertakan dalam petikan berganda seperti ">=10"; rujukan sel dan fungsi lain mesti digabungkan dengan menggunakan ampersand seperti ">"&G1.
7. MAXIFS hanya tersedia dalam Excel 2019 dan Excel untuk Office 365. Dalam versi terdahulu, fungsi ini tidak tersedia.

Begitulah anda boleh mencari nilai maksimum dalam Excel dengan syarat. Saya mengucapkan terima kasih kerana membaca dan berharap dapat berjumpa anda di blog kami tidak lama lagi!

Muat turun buku kerja latihan:

Contoh formula Excel MAXIFS (fail.xlsx)