ٹیوٹوریل دکھاتا ہے کہ شرائط کے ساتھ زیادہ سے زیادہ قدر حاصل کرنے کے لیے Excel میں MAXIFS فنکشن کو کیسے استعمال کیا جائے۔

روایتی طور پر، جب آپ کو کبھی Excel میں شرائط کے ساتھ سب سے زیادہ قدر تلاش کرنے کی ضرورت ہوتی ہے، آپ کو اپنا MAX IF فارمولا بنانا تھا۔ اگرچہ تجربہ کار صارفین کے لیے کوئی بڑی بات نہیں ہے، لیکن یہ نوزائیدہوں کے لیے کچھ مشکلات پیش کر سکتا ہے کیونکہ، سب سے پہلے، آپ کو فارمولے کی نحو کو یاد رکھنا چاہیے اور، دوم، آپ کو یہ جاننا چاہیے کہ صف کے فارمولوں کے ساتھ کیسے کام کرنا ہے۔ خوش قسمتی سے، مائیکروسافٹ نے حال ہی میں ایک نیا فنکشن متعارف کرایا ہے جس کی مدد سے ہم مشروط زیادہ سے زیادہ آسان طریقے سے کر سکتے ہیں!

Excel MAXIFS فنکشن

MAXIFS فنکشن میں سب سے بڑی عددی قدر لوٹاتا ہے۔ ایک یا زیادہ معیار پر مبنی مخصوص رینج۔

MAXIFS فنکشن کا نحو درج ذیل ہے:

کہاں:

• زیادہ سے زیادہ_رینج (ضروری) - سیلز کی وہ رینج جہاں آپ زیادہ سے زیادہ قدر تلاش کرنا چاہتے ہیں۔
• Criteria_range1 (ضرورت) - معیار1 کے ساتھ جانچنے کے لیے پہلی رینج۔
• Criteria1 - پہلی رینج پر استعمال کرنے کی شرط۔ اس کی نمائندگی ایک عدد، متن یا اظہار سے کی جا سکتی ہے۔
• Criteria_range2 / criteria2 , …(اختیاری) - اضافی رینجز اور ان سے متعلقہ معیار۔ 126 رینج/معیار کے جوڑے تک تعاون یافتہ ہیں۔

یہ MAXIFS فنکشن Excel 2019، Excel 2021، اور میں دستیاب ہے۔Windows اور Mac پر Microsoft 365 کے لیے Excel۔

مثال کے طور پر، آئیے اپنے مقامی اسکول میں فٹ بال کے سب سے بڑے کھلاڑی کو تلاش کریں۔ یہ فرض کرتے ہوئے کہ طلباء کی بلندیاں سیل D2:D11 (max_range) میں ہیں اور کھیل B2:B11 (criteria_range1) میں ہیں، لفظ "فٹ بال" کو بطور معیار1 استعمال کریں، اور آپ کو یہ فارمولا ملے گا:

=MAXIFS(D2:D11, B2:B11, "football")

فارمولے کو زیادہ ورسٹائل بنانے کے لیے، آپ کچھ سیل میں ٹارگٹ اسپورٹ ڈال سکتے ہیں (کہیں، G1) اور سیل کا حوالہ معیار1 دلیل میں شامل کر سکتے ہیں:

=MAXIFS(D2:D11, B2:B11, G1)

نوٹ۔ max_range اور criteria_range آرگیومینٹس ایک ہی سائز اور شکل کے ہونے چاہئیں، یعنی قطاروں اور کالموں کی مساوی تعداد پر مشتمل ہوں، بصورت دیگر #VALUE! غلطی واپس آ گئی ہے.

ایکسل میں MAXIFS فنکشن کا استعمال کیسے کریں - فارمولہ مثالیں

جیسا کہ آپ نے ابھی دیکھا ہے، Excel MAXIFS کافی سیدھا اور استعمال میں آسان ہے۔ تاہم، اس میں چند چھوٹی باریکیاں ہیں جو ایک بڑا فرق پیدا کرتی ہیں۔ ذیل کی مثالوں میں، ہم ایکسل میں زیادہ سے زیادہ مشروط زیادہ سے زیادہ فائدہ اٹھانے کی کوشش کریں گے۔

متعدد معیارات کی بنیاد پر زیادہ سے زیادہ قدر تلاش کریں

اس ٹیوٹوریل کے پہلے حصے میں، ہم نے ایک MAXIFS فارمولا بنایا ہے۔ ایک شرط کی بنیاد پر زیادہ سے زیادہ قدر حاصل کرنے کے لیے اس کی آسان ترین شکل میں۔ اب، ہم اس مثال کو مزید لے کر دو مختلف معیارات کا جائزہ لینے جا رہے ہیں۔

فرض کریں، آپ جونیئر اسکول میں باسکٹ بال کے سب سے بڑے کھلاڑی کو تلاش کرنا چاہتے ہیں۔ اسے کرنے کے لیے، درج ذیل کی وضاحت کریں۔دلائل:

• زیادہ سے زیادہ_رینج - اونچائیوں پر مشتمل سیلز کی ایک رینج - D2:D11۔
• Criteria_range1 - کھیلوں پر مشتمل خلیوں کی ایک رینج - B2:B11۔
• Criteria1 - "باسکٹ بال"، جو سیل G1 میں ان پٹ ہے۔
• Criteria_range2 - سیلز کی ایک رینج اسکول کی قسم - C2:C11۔
• Criteria2 - "جونیئر"، جو سیل G2 میں ان پٹ ہے۔

دلائل کو ایک ساتھ رکھنے سے، ہمیں یہ فارمولے ملتے ہیں۔ :

"ہارڈ کوڈ" کے معیار کے ساتھ:

=MAXIFS(D2:D11, B2:B11, "basketball", C2:C11, "junior")

پہلے سے طے شدہ سیلز میں معیار کے ساتھ:

=MAXIFS(D2:D11, B2:B11, G1, C2:C11, G2)

براہ کرم نوٹ کریں کہ MAXIFS ایکسل میں فنکشن کیس غیر حساس ہے، لہذا آپ کو اپنے معیار میں لیٹر کیس کے بارے میں فکر کرنے کی ضرورت نہیں ہے۔

اگر آپ اپنا استعمال کرنے کا ارادہ رکھتے ہیں۔ ایک سے زیادہ سیلز پر فارمولہ، تمام رینجز کو مطلق سیل حوالوں کے ساتھ مقفل کرنا یقینی بنائیں، اس طرح:

=MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2)

یہ اس بات کو یقینی بنائے گا کہ فارمولہ دوسرے سیلز میں صحیح طریقے سے کاپی کرتا ہے - معیار کے حوالہ جات کی بنیاد پر تبدیلی ہوتی ہے۔ سیل کی متعلقہ پوزیشن پر جہاں فارمولہ کاپی کیا جاتا ہے جبکہ t اس کی رینجز میں کوئی تبدیلی نہیں ہوئی:

اضافی بونس کے طور پر، میں آپ کو کسی دوسرے سیل سے ایک قدر نکالنے کا ایک تیز طریقہ دکھاؤں گا جو زیادہ سے زیادہ قدر سے وابستہ ہے۔ ہمارے معاملے میں، وہ سب سے لمبے شخص کا نام ہوگا۔ اس کے لیے، ہم کلاسک INDEX MATCH فارمولہ اور Nest MAXIFS کو MATCH کے پہلے استدلال میں تلاش کی قدر کے طور پر استعمال کریں گے:

=INDEX($A$2:$A$11, MATCH(MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2), $D$2:$D$11, 0))

فارمولہ ہمیں بتاتا ہے کہ نامجونیئر اسکول میں باسکٹ بال کا سب سے لمبا کھلاڑی لیام ہے:

Excel MAXIFS مع منطقی آپریٹرز

اس صورت حال میں جب آپ کو عددی معیارات کا جائزہ لینے کی ضرورت ہو، منطقی آپریٹرز استعمال کریں۔ جیسے:

• سے بڑا (>)
• سے کم (<)
• سے بڑا یا اس کے برابر (>=)
• سے کم یا اس کے برابر (<=)
• برابر نہیں ()

"برابر" آپریٹر (=) کو زیادہ تر معاملات میں چھوڑا جا سکتا ہے۔

عام طور پر، آپریٹر کا انتخاب کوئی مسئلہ نہیں ہے، سب سے مشکل حصہ صحیح نحو کے ساتھ معیار بنانا ہے۔ یہ طریقہ ہے:

• ایک منطقی آپریٹر کے بعد ایک نمبر یا متن کا دوہرے اقتباسات جیسے ">=14" یا "رننگ" میں بند ہونا ضروری ہے۔
• سیل کی صورت میں حوالہ یا کوئی اور فنکشن، حوالہ کو جوڑنے اور سٹرنگ کو ختم کرنے کے لیے سٹرنگ اور ایمپرسینڈ کو شروع کرنے کے لیے اقتباسات کا استعمال کریں، جیسے ">"&B1 یا "<"&TODAY().

یہ دیکھنے کے لیے کہ یہ عملی طور پر کیسے کام کرتا ہے، آئیے اپنے نمونے کی میز میں عمر کا کالم (کالم C) شامل کریں اور تلاش کریں۔ 13 سے 14 سال کی عمر کے لڑکوں میں زیادہ سے زیادہ اونچائی۔ یہ درج ذیل معیار کے ساتھ کیا جا سکتا ہے:

معیار1: ">=13"

Criteria2: "<=14"

چونکہ ہم ایک ہی کالم میں نمبروں کا موازنہ کرتے ہیں، دونوں صورتوں میں criteria_range ایک ہی ہے (C2:C11):

=MAXIFS(D2:D11, C2:C11, ">=13", C2:C11, "<=14")

اگر آپ معیار کو ہارڈ کوڈ نہیں کرنا چاہتے ہیں فارمولے میں، انہیں الگ الگ سیلز میں داخل کریں (جیسے G1 اور H1) اور درج ذیل کو استعمال کریں۔نحو:

=MAXIFS(D2:D11, C2:C11, ">="&G1, C2:C11, "<="&H1)

نیچے دیا گیا اسکرین شاٹ نتیجہ دکھاتا ہے:

18>

نمبروں کے علاوہ، منطقی آپریٹرز متن کے معیار کے ساتھ بھی کام کر سکتے ہیں۔ خاص طور پر، آپریٹر اس وقت کام آتا ہے جب آپ اپنے حساب سے کسی چیز کو خارج کرنا چاہتے ہیں۔ مثال کے طور پر، والی بال کو چھوڑ کر تمام کھیلوں میں سب سے لمبا طالب علم تلاش کرنے کے لیے، درج ذیل فارمولے کا استعمال کریں:

=MAXIFS(D2:D11, B2:B11, "volleyball")

یا یہ ایک، جہاں G1 خارج شدہ کھیل ہے:

=MAXIFS(D2:D11, B2:B11, ""&G1)

وائلڈ کارڈ حروف کے ساتھ MAXIFS فارمولے (جزوی مماثلت)

کسی ایسی حالت کا جائزہ لینے کے لیے جس میں ایک مخصوص متن یا کردار ہو، درج ذیل میں سے ایک وائلڈ کارڈ کریکٹر کو شامل کریں آپ کا معیار:

=MAXIFS(D2:D11, B2:B11, "*ball")

آپ کچھ سیل میں "بال" بھی ٹائپ کریں، جیسے G1، اور سیل حوالہ کے ساتھ وائلڈ کارڈ کیریکٹر کو جوڑیں:

=MAXIFS(D2:D11, B2:B11, "*"&G1)

نتیجہ اس طرح نظر آئے گا:

زیادہ سے زیادہ قدر حاصل کریں تاریخ کی حد کے اندر

چونکہ تاریخیں داخلی ایکسل سسٹم میں سیریل نمبرز کے طور پر محفوظ کی جاتی ہیں، اس لیے آپ تاریخوں کے معیار کے ساتھ اسی طرح کام کرتے ہیں جس طرح آپ نمبروں کے ساتھ کام کرتے ہیں۔

اس کی وضاحت کریں، ہم عمر کالم کو تاریخ پیدائش سے بدل دیں گے اور کسی خاص سال میں پیدا ہونے والے لڑکوں کے درمیان زیادہ سے زیادہ قد کا تعین کرنے کی کوشش کریں گے، 2004 میں۔ اس کام کو پورا کرنے کے لیے ، ہمیں تاریخ پیدائش کو "فلٹر" کرنے کی ضرورت ہے جو 1-Jan-2004 سے زیادہ یا اس کے برابر ہیں اور 31-Dec-2004 سے کم یا اس کے برابر ہیں۔

اپنا معیار بناتے وقت، یہ ضروری ہے کہ آپ تاریخیں اس فارمیٹ میں فراہم کریں جسے Excel سمجھ سکے:

=MAXIFS(D2:D11, C2:C11, ">=1-Jan-2004", C2:C11, "<=31-Dec-2004")

یا

=MAXIFS(D2:D11, C2:C11, ">=1/1/2004", C2:C11, "<=12/31/2004")

غلط تشریح کو روکنے کے لیے، DATE فنکشن کو استعمال کرنا سمجھ میں آتا ہے۔ :

=MAXIFS(D2:D11, C2:C11, ">="&DATE(2004,1,1), C2:C11, "<="&DATE(2004,12,31))

اس مثال کے لیے، ہم G1 میں ہدف کا سال ٹائپ کریں گے، اور پھر تاریخوں کی فراہمی کے لیے DATE فنکشن استعمال کریں گے:

=MAXIFS(D2:D11, C2:C11, ">="&DATE(G1,1,1), C2:C11, "<="&DATE(G1,12,31))

نوٹ۔ نمبروں کے برعکس، تاریخوں کو اقتباس کے نشانات میں بند کیا جانا چاہیے جب وہ اپنے طور پر معیار میں استعمال ہوں۔ مثال کے طور پر:

=MAXIFS(D2:D11, C2:C11, "10/5/2005")

OR منطق کے ساتھ ایک سے زیادہ معیار کی بنیاد پر زیادہ سے زیادہ قدر تلاش کریں

ایکسل میکسیفس فنکشن کو AND منطق کے ساتھ حالات کو جانچنے کے لیے ڈیزائن کیا گیا ہے - یعنی یہ صرف ان نمبروں پر کارروائی کرتا ہے۔ max_range میں جس کے تمام معیار درست ہیں۔ تاہم، کچھ حالات میں، آپ کو OR منطق کے ساتھ حالات کا جائزہ لینے کی ضرورت پڑ سکتی ہے - یعنی ان تمام نمبروں پر کارروائی کریں جن کے لیے کوئی بھی مخصوص معیار درست ہے۔

چیزوں کو سمجھنے میں آسانی پیدا کرنے کے لیے، براہ کرم درج ذیل پر غور کریں۔ مثال. فرض کریں کہ آپ ان لڑکوں کی زیادہ سے زیادہ اونچائی تلاش کرنا چاہتے ہیں جو یا تو باسکٹ بال کھیلتے ہیں یافٹ بال آپ ایسا کیسے کریں گے؟ "باسکٹ بال" کو بطور معیار1 اور "فٹ بال" کے معیار2 کے طور پر استعمال کرنا کام نہیں کرے گا، کیونکہ ایکسل یہ فرض کرے گا کہ دونوں معیارات کا درست جائزہ لینا چاہیے۔

حل یہ ہے کہ 2 الگ الگ MAXIFS فارمولے بنائے جائیں، ہر کھیل کے لیے ایک، اور پھر اعلیٰ نمبر واپس کرنے کے لیے اچھے پرانے MAX فنکشن کا استعمال کریں:

=MAX(MAXIFS(C2:C11, B2:B11, "basketball"), MAXIFS(C2:C11, B2:B11, "football"))

ذیل کا اسکرین شاٹ اس فارمولے کو ظاہر کرتا ہے لیکن پہلے سے طے شدہ ان پٹ سیلز، F1 اور H1 میں معیار کے ساتھ:

ایک اور طریقہ یہ ہے کہ OR منطق کے ساتھ MAX IF فارمولہ استعمال کیا جائے۔

ایکسل میکسیف کے بارے میں یاد رکھنے کے لیے 7 چیزیں

ذیل میں آپ کو چند ریمارکس ملیں گے۔ اس سے آپ کے فارمولوں کو بہتر بنانے اور عام غلطیوں سے بچنے میں مدد ملے گی۔ ان میں سے کچھ مشاہدات پر پہلے ہی ہماری مثالوں میں نکات اور نوٹ کے طور پر بات کی جا چکی ہے، لیکن جو کچھ آپ پہلے ہی سیکھ چکے ہیں اس کا مختصر خلاصہ حاصل کرنا مددگار ثابت ہو سکتا ہے:

1. ایکسل میں MAXIFS فنکشن حاصل کر سکتا ہے۔ ایک یا متعدد معیار کی بنیاد پر سب سے زیادہ قدر۔
2. بطور ڈیفالٹ، Excel MAXIFS AND منطق کے ساتھ کام کرتا ہے، یعنی زیادہ سے زیادہ نمبر لوٹاتا ہے۔ جو تمام مخصوص شرائط پر پورا اترتا ہے۔
3. فنکشن کے کام کرنے کے لیے، زیادہ سے زیادہ رینج اور معیار کی حدود میں ایک ہی سائز اور شکل ہونی چاہیے۔
<9 رینجز کے ساتھدرست طریقے سے کاپی کرنے کے لیے فارمولے کے مطلق سیل حوالہ جات۔
4. اپنے معیار کے نحو کو ذہن میں رکھیں! یہاں بنیادی اصول ہیں:
   • جب اپنے طور پر استعمال کیا جائے تو متن اور تاریخوں کو کوٹیشن مارکس، نمبرز اور سیل حوالہ جات میں بند کیا جانا چاہیے۔
   • جب کوئی نمبر، تاریخ یا متن استعمال کیا جائے منطقی آپریٹر کے ساتھ، پورے اظہار کو دوہرے اقتباسات جیسے ">=10" میں بند کیا جانا چاہیے۔ سیل کے حوالہ جات اور دیگر فنکشنز کو ایمپرسینڈ جیسے ">"&G1 کا استعمال کرتے ہوئے مربوط کیا جانا چاہیے۔
5. MAXIFS صرف Excel 2019 اور Excel for Office 365 میں دستیاب ہے۔ پہلے کے ورژن میں، یہ فنکشن دستیاب نہیں ہے۔

اس طرح آپ شرائط کے ساتھ ایکسل میں زیادہ سے زیادہ قدر تلاش کرسکتے ہیں۔ میں پڑھنے کے لیے آپ کا شکریہ ادا کرتا ہوں اور امید کرتا ہوں کہ آپ کو جلد ہی ہمارے بلاگ پر ملوں گا!

پریکٹس ورک بک ڈاؤن لوڈ کریں:

Excel MAXIFS فارمولے کی مثالیں (.xlsx فائل)