บทช่วยสอนแสดงวิธีใช้ฟังก์ชัน MAXIFS ใน Excel เพื่อให้ได้ค่าสูงสุดพร้อมเงื่อนไข

ตามเนื้อผ้า เมื่อคุณต้องการหาค่าสูงสุดพร้อมเงื่อนไขใน Excel คุณต้องสร้างสูตร MAX IF ของคุณเอง แม้ว่าจะไม่ใช่เรื่องใหญ่สำหรับผู้ใช้ที่มีประสบการณ์ แต่สิ่งนี้อาจนำเสนอปัญหาบางอย่างสำหรับผู้เริ่มต้น เพราะประการแรก คุณควรจำไวยากรณ์ของสูตร และประการที่สอง คุณจำเป็นต้องรู้วิธีทำงานกับสูตรอาร์เรย์ โชคดีที่ Microsoft ได้เปิดตัวฟังก์ชันใหม่เมื่อเร็วๆ นี้ ซึ่งช่วยให้เราสร้างเงื่อนไขสูงสุดด้วยวิธีง่ายๆ ได้!

ฟังก์ชัน MAXIFS ของ Excel

ฟังก์ชัน MAXIFS จะส่งคืนค่าตัวเลขที่ใหญ่ที่สุดใน ช่วงที่ระบุตามเกณฑ์อย่างน้อยหนึ่งเกณฑ์

ไวยากรณ์ของฟังก์ชัน MAXIFS เป็นดังนี้:

ที่ไหน:

• Max_range (จำเป็น) - ช่วงของเซลล์ที่คุณต้องการหาค่าสูงสุด
• Criteria_range1 (จำเป็น) - ช่วงแรกที่จะประเมินด้วย เกณฑ์ 1 .
• เกณฑ์ 1 - เงื่อนไขที่จะใช้กับช่วงแรก สามารถแสดงด้วยตัวเลข ข้อความ หรือนิพจน์
• Criteria_range2 / criteria2 , …(ไม่บังคับ) - ช่วงเพิ่มเติมและเกณฑ์ที่เกี่ยวข้อง รองรับคู่ช่วง/เกณฑ์สูงสุด 126 คู่

ฟังก์ชัน MAXIFS นี้มีให้ใช้งานใน Excel 2019, Excel 2021 และExcel สำหรับ Microsoft 365 บน Windows และ Mac

ตัวอย่างเช่น ลองหานักฟุตบอลที่สูงที่สุดในโรงเรียนท้องถิ่นของเรา สมมติว่าความสูงของนักเรียนอยู่ในเซลล์ D2:D11 (ช่วงสูงสุด) และกีฬาอยู่ในเซลล์ B2:B11 (เกณฑ์ช่วง 1) ให้ใช้คำว่า "ฟุตบอล" เป็นเกณฑ์ 1 และคุณจะได้สูตรนี้:

=MAXIFS(D2:D11, B2:B11, "football")

เพื่อให้สูตรมีความหลากหลายมากขึ้น คุณสามารถป้อนกีฬาเป้าหมายในบางเซลล์ (เช่น G1) และรวมการอ้างอิงเซลล์ใน criteria1 อาร์กิวเมนต์:

=MAXIFS(D2:D11, B2:B11, G1) <3

หมายเหตุ อาร์กิวเมนต์ max_range และ criteria_range ต้องมีขนาดและรูปร่างเหมือนกัน เช่น มีจำนวนแถวและคอลัมน์เท่ากัน มิฉะนั้น #VALUE! ข้อผิดพลาดจะถูกส่งกลับ

วิธีใช้ฟังก์ชัน MAXIFS ใน Excel - ตัวอย่างสูตร

อย่างที่คุณได้เห็น MAXIFS ของ Excel ค่อนข้างตรงไปตรงมาและใช้งานง่าย อย่างไรก็ตาม มีความแตกต่างเล็กน้อยที่สร้างความแตกต่างอย่างมาก ในตัวอย่างด้านล่าง เราจะพยายามใช้ค่าสูงสุดตามเงื่อนไขให้เกิดประโยชน์สูงสุดใน Excel

ค้นหาค่าสูงสุดตามเกณฑ์หลายเกณฑ์

ในส่วนแรกของบทช่วยสอนนี้ เราได้สร้างสูตร MAXIFS ในรูปแบบที่ง่ายที่สุดเพื่อรับค่าสูงสุดตามเงื่อนไขเดียว ตอนนี้ เราจะนำตัวอย่างนั้นมาพิจารณาเพิ่มเติมและประเมินเกณฑ์ที่แตกต่างกันสองเกณฑ์

สมมติว่าคุณต้องการหานักบาสเก็ตบอลที่สูงที่สุดในโรงเรียนมัธยมศึกษาตอนต้น หากต้องการดำเนินการ ให้กำหนดสิ่งต่อไปนี้อาร์กิวเมนต์:

• Max_range - ช่วงของเซลล์ที่มีความสูง - D2:D11
• Criteria_range1 - ช่วงของเซลล์ที่มีกีฬา - B2:B11
• Criteria1 - "บาสเก็ตบอล" ซึ่งป้อนในเซลล์ G1
• Criteria_range2 - ช่วงของเซลล์ที่กำหนด ประเภทโรงเรียน - C2:C11
• เกณฑ์ 2 - "จูเนียร์" ซึ่งป้อนในเซลล์ G2

เมื่อนำอาร์กิวเมนต์มารวมกัน เราได้สูตรเหล่านี้ :

ด้วยเกณฑ์ "ฮาร์ดโค้ด":

=MAXIFS(D2:D11, B2:B11, "basketball", C2:C11, "junior")

ด้วยเกณฑ์ในเซลล์ที่กำหนดไว้ล่วงหน้า:

=MAXIFS(D2:D11, B2:B11, G1, C2:C11, G2)

โปรดสังเกตว่า MAXIFS ฟังก์ชันใน Excel ไม่คำนึงถึงตัวพิมพ์เล็กและใหญ่ ดังนั้นคุณจึงไม่ต้องกังวลเกี่ยวกับตัวพิมพ์เล็กหรือใหญ่ในเกณฑ์ของคุณ

ในกรณีที่คุณวางแผนที่จะใช้ สูตรในหลายเซลล์ อย่าลืมล็อกช่วงทั้งหมดด้วยการอ้างอิงเซลล์แบบสัมบูรณ์ เช่น

=MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2)

วิธีนี้จะช่วยให้มั่นใจได้ว่าสูตรจะคัดลอกไปยังเซลล์อื่นๆ อย่างถูกต้อง เกณฑ์การอ้างอิงจะเปลี่ยนตาม บนตำแหน่งสัมพัทธ์ของเซลล์ที่มีการคัดลอกสูตรในขณะที่ t ช่วงของเขายังคงไม่เปลี่ยนแปลง:

เพื่อเป็นโบนัสพิเศษ ฉันจะแสดงวิธีที่รวดเร็วในการดึงค่าจากเซลล์อื่นที่เกี่ยวข้องกับค่าสูงสุด ในกรณีของเรา นั่นจะเป็นชื่อของบุคคลที่สูงที่สุด สำหรับสิ่งนี้ เราจะใช้สูตร INDEX MATCH แบบคลาสสิกและซ้อน MAXIFS ในอาร์กิวเมนต์แรกของ MATCH เป็นค่าการค้นหา:

=INDEX($A$2:$A$11, MATCH(MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2), $D$2:$D$11, 0))

สูตรบอกเราว่าชื่อของนักบาสเก็ตบอลที่สูงที่สุดในโรงเรียนมัธยมคือ Liam:

Excel MAXIFS พร้อมตัวดำเนินการเชิงตรรกะ

ในสถานการณ์ที่คุณจำเป็นต้องประเมินเกณฑ์ตัวเลข ให้ใช้ตัวดำเนินการเชิงตรรกะ เช่น:

• มากกว่า (>)
• น้อยกว่า (<)
• มากกว่าหรือเท่ากับ (>=)
• น้อยกว่าหรือเท่ากับ (<=)
• ไม่เท่ากับ ()

ตัวดำเนินการ "เท่ากับ" (=) สามารถละเว้นได้ในกรณีส่วนใหญ่

โดยปกติแล้ว การเลือกตัวดำเนินการไม่ใช่ปัญหา ส่วนที่ยากที่สุดคือการสร้างเกณฑ์ด้วยไวยากรณ์ที่ถูกต้อง มีวิธีการดังนี้:

• ตัวดำเนินการเชิงตรรกะที่ตามด้วยตัวเลขหรือข้อความต้องอยู่ในเครื่องหมายอัญประกาศคู่ เช่น ">=14" หรือ "กำลังทำงาน"
• ในกรณีของเซลล์ การอ้างอิงหรือฟังก์ชันอื่น ใช้เครื่องหมายอัญประกาศเพื่อขึ้นต้นสตริงและเครื่องหมายแอมเปอร์แซนด์เชื่อมการอ้างอิงและจบสตริง เช่น ">"&B1 หรือ "<"&TODAY().

หากต้องการดูวิธีใช้งานจริง ให้เพิ่มคอลัมน์อายุ (คอลัมน์ C) ลงในตารางตัวอย่างแล้วหา ความสูงสูงสุดของเด็กผู้ชายอายุระหว่าง 13 ถึง 14 ปี ทำได้โดยใช้เกณฑ์ต่อไปนี้:

เกณฑ์ที่ 1: ">=13"

เกณฑ์ที่ 2: "<=14"

เนื่องจากเราเปรียบเทียบตัวเลขในคอลัมน์เดียวกัน เกณฑ์_ช่วงในทั้งสองกรณีจึงเหมือนกัน (C2:C11):

=MAXIFS(D2:D11, C2:C11, ">=13", C2:C11, "<=14")

หากคุณไม่ต้องการฮาร์ดโค้ดเกณฑ์ ในสูตร ให้ป้อนข้อมูลในเซลล์แยกกัน (เช่น G1 และ H1) และใช้ข้อมูลต่อไปนี้ไวยากรณ์:

=MAXIFS(D2:D11, C2:C11, ">="&G1, C2:C11, "<="&H1)

ภาพหน้าจอด้านล่างแสดงผลลัพธ์:

นอกเหนือจากตัวเลขแล้ว ตัวดำเนินการเชิงตรรกะยังสามารถทำงานกับเกณฑ์ข้อความได้อีกด้วย โดยเฉพาะอย่างยิ่ง ตัวดำเนินการ "ไม่เท่ากับ" มีประโยชน์เมื่อคุณต้องการแยกบางสิ่งออกจากการคำนวณของคุณ ตัวอย่างเช่น หากต้องการหานักเรียนที่สูงที่สุดในทุกกีฬา ยกเว้นวอลเลย์บอล ให้ใช้สูตรต่อไปนี้:

=MAXIFS(D2:D11, B2:B11, "volleyball")

หรือสูตรนี้ โดยที่ G1 เป็นกีฬาที่ไม่รวม:

=MAXIFS(D2:D11, B2:B11, ""&G1)

สูตร MAXIFS ที่มีอักขระตัวแทน (ตรงกันบางส่วน)

ในการประเมินเงื่อนไขที่มีข้อความหรืออักขระเฉพาะ ให้รวมหนึ่งในอักขระตัวแทนต่อไปนี้ใน เกณฑ์ของคุณ:

• เครื่องหมายคำถาม (?) เพื่อจับคู่อักขระเดี่ยวใดๆ
• เครื่องหมายดอกจัน (*) เพื่อจับคู่ลำดับอักขระใดก็ได้

สำหรับ ตัวอย่างนี้ มาหาผู้ชายที่สูงที่สุดในเกมกีฬากัน เนื่องจากชื่อของเกมกีฬาทั้งหมดในชุดข้อมูลของเราลงท้ายด้วยคำว่า "บอล" เราจึงรวมคำนี้ไว้ในเกณฑ์และใช้เครื่องหมายดอกจันเพื่อจับคู่อักขระก่อนหน้า:

=MAXIFS(D2:D11, B2:B11, "*ball")

คุณสามารถ พิมพ์ "ball" ในบางเซลล์ด้วย เช่น G1 และต่ออักขระตัวแทนด้วยการอ้างอิงเซลล์:

=MAXIFS(D2:D11, B2:B11, "*"&G1)

ผลลัพธ์จะมีลักษณะดังนี้:

รับค่าสูงสุด ภายในช่วงวันที่

เนื่องจากวันที่จัดเก็บเป็นหมายเลขซีเรียลในระบบ Excel ภายใน คุณจึงทำงานกับเกณฑ์วันที่ในลักษณะเดียวกับที่คุณทำงานกับตัวเลข

ถึงยกตัวอย่างสิ่งนี้ เราจะแทนที่คอลัมน์ อายุ ด้วย วันเกิด และพยายามหาส่วนสูงสูงสุดของเด็กผู้ชายที่เกิดในปีใดปีหนึ่ง เช่น ในปี 2004 เพื่อให้งานนี้สำเร็จ เราจำเป็นต้อง "กรอง" วันเกิดที่มากกว่าหรือเท่ากับ 1-ม.ค.-2004 และน้อยกว่าหรือเท่ากับ 31-ธ.ค.-2004

เมื่อสร้างเกณฑ์ สิ่งสำคัญคือคุณต้อง ระบุวันที่ในรูปแบบที่ Excel เข้าใจได้:

=MAXIFS(D2:D11, C2:C11, ">=1-Jan-2004", C2:C11, "<=31-Dec-2004")

หรือ

=MAXIFS(D2:D11, C2:C11, ">=1/1/2004", C2:C11, "<=12/31/2004")

เพื่อป้องกันการตีความผิด ควรใช้ฟังก์ชัน DATE :

=MAXIFS(D2:D11, C2:C11, ">="&DATE(2004,1,1), C2:C11, "<="&DATE(2004,12,31))

สำหรับตัวอย่างนี้ เราจะพิมพ์ปีเป้าหมายใน G1 จากนั้นใช้ฟังก์ชัน DATE เพื่อระบุวันที่:

=MAXIFS(D2:D11, C2:C11, ">="&DATE(G1,1,1), C2:C11, "<="&DATE(G1,12,31))

หมายเหตุ ไม่เหมือนกับตัวเลข วันที่ควรอยู่ในเครื่องหมายอัญประกาศเมื่อใช้ในเกณฑ์เพียงอย่างเดียว ตัวอย่างเช่น:

=MAXIFS(D2:D11, C2:C11, "10/5/2005")

ค้นหาค่าสูงสุดตามเกณฑ์หลายเกณฑ์ด้วยตรรกะ OR

ฟังก์ชัน MAXIFS ของ Excel ออกแบบมาเพื่อทดสอบเงื่อนไขด้วยตรรกะ AND กล่าวคือ ประมวลผลเฉพาะตัวเลขเหล่านั้น ใน max_range ซึ่งเกณฑ์ทั้งหมดเป็น TRUE อย่างไรก็ตาม ในบางสถานการณ์ คุณอาจต้องประเมินเงื่อนไขด้วยตรรกะ OR เช่น ประมวลผลตัวเลขทั้งหมดที่เกณฑ์ที่ระบุเป็น TRUE

เพื่อให้เข้าใจได้ง่ายขึ้น โปรดพิจารณาสิ่งต่อไปนี้ ตัวอย่าง. สมมติว่าคุณต้องการหาความสูงสูงสุดของผู้ชายที่เล่นบาสเก็ตบอลหรือฟุตบอล. คุณจะทำอย่างไร การใช้ "บาสเก็ตบอล" เป็นเกณฑ์ 1 และ "ฟุตบอล" เกณฑ์ 2 จะไม่ทำงาน เนื่องจาก Excel จะถือว่าเกณฑ์ทั้งสองควรประเมินเป็น TRUE

วิธีแก้ไขคือสร้างสูตร MAXIFS แยกกัน 2 สูตร สูตรละ 1 สูตร จากนั้นใช้ฟังก์ชัน MAX แบบเก่าที่ดีเพื่อส่งกลับตัวเลขที่สูงขึ้น:

=MAX(MAXIFS(C2:C11, B2:B11, "basketball"), MAXIFS(C2:C11, B2:B11, "football"))

ภาพหน้าจอด้านล่างแสดงสูตรนี้ แต่มีเกณฑ์ในเซลล์อินพุตที่กำหนดไว้ล่วงหน้า F1 และ H1:

อีกวิธีหนึ่งคือการใช้สูตร MAX IF กับตรรกะ OR

7 สิ่งที่ต้องจำเกี่ยวกับ Excel MAXIFS

ด้านล่างนี้ คุณจะพบข้อสังเกตบางประการ ที่จะช่วยปรับปรุงสูตรของคุณและหลีกเลี่ยงข้อผิดพลาดทั่วไป ข้อสังเกตบางส่วนเหล่านี้ได้รับการกล่าวถึงเป็นเคล็ดลับและหมายเหตุในตัวอย่างของเราแล้ว แต่อาจเป็นประโยชน์หากได้รับข้อมูลสรุปสั้นๆ เกี่ยวกับสิ่งที่คุณได้เรียนรู้ไปแล้ว:

1. ฟังก์ชัน MAXIFS ใน Excel สามารถรับ ค่าสูงสุดตามเกณฑ์ หนึ่ง หรือ หลายเกณฑ์ .
2. ตามค่าเริ่มต้น Excel MAXIFS ทำงานร่วมกับตรรกะ และ เช่น ส่งกลับจำนวนสูงสุด ที่ตรงตามเงื่อนไขที่ระบุทั้งหมด
3. เพื่อให้ฟังก์ชันทำงานได้ ช่วงสูงสุดและช่วงเกณฑ์ต้องมี ขนาดเดียวกัน และ รูปร่าง
4. ฟังก์ชัน SUMIF ไม่คำนึงถึงตัวพิมพ์เล็กและใหญ่ กล่าวคือ ไม่รู้จักตัวพิมพ์เล็กและใหญ่ในเกณฑ์ข้อความ
5. เมื่อเขียนสูตร MAXIFS สำหรับหลายเซลล์ อย่าลืม ล็อก ช่วง กับการอ้างอิงเซลล์แบบสัมบูรณ์เพื่อให้สูตรคัดลอกได้อย่างถูกต้อง
6. โปรดคำนึงถึง ไวยากรณ์ของเกณฑ์ของคุณ ! ต่อไปนี้คือกฎหลัก:
   • เมื่อใช้แยกกัน ข้อความและวันที่ควรอยู่ในเครื่องหมายอัญประกาศ ไม่ควรใส่ตัวเลขและการอ้างอิงเซลล์
   • เมื่อใช้ตัวเลข วันที่ หรือข้อความ ด้วยตัวดำเนินการเชิงตรรกะ นิพจน์ทั้งหมดต้องอยู่ในเครื่องหมายอัญประกาศคู่ เช่น ">=10"; การอ้างอิงเซลล์และฟังก์ชันอื่นๆ ต้องเชื่อมกันโดยใช้เครื่องหมายแอมเปอร์แซนด์ เช่น ">"&G1
7. MAXIFS พร้อมใช้งานใน Excel 2019 และ Excel for Office 365 เท่านั้น ในเวอร์ชันก่อนหน้า ไม่มีฟังก์ชันนี้

นั่นคือวิธีหาค่าสูงสุดใน Excel พร้อมเงื่อนไข ขอขอบคุณที่อ่านและหวังว่าจะได้พบคุณในบล็อกของเราเร็วๆ นี้!

ดาวน์โหลดแบบฝึกหัด:

ตัวอย่างสูตร Excel MAXIFS (ไฟล์ .xlsx)