Tutorialak MAXIFS funtzioa Excel-en nola erabili erakusten du baldintzekin balio maximoa lortzeko.

Tradizioz, Excel-en baldintzekin baliorik altuena aurkitu behar zenuenean, zure MAX IF formula eraiki behar izan zenuen. Erabiltzaile esperientziadunentzat gauza handia ez bada ere, horrek zenbait zailtasun sor ditzake hasiberrientzat, lehenik eta behin, formularen sintaxia gogoratu behar duzulako eta, bigarrenik, matrize-formulekin lan egiten jakin behar duzulako. Zorionez, Microsoft-ek duela gutxi baldintzapeko max modu erraz batean egiten uzten digun funtzio berri bat aurkeztu du!

Excel MAXIFS funtzioa

MAXIFS funtzioak zenbakizko baliorik handiena itzultzen du. zehaztutako barrutia irizpide batean edo gehiagotan oinarrituta.

MAXIFS funtzioaren sintaxia hau da:

Non:

• Max_range (beharrezkoa) - balio maximoa aurkitu nahi duzun gelaxken barrutia.
• Irizpide_barrutia1 (beharrezkoa) - irizpide1 rekin ebaluatzeko lehen barrutia.
• Irizpide1 - lehenengo barrutian erabili beharreko baldintza. Zenbaki baten, testuaren edo esamolde baten bidez irudika daiteke.
• Irizpide_barrutia2 / irizpideak2 , … (aukerakoa) - barruti osagarriak eta haiei lotutako irizpideak. Gehienez 126 barruti/irizpide bikote onartzen dira.

MAXIFS funtzio hau Excel 2019, Excel 2021 etaMicrosoft 365-erako Excel Windows eta Mac-en.

Adibide gisa, aurki dezagun gure herriko ikastetxeko futbolaririk altuena. Ikasleen altuera D2:D11 (gehien_barrutia) eta kirolak B2:B11 (irizpide_barrutia1) gelaxketan daudela suposatuz, erabili "futbola" hitza irizpide1 gisa, eta formula hau lortuko duzu:

=MAXIFS(D2:D11, B2:B11, "football")

Formula polifazetikoagoa izan dadin, helburuko kirola sar dezakezu gelaxka batzuetan (esaterako, G1) eta gelaxka-erreferentzia irizpidea1 argumentuan sar dezakezu:

=MAXIFS(D2:D11, B2:B11, G1)

Oharra. max_range eta criteria_range argumentuek tamaina eta forma berekoak izan behar dute, hau da, errenkada eta zutabe kopuru berdina eduki behar dute, bestela #BALIOA! errorea itzultzen da.

Nola erabili MAXIFS funtzioa Excel-en - formula adibideak

Ikusi berri duzun bezala, Excel MAXIFS nahiko erraza eta erabiltzeko erraza da. Hala ere, diferentzia handia eragiten duten ñabardura txiki batzuk ditu. Beheko adibideetan, Excel-en baldintzapeko maximoari etekinik handiena ateratzen saiatuko gara.

Bilatu irizpide anitzetan oinarritutako gehienezko balioa

Tutorial honen lehen zatian, MAXIFS formula bat sortu dugu. bere forma sinpleenean baldintza batean oinarritutako gehienezko balioa lortzeko. Orain, adibide hori gehiago hartuko dugu eta bi irizpide ezberdin ebaluatuko ditugu.

Demagun, haur eskoletako saskibaloi jokalaririk altuena aurkitu nahi duzula. Egin ahal izateko, zehaztu honako hauargumentuak:

• Max_range - altuerak dituen gelaxka sorta - D2:D11.
• Irizpide_barrutia1 - kirolak dituen gelaxka sorta bat - B2:B11.
• Irizpide1 - "saskibaloia", G1 gelaxkan sartzen dena.
• Irizpide_barrutia2 - gelaxka-sorta bat definitzen duena. eskola mota - C2:C11.
• Irizpideak2 - "junior", G2 gelaxkan sartzen dena.

Argumentuak elkartuz, formula hauek lortzen ditugu. :

Irizpide "gogor kodetuekin":

=MAXIFS(D2:D11, B2:B11, "basketball", C2:C11, "junior")

Aurrez zehaztutako gelaxketan irizpideekin:

=MAXIFS(D2:D11, B2:B11, G1, C2:C11, G2)

Kontuan izan MAXIFS Excel-en funtzioak maiuskulak eta minuskulak bereizten ditu , beraz, ez duzu zure irizpideetan letra maiuskulaz kezkatu behar.

Zure irizpidea erabiltzeko asmoa baduzu. formula gelaxka anitzetan, ziurtatu barruti guztiak blokeatzen dituzula gelaxka-erreferentzia absolutuekin, honela:

=MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2)

Horrek bermatuko du formula beste gelaxka batzuetara behar bezala kopiatzen dela - irizpideen erreferentziak aldatu egiten dira. formula kopiatzen den gelaxkaren posizio erlatiboan t bitartean barrutiak bere horretan dirau:

Beste gehigarri gisa, gehienezko balioarekin lotutako beste gelaxka batetik balio bat ateratzeko modu azkar bat erakutsiko dizut. Gure kasuan, hori izango da pertsona altuenaren izena. Horretarako, INDEX MATCH formula klasikoa erabiliko dugu eta MAXIFS habiatuko dugu MATCH-ren lehen argumentuan bilaketa-balio gisa:

=INDEX($A$2:$A$11, MATCH(MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2), $D$2:$D$11, 0))

Formulak izenak esaten diguEskola txikiko saskibaloi jokalaririk altuena Liam da:

Excel MAXIFS operadore logikoekin

Zenbakizko irizpideak ebaluatu behar dituzunean, erabili operadore logikoak. hala nola:

• baino handiagoa (>)
• baino txikiagoa (<)
• baino handiagoa edo berdina (>=)
• (<=) baino txikiagoa edo berdina
• ()-ren berdina

"Berdin" eragilea (=) ezaba daiteke kasu gehienetan.

Normalean, operadore bat aukeratzea ez da arazorik izaten, delikatuena irizpideak sintaxi egokiarekin eraikitzea izaten da. Hona hemen nola:

• Eragile logiko bat zenbaki bat edo testu baten ondotik ">=14" edo "exekutatzen" bezalako komatxo bikoitz artean sartu behar da.
• Gelula baten kasuan. erreferentzia edo beste funtzio bat, erabili komatxoak kate bat hasteko eta ampersand bat erreferentzia kateatzeko eta katea amaitzeko, adibidez. ">"&B1 edo "<"&GAUR().

Praktikan nola funtzionatzen duen ikusteko, gehi diezaiogun Adina zutabea (C zutabea) gure lagin-taulari eta aurki ditzagun. gehienezko altuera 13 eta 14 urte bitarteko mutilen artean. Irizpide hauekin egin daiteke:

Irizpidea1: ">=13"

Irizpidea2: "<=14"

Zutabe bereko zenbakiak konparatzen ditugunez, bi kasuetan criteria_range berdina da (C2:C11):

=MAXIFS(D2:D11, C2:C11, ">=13", C2:C11, "<=14")

Irizpideak gogor kodetu nahi ez badituzu formulan, sartu gelaxka bereizietan (adibidez, G1 eta H1) eta erabili honako hausintaxia:

=MAXIFS(D2:D11, C2:C11, ">="&G1, C2:C11, "<="&H1)

Beheko pantaila-argazkiak emaitza erakusten du:

Zenbakiez gain, operadore logikoek testu irizpideekin ere lan egin dezakete. Bereziki, "ez berdina" operadorea erabilgarria da zure kalkuluetatik zerbait baztertu nahi duzunean. Adibidez, boleibola izan ezik kirol guztietan ikaslerik altuena aurkitzeko, erabili formula hau:

=MAXIFS(D2:D11, B2:B11, "volleyball")

Edo hau, non G1 kanpoan dagoen kirola den:

=MAXIFS(D2:D11, B2:B11, ""&G1)

Komodin karaktereekin MAXIFS formulak (bat-etortze partziala)

Testu edo karaktere zehatz bat duen baldintza bat ebaluatzeko, sartu komodin karaktere hauetako bat zure irizpideak:

• Galdera ikurra (?) edozein karaktere bakar bat etortzeko.
• Izartxoa (*) edozein karaktere-sekuentzia bat etortzeko.

Horretarako Adibide honetan, jakin dezagun joko-kiroletako mutil altuena. Gure datu-multzoko joko-kirol guztien izenak "pilota" hitzarekin amaitzen direnez, hitz hau sartzen dugu irizpideetan eta izartxo bat erabiltzen dugu aurreko karaktereekin bat etortzeko:

=MAXIFS(D2:D11, B2:B11, "*ball")

Hau da. ere idatzi "bola" gelaxka batzuetan, adibidez. G1, eta kateatu komodin karaktere gelaxka-erreferentziarekin:

=MAXIFS(D2:D11, B2:B11, "*"&G1)

Emaitza honela izango da:

Lortu gehienezko balioa data-tarte baten barruan

Datak serie-zenbaki gisa gordetzen direnez barneko Excel sisteman, data-irizpideekin zenbakiekin lan egiten duzun moduan lan egiten duzu.

Tohau irudikatu, Adina zutabea Jaiotze-data -rekin ordezkatuko dugu eta urte jakin batean jaiotako mutilen artean gehienezko altuera lantzen saiatuko gara, demagun 2004an. Zeregin hori betetzeko. , 2004ko urtarrilaren 1a baino handiagoak edo berdinak eta 2004-abenduaren 31 baino txikiagoak edo berdinak diren jaiotze-datak "iragazi" behar ditugu.

Zure irizpideak eraikitzean, garrantzitsua da eman datak Excel-ek uler dezakeen formatuan:

=MAXIFS(D2:D11, C2:C11, ">=1-Jan-2004", C2:C11, "<=31-Dec-2004")

Edo

=MAXIFS(D2:D11, C2:C11, ">=1/1/2004", C2:C11, "<=12/31/2004")

Interpretazio okerrak saihesteko, zentzuzkoa da DATA funtzioa erabiltzea. :

=MAXIFS(D2:D11, C2:C11, ">="&DATE(2004,1,1), C2:C11, "<="&DATE(2004,12,31))

Adibide honetarako, xede-urtea idatziko dugu G1-n, eta, ondoren, DATA funtzioa erabiliko dugu datak emateko:

=MAXIFS(D2:D11, C2:C11, ">="&DATE(G1,1,1), C2:C11, "<="&DATE(G1,12,31))

Oharra. Zenbakiek ez bezala, datak komatxoen artean sartu behar dira irizpideetan bakarrik erabiltzen direnean. Adibidez:

=MAXIFS(D2:D11, C2:C11, "10/5/2005")

Bilatu balio maximoa irizpide anitzetan oinarrituta EDO logikarekin

Excel MAXIFS funtzioa baldintzak ETA logikarekin probatzeko diseinatuta dago, hau da, zenbaki horiek soilik prozesatzen ditu. max_range n, irizpide guztiak EGIA direnean. Egoera batzuetan, ordea, baliteke baldintzak EDO logikarekin ebaluatu behar izatea, hau da, zehaztutako irizpideren bat EGIA den zenbaki guztiak prozesatu.

Gauzak errazago ulertzeko, kontuan hartu honako hau. adibidea. Demagun saskibaloian edo jokatzen duten mutilen altuera maximoa aurkitu nahi duzulafutbola. Nola egingo zenuke hori? "Saskibaloia" irizpide gisa1 eta "futbola" irizpide gisa2 erabiltzeak ez du funtzionatuko, Excel-ek bi irizpideak EGIA gisa ebaluatu beharko liratekeela suposatuko lukeelako.

Konponbidea 2 MAXIFS formula bereizi egitea da, kirol bakoitzeko bat, eta, ondoren, erabili MAX funtzio zahar ona zenbaki handiagoa itzultzeko:

=MAX(MAXIFS(C2:C11, B2:B11, "basketball"), MAXIFS(C2:C11, B2:B11, "football"))

Beheko pantaila-argazkiak formula hau erakusten du baina aurrez zehaztutako sarrerako gelaxketan, F1 eta H1 irizpideekin:

Beste modu bat MAX IF formula bat erabiltzea da OR logikarekin.

Excel MAXIFS-i buruz gogoratu beharreko 7 gauza

Behean ohar batzuk aurkituko dituzu. horrek zure formulak hobetzen eta ohiko akatsak saihesten lagunduko dizu. Behaketa horietako batzuk aholku eta ohar gisa eztabaidatu dira dagoeneko gure adibideetan, baina baliteke lehendik ikasitakoaren laburpen labur bat jasotzea:

1. Excel-eko MAXIFS funtzioak lor dezake. bat edo irizpide anitzetan n oinarritutako baliorik altuena.
2. Lehenetsita, Excel MAXIFS AND logikaz rekin funtzionatzen du, hau da, gehienezko kopurua itzultzen du. zehaztutako baldintza guztiak betetzen dituena.
3. Funtzioak funtziona dezan, gehienezko barrutiak eta irizpideen barrutiek tamaina bera eta forma izan behar dute.
4. SUMIF funtzioak maiuskulak eta minuskulak bereizten ditu , hau da, ez ditu letra maiuskulak ezagutzen testu-irizpideetan.
5. Maxifs formula bat idaztean hainbat gelaxketarako, gogoratu blokeatzea. barrutiak rekinformula zuzen kopiatzeko gelaxka-erreferentzia absolutuak.
6. Kontuan izan zure irizpideen sintaxia ! Hona hemen arau nagusiak:
   • Bere kabuz erabiltzen direnean, testuak eta datak komatxoen artean sartu behar dira, ez dira zenbakiak eta gelaxken erreferentziak sartu behar.
   • Zenbaki, data edo testu bat erabiltzen denean. eragile logiko batekin, adierazpen osoa ">=10" bezalako komatxo bikoitz artean sartu behar da; gelaxken erreferentziak eta beste funtzio batzuk kateatu behar dira ">"&G1 bezalako ampersand bat erabiliz.
7. MAXIFS Excel 2019 eta Excel for Office 365-en soilik dago eskuragarri. Aurreko bertsioetan, funtzio hau ez dago erabilgarri.

Horrela aurki dezakezu balio maximoa Excel-en baldintzekin. Eskerrik asko irakurtzeagatik eta laster gure blogean ikustea espero dut!

Deskargatu praktika-koadernoa:

Excel MAXIFS formula adibideak (.xlsx fitxategia)