O titorial mostra como usar a función MAXIFS en Excel para obter o valor máximo con condicións.

Tradicionalmente, cando sempre necesitaba atopar o valor máis alto con condicións en Excel, tiveches que construír a túa propia fórmula MAX IF. Aínda que non é un gran problema para os usuarios experimentados, isto pode presentar certas dificultades para os novatos porque, en primeiro lugar, debes lembrar a sintaxe da fórmula e, en segundo lugar, debes saber como traballar con fórmulas matriciales. Afortunadamente, Microsoft presentou recentemente unha nova función que nos permite facer o máximo condicional dun xeito sinxelo!

Función MAXIFS de Excel

A función MAXIFS devolve o maior valor numérico do intervalo especificado en base a un ou máis criterios.

A sintaxe da función MAXIFS é a seguinte:

Onde:

• Intervalo_máx. (obrigatorio): o intervalo de celas onde quere atopar o valor máximo.
• Intervalo_criterio1 (obrigatorio) - o primeiro intervalo a avaliar con criterio1 .
• Criterio1 : a condición que se debe utilizar no primeiro intervalo. Pódese representar mediante un número, texto ou expresión.
• Intervalo_criterio2 / criterio2 , …(opcional) - intervalos adicionais e os seus criterios relacionados. Admítense ata 126 pares de intervalos/criterios.

Esta función MAXIFS está dispoñible en Excel 2019, Excel 2021 eExcel para Microsoft 365 en Windows e Mac.

Como exemplo, busquemos o xogador de fútbol máis alto da nosa escola local. Asumindo que a altura dos estudantes está nas celas D2:D11 (max_range) e os deportes están en B2:B11 (criteria_range1), use a palabra "fútbol" como criterio1 e obterá esta fórmula:

=MAXIFS(D2:D11, B2:B11, "football")

Para facer a fórmula máis versátil, pode introducir o deporte obxectivo nalgunha cela (por exemplo, G1) e incluír a referencia da cela no argumento criterio1 :

=MAXIFS(D2:D11, B2:B11, G1)

Nota. Os argumentos max_range e criteria_range deben ter o mesmo tamaño e forma, é dicir, conter o mesmo número de filas e columnas, se non, o #VALOR! devólvese o erro.

Como usar a función MAXIFS en Excel - exemplos de fórmulas

Como acabas de ver, o MAXIFS de Excel é bastante sinxelo e fácil de usar. Non obstante, ten algúns pequenos matices que marcan unha gran diferenza. Nos exemplos seguintes, tentaremos aproveitar ao máximo o máximo condicional en Excel.

Atopa o valor máximo en función de varios criterios

Na primeira parte deste tutorial, creamos unha fórmula MAXIFS na súa forma máis sinxela para obter o valor máximo baseado nunha condición. Agora, imos levar ese exemplo máis alá e avaliar dous criterios diferentes.

Supoño que queres atopar o xogador de baloncesto máis alto da escola infantil. Para facelo, defina o seguinteargumentos:

• Rango_máx. - un intervalo de celas que contén alturas - D2:D11.
• Rango_criterio1 - un intervalo de celas que contén deportes - B2:B11.
• Criterios1 - "baloncesto", que se introduce na cela G1.
• Rango_criterios2 : un intervalo de celas que define o tipo de escola - C2:C11.
• Criterios2 - "junior", que se introduce na cela G2.

Xuntando os argumentos, obtemos estas fórmulas :

Con criterios "codificados":

=MAXIFS(D2:D11, B2:B11, "basketball", C2:C11, "junior")

Con criterios en celas predefinidas:

=MAXIFS(D2:D11, B2:B11, G1, C2:C11, G2)

Ten en conta que o MAXIFS a función en Excel é insensible entre maiúsculas e minúsculas , polo que non debe preocuparse polas letras maiúsculas dos seus criterios.

No caso de que planea usar o seu criterio. fórmula en varias celas, asegúrese de bloquear todos os intervalos con referencias de cela absolutas, como esta:

=MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2)

Isto asegurará que a fórmula se copie a outras celas correctamente; as referencias de criterios cambian segundo na posición relativa da cela onde se copia a fórmula mentres t os intervalos permanecen inalterados:

Como extra extra, mostrarei un xeito rápido de extraer un valor doutra cela que estea asociado co valor máximo. No noso caso, ese será o nome da persoa máis alta. Para iso, usaremos a fórmula clásica INDEX MATCH e anidaremos MAXIFS no primeiro argumento de MATCH como valor de busca:

=INDEX($A$2:$A$11, MATCH(MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2), $D$2:$D$11, 0))

A fórmula indícanos que o nomeO xogador de baloncesto máis alto da escola infantil é Liam:

Excel MAXIFS con operadores lóxicos

Na situación na que necesites avaliar criterios numéricos, utiliza operadores lóxicos como:

• maior que (>)
• menor que (<)
• maior ou igual a (>=)
• menor ou igual a (<=)
• non igual a ()

O operador "igual a" (=) pódese omitir na maioría dos casos.

Normalmente, escoller un operador non é un problema, o máis complicado é construír criterios coa sintaxe correcta. Vexa como:

• Un operador lóxico seguido dun número ou texto debe ir entre comiñas dobres como ">=14" ou "en execución".
• No caso dunha cela referencia ou outra función, use as comiñas para comezar unha cadea e un ampersand para concatenar a referencia e rematar a cadea, p. ex. ">"&B1 ou "<"&HOXE().

Para ver como funciona na práctica, engademos a columna Idade (columna C) á nosa táboa de mostra e busquemos a estatura máxima entre os rapaces de entre 13 e 14 anos. Pódese facer cos seguintes criterios:

Criterios1: ">=13"

Criterios2: "<=14"

Debido a que comparamos os números da mesma columna, criteria_range en ambos casos é o mesmo (C2:C11):

=MAXIFS(D2:D11, C2:C11, ">=13", C2:C11, "<=14")

Se non quere codificar os criterios na fórmula, introdúceos en celas separadas (por exemplo, G1 e H1) e usa o seguintesintaxe:

=MAXIFS(D2:D11, C2:C11, ">="&G1, C2:C11, "<="&H1)

A seguinte captura de pantalla mostra o resultado:

Ademais dos números, os operadores lóxicos tamén poden traballar con criterios de texto. En particular, o operador "non igual a" é útil cando queres excluír algo dos teus cálculos. Por exemplo, para atopar o alumno máis alto de todos os deportes, excepto o voleibol, use a seguinte fórmula:

=MAXIFS(D2:D11, B2:B11, "volleyball")

Ou esta, onde G1 é o deporte excluído:

=MAXIFS(D2:D11, B2:B11, ""&G1)

Fórmulas MAXIFS con caracteres comodín (coincidencia parcial)

Para avaliar unha condición que conteña un texto ou carácter específico, inclúa un dos seguintes caracteres comodín en os teus criterios:

• Signo de interrogación (?) para que coincida con calquera carácter.
• Asterisco (*) para que coincida con calquera secuencia de caracteres.

Para este exemplo, imos descubrir o mozo máis alto dos deportes de xogo. Dado que os nomes de todos os deportes do noso conxunto de datos rematan coa palabra "pelota", incluímos esta palabra nos criterios e utilizamos un asterisco para facer coincidir os caracteres anteriores:

=MAXIFS(D2:D11, B2:B11, "*ball")

Podes tamén escribe "bola" nalgunha cela, por exemplo. G1 e concatena o carácter comodín coa referencia da cela:

=MAXIFS(D2:D11, B2:B11, "*"&G1)

O resultado será o seguinte:

Obter o valor máximo dentro dun intervalo de datas

Debido a que as datas se almacenan como números de serie no sistema interno de Excel, traballas cos criterios de datas do mesmo xeito que traballas cos números.

ParaPara ilustralo, substituiremos a columna Idade por Data de nacemento e tentaremos calcular a estatura máxima entre os nenos nacidos nun determinado ano, por exemplo, en 2004. Para realizar esta tarefa , necesitamos "filtrar" as datas de nacemento que sexan maiores ou iguais ao 1-xan-2004 e inferiores ou iguais ao 31-dec-2004.

Ao crear os teus criterios, é importante que ti proporcione as datas no formato que Excel poida entender:

=MAXIFS(D2:D11, C2:C11, ">=1-Jan-2004", C2:C11, "<=31-Dec-2004")

Ou

=MAXIFS(D2:D11, C2:C11, ">=1/1/2004", C2:C11, "<=12/31/2004")

Para evitar interpretacións erróneas, ten sentido utilizar a función DATE :

=MAXIFS(D2:D11, C2:C11, ">="&DATE(2004,1,1), C2:C11, "<="&DATE(2004,12,31))

Para este exemplo, escribiremos o ano de destino en G1 e, a continuación, usaremos a función DATA para proporcionar as datas:

=MAXIFS(D2:D11, C2:C11, ">="&DATE(G1,1,1), C2:C11, "<="&DATE(G1,12,31))

Nota. A diferenza dos números, as datas deben ir entre comiñas cando se usan nos criterios por si soas. Por exemplo:

=MAXIFS(D2:D11, C2:C11, "10/5/2005")

Atopa o valor máximo baseado en varios criterios con lóxica OU

A función MAXIFS de Excel está deseñada para probar as condicións coa lóxica AND, é dicir, procesa só eses números en max_range para o que todos os criterios son VERDADEIROS. Con todo, nalgunhas situacións, é posible que necesites avaliar as condicións coa lóxica OU, é dicir, procesar todos os números para os que algún dos criterios especificados é VERDADEIRO.

Para facilitar a comprensión das cousas, ten en conta o seguinte exemplo. Supoñamos que queres atopar a estatura máxima dos rapaces que xogan ou ben ao baloncestofútbol. Como farías iso? Usar "baloncesto" como criterio1 e como criterio de "fútbol"2 non funcionará, porque Excel suporía que ambos os criterios deberían avaliarse como VERDADEIRO.

A solución é facer dúas fórmulas MAXIFS separadas, unha por cada deporte, e, a continuación, use a boa antiga función MAX para devolver un número máis alto:

=MAX(MAXIFS(C2:C11, B2:B11, "basketball"), MAXIFS(C2:C11, B2:B11, "football"))

A captura de pantalla a continuación mostra esta fórmula pero cos criterios en celas de entrada predefinidas, F1 e H1:

Outro xeito é utilizar unha fórmula MAX IF con lóxica OU.

7 cousas para recordar sobre Excel MAXIFS

A continuación atoparás algunhas observacións que axudará a mellorar as súas fórmulas e evitar erros comúns. Algunhas destas observacións xa se comentaron como consellos e notas nos nosos exemplos, pero pode ser útil obter un pequeno resumo do que xa aprendeu:

1. A función MAXIFS en Excel pode obter o valor máis alto baseado en un ou múltiples criterios .
2. Por defecto, Excel MAXIFS funciona coa lóxica AND , é dicir, devolve o número máximo que cumpra todas as condicións especificadas.
3. Para que a función funcione, o intervalo máximo e os intervalos de criterios deben ter o mesmo tamaño e forma .
4. A función SUMIF é insensible entre maiúsculas e minúsculas , é dicir, non recoñece as letras maiúsculas nos criterios de texto.
5. Ao escribir unha fórmula MAXIFS para varias celas, recorda bloquear o intervalos conreferencias de cela absolutas para que a fórmula se copie correctamente.
6. Ten en conta a sintaxe dos teus criterios ! Estas son as principais regras:
   • Cando se usan por si só, o texto e as datas deben ir entre comiñas, os números e as referencias de celas non.
   • Cando se usa un número, data ou texto. cun operador lóxico, a expresión completa debe ir entre comiñas dobres como ">=10"; as referencias de celas e outras funcións deben concatenarse mediante un ampersand como ">"&G1.
7. MAXIFS só está dispoñible en Excel 2019 e Excel para Office 365. Nas versións anteriores, esta función non está dispoñible.

Así podes atopar o valor máximo en Excel con condicións. Grazas por ler e espero verte pronto no noso blog!

Descargar o libro de prácticas:

Exemplos de fórmulas de Excel MAXIFS (ficheiro .xlsx)