O'quv qo'llanma Excelda MAXIFS funksiyasidan shartlar bilan maksimal qiymatni olish uchun qanday foydalanishni ko'rsatadi.

An'anaga ko'ra, Excelda shartlar bilan eng yuqori qiymatni topish kerak bo'lganda, siz o'zingizning MAX IF formulangizni yaratishingiz kerak edi. Tajribali foydalanuvchilar uchun unchalik katta bo'lmasa-da, bu yangi boshlanuvchilar uchun ma'lum qiyinchiliklarni keltirib chiqarishi mumkin, chunki birinchidan, formulaning sintaksisini eslab qolish kerak, ikkinchidan, massiv formulalari bilan ishlashni bilishingiz kerak. Yaxshiyamki, Microsoft yaqinda shartli maksni oson bajarish imkonini beruvchi yangi funksiyani taqdim etdi!

Excel MAXIFS funksiyasi

MAXIFS funksiyasi eng katta raqamli qiymatni qaytaradi. bir yoki bir nechta mezonga asoslangan belgilangan diapazon.

MAXIFS funksiyasining sintaksisi quyidagicha:

Bu yerda:

• Maks_oraliq (majburiy) - maksimal qiymatni topmoqchi bo'lgan katakchalar diapazoni.
• Kriteriyalar_diapazoni1 (majburiy) - mezonlar1 bilan baholash uchun birinchi diapazon.
• Kriteriya1 - birinchi diapazonda foydalanish sharti. U raqam, matn yoki ifoda bilan ifodalanishi mumkin.
• Kriteria_diapazoni2 / kriteria2 , …(ixtiyoriy) - qoʻshimcha diapazonlar va ularga tegishli mezonlar. 126 tagacha diapazon/kriteriyalar juftligi qoʻllab-quvvatlanadi.

Ushbu MAXIFS funksiyasi Excel 2019, Excel 2021 va versiyalarida mavjud.Windows va Mac-da Microsoft 365 uchun Excel.

Masalan, mahalliy maktabimizdagi eng uzun bo'yli futbolchini topamiz. O‘quvchilarning bo‘yi D2:D11 katakchalarida (maksimal_oraliq) va sport B2:B11da (kriteria_oraliq1) deb faraz qilsak, 1-mezon sifatida “futbol” so‘zidan foydalaning va siz quyidagi formulani olasiz:

=MAXIFS(D2:D11, B2:B11, "football")

Formulani ko'p qirrali qilish uchun siz maqsadli sport turini ba'zi katakchalarga kiritishingiz mumkin (masalan, G1) va hujayra havolasini criteria1 argumentiga qo'shishingiz mumkin:

=MAXIFS(D2:D11, B2:B11, G1)

Eslatma. maksimal_oraliq va kriteria_oraliq argumentlari bir xil oʻlcham va shaklda boʻlishi kerak, yaʼni qatorlar va ustunlar soni teng boʻlishi kerak, aks holda #VALUE! xato qaytariladi.

Excelda MAXIFS funksiyasidan qanday foydalanish - formula misollari

Yaqinda ko'rganingizdek, Excel MAXIFS juda sodda va ulardan foydalanish oson. Biroq, u katta farq qiladigan bir nechta kichik nuanslarga ega. Quyidagi misollarda biz Excelda shartli maksimal qiymatdan maksimal darajada foydalanishga harakat qilamiz.

Ko'p mezon asosida maksimal qiymatni toping

Ushbu qo'llanmaning birinchi qismida biz MAXIFS formulasini yaratdik. eng oddiy shaklda bitta shart asosida maksimal qiymatni olish. Endi biz ushbu misolni davom ettiramiz va ikki xil mezonni baholaymiz.

Aytaylik, siz maktabdagi eng baland basketbolchini topmoqchisiz. Buni amalga oshirish uchun quyidagilarni aniqlangargumentlar:

• Maks_oraliq - balandliklarni o'z ichiga olgan katakchalar diapazoni - D2:D11.
• Kriteria_diapazoni1 - sport ma'lumotlarini o'z ichiga olgan hujayralar qatori - B2:B11.
• Kriteriyalar1 - G1 katakchasiga kiritiladigan "basketbol".
• Kriteria_diapazoni2 - belgilovchi katakchalar diapazoni. maktab turi - C2:C11.
• Kriteriyalar2 - G2 katakchaga kiritiladigan "junior".

Argumentlarni birlashtirib, biz ushbu formulalarni olamiz :

"Qattiq kodlangan" mezonlar bilan:

=MAXIFS(D2:D11, B2:B11, "basketball", C2:C11, "junior")

Oldindan belgilangan hujayralardagi mezonlar bilan:

=MAXIFS(D2:D11, B2:B11, G1, C2:C11, G2)

E'tibor bering, MAXIFS Excel funksiyasi katta-kichik harflarni sezmaydi , shuning uchun siz o'z mezonlaringizdagi harflar katta-kichikligi haqida qayg'urmasligingiz kerak.

Agar siz o'z harflaringizni ishlatmoqchi bo'lsangiz formulani bir nechta katakchalarda o'rnatish uchun barcha diapazonlarni mutlaq hujayra havolalari bilan bloklashni unutmang, masalan:

=MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2)

Bu formula boshqa yacheykalarga to'g'ri nusxalanishini ta'minlaydi - havolalar mezonlari asosida o'zgaradi t paytida formula ko'chiriladigan katakning nisbiy holati bo'yicha u diapazonlar o'zgarishsiz qoladi:

Qo'shimcha bonus sifatida men sizga maksimal qiymat bilan bog'liq bo'lgan boshqa hujayradan qiymat chiqarishning tezkor usulini ko'rsataman. Bizning holatda, bu eng baland odamning ismi bo'ladi. Buning uchun biz klassik INDEX MATCH formulasidan foydalanamiz va qidiruv qiymati sifatida MATCH ning birinchi argumentida MAXIFS ni joylashtiramiz:

=INDEX($A$2:$A$11, MATCH(MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2), $D$2:$D$11, 0))

Formula bizga nom ekanligini aytadi.o'rta maktabdagi eng baland basketbolchi Liam:

Mantiqiy operatorlar bilan Excel MAXIFS

Raqamli mezonlarni baholash kerak bo'lgan vaziyatda mantiqiy operatorlardan foydalaning. masalan:

• katta (>)
• kichik (<)
• katta yoki teng (>=)
• (<=) dan kichik yoki teng
• () ga teng emas

Koʻp hollarda “teng” operatori (=) oʻtkazib yuborilishi mumkin.

Odatda operator tanlash muammo emas, eng qiyin qismi to'g'ri sintaksis bilan mezonlarni yaratishdir. Mana shunday:

• Mantiqiy operatordan keyin raqam yoki matn qo'sh qo'shtirnoq ichiga olinishi kerak, masalan, ">=14" yoki "ishlayotgan".
• Yacheyka bo'lsa. mos yozuvlar yoki boshqa funksiya boʻlsa, satrni boshlash uchun qoʻshtirnoqlardan foydalaning va havolani birlashtirish va satrni tugatish uchun ampersanddan foydalaning, masalan. ">"&B1 yoki "<"&BUGUN().

Uning amalda qanday ishlashini ko'rish uchun keling, Namuna jadvalimizga Yosh ustunini (C ustuni) qo'shamiz va topamiz. 13 yoshdan 14 yoshgacha bo'lgan o'g'il bolalar orasidagi maksimal bo'y. Buni quyidagi mezonlar bilan amalga oshirish mumkin:

Mezon1: ">=13"

Mezon2: "<=14"

Biz bir xil ustundagi raqamlarni solishtirganimiz sababli, ikkala holatda ham mezon_diapazoni bir xil (C2:C11):

=MAXIFS(D2:D11, C2:C11, ">=13", C2:C11, "<=14")

Agar siz mezonlarni qattiq kodlashni xohlamasangiz formulada ularni alohida katakchalarga kiriting (masalan, G1 va H1) va quyidagilardan foydalaningsintaksis:

=MAXIFS(D2:D11, C2:C11, ">="&G1, C2:C11, "<="&H1)

Quyidagi skrinshotda natija ko'rsatilgan:

Raqamlardan tashqari mantiqiy operatorlar ham matn mezonlari bilan ishlashi mumkin. Xususan, siz hisob-kitoblaringizdan biror narsani chiqarib tashlamoqchi bo'lsangiz, "teng emas" operatori yordam beradi. Masalan, voleyboldan tashqari barcha sport turlari bo‘yicha eng baland bo‘yli o‘quvchini topish uchun quyidagi formuladan foydalaning:

=MAXIFS(D2:D11, B2:B11, "volleyball")

Yoki bu, G1 sportdan tashqari:

=MAXIFS(D2:D11, B2:B11, ""&G1)

Joyker belgilarga ega MAXIFS formulalari (qisman mos)

Muayyan matn yoki belgini o'z ichiga olgan shartni baholash uchun quyidagi joker belgilardan birini kiriting. mezonlaringiz:

• Istalgan bitta belgiga mos keladigan savol belgisi (?).
• Har qanday belgilar ketma-ketligiga mos keladigan yulduzcha (*).

Uchun bu misol, keling, o'yin sportidagi eng uzun yigitni topamiz. Maʼlumotlar toʻplamimizdagi barcha oʻyin sport turlarining nomlari “toʻp” soʻzi bilan tugaganligi sababli, biz ushbu soʻzni mezonlarga kiritamiz va oldingi belgilarga mos kelish uchun yulduzchadan foydalanamiz:

=MAXIFS(D2:D11, B2:B11, "*ball")

Siz buni qilishingiz mumkin. shuningdek, ba'zi kataklarda "to'p" ni yozing, masalan. G1 va joker belgini hujayra havolasi bilan birlashtiring:

=MAXIFS(D2:D11, B2:B11, "*"&G1)

Natija quyidagicha ko'rinadi:

Maksimal qiymatni oling sana oralig'ida

Sanalar ichki Excel tizimida seriya raqamlari sifatida saqlanganligi sababli, siz raqamlar bilan ishlaganingizdek sanalar mezonlari bilan ishlaysiz.

ToBuni tasvirlab bering, biz Yosh ustunini Tug'ilgan sana bilan almashtiramiz va ma'lum bir yilda, aytaylik 2004 yilda tug'ilgan o'g'il bolalarning maksimal bo'yini aniqlashga harakat qilamiz. Bu vazifani bajarish uchun , 2004-yilning 1-yanvaridan katta yoki unga teng va 2004-yilning 31-dekabriga teng yoki undan kichik bo‘lgan tug‘ilgan sanalarni “filtrlashimiz” kerak.

Mezonlarni tuzayotganda, bu muhim ahamiyatga ega. Sanalarni Excel tushunadigan formatda taqdim eting:

=MAXIFS(D2:D11, C2:C11, ">=1-Jan-2004", C2:C11, "<=31-Dec-2004")

Yoki

=MAXIFS(D2:D11, C2:C11, ">=1/1/2004", C2:C11, "<=12/31/2004")

Noto'g'ri talqin qilishning oldini olish uchun DATE funksiyasidan foydalanish maqsadga muvofiqdir. :

=MAXIFS(D2:D11, C2:C11, ">="&DATE(2004,1,1), C2:C11, "<="&DATE(2004,12,31))

Ushbu misol uchun biz maqsadli yilni G1-ga kiritamiz va keyin sanalarni berish uchun DATE funksiyasidan foydalanamiz:

=MAXIFS(D2:D11, C2:C11, ">="&DATE(G1,1,1), C2:C11, "<="&DATE(G1,12,31))

Eslatma. Raqamlardan farqli o'laroq, sanalar o'z-o'zidan mezonlarda qo'llanilganda qo'shtirnoq ichiga olinishi kerak. Masalan:

=MAXIFS(D2:D11, C2:C11, "10/5/2005")

YOKI mantiq bilan bir nechta mezonlar asosida maksimal qiymatni toping

Excel MAXIFS funksiyasi shartlarni AND mantiqi bilan sinab ko'rish uchun mo'ljallangan - ya'ni u faqat shu raqamlarni qayta ishlaydi. maksimal_oraliq da barcha mezonlar TRUE. Biroq, ba'zi hollarda shartlarni OR mantig'i bilan baholashingiz kerak bo'lishi mumkin, ya'ni belgilangan mezonlardan har biri TO'G'ri bo'lgan barcha raqamlarni qayta ishlash.

Tushunishni osonlashtirish uchun quyidagilarni ko'rib chiqing. misol. Aytaylik, siz basketbol yoki basketbol o'ynaydigan bolalarning maksimal balandligini topmoqchisizfutbol. Buni qanday qilgan bo'lardingiz? “Basketbol”ni 1 mezon va “futbol” mezoni2 sifatida ishlatish ishlamaydi, chunki Excel ikkala mezonni ham TRUE deb baholashi kerak.

Yechim har bir sport turi uchun bittadan ikkita alohida MAXIFS formulasini yaratishdir. va undan keyin yuqoriroq raqamni qaytarish uchun eski MAX funksiyasidan foydalaning:

=MAX(MAXIFS(C2:C11, B2:B11, "basketball"), MAXIFS(C2:C11, B2:B11, "football"))

Quyidagi skrinshotda ushbu formula ko‘rsatilgan, lekin mezonlar F1 va H1 oldindan belgilangan kiritish kataklarida ko‘rsatilgan:

Yana bir usul - MAX IF formulasini OR mantiqi bilan ishlatishdir.

Excel MAXIFS haqida 7 ta esda tutish kerak bo'lgan narsa

Quyida siz bir nechta izohlarni topasiz. Bu sizning formulalaringizni yaxshilashga va keng tarqalgan xatolardan qochishga yordam beradi. Ushbu kuzatishlarning ba'zilari allaqachon misollarimizda maslahat va eslatmalar sifatida muhokama qilingan, ammo siz allaqachon o'rgangan narsalaringiz haqida qisqacha ma'lumot olish foydali bo'lishi mumkin:

1. Excel'dagi MAXIFS funktsiyasi bitta yoki bir nechta mezonga asoslangan eng yuqori qiymat.
2. Sukut bo'yicha Excel MAXIFS VA mantiq bilan ishlaydi, ya'ni maksimal raqamni qaytaradi. barcha belgilangan shartlarga javob beradi.
3. Funktsiya ishlashi uchun maksimal diapazon va mezon diapazonlari bir xil o'lchamda va shakl bo'lishi kerak.
4. SUMIF funksiyasi katta-kichik harflarni sezmaydi , ya'ni u matn mezonlarida katta-kichik harflarni tanimaydi.
5. Bir nechta katakchalar uchun MAXIFS formulasini yozayotganda bloklashni unutmang. diapazonlari bilanformuladan to'g'ri nusxa ko'chirish uchun mutlaq hujayra havolalari.
6. Mezonlaringizning sintaksisiga e'tibor bering ! Mana asosiy qoidalar:
   • O'z-o'zidan foydalanilganda matn va sanalar qo'shtirnoq ichiga olinishi kerak, raqamlar va katakchalar havola qilinmasligi kerak.
   • Raqam, sana yoki matn ishlatilganda mantiqiy operator bilan butun ifoda ">=10" kabi qo'sh tirnoq ichiga olinishi kerak; hujayra havolalari va boshqa funksiyalar ">"&G1 kabi ampersand yordamida birlashtirilishi kerak.
7. MAXIFS faqat Excel 2019 va Excel uchun Office 365 da mavjud. Oldingi versiyalarda, bu funksiya mavjud emas.

Shunday qilib Excelda shartlar bilan maksimal qiymatni topishingiz mumkin. O'qiganingiz uchun tashakkur va sizni tez orada blogimizda ko'rishga umid qilaman!

Amaliy ish kitobini yuklab oling:

Excel MAXIFS formula misollari (.xlsx fayli)