튜토리얼에서는 Excel에서 MAXIFS 함수를 사용하여 조건으로 최대값을 구하는 방법을 보여줍니다.

전통적으로 Excel에서 조건으로 최대값을 찾아야 할 때 자신만의 MAX IF 공식을 만들어야 했습니다. 숙련된 사용자에게는 큰 문제가 아니지만, 첫 번째로 수식의 구문을 기억해야 하고 두 번째로 배열 수식을 사용하는 방법을 알아야 하기 때문에 초보자에게는 특정 어려움이 있을 수 있습니다. 운 좋게도 Microsoft는 최근 조건부 최대화를 쉽게 수행할 수 있는 새로운 함수를 도입했습니다!

Excel MAXIFS 함수

MAXIFS 함수는 가장 큰 숫자 값을 반환합니다. 하나 이상의 기준에 따라 지정된 범위.

MAXIFS 함수의 구문은 다음과 같습니다.

여기서:

• Max_range (필수) - 최대값을 찾으려는 셀 범위입니다.
• Criteria_range1 (필수) - criteria1 로 평가할 첫 번째 범위.
• Criteria1 - 첫 번째 범위에서 사용할 조건. 숫자, 텍스트 또는 식으로 나타낼 수 있습니다.
• Criteria_range2 / criteria2 , …(선택 사항) - 추가 범위 및 관련 기준. 최대 126개의 범위/기준 쌍이 지원됩니다.

이 MAXIFS 기능은 Excel 2019, Excel 2021 및Windows 및 Mac의 Microsoft 365용 Excel.

예를 들어 우리 지역 학교에서 가장 키가 큰 축구 선수를 찾아보겠습니다. 학생의 키가 셀 D2:D11(max_range)에 있고 스포츠가 B2:B11(criteria_range1)에 있다고 가정하고 "축구"라는 단어를 criteria1로 사용하면 다음 공식을 얻을 수 있습니다.

=MAXIFS(D2:D11, B2:B11, "football")

공식을 더 다양하게 만들려면 일부 셀(예: G1)에 대상 스포츠를 입력하고 기준1 인수에 셀 참조를 포함할 수 있습니다:

=MAXIFS(D2:D11, B2:B11, G1)

참고. max_range 및 criteria_range 인수는 크기와 모양이 같아야 합니다. 즉, 동일한 수의 행과 열을 포함해야 합니다. 그렇지 않으면 #VALUE! 오류가 반환됩니다.

Excel에서 MAXIFS 함수를 사용하는 방법 - 수식 예제

방금 살펴본 것처럼 Excel MAXIFS는 매우 간단하고 사용하기 쉽습니다. 그러나 큰 차이를 만드는 몇 가지 작은 뉘앙스가 있습니다. 아래 예에서는 Excel에서 조건부 최대값을 최대한 활용하려고 합니다.

여러 기준을 기반으로 최대값 찾기

이 자습서의 첫 번째 부분에서는 MAXIFS 수식을 만들었습니다. 가장 간단한 형태로 하나의 조건에 따라 최대값을 얻습니다. 이제 이 예를 더 살펴보고 두 가지 기준을 평가해 보겠습니다.

중학교에서 가장 키가 큰 농구 선수를 찾고 싶다고 가정해 보겠습니다. 완료하려면 다음을 정의하십시오.arguments:

• Max_range - 높이를 포함하는 셀 범위 - D2:D11.
• Criteria_range1 - 스포츠를 포함하는 셀 범위 - B2:B11.
• Criteria1 - G1 셀에 입력되는 "농구".
• Criteria_range2 - 다음을 정의하는 셀 범위 학교 유형 - C2:C11.
• Criteria2 - 셀 G2에 입력되는 "주니어".

인수를 함께 넣으면 다음 공식을 얻습니다. :

"하드코딩된" 기준:

=MAXIFS(D2:D11, B2:B11, "basketball", C2:C11, "junior")

사전 정의된 셀의 기준:

=MAXIFS(D2:D11, B2:B11, G1, C2:C11, G2)

MAXIFS는 Excel의 함수는 대소문자 구분 이므로 기준에서 대소문자에 대해 걱정할 필요가 없습니다.

여러 셀에 수식을 사용하려면 다음과 같이 절대 셀 참조로 모든 범위를 잠가야 합니다.

=MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2)

이렇게 하면 수식이 다른 셀에 올바르게 복사됩니다. t 동안 수식이 복사되는 셀의 상대적 위치 범위는 변경되지 않습니다.

추가 보너스로 최대 값과 연결된 다른 셀에서 값을 추출하는 빠른 방법을 보여 드리겠습니다. 우리의 경우 가장 키가 큰 사람의 이름이 됩니다. 이를 위해 MATCH의 첫 번째 인수에서 고전적인 INDEX MATCH 공식과 중첩 MAXIFS를 조회 값으로 사용합니다.

=INDEX($A$2:$A$11, MATCH(MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2), $D$2:$D$11, 0))

공식은 이름이중학교에서 가장 키가 큰 농구 선수 중 Liam:

논리 연산자가 포함된 Excel MAXIFS

숫자 기준을 평가해야 하는 상황에서 논리 연산자 사용 예:

• 보다 큼(>)
• 미만(<)
• 크거나 같음(>=)
• 작거나 같음(<=)
• 같지 않음()

"같음" 연산자(=)는 대부분의 경우 생략할 수 있습니다.

일반적으로 연산자를 선택하는 것은 문제가 아니며 가장 까다로운 부분은 올바른 구문으로 기준을 구축하는 것입니다. 방법은 다음과 같습니다.

• 숫자 또는 텍스트가 뒤에 오는 논리 연산자는 ">=14" 또는 "running"과 같이 큰따옴표로 묶어야 합니다.
• 셀의 경우 참조 또는 다른 함수의 경우 따옴표를 사용하여 문자열을 시작하고 앰퍼샌드를 사용하여 참조를 연결하고 문자열을 끝냅니다. ">"&B1 또는 "<"&TODAY().

실제 작동 방식을 확인하기 위해 샘플 테이블에 연령 열(열 C)을 추가하고 다음을 찾아보겠습니다. 13세에서 14세 사이의 소년 중 최대 키입니다. 이는 다음 기준으로 수행할 수 있습니다.

기준 1: ">=13"

기준 2: "<=14"

같은 열의 숫자를 비교하기 때문에 두 경우 모두 criteria_range가 동일합니다(C2:C11):

=MAXIFS(D2:D11, C2:C11, ">=13", C2:C11, "<=14")

기준을 하드코딩하지 않으려는 경우 수식에서 별도의 셀(예: G1 및 H1)에 입력하고 다음을 사용합니다.구문:

=MAXIFS(D2:D11, C2:C11, ">="&G1, C2:C11, "<="&H1)

아래 스크린샷은 결과를 보여줍니다.

숫자 외에도 논리 연산자는 텍스트 기준으로도 작업할 수 있습니다. 특히 "같지 않음" 연산자는 계산에서 제외하려는 경우에 유용합니다. 예를 들어, 배구를 제외한 모든 스포츠에서 가장 키가 큰 학생을 찾으려면 다음 공식을 사용하십시오.

와일드카드 문자가 있는 MAXIFS 수식(부분 일치)

특정 텍스트나 문자가 포함된 조건을 평가하려면 다음 와일드카드 문자 중 하나를 기준:

• 단일 문자와 일치하는 물음표(?)
• 모든 문자 시퀀스와 일치하는 별표(*)

이 예에서는 게임 스포츠에서 가장 키가 큰 남자를 찾아봅시다. 데이터 세트에 있는 모든 게임 스포츠의 이름은 "공"이라는 단어로 끝나기 때문에 이 단어를 기준에 포함하고 별표를 사용하여 이전 문자와 일치시킵니다.

=MAXIFS(D2:D11, B2:B11, "*ball")

다음과 같이 할 수 있습니다. 또한 일부 셀에 "ball"을 입력합니다. G1, 와일드카드 문자를 셀 참조와 연결:

=MAXIFS(D2:D11, B2:B11, "*"&G1)

결과는 다음과 같습니다.

최대 값 가져오기 날짜 범위 내

날짜는 내부 Excel 시스템에 일련 번호로 저장되기 때문에 숫자로 작업하는 것과 동일한 방식으로 날짜 기준으로 작업합니다.

To이를 설명하기 위해 Age 열을 Date of Birth 로 바꾸고 특정 연도(예: 2004년)에 태어난 남자아이의 최대 키를 알아내려고 합니다. 이 작업을 수행하기 위해 , 2004년 1월 1일보다 크거나 같고 2004년 12월 31일보다 작거나 같은 생년월일을 "필터링"해야 합니다.

기준을 작성할 때 다음 사항이 중요합니다. Excel이 이해할 수 있는 형식으로 날짜를 제공합니다.

=MAXIFS(D2:D11, C2:C11, ">=1-Jan-2004", C2:C11, "<=31-Dec-2004")

또는

=MAXIFS(D2:D11, C2:C11, ">=1/1/2004", C2:C11, "<=12/31/2004")

오해를 방지하려면 DATE 함수를 활용하는 것이 좋습니다. :

=MAXIFS(D2:D11, C2:C11, ">="&DATE(2004,1,1), C2:C11, "<="&DATE(2004,12,31))

이 예에서는 목표 연도를 G1에 입력한 다음 DATE 함수를 사용하여 날짜를 제공합니다.

=MAXIFS(D2:D11, C2:C11, ">="&DATE(G1,1,1), C2:C11, "<="&DATE(G1,12,31))

참고. 숫자와 달리 날짜는 단독으로 기준에 사용될 때 따옴표로 묶어야 합니다. 예:

=MAXIFS(D2:D11, C2:C11, "10/5/2005")

OR 논리를 사용하여 여러 기준을 기반으로 최대값 찾기

Excel MAXIFS 기능은 AND 논리를 사용하여 조건을 테스트하도록 설계되었습니다. 즉, 해당 숫자만 처리합니다. 모든 기준이 TRUE인 max_range 에서. 그러나 경우에 따라 OR 논리로 조건을 평가해야 할 수도 있습니다. 즉, 지정된 기준이 TRUE인 모든 숫자를 처리해야 합니다.

이해를 더 쉽게 하려면 다음을 고려하세요. 예시. 농구 또는 농구를 하는 남자의 최대 키를 찾고 싶다고 가정해 보겠습니다축구. 어떻게 하시겠습니까? "농구"를 기준1 및 "축구" 기준2로 사용하면 작동하지 않습니다. Excel에서 두 기준이 모두 TRUE로 평가되어야 한다고 가정하기 때문입니다.

해법은 각 스포츠당 하나씩 2개의 별도 MAXIFS 공식을 만드는 것입니다. 그런 다음 기존 MAX 함수를 사용하여 더 높은 숫자를 반환합니다.

=MAX(MAXIFS(C2:C11, B2:B11, "basketball"), MAXIFS(C2:C11, B2:B11, "football"))

아래 스크린샷은 이 수식을 보여주지만 미리 정의된 입력 셀 F1 및 H1의 기준을 사용합니다.

또 다른 방법은 MAX IF 수식을 OR 논리와 함께 사용하는 것입니다.

Excel MAXIFS에 대해 기억해야 할 7가지 사항

다음은 몇 가지 참고 사항입니다. 공식을 개선하고 일반적인 오류를 피하는 데 도움이 됩니다. 이러한 관찰 중 일부는 예제에서 팁과 참고 사항으로 이미 논의되었지만 이미 학습한 내용에 대한 간략한 요약을 얻는 것이 도움이 될 수 있습니다.

1. Excel의 MAXIFS 함수는 다음을 얻을 수 있습니다. 하나 또는 여러 기준 을 기반으로 가장 높은 값.
2. 기본적으로 Excel MAXIFS는 AND 논리 와 함께 작동합니다. 즉, 최대 수를 반환합니다. 지정된 조건을 모두 충족합니다.
3. 기능이 작동하려면 최대 범위 및 기준 범위가 동일한 크기 및 모양 이어야 합니다.
4. SUMIF 함수는 대소문자를 구분하지 않습니다 . 즉, 텍스트 기준에서 대소문자를 인식하지 않습니다.
5. 여러 셀에 대한 MAXIFS 수식을 작성할 때 범위 수식을 올바르게 복사하기 위한 절대 셀 참조.
6. 기준 구문 에 주의하십시오! 주요 규칙은 다음과 같습니다.
   • 단독으로 사용할 경우 텍스트와 날짜는 따옴표로 묶어야 하며 숫자와 셀 참조는 안됩니다.
   • 숫자, 날짜 또는 텍스트를 사용할 경우 논리 연산자를 사용하는 경우 전체 표현식을 ">=10"과 같이 큰따옴표로 묶어야 합니다. 셀 참조 및 기타 함수는 ">"&G1과 같은 앰퍼샌드를 사용하여 연결해야 합니다.
7. MAXIFS는 Excel 2019 및 Excel for Office 365에서만 사용할 수 있습니다. 이전 버전에서는 이 기능은 사용할 수 없습니다.

조건으로 엑셀에서 최대값을 구하는 방법입니다. 읽어 주셔서 감사합니다. 곧 블로그에서 뵙기를 바랍니다!

연습 통합 문서 다운로드:

Excel MAXIFS 수식 예제(.xlsx 파일)