Die tutoriaal wys hoe om die MAXIFS-funksie in Excel te gebruik om die maksimum waarde met voorwaardes te kry.

Tradisioneel, wanneer jy ooit nodig gehad het om die hoogste waarde met voorwaardes in Excel te vind, jy moes jou eie MAX IF-formule bou. Alhoewel dit nie 'n groot probleem vir ervare gebruikers is nie, kan dit sekere probleme vir beginners inhou, want eerstens moet jy die formule se sintaksis onthou en tweedens moet jy weet hoe om met skikkingsformules te werk. Gelukkig het Microsoft onlangs 'n nuwe funksie bekendgestel waarmee ons voorwaardelike maksimum 'n maklike manier kan doen!

Excel MAXIFS-funksie

Die MAXIFS-funksie gee die grootste numeriese waarde in die gespesifiseerde reeks gebaseer op een of meer kriteria.

Die sintaksis van die MAXIFS-funksie is soos volg:

Waar:

• Maks_reeks (vereis) - die reeks selle waar jy die maksimum waarde wil vind.
• Kriteria_reeks1 (vereis) - die eerste reeks om te evalueer met kriteria1 .
• Kriteria1 - die voorwaarde om op die eerste reeks te gebruik. Dit kan deur 'n getal, teks of uitdrukking voorgestel word.
• Kriteriareeks2 / kriteria2 , …(opsioneel) - bykomende reekse en hul verwante kriteria. Tot 126 reeks/kriteria-pare word ondersteun.

Hierdie MAXIFS-funksie is beskikbaar in Excel 2019, Excel 2021 enExcel vir Microsoft 365 op Windows en Mac.

As 'n voorbeeld, kom ons vind die langste sokkerspeler in ons plaaslike skool. Gestel die studente se hoogtes is in selle D2:D11 (maks_reeks) en sport is in B2:B11 (kriteria_reeks1), gebruik die woord "sokker" as kriteria1, en jy sal hierdie formule kry:

=MAXIFS(D2:D11, B2:B11, "football")

Om die formule meer veelsydig te maak, kan jy die teikensport in een of ander sel invoer (bv. G1) en die selverwysing in die kriteria1 -argument insluit:

=MAXIFS(D2:D11, B2:B11, G1)

Let wel. Die argumente maksimum_reeks en kriteriareeks moet dieselfde grootte en vorm hê, d.w.s. die gelyke aantal rye en kolomme bevat, anders moet die #WAARDE! fout word teruggestuur.

Hoe om MAXIFS-funksie in Excel te gebruik - formulevoorbeelde

Soos jy sopas gesien het, is die Excel MAXIFS redelik eenvoudig en maklik om te gebruik. Dit het egter 'n paar klein nuanses wat 'n groot verskil maak. In die onderstaande voorbeelde sal ons probeer om die meeste van voorwaardelike maksimum in Excel te maak.

Vind maksimum waarde gebaseer op veelvuldige kriteria

In die eerste deel van hierdie tutoriaal het ons 'n MAXIFS-formule geskep in sy eenvoudigste vorm om die maksimum waarde gebaseer op een voorwaarde te kry. Nou gaan ons daardie voorbeeld verder neem en twee verskillende kriteria evalueer.

Gestel, jy wil die langste basketbalspeler in junior skool vind. Om dit te laat doen, definieer die volgendeargumente:

• Maks_reeks - 'n reeks selle wat hoogtes bevat - D2:D11.
• Kriteria_reeks1 - 'n reeks selle wat sport bevat - B2:B11.
• Kriteria1 - "basketbal", wat in sel G1 ingevoer word.
• Kriteriareeks2 - 'n reeks selle wat die skooltipe - C2:C11.
• Kriteria2 - "junior", wat ingevoer word in sel G2.

As ons die argumente bymekaar sit, kry ons hierdie formules :

Met "hardgekodeerde" kriteria:

=MAXIFS(D2:D11, B2:B11, "basketball", C2:C11, "junior")

Met kriteria in voorafbepaalde selle:

=MAXIFS(D2:D11, B2:B11, G1, C2:C11, G2)

Let asseblief kennis dat die MAXIFS funksie in Excel is hoofletter-onsensitief , so jy hoef nie bekommerd te wees oor die letterkas in jou kriteria nie.

In geval jy van plan is om jou formule op veelvuldige selle, maak seker dat jy al die reekse met absolute selverwysings sluit, soos volg:

=MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2)

Dit sal verseker dat die formule korrek na ander selle kopieer - die kriteriaverwysings verander op grond van op die relatiewe posisie van die sel waar die formule gekopieer word terwyl t Die reekse bly onveranderd:

As 'n ekstra bonus, sal ek jou 'n vinnige manier wys om 'n waarde uit 'n ander sel te onttrek wat met die maksimum waarde geassosieer word. In ons geval sal dit die naam van die langste persoon wees. Hiervoor sal ons die klassieke INDEX MATCH formule en nes MAXIFS in die eerste argument van MATCH as die opsoekwaarde gebruik:

=INDEX($A$2:$A$11, MATCH(MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2), $D$2:$D$11, 0))

Die formule sê vir ons dat die naamvan die langste basketbalspeler in junior skool is Liam:

Excel MAXIFS met logiese operateurs

In situasies wanneer jy numeriese kriteria moet evalueer, gebruik logiese operateurs soos:

• groter as (>)
• minder as (<)
• groter as of gelyk aan (>=)
• minder as of gelyk aan (<=)
• nie gelyk aan ()

Die "gelyk aan" operateur (=) kan in die meeste gevalle weggelaat word.

Gewoonlik is die keuse van 'n operateur nie 'n probleem nie, die moeilikste deel is om kriteria met die korrekte sintaksis te bou. Dit is hoe:

• 'n Logiese operateur gevolg deur 'n nommer of teks moet in dubbele aanhalingstekens ingesluit word soos ">=14" of "hardloop".
• In die geval van 'n sel verwysing of 'n ander funksie, gebruik die aanhalingstekens om 'n string en 'n ampersand te begin om die verwysing saam te voeg en die string af te maak, bv. ">"&B1 of "<"&TODAY().

Om te sien hoe dit in die praktyk werk, kom ons voeg die Ouderdomskolom (kolom C) by ons voorbeeldtabel en vind die maksimum lengte onder die seuns tussen 13 en 14. Dit kan gedoen word met die volgende kriteria:

Kriteria1: ">=13"

Kriteria2: "<=14"

Omdat ons die getalle in dieselfde kolom vergelyk, is kriteria_reeks in beide gevalle dieselfde (C2:C11):

=MAXIFS(D2:D11, C2:C11, ">=13", C2:C11, "<=14")

As jy nie die kriteria wil hardkodeer nie in die formule, voer hulle in aparte selle in (bv. G1 en H1) en gebruik die volgendesintaksis:

=MAXIFS(D2:D11, C2:C11, ">="&G1, C2:C11, "<="&H1)

Die skermkiekie hieronder wys die resultaat:

Afgesien van getalle, kan logiese operateurs ook met tekskriteria werk. Die "nie gelyk aan"-operateur is veral handig wanneer jy iets van jou berekeninge wil uitsluit. Byvoorbeeld, om die langste student in alle sportsoorte uitgesluit vlugbal te vind, gebruik die volgende formule:

=MAXIFS(D2:D11, B2:B11, "volleyball")

Of hierdie een, waar G1 die uitgeslote sportsoort is:

=MAXIFS(D2:D11, B2:B11, ""&G1)

MAXIFS-formules met jokertekenkarakters (gedeeltelike passing)

Om 'n toestand te evalueer wat 'n spesifieke teks of karakter bevat, sluit een van die volgende jokertekenkarakters in jou kriteria:

• Vraagteken (?) om enige enkele karakter te pas.
• Asterisk (*) om enige volgorde van karakters te pas.

Vir hierdie voorbeeld, kom ons vind uit wat die langste ou in spelsport is. Omdat die name van alle spelsportsoorte in ons datastel met die woord "bal" eindig, sluit ons hierdie woord by die kriteria in en gebruik 'n asterisk om enige vorige karakters te pas:

=MAXIFS(D2:D11, B2:B11, "*ball")

Jy kan tik ook "bal" in een of ander sel, bv. G1, en voeg die jokerteken saam met die selverwysing:

=MAXIFS(D2:D11, B2:B11, "*"&G1)

Die resultaat sal soos volg lyk:

Kry maksimum waarde binne 'n datumreeks

Omdat datums as reeksnommers in die interne Excel-stelsel gestoor word, werk jy met die datumkriteria op dieselfde manier as wat jy met nommers werk.

Omillustreer dit, ons sal die Ouderdom -kolom vervang met Geboortedatum en probeer om die maksimum lengte onder die seuns wat in 'n spesifieke jaar gebore is, sê in 2004, uit te werk. Om hierdie taak uit te voer , moet ons die geboortedatums "filtreer" wat groter as of gelyk is aan 1-Jan-2004 en minder as of gelyk aan 31-Des-2004.

Wanneer jy jou kriteria bou, is dit belangrik dat jy verskaf die datums in die formaat wat Excel kan verstaan:

=MAXIFS(D2:D11, C2:C11, ">=1-Jan-2004", C2:C11, "<=31-Dec-2004")

Of

=MAXIFS(D2:D11, C2:C11, ">=1/1/2004", C2:C11, "<=12/31/2004")

Om waninterpretasie te voorkom, maak dit sin om die DATUM-funksie te gebruik :

=MAXIFS(D2:D11, C2:C11, ">="&DATE(2004,1,1), C2:C11, "<="&DATE(2004,12,31))

Vir hierdie voorbeeld sal ons die teikenjaar in G1 tik, en dan die DATUM-funksie gebruik om die datums te verskaf:

=MAXIFS(D2:D11, C2:C11, ">="&DATE(G1,1,1), C2:C11, "<="&DATE(G1,12,31))

Let wel. Anders as syfers, moet datums in aanhalingstekens ingesluit word wanneer dit op hul eie in die kriteria gebruik word. Byvoorbeeld:

=MAXIFS(D2:D11, C2:C11, "10/5/2005")

Vind maksimum waarde gebaseer op veelvuldige kriteria met OF-logika

Die Excel MAXIFS-funksie is ontwerp om die toestande met die EN-logika te toets - dit wil sê dit verwerk slegs daardie getalle in maks_reeks waarvoor al die kriteria WAAR is. In sommige situasies sal jy egter dalk die voorwaardes met die OF-logika moet evalueer - d.w.s. verwerk al die getalle waarvoor enige van die gespesifiseerde kriteria WAAR is.

Om dinge makliker te verstaan, oorweeg asseblief die volgende voorbeeld. Gestel jy wil die maksimum hoogte vind van die ouens wat óf basketbal óf speelsokker. Hoe sou jy dit doen? Om "basketbal" as kriteria1 en as "voetbal"-kriteria2 te gebruik, sal nie werk nie, want Excel sal aanneem dat beide kriteria na WAAR behoort te evalueer.

Die oplossing is om 2 aparte MAXIFS-formules te maak, een per elke sportsoort, en gebruik dan die goeie ou MAX-funksie om 'n hoër getal terug te gee:

=MAX(MAXIFS(C2:C11, B2:B11, "basketball"), MAXIFS(C2:C11, B2:B11, "football"))

Die skermkiekie hieronder wys hierdie formule maar met die kriteria in voorafbepaalde invoerselle, F1 en H1:

'n Ander manier is om 'n MAX IF formule met OF logika te gebruik.

7 dinge om te onthou oor Excel MAXIFS

Hieronder vind jy 'n paar opmerkings wat sal help om jou formules te verbeter en algemene foute te vermy. Sommige van hierdie waarnemings is reeds bespreek as wenke en notas in ons voorbeelde, maar dit kan nuttig wees om 'n kort opsomming te kry van wat jy reeds geleer het:

1. Die MAXIFS-funksie in Excel kan kry die hoogste waarde gebaseer op een of veelvuldige kriteria .
2. By verstek werk Excel MAXIFS met die EN logika , dit wil sê gee die maksimum getal terug wat aan al die gespesifiseerde voorwaardes voldoen.
3. Vir die funksie om te werk, moet die maksimum reeks en kriteriareekse dieselfde grootte en vorm hê.
4. Die SUMIF-funksie is hoofletter-onsensitief , dit wil sê dit herken nie die letterkas in tekskriteria nie.
5. Wanneer jy 'n MAXIFS-formule vir veelvuldige selle skryf, onthou om te sluit die reekse metabsolute selverwysings vir die formule om korrek te kopieer.
6. Let op die sintaksis van jou kriteria ! Hier is die hoofreëls:
   • Wanneer dit op hul eie gebruik word, moet teks en datums in aanhalingstekens ingesluit word, nommers en selverwysings moet nie.
   • Wanneer 'n nommer, datum of teks gebruik word met 'n logiese operateur, moet die hele uitdrukking in dubbele aanhalingstekens ingesluit word soos ">=10"; selverwysings en ander funksies moet aaneengeskakel word deur 'n ampersand soos ">"&G1 te gebruik.
7. MAXIFS is slegs beskikbaar in Excel 2019 en Excel vir Office 365. In vroeër weergawes, hierdie funksie is nie beskikbaar nie.

Dis hoe jy die maksimum waarde in Excel met voorwaardes kan vind. Ek bedank jou vir die lees en hoop om jou binnekort op ons blog te sien!

Laai oefenwerkboek af:

Excel MAXIFS formule voorbeelde (.xlsx lêer)