ບົດສອນສະແດງວິທີການໃຊ້ຟັງຊັນ MAXIFS ໃນ Excel ເພື່ອໃຫ້ໄດ້ຄ່າສູງສຸດດ້ວຍເງື່ອນໄຂ.

ຕາມປະເພນີ, ເມື່ອເຈົ້າຕ້ອງການຊອກຫາຄ່າສູງສຸດດ້ວຍເງື່ອນໄຂໃນ Excel, ທ່ານຕ້ອງສ້າງສູດ MAX IF ຂອງທ່ານເອງ. ໃນຂະນະທີ່ບໍ່ແມ່ນເລື່ອງໃຫຍ່ສໍາລັບຜູ້ໃຊ້ທີ່ມີປະສົບການ, ທີ່ອາດຈະສະເຫນີຄວາມຫຍຸ້ງຍາກບາງຢ່າງສໍາລັບຈົວເພາະວ່າ, ກ່ອນອື່ນ ໝົດ, ທ່ານຄວນຈື່ຈໍາ syntax ຂອງສູດແລະ, ອັນທີສອງ, ທ່ານຈໍາເປັນຕ້ອງຮູ້ວິທີການເຮັດວຽກກັບສູດອາເລ. ໂຊກດີ, ບໍ່ດົນມານີ້ Microsoft ໄດ້ນໍາສະເຫນີຟັງຊັນໃຫມ່ທີ່ໃຫ້ພວກເຮົາເຮັດຕາມເງື່ອນໄຂສູງສຸດເປັນວິທີທີ່ງ່າຍ!

ຟັງຊັນ Excel MAXIFS

ຟັງຊັນ MAXIFS ສົ່ງຄ່າຕົວເລກທີ່ໃຫຍ່ທີ່ສຸດໃນ ໄລຍະທີ່ລະບຸໂດຍອີງຕາມໜຶ່ງ ຫຼືຫຼາຍມາດຖານ.

ໄວຍະກອນຂອງຟັງຊັນ MAXIFS ມີດັ່ງນີ້:

Where:

• Max_range (ຕ້ອງການ) - ຊ່ວງຂອງເຊວທີ່ທ່ານຕ້ອງການຊອກຫາຄ່າສູງສຸດ.
• ເກນ_ໄລຍະ1 (ຕ້ອງການ) - the ໄລຍະທຳອິດເພື່ອປະເມີນດ້ວຍ ເງື່ອນໄຂ 1 .
• ເງື່ອນໄຂ 1 - ເງື່ອນໄຂທີ່ຈະໃຊ້ໃນໄລຍະທຳອິດ. ມັນສາມາດຖືກສະແດງໂດຍຕົວເລກ, ຂໍ້ຄວາມ ຫຼືການສະແດງຜົນ. ຮອງຮັບສູງສຸດ 126 range/criteria pairs.

ຟັງຊັນ MAXIFS ນີ້ມີຢູ່ໃນ Excel 2019, Excel 2021, ແລະExcel ສໍາລັບ Microsoft 365 ໃນ Windows ແລະ Mac.

ເປັນຕົວຢ່າງ, ໃຫ້ຊອກຫານັກກິລາບານເຕະທີ່ສູງທີ່ສຸດໃນໂຮງຮຽນທ້ອງຖິ່ນຂອງພວກເຮົາ. ສົມມຸດຄວາມສູງຂອງນັກຮຽນຢູ່ໃນເຊລ D2:D11 (max_range) ແລະກິລາຢູ່ໃນ B2:B11 (criteria_range1), ໃຫ້ໃຊ້ຄໍາວ່າ "ບານເຕະ" ເປັນເງື່ອນໄຂ1, ແລະທ່ານຈະໄດ້ຮັບສູດນີ້:

=MAXIFS(D2:D11, B2:B11, "football")

ເພື່ອເຮັດໃຫ້ສູດຄຳນວນມີຄວາມຄ່ອງແຄ້ວຫຼາຍຂຶ້ນ, ທ່ານສາມາດໃສ່ກິລາເປົ້າໝາຍໃນບາງເຊລ (ເວົ້າ, G1) ແລະລວມເອົາການອ້າງອີງເຊລໃສ່ໃນອາກິວເມັນ criteria1 :

=MAXIFS(D2:D11, B2:B11, G1)

ໝາຍເຫດ. arguments max_range ແລະ criteria_range ຕ້ອງມີຂະໜາດ ແລະຮູບຮ່າງດຽວກັນ, ເຊັ່ນ: ມີຈຳນວນແຖວ ແລະຖັນເທົ່າກັນ, ຖ້າບໍ່ດັ່ງນັ້ນ #VALUE! ຂໍ້ຜິດພາດຖືກສົ່ງຄືນ.

ວິທີໃຊ້ຟັງຊັນ MAXIFS ໃນ Excel - ຕົວຢ່າງສູດ

ດັ່ງທີ່ເຈົ້າຫາກໍ່ເຫັນ, Excel MAXIFS ແມ່ນຂ້ອນຂ້າງກົງໄປກົງມາ ແລະໃຊ້ງ່າຍ. ຢ່າງໃດກໍຕາມ, ມັນມີ nuances ເລັກນ້ອຍທີ່ເຮັດໃຫ້ມີຄວາມແຕກຕ່າງຢ່າງຫຼວງຫຼາຍ. ໃນຕົວຢ່າງຂ້າງລຸ່ມນີ້, ພວກເຮົາຈະພະຍາຍາມເຮັດໃຫ້ສູງສຸດຂອງເງື່ອນໄຂສູງສຸດໃນ Excel.

ຊອກຫາຄ່າສູງສຸດໂດຍອີງໃສ່ຫຼາຍເງື່ອນໄຂ

ໃນສ່ວນທໍາອິດຂອງການສອນນີ້, ພວກເຮົາໄດ້ສ້າງສູດ MAXIFS. ໃນຮູບແບບທີ່ງ່າຍດາຍທີ່ສຸດເພື່ອໃຫ້ໄດ້ຄ່າສູງສຸດໂດຍອີງໃສ່ເງື່ອນໄຂຫນຶ່ງ. ດຽວນີ້, ພວກເຮົາຈະເອົາຕົວຢ່າງນັ້ນຕື່ມອີກ ແລະປະເມີນສອງເງື່ອນໄຂທີ່ແຕກຕ່າງກັນ.

ສົມມຸດວ່າ, ເຈົ້າຕ້ອງການຊອກຫານັກກິລາບ້ວງທີ່ສູງທີ່ສຸດໃນໂຮງຮຽນປະຖົມ. ເພື່ອໃຫ້ມັນເຮັດໄດ້, ໃຫ້ກໍານົດດັ່ງຕໍ່ໄປນີ້arguments:

• Max_range - ຊ່ວງຂອງເຊວທີ່ບັນຈຸຄວາມສູງ - D2:D11.
• Criteria_range1 - ຊ່ວງຂອງເຊວທີ່ບັນຈຸກິລາ - B2:B11.
• ເງື່ອນໄຂ 1 - "ບ້ວງ", ເຊິ່ງເປັນການປ້ອນຂໍ້ມູນໃນເຊລ G1.
• ເກນ_ຊ່ວງ2 - ຊ່ວງຂອງເຊວທີ່ກຳນົດຄ່າ ປະເພດໂຮງຮຽນ - C2:C11.
• ເງື່ອນໄຂ 2 - "junior", ເຊິ່ງແມ່ນ input ໃນເຊລ G2.

ການວາງອາກິວເມັນຮ່ວມກັນ, ພວກເຮົາໄດ້ຮັບສູດເຫຼົ່ານີ້. :

ດ້ວຍເກນ "hardcoded":

=MAXIFS(D2:D11, B2:B11, "basketball", C2:C11, "junior")

ມີເກນໃນຕາລາງທີ່ກຳນົດໄວ້ລ່ວງໜ້າ:

=MAXIFS(D2:D11, B2:B11, G1, C2:C11, G2)

ກະລຸນາສັງເກດວ່າ MAXIFS ຟັງຊັນໃນ Excel ແມ່ນ ຕົວພິມນ້ອຍ , ດັ່ງນັ້ນທ່ານບໍ່ຈໍາເປັນຕ້ອງກັງວົນກ່ຽວກັບກໍລະນີຕົວອັກສອນໃນເງື່ອນໄຂຂອງທ່ານ.

ໃນກໍລະນີທີ່ທ່ານວາງແຜນທີ່ຈະໃຊ້ ສູດໃນຫຼາຍເຊລ, ໃຫ້ແນ່ໃຈວ່າຈະລັອກທຸກໄລຍະດ້ວຍການອ້າງອີງເຊລແບບສົມບູນ, ເຊັ່ນນີ້:

=MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2)

ນີ້ຈະຮັບປະກັນວ່າສູດສຳເນົາໄປຫາເຊລອື່ນຢ່າງຖືກຕ້ອງ - ເງື່ອນໄຂການອ້າງອີງການປ່ຽນແປງໂດຍອີງໃສ່ ຢູ່ໃນຕໍາແຫນ່ງທີ່ກ່ຽວຂ້ອງຂອງຕາລາງທີ່ສູດໄດ້ຖືກຄັດລອກໃນຂະນະທີ່ t ຂອບເຂດຂອງລາວຍັງຄົງບໍ່ປ່ຽນແປງ:

ເປັນໂບນັດພິເສດ, ຂ້ອຍຈະສະແດງໃຫ້ທ່ານເຫັນວິທີທີ່ໄວໃນການດຶງຄ່າຈາກເຊລອື່ນທີ່ກ່ຽວຂ້ອງກັບຄ່າສູງສຸດ. ໃນກໍລະນີຂອງພວກເຮົາ, ນັ້ນຈະເປັນຊື່ຂອງຄົນສູງທີ່ສຸດ. ສໍາລັບນີ້, ພວກເຮົາຈະໃຊ້ສູດ INDEX MATCH ຄລາສສິກ ແລະວາງ MAXIFS ໃນອາກິວເມັນທໍາອິດຂອງ MATCH ເປັນຄ່າຊອກຫາ:

=INDEX($A$2:$A$11, MATCH(MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2), $D$2:$D$11, 0))

ສູດບອກພວກເຮົາວ່າຊື່ນັກກິລາບ້ວງທີ່ສູງທີ່ສຸດໃນໂຮງຮຽນປະຖົມແມ່ນ Liam:

Excel MAXIFS ກັບຕົວປະຕິບັດການຕາມເຫດຜົນ

ໃນສະຖານະການທີ່ທ່ານຕ້ອງການປະເມີນເງື່ອນໄຂຕົວເລກ, ໃຫ້ໃຊ້ຕົວປະຕິບັດການຕາມເຫດຜົນ ເຊັ່ນ:

• ໃຫຍ່ກວ່າ (>)
• ນ້ອຍກວ່າ (<)
• ໃຫຍ່ກວ່າ ຫຼືເທົ່າກັບ (>=)
• ນ້ອຍກວ່າ ຫຼືເທົ່າກັບ (<=)
• ບໍ່ເທົ່າກັບ ()

ຕົວດຳເນີນການ "ເທົ່າກັບ" (=) ສາມາດຖືກລະເວັ້ນໃນກໍລະນີສ່ວນໃຫຍ່.

ໂດຍປົກກະຕິແລ້ວ, ການເລືອກຕົວປະຕິບັດການບໍ່ແມ່ນບັນຫາ, ພາກສ່ວນທີ່ຫຍຸ້ງຍາກທີ່ສຸດແມ່ນການສ້າງເງື່ອນໄຂທີ່ມີ syntax ທີ່ຖືກຕ້ອງ. ນີ້ແມ່ນວິທີ:

• ຕົວປະຕິບັດການຕາມເຫດຜົນຕາມດ້ວຍຕົວເລກ ຫຼື ຂໍ້ຄວາມຕ້ອງຖືກຕິດຢູ່ໃນວົງຢືມຄູ່ເຊັ່ນ ">=14" ຫຼື "ແລ່ນ".
• ໃນກໍລະນີຂອງເຊລ. ການອ້າງອິງຫຼືຟັງຊັນອື່ນ, ໃຊ້ວົງຢືມເພື່ອເລີ່ມຕົ້ນ string ແລະ ampersand ເພື່ອ concatenate ການອ້າງອິງແລະເຮັດສໍາເລັດ string off, e.g. ">"&B1 ຫຼື "<"&TODAY().

ເພື່ອເບິ່ງວ່າມັນເຮັດວຽກແນວໃດໃນພາກປະຕິບັດ, ໃຫ້ເພີ່ມຖັນອາຍຸ (ຖັນ C) ໃສ່ຕາຕະລາງຕົວຢ່າງຂອງພວກເຮົາ ແລະຊອກຫາ ຄວາມສູງສູງສຸດຂອງເດັກຊາຍອາຍຸລະຫວ່າງ 13 ຫາ 14 ປີ. ອັນນີ້ສາມາດເຮັດໄດ້ດ້ວຍເງື່ອນໄຂຕໍ່ໄປນີ້:

ເງື່ອນໄຂ 1: ">=13"

ເງື່ອນໄຂ 2: "<=14"

ເນື່ອງຈາກວ່າພວກເຮົາສົມທຽບຕົວເລກໃນຖັນດຽວກັນ, criteria_range ໃນທັງສອງກໍລະນີແມ່ນຄືກັນ (C2:C11):

=MAXIFS(D2:D11, C2:C11, ">=13", C2:C11, "<=14")

ຖ້າທ່ານບໍ່ຕ້ອງການ hardcode ເງື່ອນໄຂ. ໃນສູດ, ປ້ອນພວກມັນຢູ່ໃນເຊລແຍກຕ່າງຫາກ (ເຊັ່ນ: G1 ແລະ H1) ແລະໃຊ້ສິ່ງຕໍ່ໄປນີ້syntax:

=MAXIFS(D2:D11, C2:C11, ">="&G1, C2:C11, "<="&H1)

ພາບໜ້າຈໍຂ້າງລຸ່ມສະແດງໃຫ້ເຫັນຜົນໄດ້ຮັບ:

ນອກຈາກຕົວເລກ, ໂຕປະຕິບັດການຕາມເຫດຜົນຍັງສາມາດເຮັດວຽກກັບເງື່ອນໄຂຂໍ້ຄວາມໄດ້. ໂດຍສະເພາະ, ຕົວປະຕິບັດການ "ບໍ່ເທົ່າກັບ" ມີປະໂຫຍດໃນເວລາທີ່ທ່ານຕ້ອງການຍົກເວັ້ນບາງສິ່ງບາງຢ່າງຈາກການຄິດໄລ່ຂອງທ່ານ. ຕົວຢ່າງ, ເພື່ອຊອກຫານັກຮຽນທີ່ສູງທີ່ສຸດໃນກິລາທັງໝົດບໍ່ລວມເອົາບານສົ່ງ, ໃຫ້ໃຊ້ສູດຕໍ່ໄປນີ້:

=MAXIFS(D2:D11, B2:B11, "volleyball")

ຫຼືອັນນີ້, ເຊິ່ງ G1 ເປັນກິລາທີ່ຍົກເວັ້ນ:

=MAXIFS(D2:D11, B2:B11, ""&G1)

ສູດ MAXIFS ທີ່ມີຕົວອັກສອນແທນຕົວ (ການຈັບຄູ່ບາງສ່ວນ)

ເພື່ອປະເມີນເງື່ອນໄຂທີ່ມີຂໍ້ຄວາມ ຫຼືຕົວອັກສອນສະເພາະ, ໃຫ້ໃສ່ຕົວໜັງສືແທນອັນໜຶ່ງຕໍ່ໄປນີ້ໃນ ເງື່ອນໄຂຂອງທ່ານ:

• ເຄື່ອງໝາຍຄໍາຖາມ (?) ໃຫ້ກົງກັບຕົວອັກສອນຕົວດຽວ.
• ເຄື່ອງໝາຍດາວ (*) ເພື່ອໃຫ້ກົງກັບລໍາດັບຂອງຕົວອັກສອນໃດນຶ່ງ.

ສຳລັບ ຕົວຢ່າງນີ້, ໃຫ້ຊອກຫາຜູ້ຊາຍທີ່ສູງທີ່ສຸດໃນກິລາເກມ. ເພາະວ່າຊື່ຂອງກິລາເກມທັງໝົດໃນຊຸດຂໍ້ມູນຂອງພວກເຮົາລົງທ້າຍດ້ວຍຄຳວ່າ "ບານ", ພວກເຮົາຈຶ່ງລວມເອົາຄຳນີ້ເຂົ້າໃນເງື່ອນໄຂ ແລະໃຊ້ເຄື່ອງໝາຍດາວເພື່ອໃຫ້ກົງກັບຕົວອັກສອນກ່ອນໜ້າ:

=MAXIFS(D2:D11, B2:B11, "*ball")

ເຈົ້າສາມາດ ພິມ "ບານ" ໃນບາງຫ້ອງ, ເຊັ່ນ. G1, ແລະປະກອບຕົວອັກສອນແທນຕົວດ້ວຍການອ້າງອີງຕາລາງ:

=MAXIFS(D2:D11, B2:B11, "*"&G1)

ຜົນໄດ້ຮັບຈະປາກົດດັ່ງນີ້:

ຮັບຄ່າສູງສຸດ ພາຍໃນຂອບເຂດວັນທີ

ເນື່ອງຈາກວ່າວັນທີຖືກເກັບໄວ້ເປັນເລກລໍາດັບໃນລະບົບ Excel ພາຍໃນ, ທ່ານເຮັດວຽກກັບເງື່ອນໄຂຂອງວັນທີໃນລັກສະນະດຽວກັນກັບທ່ານເຮັດວຽກກັບຕົວເລກ.

ເພື່ອສະແດງຕົວຢ່າງນີ້, ພວກເຮົາຈະປ່ຽນຖັນ ອາຍຸ ດ້ວຍ ວັນເດືອນປີເກີດ ແລະພະຍາຍາມຊອກຫາຄວາມສູງສູງສຸດຂອງເດັກຊາຍທີ່ເກີດໃນປີໃດໜຶ່ງ, ເວົ້າໃນປີ 2004. ເພື່ອເຮັດໜ້າທີ່ນີ້ໃຫ້ສຳເລັດ. , ພວກເຮົາຈໍາເປັນຕ້ອງ "ກັ່ນຕອງ" ວັນເດືອນປີເກີດທີ່ໃຫຍ່ກວ່າ ຫຼືເທົ່າກັບ 1-Jan-2004 ແລະໜ້ອຍກວ່າ ຫຼືເທົ່າກັບ 31-Dec-2004.

ເມື່ອສ້າງເງື່ອນໄຂຂອງທ່ານ, ມັນເປັນສິ່ງສໍາຄັນທີ່ທ່ານ ໃຫ້ວັນທີໃນຮູບແບບທີ່ Excel ສາມາດເຂົ້າໃຈໄດ້:

=MAXIFS(D2:D11, C2:C11, ">=1-Jan-2004", C2:C11, "<=31-Dec-2004")

ຫຼື

=MAXIFS(D2:D11, C2:C11, ">=1/1/2004", C2:C11, "<=12/31/2004")

ເພື່ອປ້ອງກັນການຕີຄວາມຫມາຍຜິດ, ມັນສົມເຫດສົມຜົນທີ່ຈະໃຊ້ຟັງຊັນ DATE. :

=MAXIFS(D2:D11, C2:C11, ">="&DATE(2004,1,1), C2:C11, "<="&DATE(2004,12,31))

ຕົວຢ່າງນີ້, ພວກເຮົາຈະພິມປີເປົ້າໝາຍໃນ G1, ແລະຫຼັງຈາກນັ້ນໃຊ້ຟັງຊັນ DATE ເພື່ອສະໜອງວັນທີ:

=MAXIFS(D2:D11, C2:C11, ">="&DATE(G1,1,1), C2:C11, "<="&DATE(G1,12,31))

ໝາຍເຫດ. ບໍ່ຄືກັບຕົວເລກ, ວັນທີຄວນຖືກໃສ່ໃນເຄື່ອງໝາຍວົງຢືມເມື່ອໃຊ້ໃນເງື່ອນໄຂຂອງຕົນເອງ. ຕົວຢ່າງ:

=MAXIFS(D2:D11, C2:C11, "10/5/2005")

ຊອກຫາຄ່າສູງສຸດໂດຍອີງໃສ່ຫຼາຍເງື່ອນໄຂທີ່ມີ OR logic

ຟັງຊັນ Excel MAXIFS ຖືກອອກແບບມາເພື່ອທົດສອບເງື່ອນໄຂດ້ວຍ AND logic - i.e. ມັນປະມວນຜົນຕົວເລກເຫຼົ່ານັ້ນເທົ່ານັ້ນ. ໃນ max_range ເຊິ່ງເງື່ອນໄຂທັງໝົດແມ່ນ TRUE. ຢ່າງໃດກໍຕາມ, ໃນບາງສະຖານະການ, ທ່ານອາດຈະຈໍາເປັນຕ້ອງໄດ້ປະເມີນເງື່ອນໄຂທີ່ມີເຫດຜົນ OR - i.e. ປະມວນຜົນຕົວເລກທັງຫມົດທີ່ເງື່ອນໄຂທີ່ລະບຸໄວ້ເປັນຄວາມຈິງ.

ເພື່ອເຮັດໃຫ້ສິ່ງທີ່ເຂົ້າໃຈງ່າຍຂຶ້ນ, ກະລຸນາພິຈາລະນາຕໍ່ໄປນີ້. ຕົວຢ່າງ. ສົມມຸດວ່າທ່ານຕ້ອງການຊອກຫາຄວາມສູງສູງສຸດຂອງຜູ້ຊາຍທີ່ຫຼິ້ນບ້ວງຫຼືບານເຕະ. ເຈົ້າຈະເຮັດແນວນັ້ນໄດ້ແນວໃດ? ການນໍາໃຊ້ "ບານບ້ວງ" ເປັນເງື່ອນໄຂ 1 ແລະ "ບານເຕະ" ເງື່ອນໄຂ 2 ຈະບໍ່ເຮັດວຽກ, ເພາະວ່າ Excel ຈະສົມມຸດວ່າທັງສອງເງື່ອນໄຂຄວນປະເມີນເປັນ TRUE.

ການແກ້ໄຂແມ່ນເຮັດ 2 ສູດ MAXIFS ແຍກຕ່າງຫາກ, ຫນຶ່ງຕໍ່ແຕ່ລະກິລາ, ແລະຫຼັງຈາກນັ້ນໃຊ້ຟັງຊັນ MAX ເກົ່າທີ່ດີເພື່ອສົ່ງຄືນຕົວເລກທີ່ສູງກວ່າ:

=MAX(MAXIFS(C2:C11, B2:B11, "basketball"), MAXIFS(C2:C11, B2:B11, "football"))

ຮູບໜ້າຈໍຂ້າງລຸ່ມນີ້ສະແດງສູດນີ້ແຕ່ມີເງື່ອນໄຂໃນເຊລປ້ອນຂໍ້ມູນທີ່ກໍານົດໄວ້ກ່ອນ, F1 ແລະ H1:

ອີກວິທີຫນຶ່ງແມ່ນການໃຊ້ສູດ MAX IF ທີ່ມີເຫດຜົນ OR.

7 ສິ່ງທີ່ຈະຈື່ຈໍາກ່ຽວກັບ Excel MAXIFS

ຂ້າງລຸ່ມນີ້ທ່ານຈະເຫັນບາງຂໍ້ສັງເກດ ທີ່ຈະຊ່ວຍປັບປຸງສູດຂອງທ່ານແລະຫຼີກເວັ້ນຄວາມຜິດພາດທົ່ວໄປ. ບາງຂໍ້ສັງເກດເຫຼົ່ານີ້ໄດ້ຖືກສົນທະນາແລ້ວເປັນຄໍາແນະນໍາແລະບັນທຶກໃນຕົວຢ່າງຂອງພວກເຮົາ, ແຕ່ມັນອາດຈະເປັນປະໂຫຍດທີ່ຈະໄດ້ສະຫຼຸບສັ້ນໆກ່ຽວກັບສິ່ງທີ່ທ່ານໄດ້ຮຽນຮູ້ແລ້ວ:

1. ຟັງຊັນ MAXIFS ໃນ Excel ສາມາດໄດ້ຮັບ. ຄ່າສູງສຸດໂດຍອີງໃສ່ one ຫຼື ຫຼາຍເງື່ອນໄຂ .
2. ຕາມຄ່າເລີ່ມຕົ້ນ, Excel MAXIFS ເຮັດວຽກກັບ AND logic , i.e. ສົ່ງຄ່າສູງສຸດ. ທີ່ຕອບສະໜອງໄດ້ທຸກເງື່ອນໄຂທີ່ລະບຸໄວ້.
3. ເພື່ອໃຫ້ຟັງຊັນເຮັດວຽກໄດ້, ໄລຍະສູງສຸດ ແລະຂອບເຂດເງື່ອນໄຂຕ້ອງມີ ຂະໜາດດຽວກັນ ແລະ ຮູບຮ່າງ .
4. ຟັງຊັນ SUMIF ແມ່ນ ຕົວພິມນ້ອຍ , i.e. ມັນບໍ່ໄດ້ຮັບຮູ້ຕົວພິມນ້ອຍໃນເງື່ອນໄຂຂອງຂໍ້ຄວາມ. ຊ່ວງ ກັບການອ້າງອີງເຊລແບບສົມບູນສຳລັບສູດການຄັດລອກຢ່າງຖືກຕ້ອງ.
5. ຄິດເຖິງ syntax ຂອງເງື່ອນໄຂຂອງທ່ານ ! ນີ້ແມ່ນກົດລະບຽບຕົ້ນຕໍ:
   • ເມື່ອໃຊ້ດ້ວຍຕົວມັນເອງ, ຂໍ້ຄວາມ ແລະວັນທີຄວນຖືກໃສ່ໃນເຄື່ອງໝາຍວົງຢືມ, ຕົວເລກ ແລະການອ້າງອີງເຊລບໍ່ຄວນ.
   • ເມື່ອໃຊ້ຕົວເລກ, ວັນທີ ຫຼືຂໍ້ຄວາມ. ດ້ວຍຕົວປະຕິບັດການຢ່າງມີເຫດຜົນ, ການສະແດງຜົນທັງໝົດຈະຕ້ອງຖືກໃສ່ໃນວົງຢືມສອງເທົ່າເຊັ່ນ ">=10"; ການອ້າງອິງເຊລ ແລະຟັງຊັນອື່ນໆຈະຕ້ອງຖືກປະສານກັນໂດຍການໃຊ້ຕົວຂະຫຍາຍເຊັ່ນ ">"&G1.
6. MAXIFS ສາມາດໃຊ້ໄດ້ໃນ Excel 2019 ແລະ Excel ສໍາລັບ Office 365 ເທົ່ານັ້ນ. ໃນລຸ້ນກ່ອນໜ້າ, ຟັງຊັນນີ້ບໍ່ສາມາດໃຊ້ໄດ້.

ນັ້ນແມ່ນວິທີທີ່ເຈົ້າສາມາດຊອກຫາຄ່າສູງສຸດໃນ Excel ດ້ວຍເງື່ອນໄຂ. ຂ້າພະເຈົ້າຂໍຂອບໃຈທ່ານສໍາລັບການອ່ານແລະຫວັງວ່າຈະໄດ້ພົບທ່ານໃນ blog ຂອງພວກເຮົາໃນໄວໆນີ້!

ດາວໂຫລດປື້ມຄູ່ມືການປະຕິບັດ:

ຕົວຢ່າງສູດ Excel MAXIFS (ໄຟລ໌ .xlsx)