Kennsluforritið sýnir hvernig á að nota MAXIFS aðgerðina í Excel til að fá hámarksgildi með skilyrðum.

Hefð, þegar þú þurftir einhvern tíma að finna hæsta gildi með skilyrðum í Excel, þú þurftir að búa til þína eigin MAX IF formúlu. Þó að það sé ekki mikið mál fyrir reynda notendur, gæti það skapað ákveðna erfiðleika fyrir byrjendur vegna þess að í fyrsta lagi ættir þú að muna setningafræði formúlunnar og í öðru lagi þarftu að vita hvernig á að vinna með fylkisformúlur. Sem betur fer hefur Microsoft nýlega kynnt nýja aðgerð sem gerir okkur kleift að gera skilyrt hámark á auðveldan hátt!

Excel MAXIFS fall

MAXIFS fallið skilar stærsta tölugildi í tilgreint svið byggt á einu eða fleiri forsendum.

Setjafræði MAXIFS fallsins er sem hér segir:

Where:

• Hámarkssvið (áskilið) - svið frumna þar sem þú vilt finna hámarksgildi.
• Criteria_svið1 (áskilið) - fyrsta svið til að meta með viðmið1 .
• Viðmið1 - skilyrðið sem á að nota á fyrsta svið. Það getur verið táknað með tölu, texta eða tjáningu.
• Criteria_range2 / criteria2 , …(valfrjálst) - viðbótarsvið og tengd viðmið þeirra. Allt að 126 svið/viðmiðapör eru studd.

Þessi MAXIFS aðgerð er fáanleg í Excel 2019, Excel 2021 ogExcel fyrir Microsoft 365 á Windows og Mac.

Sem dæmi skulum við finna hæsta fótboltamanninn í skólanum okkar. Að því gefnu að hæð nemenda sé í hólfum D2:D11 (max_range) og íþróttir eru í B2:B11 (criteria_range1), notaðu orðið "fótbolti" sem viðmið1 og þú færð þessa formúlu:

=MAXIFS(D2:D11, B2:B11, "football")

Til að gera formúluna fjölhæfari geturðu sett inn markíþróttina í einhverjum reit (t.d. G1) og sett frumatilvísunina inn í criteria1 rökin:

=MAXIFS(D2:D11, B2:B11, G1)

Athugið. max_range og criteria_range rökin verða að vera af sömu stærð og lögun, þ.e.a.s. innihalda jafnmarga lína og dálka, annars er #VALUE! villa er skilað.

Hvernig á að nota MAXIFS aðgerðina í Excel - formúludæmi

Eins og þú hefur séð nýlega er Excel MAXIFS frekar einfalt og auðvelt í notkun. Hins vegar hefur það nokkur smá blæbrigði sem skipta miklu. Í dæmunum hér að neðan munum við reyna að nýta sem mest skilyrt hámark í Excel.

Finndu hámarksgildi byggt á mörgum forsendum

Í fyrsta hluta þessa kennsluefnis bjuggum við til MAXIFS formúlu í sinni einföldustu mynd til að fá hámarksgildi miðað við eitt skilyrði. Nú ætlum við að taka þetta dæmi lengra og meta tvö mismunandi viðmið.

Svona að þú viljir finna hæsta körfuboltamanninn í unglingaskóla. Til að láta gera það skaltu skilgreina eftirfarandirök:

• Max_range - svið fruma sem innihalda hæðir - D2:D11.
• Criteria_range1 - svið af frumum sem innihalda íþróttir - B2:B11.
• Criteria1 - "körfubolti", sem er inntak í reit G1.
• Criteria_range2 - svið af frumum sem skilgreina skólategund - C2:C11.
• Criteria2 - "yngri", sem er inntak í reit G2.

Þegar við setjum rökin saman fáum við þessar formúlur :

Með "harðkóða" viðmiðum:

=MAXIFS(D2:D11, B2:B11, "basketball", C2:C11, "junior")

Með viðmiðum í fyrirfram skilgreindum hólfum:

=MAXIFS(D2:D11, B2:B11, G1, C2:C11, G2)

Vinsamlegast athugaðu að MAXIFS aðgerðin í Excel er hástafaónæmir , svo þú þarft ekki að hafa áhyggjur af hástöfum í forsendum þínum.

Ef þú ætlar að nota formúlu á mörgum frumum, vertu viss um að læsa öllum sviðum með algerum frumutilvísunum, svona:

=MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2)

Þetta mun tryggja að formúlan afritist rétt í aðrar frumur - viðmiðunartilvísanir breytast miðað við á hlutfallslegri staðsetningu frumunnar þar sem formúlan er afrituð á meðan t sviðin haldast óbreytt:

Sem auka bónus mun ég sýna þér fljótlega leið til að draga gildi úr öðrum reit sem tengist hámarksgildinu. Í okkar tilviki mun það vera nafn hæsta manneskjunnar. Til þess munum við nota klassísku INDEX MATCH formúluna og hreiðra MAXIFS í fyrstu röksemdafærslu MATCH sem uppflettingargildi:

=INDEX($A$2:$A$11, MATCH(MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2), $D$2:$D$11, 0))

Formúlan segir okkur að nafniðaf hæsta körfuboltamanni í unglingaskóla er Liam:

Excel MAXIFS með rökrænum aðgerðum

Í þeim aðstæðum þegar þú þarft að meta töluleg viðmið, notaðu rökræna aðgerða. eins og:

• stærri en (>)
• minna en (<)
• stærri en eða jafnt og (>=)
• minna en eða jafnt og (<=)
• ekki jafnt og ()

Hægt er að sleppa „jafn við“ (=) í flestum tilfellum.

Venjulega er ekki vandamál að velja rekstraraðila, það erfiðasta er að búa til viðmið með réttri setningafræði. Svona er það:

• Rökrænn rekstraraðili sem fylgt er eftir með tölu eða texta verður að vera innan um tvöfalda gæsalappir eins og ">=14" eða "hlaupandi".
• Ef um reit er að ræða tilvísun eða annað fall, notaðu gæsalappirnar til að hefja streng og ampermerki til að sameina tilvísunina og klára strenginn, t.d. ">"&B1 eða "<"&TODAY().

Til að sjá hvernig það virkar í reynd skulum við bæta Aldursdálknum (dálki C) við sýnishornstöfluna okkar og finna hámarkshæð meðal drengja á aldrinum 13 til 14 ára. Þetta er hægt að gera með eftirfarandi forsendum:

Criteria1: ">=13"

Criteria2: "<=14"

Vegna þess að við berum saman tölurnar í sama dálki er criteria_range í báðum tilfellum það sama (C2:C11):

=MAXIFS(D2:D11, C2:C11, ">=13", C2:C11, "<=14")

Ef þú vilt ekki harðkóða viðmiðin í formúlunni, settu þær inn í aðskildar reiti (t.d. G1 og H1) og notaðu eftirfarandisetningafræði:

=MAXIFS(D2:D11, C2:C11, ">="&G1, C2:C11, "<="&H1)

Skjámyndin hér að neðan sýnir niðurstöðuna:

Fyrir utan tölur geta rökrænir rekstraraðilar einnig unnið með textaviðmið. Sérstaklega kemur "ekki jafnt og" rekstraraðili sér vel þegar þú vilt útiloka eitthvað frá útreikningum þínum. Til dæmis, til að finna hæsta nemandann í öllum íþróttum fyrir utan blak, notaðu eftirfarandi formúlu:

=MAXIFS(D2:D11, B2:B11, "volleyball")

Eða þessa, þar sem G1 er undanskilin íþrótt:

=MAXIFS(D2:D11, B2:B11, ""&G1)

MAXIFS formúlur með algildisstöfum (samsvörun að hluta)

Til að meta ástand sem inniheldur tiltekinn texta eða staf skaltu hafa eitt af eftirfarandi algildisstöfum í skilyrðin þín:

• Spurningarmerki (?) til að passa við einhvern stakan staf.
• Stjarna (*) til að passa við hvaða röð stafa sem er.

Fyrir þetta dæmi, við skulum finna út hæsta strákinn í íþróttum. Þar sem nöfn allra leikjaíþrótta í gagnasafninu okkar enda á orðinu „bolti“, tökum við þetta orð inn í viðmiðin og notum stjörnu til að passa við fyrri stafi:

=MAXIFS(D2:D11, B2:B11, "*ball")

Þú getur skrifaðu líka "ball" í einhvern reit, t.d. G1, og tengdu algildisstafinn við frumutilvísunina:

=MAXIFS(D2:D11, B2:B11, "*"&G1)

Niðurstaðan mun líta svona út:

Fá hámarksgildi innan dagsetningarbils

Vegna þess að dagsetningar eru geymdar sem raðnúmer í innra Excel kerfinu vinnur þú með dagsetningarviðmiðin á sama hátt og þú vinnur með tölur.

Til aðútskýrðu þetta, við munum skipta út Aldur dálknum fyrir Fæðingardag og reyna að reikna út hámarkshæð meðal drengja sem fæddir eru á tilteknu ári, td árið 2004. Til að ná þessu verkefni , við þurfum að "sía" fæðingardagana sem eru stærri en eða jafnir og 1-jan-2004 og minni en eða jafn og 31-des-2004.

Þegar viðmiðin eru byggð er mikilvægt að þú gefðu upp dagsetningarnar á því sniði sem Excel getur skilið:

=MAXIFS(D2:D11, C2:C11, ">=1-Jan-2004", C2:C11, "<=31-Dec-2004")

Eða

=MAXIFS(D2:D11, C2:C11, ">=1/1/2004", C2:C11, "<=12/31/2004")

Til að koma í veg fyrir rangtúlkun er skynsamlegt að nota DATE aðgerðina :

=MAXIFS(D2:D11, C2:C11, ">="&DATE(2004,1,1), C2:C11, "<="&DATE(2004,12,31))

Fyrir þetta dæmi munum við slá inn markárið í G1 og nota síðan DATE fallið til að gefa upp dagsetningarnar:

=MAXIFS(D2:D11, C2:C11, ">="&DATE(G1,1,1), C2:C11, "<="&DATE(G1,12,31))

Athugið. Ólíkt tölum ættu dagsetningar að vera settar innan gæsalappa þegar þær eru notaðar í viðmiðunum einar og sér. Til dæmis:

=MAXIFS(D2:D11, C2:C11, "10/5/2005")

Finndu hámarksgildi byggt á mörgum forsendum með OR rökfræði

Excel MAXIFS fallið er hannað til að prófa skilyrðin með OG rökfræðinni - þ.e.a.s. hún vinnur aðeins úr þeim tölum í hámarkssviði þar sem öll skilyrðin eru SÖNN. Í sumum tilfellum gætir þú hins vegar þurft að meta skilyrðin með OR rökfræðinni - þ.e.a.s. vinna úr öllum tölunum sem eitthvað af tilgreindum forsendum er SANNT fyrir.

Til að gera hlutina auðveldari að skilja skaltu íhuga eftirfarandi dæmi. Segjum sem svo að þú viljir finna hámarkshæð strákanna sem spila annað hvort körfubolta eðafótbolta. Hvernig myndir þú gera það? Að nota "körfubolta" sem viðmið1 og sem "fótbolta" viðmið2 mun ekki virka, því Excel myndi gera ráð fyrir að bæði viðmiðin ættu að vera SÖNN.

Lausnin er að búa til 2 aðskildar MAXIFS formúlur, eina fyrir hverja íþrótt, og notaðu svo gamla góða MAX fallið til að skila hærri tölu:

=MAX(MAXIFS(C2:C11, B2:B11, "basketball"), MAXIFS(C2:C11, B2:B11, "football"))

Skjámyndin hér að neðan sýnir þessa formúlu en með viðmiðunum í fyrirfram skilgreindum inntakshólfum, F1 og H1:

Önnur leið er að nota MAX IF formúlu með OR rökfræði.

7 atriði sem þarf að muna um Excel MAXIFS

Hér að neðan eru nokkrar athugasemdir sem mun hjálpa til við að bæta formúlurnar þínar og forðast algengar villur. Sumar þessara athugana hafa þegar verið ræddar sem ábendingar og athugasemdir í dæmunum okkar, en það gæti verið gagnlegt að fá stutta samantekt á því sem þú hefur þegar lært:

1. MAXIFS aðgerðin í Excel getur fengið hæsta gildi byggt á einu eða mörgum viðmiðum .
2. Sjálfgefið er að Excel MAXIFS vinnur með AND rökfræði , þ.e. skilar hámarksfjölda sem uppfyllir öll tilgreind skilyrði.
3. Til að aðgerðin virki verða hámarkssvið og viðmiðunarsvið að hafa sama stærð og lögun .
4. SUMIF aðgerðin er ónæmir fyrir hástöfum , þ.e.a.s. hún þekkir ekki hástafi í textaviðmiðum.
5. Þegar þú skrifar MAXIFS formúlu fyrir margar frumur, mundu að læsa svið meðalgjörar frumutilvísanir til að formúlan sé rétt afrituð.
6. Hugsaðu um setningafræði viðmiðanna þinna ! Hér eru helstu reglurnar:
   • Þegar það er notað eitt og sér ætti texti og dagsetningar að vera innan gæsalappa, tölur og hólfatilvísanir ættu ekki að vera.
   • Þegar númer, dagsetning eða texti er notaður með rökrænum rekstraraðila, verður öll tjáningin að vera innan tveggja gæsalappa eins og ">=10"; hólfatilvísanir og aðrar aðgerðir verða að vera sameinaðar með því að nota og-merki eins og ">"&G1.
7. MAXIFS er aðeins fáanlegt í Excel 2019 og Excel fyrir Office 365. Í fyrri útgáfum, þessi aðgerð er ekki tiltæk.

Þannig geturðu fundið hámarksgildi í Excel með skilyrðum. Ég þakka þér fyrir lesturinn og vonast til að sjá þig á blogginu okkar fljótlega!

Sækja æfingabók:

Excel MAXIFS formúludæmi (.xlsx skrá)