Tabloya naverokê
Dersdar nîşan dide ka meriv çawa fonksiyona MAXIFS-ê li Excel bikar tîne da ku bi şert û mercan re nirxa herî zêde bi dest bixe. diviya bû ku hûn formula MAX IF-ya xwe ava bikin. Digel ku ji bo bikarhênerên bi ezmûn ne tiştek mezin e, dibe ku ew ji bo nûxwazan hin dijwariyan peyda bike ji ber ku, yekem, divê hûn hevoksaziya formulê bi bîr bînin û, ya duyemîn, hûn hewce ne ku hûn zanibin ka meriv çawa bi formulên array re dixebite. Xwezî, Microsoft di van demên dawî de fonksiyonek nû destnîşan kir ku dihêle em max-ya şertî bi rengek hêsan bikin!
Fonksiyon Excel MAXIFS
Fonksiyon MAXIFS nirxa hejmarî ya herî mezin di nav de vedigerîne. rêjeyek diyarkirî li ser bingeha yek an çend pîvanan pêk tê.
Sîntaksa fonksiyona MAXIFS wiha ye:
MAXIFS(range_max, pîvan_range1, pîvan1, [range_pîvan2, pîvan2],…)Li ku:
- Max_range (pêdivî) - rêza şaneyên ku hûn dixwazin nirxa herî zêde bibînin. rêza yekem a ku bi krîteran1 binirxîne.
- Krîterên1 - şerta ku di rêza yekem de were bikar anîn. Ew dikare bi jimarek, nivîsarek an biwêjekê were temsîl kirin.
- Range_Krîter2 / pîvan2 , …(vebijarkî) - rêzikên zêde û pîvanên pêwendiya wan. Heya 126 cotên rêze/pîvan têne piştgirî kirin.
Ev fonksiyona MAXIFS di Excel 2019, Excel 2021, ûExcel ji bo Microsoft 365 li ser Windows û Mac-ê.
Wek nimûne, em lîstikvanê fûtbolê yê herî dirêj li dibistana xweya herêmî bibînin. Bihesibînin ku bilindahiya xwendekaran di şaneyên D2:D11 (max_range) de û werzîş di B2:B11 de (krîterên_range1) bin, peyva "futbol" wekî pîvan1 bikar bînin, û hûn ê vê formulê bistînin:
=MAXIFS(D2:D11, B2:B11, "football")
Ji bo ku formula piralîtir bibe, hûn dikarin werzîşa mebestê di hin şaneyê de binivîsin (bibêjin, G1) û referansa hucreyê têxin nav argumana krîtera1 :
=MAXIFS(D2:D11, B2:B11, G1)
Nîşe. Divê argumanên max_range û range_krîteran bi heman mezinahî û şikilê bin, ango hejmara rêz û stûnên wekhev hebin, wekî din #VALUE! xeletî tê vegerandin.
Meriv çawa fonksiyona MAXIFS di Excel-ê de bikar tîne - nimûneyên formula
Wek ku we nû dît, Excel MAXIFS pir sade û karanîna hêsan e. Lêbelê, ew çend hûrgelên piçûk hene ku cûdahiyek mezin çêdike. Di mînakên jêrîn de, em ê hewl bidin ku herî zêde ji max-ya şertî ya di Excel de bikar bînin.
Nirxa herî zêde li ser bingeha pir pîvanan bibînin
Di beşa yekem a vê dersê de, me formula MAXIFS çêkir. di forma xweya herî hêsan de ku li ser yek şertê nirxa herî zêde bistînin. Naha, em ê wê nimûneyê pêşdetir bigirin û du pîvanên cûda binirxînin.
Bifikirin, hûn dixwazin di dibistana ciwan de lîstikvanê basketbolê yê herî dirêj bibînin. Ji bo ku wê were kirin, jêrîn diyar bikinarguman:
- Max_range - rêzek hucreyên ku bilindahiyê vedigirin - D2:D11.
- Rêbaza_Krîteran1 - rêzek şaneyên ku werzîşê dihewîne - B2:B11.
- Krîterên1 - "basketbol", ku di hucreya G1 de têketinê.
- Rêza_Krîteran2 - rêzek şaneyên ku diyar dikin Tîpa dibistanê - C2:C11.
- Krîterên2 - "biçûk", ku di hucreya G2 de têketinê.
Argûmanan bidin hev, em van formulan distînin. :
Bi pîvanên "hardcoded":
=MAXIFS(D2:D11, B2:B11, "basketball", C2:C11, "junior")
Digel pîvanên di şaneyên pêşwext de:
=MAXIFS(D2:D11, B2:B11, G1, C2:C11, G2)
Ji kerema xwe bala xwe bidin ku MAXIFS fonksiyona di Excel de bêhesasiyet e , ji ber vê yekê hûn ne hewce ne ku hûn di pîvanên xwe de ji doza tîpa xeman nebin.
Heke hûn plan dikin ku xwe bikar bînin formula li ser gelek şaneyan, pê ewle bin ku hûn hemî rêzan bi referansên hucreyê yên mutleq kilît bikin, bi vî rengî:
=MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2)
Ev ê piştrast bike ku formula li ser şaneyên din rast kopî bike - referansên pîvanan li gorî xwe diguhezin li ser helwesta nisbî ya şaneya ku formula tê kopîkirin dema t ew rêjeyên neguherbar dimînin:
Wek bonusek zêde, ez ê rêyek bilez nîşanî we bidim ku hûn nirxek ji şaneyek din a ku bi nirxa herî zêde ve girêdayî ye derxînin. Di rewşa me de, ew ê navê kesê herî dirêj be. Ji bo vê yekê, em ê di argumana yekem a MATCH-ê de wekî nirxa lêgerînê formula INDEX MATCH-a klasîk û MAXIFS hêlînê bikar bînin:
=INDEX($A$2:$A$11, MATCH(MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2), $D$2:$D$11, 0))
Formul ji me re dibêje ku navbasketbolvanê herî dirêj ê dibistana seretayî Liam e:
Excel MAXIFS bi operatorên mentiqî re
Di rewşa ku hûn hewce ne ku pîvanên hejmarî binirxînin, operatorên mentiqî bikar bînin. wek:
- mezintir ji (>)
- kêmtir ji (<)
- mezintir an wekhev ji (>=)
- kêmtir an wekhev (<=)
- ne wekhevî ()
Operatora "wekhev" (=) di pir rewşan de dikare were derxistin.
Bi gelemperî, hilbijartina operatorek ne pirsgirêk e, beşa herî dijwar ev e ku meriv pîvanan bi hevoksaziya rast ava bike. Bi vî awayî ye:
- Operatorek mentiqî ku li pey jimarek an nivîsek tê divê di nav ducaran de wek ">=14" an "running" were girtin.
- Di şaneyek de. referans an fonksiyonek din, ji bo destpêkirina rêzek û ampersand-ê bikar bînin da ku referansê bi hev ve girêbidin û rêzê biqedînin, mînak. ">"&B1 an "<"&TODAY().
Ji bo ku bibînin ka ew di pratîkê de çawa dixebite, werin em stûna Temen (stûna C) li tabloya nimûneya xwe zêde bikin û bibînin bilindahiya herî zêde di nav kurên di navbera 13 û 14 salî de. Ev dikare bi pîvanên jêrîn pêk were:
Krîterên1: ">=13"
Krîterên2: "<=14"
Ji ber ku em hejmarên di heman stûnê de didin ber hev, pîvan_range di her du rewşan de yek e (C2:C11):
=MAXIFS(D2:D11, C2:C11, ">=13", C2:C11, "<=14")
Heke hûn nexwazin pîvanan kod bikin di formulê de, wan di şaneyên cuda de binivîsin (mînak G1 û H1) û jêrîn bikar bîninhevoksazî:
=MAXIFS(D2:D11, C2:C11, ">="&G1, C2:C11, "<="&H1)
Di dîmena jêrîn de encam nîşan dide:
Ji bilî hejmaran, operatorên mentiqî dikarin bi pîvanên nivîsê re jî bixebitin. Bi taybetî, dema ku hûn dixwazin tiştek ji hesabên xwe derxînin, operatora "ne wekhev" bi kêr tê. Mînakî, ji bo dîtina xwendekarê herî dirêj di hemî werzîşên ji bilî voleybolê de, formula jêrîn bikar bînin:
=MAXIFS(D2:D11, B2:B11, "volleyball")
An jî ev yek, ku G1 werzîşa jêderkirî ye:
=MAXIFS(D2:D11, B2:B11, ""&G1)
Formulên MAXIFS yên bi tîpên hovane (lihevhatina qismî)
Ji bo nirxandina şertek ku nivîsek an karakterek taybetî dihewîne, yek ji karakterên hovane yên jêrîn têxe nav pîvanên te:
- Nîşana pirsê (?) ji bo ku her tîpekê li hev bigre.
- Asterîsk (*) ji bo ku rêzek tîpan li hev bîne.
Ji bo ev nimûne, em di lîstikên lîstikê de zilamê herî dirêj bibînin. Ji ber ku navên hemî werzîşên lîstikê yên di databasa me de bi peyva "ball" diqede, em vê peyvê di nav pîvanan de digirin û stêrkek bikar tînin da ku bi her tîpên berê re li hev bikin:
=MAXIFS(D2:D11, B2:B11, "*ball")
Hûn dikarin di hin hucreyan de jî "ball" binivîsin, mînak. G1, û karaktera hovane bi referansa şaneyê ve girêbide:
=MAXIFS(D2:D11, B2:B11, "*"&G1)
Encam dê wiha xuya bike:
Nirxa herî zêde bistînin di nav rêzeka tarîxê de
Ji ber ku tarîx di pergala navxweyî ya Excel de wekî jimareyên rêzê têne tomar kirin, hûn bi pîvanên tarîxê re mîna ku hûn bi hejmaran re dixebitin dixebitin.
Ji boJi bo vê yekê ronî bikin, em ê stûna Temen bi Dîroka Jidayikbûnê biguherînin û hewl bidin ku bilindahiya herî zêde di nav kurên ku di salek taybetî de ji dayik bûne, bêje di 2004 de hatine dinyayê. Ji bo pêkanîna vî karî , pêdivî ye ku em tarîxên jidayikbûnê yên ku ji 1-Jan-2004 mezintir an wekhev in û ji 31-Dec-2004 kêmtir an wekhev in, "filter" bikin.
Dema ku pîvanên xwe ava dikin, girîng e ku hûn tarîxên bi forma ku Excel dikare fêm bike peyda bikin:
=MAXIFS(D2:D11, C2:C11, ">=1-Jan-2004", C2:C11, "<=31-Dec-2004")
An
=MAXIFS(D2:D11, C2:C11, ">=1/1/2004", C2:C11, "<=12/31/2004")
Ji bo pêşîgirtina li şîrovekirina şaş, maqûl e ku meriv fonksiyona DATE bikar bîne. :
=MAXIFS(D2:D11, C2:C11, ">="&DATE(2004,1,1), C2:C11, "<="&DATE(2004,12,31))
Ji bo vê nimûneyê, em ê sala armancê di G1-ê de binivîsin, û dûv re fonksiyona DATE bikar bînin da ku dîrokan peyda bikin:
=MAXIFS(D2:D11, C2:C11, ">="&DATE(G1,1,1), C2:C11, "<="&DATE(G1,12,31))
Nîşe. Berevajî jimareyan, dema ku bi serê xwe di pîvanan de têne bikar anîn divê tarîx di nav nîşanan de bêne girtin. Mînakî:
=MAXIFS(D2:D11, C2:C11, "10/5/2005")
Bi mantiqa OR-ê re li ser bingeha pir pîvanan nirxa herî zêde bibînin
Fonksiyonek Excel MAXIFS ji bo ceribandina şert û mercên bi mantiqa AND-ê hatî çêkirin - ango ew tenê wan hejmaran pêvajoyê dike. di max_range de ku hemû pîvan RAST in. Lêbelê, di hin rewşan de, dibe ku hûn hewce bikin ku hûn şertan bi mantiqa OR binirxînin - ango hemî hejmarên ku ji bo wan pîvanên diyarkirî RAST e binirxînin.
Ji bo fêmkirina tiştan hêsantir, ji kerema xwe van tiştan binirxînin mînak. Bifikirin ku hûn dixwazin bilindahiya herî zêde ya xortên ku basketbolê dilîzin an jî bibîninfutbolê. Hûn ê çawa bikin? Bikaranîna "basketbolê" wekî pîvan1 û wekî pîvanên "futbolê"2 dê nexebite, ji ber ku Excel dê texmîn bike ku her du pîvan divê RAST binirxînin.
Çareserî çêkirina 2 formulên MAXIFS-ê yên cihê ye, yek ji her werzîşê re, û dûv re fonksiyona MAX-a baş a kevn bikar bînin da ku hejmareke zêde vegerînin:
=MAX(MAXIFS(C2:C11, B2:B11, "basketball"), MAXIFS(C2:C11, B2:B11, "football"))
Pînenga jêrîn vê formulasê nîşan dide lê bi pîvanên di şaneyên têketina pêşwext, F1 û H1 de:
Rêyek din ev e ku hûn formula MAX IF bi mentiqê OR bikar bînin.
7 tiştên ku di derbarê Excel MAXIFS de bi bîr bînin
Li jêr hûn ê çend têbînîyan bibînin ew ê ji bo baştirkirina formulên xwe bibe alîkar û ji xeletiyên hevpar dûr bixe. Hin ji van çavdêriyan jixwe di mînakên me de wekî serişte û notan hatine nîqaş kirin, lê dibe ku ew arîkar be ku hûn kurteyek ji tiştên ku we berê fêr bûne bistînin:
- Fonksiyon MAXIFS li Excel dikare bibe nirxa herî bilind li ser bingeha yek an gelek pîvanan .
- Bi xwerû, Excel MAXIFS bi Û mantiqa re dixebite, ango hejmara herî zêde vedigerîne. ku hemû şert û mercên diyarkirî pêk tîne.
- Ji bo ku fonksiyon kar bike, divê rêza herî zêde û rêzikên pîvanan xwedî eynî mezinahî û şêwe bin.
- Fonksiyon SUMIF nehesasîyeta mezin e , ango di pîvanên nivîsê de halê tîpan nas nake.
- Dema ku formulek MAXIFS ji bo gelek şaneyan dinivîse, ji bîr mekin ku kilît bikin. rêze biReferansên hucreyê yên mutleq ji bo formula ku rast kopî bike.
- Li hevoksaziya pîvanên xwe bifikirin ! Li vir qaîdeyên sereke ev in:
- Dema ku bi serê xwe têne bikar anîn, divê nivîs û tarîx di nav nîşanan de bêne girtin, divê hejmar û referansên şaneyê neyên girtin.
- Gava hejmarek, dîrok an nivîsek tê bikar anîn. bi operatoreke mentiqî, divê hemû biwêj di nav lêkerên ducarî yên mîna ">=10" de were girtin; Referansên hucreyê û fonksiyonên din divê bi karanîna ampersandek mîna ">"&G1 bêne hev kirin.
- MAXIFS tenê di Excel 2019 û Excel ji bo Office 365 de heye. Di guhertoyên berê de, ev fonksiyon ne berdest e.
Bi vî awayî hûn dikarin nirxa herî zêde di Excel de bi şert û mercan bibînin. Ez ji bo xwendinê spas dikim û hêvî dikim ku we di demek nêzîk de li ser bloga xwe bibînim!
Pirtûka xebatê ya pratîkê dakêşin:
Mînakên formula Excel MAXIFS (pelê .xlsx)
