این آموزش نحوه استفاده از تابع MAXIFS در اکسل را برای به دست آوردن حداکثر مقدار با شرایط نشان می دهد.

به طور سنتی، زمانی که شما نیاز به پیدا کردن بالاترین مقدار با شرایط در اکسل داشته باشید، شما باید فرمول MAX IF خود را بسازید. اگرچه برای کاربران باتجربه مشکلی نیست، اما ممکن است برای تازه‌کارها مشکلات خاصی ایجاد کند، زیرا اولاً، باید نحو فرمول را به خاطر بسپارید و ثانیاً باید بدانید که چگونه با فرمول‌های آرایه کار کنید. خوشبختانه، مایکروسافت اخیراً یک تابع جدید معرفی کرده است که به ما امکان می دهد حداکثر شرطی را به روشی آسان انجام دهیم!

عملکرد Excel MAXIFS

تابع MAXIFS بزرگترین مقدار عددی را در محدوده مشخص شده بر اساس یک یا چند معیار.

سینتکس تابع MAXIFS به شرح زیر است:

کجا:

• Max_range (الزامی) - محدوده سلول هایی که می خواهید حداکثر مقدار را پیدا کنید.
• Criteria_range1 (الزامی) - اولین محدوده برای ارزیابی با معیار1 .
• معیار1 - شرطی که در محدوده اول استفاده می شود. می توان آن را با یک عدد، متن یا عبارت نشان داد.
• محدوده_معیار2 / معیار2 ، ...(اختیاری) - محدوده های اضافی و معیارهای مرتبط با آنها. حداکثر 126 جفت محدوده/معیار پشتیبانی می‌شود.

این تابع MAXIFS در Excel 2019، Excel 2021 وExcel برای مایکروسافت 365 در ویندوز و مک.

به عنوان مثال، بیایید بلندقدترین بازیکن فوتبال در مدرسه محلی خود را پیدا کنیم. با فرض اینکه قد دانش‌آموزان در سلول‌های D2:D11 (محدوده_حداکثر) و ورزش‌ها در B2:B11 (محدوده_معیار1) هستند، از کلمه "فوتبال" به عنوان معیار1 استفاده کنید و این فرمول را دریافت خواهید کرد:

=MAXIFS(D2:D11, B2:B11, "football")

برای اینکه فرمول همه کاره تر شود، می توانید ورزش هدف را در برخی از سلول ها (مثلا G1) وارد کنید و مرجع سلول را در آرگومان criteria1 وارد کنید:

=MAXIFS(D2:D11, B2:B11, G1)

توجه. آرگومان های max_range و criteria_range باید هم اندازه و هم شکل باشند، یعنی شامل تعداد مساوی سطر و ستون باشند، در غیر این صورت #VALUE! خطا برگردانده می شود.

نحوه استفاده از تابع MAXIFS در اکسل - نمونه های فرمول

همانطور که مشاهده کردید، Excel MAXIFS کاملاً ساده و آسان برای استفاده است. با این حال، چند تفاوت کوچک دارد که تفاوت بزرگی ایجاد می کند. در مثال های زیر سعی خواهیم کرد حداکثر استفاده را از حداکثر شرطی در اکسل ببریم.

یافتن حداکثر مقدار بر اساس معیارهای متعدد

در قسمت اول این آموزش، فرمول MAXIFS ایجاد کردیم. در ساده ترین شکل آن برای به دست آوردن حداکثر مقدار بر اساس یک شرط. اکنون می‌خواهیم آن مثال را بیشتر بررسی کنیم و دو معیار مختلف را ارزیابی کنیم.

فرض کنید، شما می‌خواهید بلندقدترین بازیکن بسکتبال را در مدرسه ابتدایی پیدا کنید. برای انجام آن موارد زیر را تعریف کنیدآرگومان ها:

• Max_range - محدوده ای از سلول های حاوی ارتفاع - D2:D11.
• Criteria_range1 - محدوده ای از سلول های حاوی ورزش - B2:B11.
• Criteria1 - "basketball" که در سلول G1 ورودی است.
• محدوده_معیار2 - محدوده ای از سلول ها که نوع مدرسه - C2:C11.
• Criteria2 - "junior" که در سلول G2 ورودی است.

با کنار هم قرار دادن آرگومان ها، این فرمول ها را به دست می آوریم. :

با معیارهای "Hardcoded":

=MAXIFS(D2:D11, B2:B11, "basketball", C2:C11, "junior")

با معیارهای موجود در سلول های از پیش تعریف شده:

=MAXIFS(D2:D11, B2:B11, G1, C2:C11, G2)

لطفاً توجه داشته باشید که MAXIFS تابع در اکسل بدون حساس به حروف کوچک و بزرگ است، بنابراین لازم نیست نگران حروف کوچک و بزرگ در معیارهای خود باشید.

در صورتی که قصد دارید از خود استفاده کنید فرمول روی چندین سلول، مطمئن شوید که همه محدوده‌ها را با ارجاعات سلولی مطلق قفل کنید، مانند این:

=MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2)

با این کار اطمینان حاصل می‌شود که فرمول به درستی در سلول‌های دیگر کپی می‌شود - مراجع معیارها بر اساس تغییر می‌کنند. در موقعیت نسبی سلولی که در آن فرمول کپی می شود در حالی که t محدوده‌های او بدون تغییر باقی می‌مانند:

به‌عنوان یک امتیاز اضافی، من راهی سریع برای استخراج یک مقدار از سلول دیگری که با حداکثر مقدار مرتبط است را به شما نشان خواهم داد. در مورد ما، این نام بلندترین فرد خواهد بود. برای این کار، از فرمول کلاسیک INDEX MATCH و nest MAXIFS در اولین آرگومان MATCH به عنوان مقدار جستجو استفاده می کنیم:

=INDEX($A$2:$A$11, MATCH(MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2), $D$2:$D$11, 0))

فرمول به ما می گوید که نامیکی از بلند قدترین بسکتبالیست های دوره راهنمایی لیام است:

Excel MAXIFS با عملگرهای منطقی

در شرایطی که نیاز به ارزیابی معیارهای عددی دارید، از عملگرهای منطقی استفاده کنید. مانند:

• بزرگتر از (>)
• کمتر از (<)
• بزرگتر یا مساوی با (>=)
• کمتر یا مساوی با (<=)
• نه برابر با ()

عملگر "برابر با" (=) را می توان در اکثر موارد حذف کرد.

معمولاً انتخاب یک اپراتور مشکلی نیست، مشکل‌ترین بخش این است که معیارهایی با نحو صحیح بسازید. به این صورت است:

• یک عملگر منطقی به همراه یک عدد یا متن باید در دو گیومه مانند ">=14" یا "running" محصور شود.
• در صورت وجود سلول مرجع یا تابع دیگری، از نقل قول برای شروع یک رشته و علامت علامت برای به هم پیوستن مرجع و پایان دادن به رشته استفاده کنید، به عنوان مثال. ">"&B1 یا "<"&TODAY().

برای اینکه ببینیم در عمل چگونه کار می کند، بیایید ستون Age (ستون C) را به جدول نمونه خود اضافه کنیم و پیدا کنیم حداکثر قد در میان پسران 13 تا 14 ساله. این را می توان با معیارهای زیر انجام داد:

معیار 1: ">=13"

معیار2: "<=14"

از آنجایی که ما اعداد را در یک ستون مقایسه می کنیم، محدوده_ معیار در هر دو مورد یکسان است (C2:C11):

=MAXIFS(D2:D11, C2:C11, ">=13", C2:C11, "<=14")

اگر نمی خواهید معیارها را کدگذاری کنید در فرمول، آنها را در سلول های جداگانه (مانند G1 و H1) وارد کنید و از موارد زیر استفاده کنیدنحو:

=MAXIFS(D2:D11, C2:C11, ">="&G1, C2:C11, "<="&H1)

تصویر صفحه زیر نتیجه را نشان می دهد:

علاوه بر اعداد، عملگرهای منطقی نیز می توانند با معیارهای متن کار کنند. به طور خاص، عملگر «نه برابر» برای زمانی مفید است که بخواهید چیزی را از محاسبات خود حذف کنید. به عنوان مثال، برای پیدا کردن قد بلندترین دانش آموز در همه ورزش ها به استثنای والیبال، از فرمول زیر استفاده کنید:

=MAXIFS(D2:D11, B2:B11, "volleyball")

یا این یکی، که در آن G1 ورزش حذف شده است:

=MAXIFS(D2:D11, B2:B11, ""&G1)

معیارهای شما:

• علامت سوال (؟) برای مطابقت با هر نویسه.
• ستاره (*) برای مطابقت با هر دنباله ای از نویسه ها.

برای در این مثال، بیایید قد بلندترین مرد در ورزش های بازی را بشناسیم. از آنجایی که نام همه ورزش‌های بازی در مجموعه داده ما با کلمه "ball" ختم می‌شود، ما این کلمه را در معیارها قرار می‌دهیم و از یک ستاره برای مطابقت با شخصیت‌های قبلی استفاده می‌کنیم:

=MAXIFS(D2:D11, B2:B11, "*ball")

شما می‌توانید همچنین "توپ" را در برخی از سلول ها تایپ کنید، به عنوان مثال. G1، و کاراکتر عام را با مرجع سلول الحاق کنید:

=MAXIFS(D2:D11, B2:B11, "*"&G1)

نتیجه به صورت زیر خواهد بود:

دریافت حداکثر مقدار در محدوده تاریخ

از آنجا که تاریخ ها به عنوان شماره سریال در سیستم اکسل داخلی ذخیره می شوند، شما با معیارهای تاریخ به همان روشی که با اعداد کار می کنید کار می کنید.

بهبرای نشان دادن این موضوع، ستون سن را با تاریخ تولد جایگزین می کنیم و سعی می کنیم حداکثر قد را در میان پسرانی که در یک سال خاص متولد شده اند، مثلاً در سال 2004، محاسبه کنیم. برای انجام این کار. ، ما باید تاریخ تولدهایی را که بزرگتر یا مساوی با 1-ژان-2004 و کمتر یا مساوی با 31-دسامبر-2004 هستند، "فیلتر" کنیم.

هنگام ایجاد معیارهای خود، مهم است که شما تاریخ ها را در قالبی که اکسل می تواند درک کند ارائه دهید:

=MAXIFS(D2:D11, C2:C11, ">=1-Jan-2004", C2:C11, "<=31-Dec-2004")

یا

=MAXIFS(D2:D11, C2:C11, ">=1/1/2004", C2:C11, "<=12/31/2004")

برای جلوگیری از تفسیر نادرست، منطقی است که از تابع DATE استفاده کنید. :

=MAXIFS(D2:D11, C2:C11, ">="&DATE(2004,1,1), C2:C11, "<="&DATE(2004,12,31))

برای این مثال، سال مورد نظر را در G1 تایپ می کنیم و سپس از تابع DATE برای ارائه تاریخ ها استفاده می کنیم:

=MAXIFS(D2:D11, C2:C11, ">="&DATE(G1,1,1), C2:C11, "<="&DATE(G1,12,31))

توجه. برخلاف اعداد، زمانی که تاریخ ها به تنهایی در معیارها استفاده می شوند، باید در گیومه قرار گیرند. به عنوان مثال:

=MAXIFS(D2:D11, C2:C11, "10/5/2005")

یافتن حداکثر مقدار بر اساس چندین معیار با منطق OR

عملکرد Excel MAXIFS برای آزمایش شرایط با منطق AND طراحی شده است - یعنی فقط آن اعداد را پردازش می کند. در محدوده_حداکثر که همه معیارها برای آن درست است. با این حال، در برخی شرایط، ممکن است لازم باشد شرایط را با منطق OR ارزیابی کنید - یعنی تمام اعدادی را که هر یک از معیارهای مشخص شده برای آنها درست است پردازش کنید.

برای درک آسان تر، لطفاً موارد زیر را در نظر بگیرید. مثال. فرض کنید می خواهید حداکثر قد بچه هایی را که یا بسکتبال بازی می کنند پیدا کنیدفوتبال. چگونه می خواهید انجام دهید؟ استفاده از "بسکتبال" به عنوان معیار 1 و به عنوان معیار "فوتبال" 2 کارساز نخواهد بود، زیرا اکسل فرض می کند که هر دو معیار باید درست ارزیابی شوند.

راه حل این است که 2 فرمول MAXIFS جداگانه ایجاد کنید، یکی برای هر ورزش، و سپس از تابع خوب قدیمی MAX برای برگرداندن عدد بالاتر استفاده کنید:

=MAX(MAXIFS(C2:C11, B2:B11, "basketball"), MAXIFS(C2:C11, B2:B11, "football"))

تصویر صفحه زیر این فرمول را نشان می دهد اما با معیارهای موجود در سلول های ورودی از پیش تعریف شده، F1 و H1:

روش دیگر استفاده از فرمول MAX IF با منطق OR است.

7 نکته در مورد Excel MAXIFS که باید به خاطر بسپارید

در زیر چند نکته را خواهید دید. که به بهبود فرمول های شما و جلوگیری از خطاهای رایج کمک می کند. برخی از این مشاهدات قبلاً به عنوان نکات و یادداشت‌هایی در مثال‌های ما مورد بحث قرار گرفته‌اند، اما دریافت خلاصه‌ای از آنچه قبلاً آموخته‌اید می‌تواند مفید باشد:

1. عملکرد MAXIFS در اکسل می‌تواند دریافت کند. بالاترین مقدار بر اساس یک یا چند معیار .
2. به طور پیش فرض، Excel MAXIFS با منطق AND کار می کند، یعنی حداکثر عدد را برمی گرداند. که تمام شرایط مشخص شده را برآورده می کند.
3. برای اینکه تابع کار کند، محدوده حداکثر و معیارها باید دارای اندازه یکسان و شکل باشند.
4. عملکرد SUMIF به حروف کوچک و بزرگ حساس است، یعنی حروف حروف را در معیارهای متن تشخیص نمی‌دهد.
5. هنگام نوشتن فرمول MAXIFS برای چندین سلول، به یاد داشته باشید که قفل کنید. محدوده باارجاعات سلول مطلق برای فرمول برای کپی صحیح.
6. به نحو معیارهای خود توجه کنید ! قوانین اصلی در اینجا آمده است:
   • وقتی متن و تاریخ به تنهایی استفاده می شود، باید در گیومه قرار داده شود، اعداد و ارجاعات سلولی نباید.
   • وقتی از یک عدد، تاریخ یا متن استفاده می شود. با یک عملگر منطقی، کل عبارت باید در دو گیومه مانند ">=10" محصور شود. مراجع سلولی و سایر توابع باید با استفاده از علامت علامتی مانند ">"&G1 به هم متصل شوند.
7. MAXIFS فقط در Excel 2019 و Excel برای Office 365 موجود است. در نسخه‌های قبلی، این تابع در دسترس نیست.

به این ترتیب می توانید حداکثر مقدار را در Excel با شرایط پیدا کنید. از شما سپاسگزارم که خواندید و امیدوارم به زودی شما را در وبلاگ خود ببینیم!

دانلود کتاب تمرین:

نمونه‌های فرمول اکسل MAXIFS (فایل xlsx.)