Udhëzuesi tregon se si të përdorni funksionin MAXIFS në Excel për të marrë vlerën maksimale me kushtet.

Tradicionalisht, kur ju është dashur ndonjëherë të gjeni vlerën më të lartë me kushtet në Excel, ju duhej të ndërtoni formulën tuaj MAX IF. Megjithëse nuk është një punë e madhe për përdoruesit me përvojë, kjo mund të paraqesë disa vështirësi për fillestarët, sepse, së pari, duhet të mbani mend sintaksën e formulës dhe, së dyti, duhet të dini se si të punoni me formulat e grupeve. Për fat, Microsoft ka prezantuar së fundi një funksion të ri që na lejon të bëjmë maksimumin e kushtëzuar në një mënyrë të thjeshtë!

Funksioni Excel MAXIFS

Funksioni MAXIFS kthen vlerën më të madhe numerike në diapazoni i specifikuar bazuar në një ose më shumë kritere.

Sintaksa e funksionit MAXIFS është si më poshtë:

Ku:

• Vapa_maksimumi (kërkohet) - diapazoni i qelizave ku dëshironi të gjeni vlerën maksimale.
• Rapja_kriterore1 (kërkohet) - diapazoni i parë për t'u vlerësuar me kriteri1 .
• Kriteri1 - kushti që duhet përdorur në intervalin e parë. Ai mund të përfaqësohet me një numër, tekst ose shprehje.
• Vapa_Criteria2 / kriteri2 , …(opsionale) - vargjet shtesë dhe kriteret e tyre të lidhura. Mbështeten deri në 126 çifte diapazoni/kriteresh.

Ky funksion MAXIFS disponohet në Excel 2019, Excel 2021 dheExcel për Microsoft 365 në Windows dhe Mac.

Si shembull, le të gjejmë futbollistin më të gjatë në shkollën tonë lokale. Duke supozuar se lartësitë e nxënësve janë në qelizat D2:D11 (max_range) dhe sportet janë në B2:B11 (varg_kriteri1), përdorni fjalën "futboll" si kriter1, dhe do të merrni këtë formulë:

=MAXIFS(D2:D11, B2:B11, "football")

Për ta bërë formulën më të gjithanshme, mund të futni sportin e synuar në disa qeliza (të themi, G1) dhe të përfshini referencën e qelizës në argumentin criteria1 :

=MAXIFS(D2:D11, B2:B11, G1)

Shënim. Argumentet max_range dhe criteria_range duhet të jenë të së njëjtës madhësi dhe formë, d.m.th. të përmbajnë numrin e barabartë të rreshtave dhe kolonave, përndryshe #VALUE! gabimi është kthyer.

Si të përdorni funksionin MAXIFS në Excel - shembuj formulash

Siç e keni parë sapo, Excel MAXIFS është mjaft i drejtpërdrejtë dhe i lehtë për t'u përdorur. Megjithatë, ajo ka disa nuanca të vogla që bëjnë një ndryshim të madh. Në shembujt e mëposhtëm, ne do të përpiqemi të shfrytëzojmë maksimumin nga maksimumi i kushtëzuar në Excel.

Gjeni vlerën maksimale bazuar në kritere të shumta

Në pjesën e parë të këtij tutoriali, ne krijuam një formulë MAXIFS në formën e tij më të thjeshtë për të marrë vlerën maksimale bazuar në një kusht. Tani, ne do ta marrim atë shembull më tej dhe do të vlerësojmë dy kritere të ndryshme.

Supozojmë se ju dëshironi të gjeni basketbollistin më të gjatë në shkollën e mesme. Për ta bërë atë, përcaktoni sa vijonargumentet:

• Rap_maksimumi - një gamë qelizash që përmbajnë lartësi - D2:D11.
• Vapa_kriterore1 - një varg qelizash që përmbajnë sporte - B2:B11.
• Kriteret1 - "basketboll", i cili futet në qelizën G1.
• Vapa_Criteria2 - një varg qelizash që përcaktojnë lloji i shkollës - C2:C11.
• Kriteret2 - "junior", i cili futet në qelizën G2.

Duke i bashkuar argumentet, marrim këto formula :

Me kritere "të koduara të forta":

=MAXIFS(D2:D11, B2:B11, "basketball", C2:C11, "junior")

Me kritere në qelizat e paracaktuara:

=MAXIFS(D2:D11, B2:B11, G1, C2:C11, G2)

Ju lutemi vini re se MAXIFS funksioni në Excel është i pandjeshëm ndaj shkronjave , kështu që nuk duhet të shqetësoheni për shkronjat në kriteret tuaja.

Në rast se planifikoni të përdorni formula në qeliza të shumta, sigurohuni që të kyçni të gjitha vargjet me referenca absolute të qelizave, si kjo:

=MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2)

Kjo do të sigurojë që formula të kopjohet në qeliza të tjera në mënyrë korrekte - referencat e kritereve ndryshojnë në bazë në pozicionin relativ të qelizës ku kopjohet formula ndërsa t vargjet e tij mbeten të pandryshuara:

Si një bonus shtesë, unë do t'ju tregoj një mënyrë të shpejtë për të nxjerrë një vlerë nga një qelizë tjetër që lidhet me vlerën maksimale. Në rastin tonë, ky do të jetë emri i personit më të gjatë. Për këtë, ne do të përdorim formulën klasike INDEX MATCH dhe do të vendosim MAXIFS në argumentin e parë të MATCH si vlerë kërkimore:

=INDEX($A$2:$A$11, MATCH(MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2), $D$2:$D$11, 0))

Formula na tregon se emringa basketbollisti më i gjatë në shkollën e mesme është Liam:

Excel MAXIFS me operatorë logjikë

Në situatën kur duhet të vlerësoni kriteret numerike, përdorni operatorë logjikë të tilla si:

• më e madhe se (>)
• më e vogël se (<)
• më e madhe se ose e barabartë me (>=)
• më pak ose e barabartë me (<=)
• jo e barabartë me ()

Operatori "e barabartë me" (=) mund të hiqet në shumicën e rasteve.

Zakonisht, zgjedhja e një operatori nuk është problem, pjesa më e ndërlikuar është të ndërtoni kritere me sintaksën e duhur. Ja se si:

• Një operator logjik i ndjekur nga një numër ose tekst duhet të mbyllet në thonjëza të dyfishta si ">=14" ose "running".
• Në rast të një qelize referencë ose një funksion tjetër, përdorni thonjëzat për të filluar një varg dhe një ampersand për të lidhur referencën dhe për të përfunduar vargun, p.sh. ">"&B1 ose "<"&TODAY().

Për të parë se si funksionon në praktikë, le të shtojmë kolonën Mosha (kolona C) në tabelën tonë të mostrës dhe të gjejmë gjatësia maksimale midis djemve të moshës 13 dhe 14 vjeç. Kjo mund të bëhet me kriteret e mëposhtme:

Kriteri 1: ">=13"

Kriteri 2: "<=14"

Për shkak se ne krahasojmë numrat në të njëjtën kolonë, diapazoni_kriteror në të dyja rastet është i njëjtë (C2:C11):

=MAXIFS(D2:D11, C2:C11, ">=13", C2:C11, "<=14")

Nëse nuk dëshironi të kodoni kriteret në formulë, futini ato në qeliza të veçanta (p.sh. G1 dhe H1) dhe përdorni sa vijonsintaksa:

=MAXIFS(D2:D11, C2:C11, ">="&G1, C2:C11, "<="&H1)

Pastroja e mëposhtme tregon rezultatin:

Përveç numrave, operatorët logjikë mund të punojnë edhe me kriteret e tekstit. Në veçanti, operatori "jo i barabartë me" është i dobishëm kur dëshironi të përjashtoni diçka nga llogaritjet tuaja. Për shembull, për të gjetur nxënësin më të gjatë në të gjitha sportet me përjashtim të volejbollit, përdorni formulën e mëposhtme:

=MAXIFS(D2:D11, B2:B11, "volleyball")

Ose këtë, ku G1 është sporti i përjashtuar:

=MAXIFS(D2:D11, B2:B11, ""&G1)

Formulat MAXIFS me karaktere të gërmave (përputhje e pjesshme)

Për të vlerësuar një kusht që përmban një tekst ose karakter specifik, përfshini një nga karakteret e mëposhtme të karaktereve të gërmave në kriteret tuaja:

• Pikëpyetja (?) që të përputhet me çdo karakter të vetëm.
• Ylli (*) që të përputhet me çdo sekuencë karakteresh.

Për këtë shembull, le të zbulojmë djalin më të gjatë në sportet e lojërave. Për shkak se emrat e të gjitha sporteve të lojërave në grupin tonë të të dhënave përfundojnë me fjalën "top", ne e përfshijmë këtë fjalë në kritere dhe përdorim një yll për të përputhur me çdo karakter të mëparshëm:

=MAXIFS(D2:D11, B2:B11, "*ball")

Ju mund të gjithashtu shkruani "top" në ndonjë qelizë, p.sh. G1, dhe lidhni karakterin e shkrepjes me referencën e qelizës:

=MAXIFS(D2:D11, B2:B11, "*"&G1)

Rezultati do të duket si më poshtë:

Merrni vlerën maksimale brenda një diapazoni datash

Për shkak se datat ruhen si numra serialë në sistemin e brendshëm Excel, ju punoni me kriteret e datave në të njëjtën mënyrë si punoni me numrat.

PërPër ta ilustruar këtë, ne do të zëvendësojmë kolonën Mosha me Data e lindjes dhe do të përpiqemi të përcaktojmë lartësinë maksimale midis djemve të lindur në një vit të caktuar, le të themi në vitin 2004. Për të përmbushur këtë detyrë , duhet të "filtrojmë" datat e lindjes që janë më të mëdha se ose të barabarta me 1-Jan-2004 dhe më të vogla se ose të barabarta me 31-Dec-2004.

Kur ndërtoni kriteret tuaja, është e rëndësishme që ju jepni datat në formatin që mund të kuptojë Excel:

=MAXIFS(D2:D11, C2:C11, ">=1-Jan-2004", C2:C11, "<=31-Dec-2004")

Ose

=MAXIFS(D2:D11, C2:C11, ">=1/1/2004", C2:C11, "<=12/31/2004")

Për të parandaluar keqinterpretimet, ka kuptim të përdoret funksioni DATE :

=MAXIFS(D2:D11, C2:C11, ">="&DATE(2004,1,1), C2:C11, "<="&DATE(2004,12,31))

Për këtë shembull, ne do të shkruajmë vitin e synuar në G1 dhe më pas do të përdorim funksionin DATE për të dhënë datat:

=MAXIFS(D2:D11, C2:C11, ">="&DATE(G1,1,1), C2:C11, "<="&DATE(G1,12,31))

Shënim. Ndryshe nga numrat, datat duhet të futen në thonjëza kur përdoren më vete në kritere. Për shembull:

=MAXIFS(D2:D11, C2:C11, "10/5/2005")

Gjeni vlerën maksimale bazuar në kritere të shumta me logjikën OSE

Funksioni Excel MAXIFS është krijuar për të testuar kushtet me logjikën AND - d.m.th përpunon vetëm ata numra në max_range për të cilën të gjitha kriteret janë TË VËRTETA. Megjithatë, në disa situata, mund t'ju duhet të vlerësoni kushtet me logjikën OSE - d.m.th. të përpunoni të gjithë numrat për të cilët ndonjë nga kriteret e specifikuara është i VËRTETË.

Për t'i bërë gjërat më të lehta për t'u kuptuar, ju lutemi merrni parasysh sa vijon shembull. Supozoni se doni të gjeni lartësinë maksimale të djemve që luajnë ose basketboll osefutbolli. Si do ta bënit këtë? Përdorimi i "basketbollit" si kriter1 dhe si kriter i "futbollit"2 nuk do të funksionojë, sepse Excel do të supozonte se të dy kriteret duhet të vlerësohen në TË VËRTETË.

Zgjidhja është të bëni 2 formula të veçanta MAXIFS, një për çdo sport, dhe më pas përdorni funksionin e vjetër të mirë MAX për të kthyer një numër më të madh:

=MAX(MAXIFS(C2:C11, B2:B11, "basketball"), MAXIFS(C2:C11, B2:B11, "football"))

Pamja e ekranit më poshtë tregon këtë formulë, por me kriteret në qelizat hyrëse të paracaktuara, F1 dhe H1:

Një mënyrë tjetër është të përdorni një formulë MAX IF me logjikën OSE.

7 gjëra që duhen mbajtur mend rreth Excel MAXIFS

Më poshtë do të gjeni disa vërejtje që do të ndihmojë për të përmirësuar formulat tuaja dhe për të shmangur gabimet e zakonshme. Disa nga këto vëzhgime janë diskutuar tashmë si këshilla dhe shënime në shembujt tanë, por mund të jetë e dobishme të merrni një përmbledhje të shkurtër të asaj që keni mësuar tashmë:

1. Funksioni MAXIFS në Excel mund të marrë vlera më e lartë e bazuar në një ose kritere të shumta .
2. Si parazgjedhje, Excel MAXIFS punon me logjikën AND , d.m.th. kthen numrin maksimal që plotëson të gjitha kushtet e specifikuara.
3. Që funksioni të funksionojë, diapazoni maksimal dhe diapazoni i kritereve duhet të kenë të njëjtën madhësi dhe formë .
4. Funksioni SUMIF është pandjeshëm ndaj shkronjave , d.m.th. nuk njeh shkronjat e vogla në kriteret e tekstit.
5. Kur shkruani një formulë MAXIFS për shumë qeliza, mbani mend të kyçni shkon meReferencat absolute të qelizave që formula të kopjohet saktë.
6. Kini parasysh sintaksën e kritereve tuaja ! Këtu janë rregullat kryesore:
   • Kur përdoren më vete, teksti dhe datat duhet të futen në thonjëza, numrat dhe referencat e qelizave jo.
   • Kur përdoret një numër, datë ose tekst me një operator logjik, e gjithë shprehja duhet të mbyllet në thonjëza të dyfishta si ">=10"; Referencat e qelizave dhe funksionet e tjera duhet të lidhen duke përdorur një ampersand si ">"&G1.
7. MAXIFS disponohet vetëm në Excel 2019 dhe Excel për Office 365. Në versionet e mëparshme, ky funksion nuk është i disponueshëm.

Kështu mund të gjesh vlerën maksimale në Excel me kushte. Ju falënderoj që lexoni dhe shpresoj t'ju shohim së shpejti në blogun tonë!

Shkarko librin e punës praktike:

Shembuj të formulave Excel MAXIFS (skedari .xlsx)