Tutorial pokazuje jak wykorzystać funkcję MAXIFS w Excelu, aby uzyskać maksymalną wartość z warunkami.

Tradycyjnie, kiedy kiedykolwiek potrzebowałeś znaleźć najwyższą wartość z warunkami w Excelu, musiałeś zbudować własną formułę MAX IF. Chociaż nie jest to duży problem dla doświadczonych użytkowników, może to stanowić pewne trudności dla nowicjuszy, ponieważ, po pierwsze, powinieneś pamiętać składnię formuły, a po drugie, musisz wiedzieć, jak pracować z formułami tablicowymi. Na szczęście, Microsoft niedawno wprowadził nowyfunkcja, która pozwala nam zrobić warunkowe maksimum w łatwy sposób!

Funkcja MAXIFS w programie Excel

Funkcja MAXIFS zwraca największą wartość liczbową w określonym zakresie na podstawie jednego lub więcej kryteriów.

Składnia funkcji MAXIFS jest następująca:

Gdzie:

• Max_zakres (wymagane) - zakres komórek, w których chcemy znaleźć wartość maksymalną.
• Kryteria_zakresu1 (wymagane) - pierwszy zakres do oceny z kryteria1 .
• Kryteria1 - warunek do zastosowania na pierwszym zakresie. Może być reprezentowany przez liczbę, tekst lub wyrażenie.
• Kryteria_zakresu2 / kryteria2 , ...(opcjonalnie) - dodatkowe zakresy i związane z nimi kryteria. Obsługiwanych jest do 126 par zakres/kryterium.

Ta funkcja MAXIFS jest dostępna w programie Excel 2019, Excel 2021 i Excel dla Microsoft 365 w systemie Windows i Mac.

Jako przykład znajdźmy najwyższego piłkarza w naszej lokalnej szkole. Zakładając, że wysokości uczniów znajdują się w komórkach D2:D11 (max_zakres), a sporty w B2:B11 (kryteria_zakresu1), użyj słowa "piłka nożna" jako kryterium1, a otrzymasz taką formułę:

=MAXIFS(D2:D11, B2:B11, "piłka nożna")

Aby uczynić formułę bardziej uniwersalną, można wprowadzić sport docelowy do jakiejś komórki (powiedzmy G1) i zawrzeć odwołanie do komórki w polu kryteria1 argument:

=MAXIFS(D2:D11, B2:B11, G1)

Uwaga. maksymalny zakres oraz kryteria_zakresu argumenty muszą mieć ten sam rozmiar i kształt, czyli zawierać jednakową liczbę wierszy i kolumn, w przeciwnym razie zwracany jest błąd #VALUE!

Jak używać funkcji MAXIFS w Excelu - przykłady formuł

Jak właśnie zobaczyłeś, MAXIFS w Excelu jest dość prosty i łatwy w użyciu. Ma jednak kilka małych niuansów, które robią dużą różnicę. W poniższych przykładach postaramy się jak najlepiej wykorzystać warunkowe max w Excelu.

Znajdź wartość maksymalną na podstawie wielu kryteriów

W pierwszej części tego poradnika stworzyliśmy formułę MAXIFS w jej najprostszej postaci, aby uzyskać wartość maksymalną na podstawie jednego warunku. Teraz zamierzamy posunąć ten przykład dalej i ocenić dwa różne kryteria.

Załóżmy, że chcesz znaleźć najwyższego koszykarza w gimnazjum. Aby to zrobić, zdefiniuj następujące argumenty:

• Max_zakres - zakres komórek zawierających wysokości - D2:D11.
• Kryteria_zakresu1 - zakres komórek zawierających sporty - B2:B11.
• Kryteria1 - "koszykówka", która jest wprowadzana do komórki G1.
• Kryteria_zakresu2 - zakres komórek określających typ szkoły - C2:C11.
• Kryteria2 - "junior", który jest wprowadzany do komórki G2.

Składając te argumenty w całość, otrzymujemy takie oto wzory:

Z "twardo" zakodowanymi kryteriami:

=MAXIFS(D2:D11, B2:B11, "koszykówka", C2:C11, "junior")

Z kryteriami w predefiniowanych komórkach:

=MAXIFS(D2:D11, B2:B11, G1, C2:C11, G2)

Proszę zauważyć, że funkcja MAXIFS w Excelu to. bez rozróżniania wielkości liter , więc nie musisz się martwić o wielkość liter w swoich kryteriach.

W przypadku, gdy planujesz użyć swojej formuły na wielu komórkach, pamiętaj, aby zablokować wszystkie zakresy za pomocą bezwzględnych odniesień do komórek, jak to:

=MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2)

Zapewni to prawidłowe kopiowanie formuły do innych komórek - odwołania do kryteriów zmieniają się na podstawie względnego położenia komórki, do której kopiowana jest formuła, podczas gdy zakresy pozostają niezmienione:

Jako dodatkowy bonus pokażę Ci szybki sposób na wyciągnięcie z innej komórki wartości, która jest związana z wartością max. W naszym przypadku będzie to imię i nazwisko najwyższej osoby. W tym celu będziemy używać klasycznej formuły INDEX MATCH i zagnieżdżać MAXIFS w pierwszym argumencie MATCH jako wartość lookup:

=INDEX($A$2:$A$11, MATCH(MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2), $D$2:$D$11, 0))

Wzór mówi nam, że imię najwyższego koszykarza w gimnazjum to Liam:

Excel MAXIFS z operatorami logicznymi

W sytuacji, gdy musisz ocenić kryteria numeryczne, użyj operatorów logicznych, takich jak:

• większy niż (>)
• mniej niż (<)
• większy lub równy (>=)
• mniejszy lub równy (<=)
• nie równa się ()

Operator "równy" (=) może być pominięty w większości przypadków.

Zazwyczaj wybór operatora nie jest problemem, najtrudniejszą częścią jest zbudowanie kryteriów z poprawną składnią.Oto jak:

• Operator logiczny, po którym następuje liczba lub tekst, musi być ujęty w podwójne cudzysłowy, jak ">=14" lub "running".
• W przypadku odwołania do komórki lub innej funkcji, użyj cudzysłowu, aby rozpocząć ciąg i ampersand, aby połączyć odwołanie i zakończyć ciąg, np. ">"&B1 lub "<"&DZIŚ().

Aby zobaczyć, jak to działa w praktyce, dodajmy do naszej przykładowej tabeli kolumnę Wiek (kolumna C) i znajdźmy maksymalny wzrost wśród chłopców w wieku od 13 do 14 lat. Można to zrobić za pomocą następujących kryteriów:

Kryterium1: ">=13"

Kryterium2: "<=14"

Ponieważ porównujemy liczby w tej samej kolumnie, criteria_range w obu przypadkach jest takie samo (C2:C11):

=MAXIFS(D2:D11, C2:C11, ">=13", C2:C11, "<=14")

Jeśli nie chcesz kodować kryteriów w formule, wprowadź je do osobnych komórek (np. G1 i H1) i użyj następującej składni:

=MAXIFS(D2:D11, C2:C11, ">="&G1, C2:C11, "<="&H1)

Poniższy zrzut ekranu przedstawia wynik:

Oprócz liczb, operatorzy logiczni mogą również pracować z kryteriami tekstowymi. W szczególności operator "nie równa się" jest przydatny, gdy chcesz wykluczyć coś ze swoich obliczeń. Na przykład, aby znaleźć najwyższego ucznia we wszystkich sportach z wyjątkiem siatkówki, użyj następującej formuły:

=MAXIFS(D2:D11, B2:B11, "siatkówka")

Albo ten, gdzie G1 jest sportem wykluczonym:

=MAXIFS(D2:D11, B2:B11, ""&G1)

Formuły MAXIFS ze znakami wieloznacznymi (dopasowanie częściowe)

Aby ocenić warunek, który zawiera określony tekst lub znak, dołącz do swoich kryteriów jeden z następujących znaków wieloznacznych:

• Znak zapytania (?), aby dopasować dowolny pojedynczy znak.
• Gwiazdka (*) do dopasowania dowolnego ciągu znaków.

Dla tego przykładu, znajdźmy najwyższego faceta w sportach gier. Ponieważ nazwy wszystkich sportów gier w naszym zbiorze danych kończą się słowem "piłka", włączamy to słowo do kryteriów i używamy gwiazdki, aby dopasować wszelkie poprzednie znaki:

=MAXIFS(D2:D11, B2:B11, "*kula")

Można też wpisać "kulkę" w jakiejś komórce, np. G1, i konkatenować znak wieloznaczny z odwołaniem do komórki:

=MAXIFS(D2:D11, B2:B11, "*"&G1)

Wynik będzie wyglądał następująco:

Uzyskaj maksymalną wartość w zakresie dat

Ponieważ daty są przechowywane jako numery seryjne w wewnętrznym systemie Excela, z kryteriami dat pracujesz w taki sam sposób, jak z liczbami.

Aby to zobrazować, zastąpimy Wiek kolumna z Data urodzenia i spróbuj opracować maksymalny wzrost wśród chłopców urodzonych w danym roku, powiedzmy w 2004 r. Aby wykonać to zadanie, musimy "przefiltrować" daty urodzenia, które są większe lub równe 1-Jan-2004 i mniejsze lub równe 31-Dec-2004.

Podczas budowania kryteriów ważne jest, abyś podał daty w formacie zrozumiałym dla Excela:

=MAXIFS(D2:D11, C2:C11, ">=1-Jan-2004", C2:C11, "<=31-Dec-2004")

Albo

=MAXIFS(D2:D11, C2:C11, ">=1/1/2004", C2:C11, "<=12/31/2004")

Aby zapobiec błędnej interpretacji, sensowne jest wykorzystanie funkcji DATE:

=MAXIFS(D2:D11, C2:C11, ">="&DATE(2004,1,1), C2:C11, "<="&DATE(2004,12,31))

W tym przykładzie wpiszemy rok docelowy w G1, a następnie użyjemy funkcji DATE, aby dostarczyć daty:

=MAXIFS(D2:D11, C2:C11, ">="&DATE(G1,1,1), C2:C11, "<="&DATE(G1,12,31))

Uwaga. W przeciwieństwie do liczb, daty powinny być ujęte w cudzysłów, gdy są używane w kryteriach samodzielnie. Na przykład:

=MAXIFS(D2:D11, C2:C11, "10/5/2005")

Znajdź maksymalną wartość na podstawie wielu kryteriów z logiką OR

Funkcja MAXIFS w Excelu służy do testowania warunków za pomocą logiki AND - tzn. przetwarza tylko te liczby, które w maksymalny zakres dla których wszystkie kryteria są TRUE. W niektórych sytuacjach może jednak zajść potrzeba oceny warunków za pomocą logiki OR - czyli przetworzenia wszystkich liczb, dla których którekolwiek z określonych kryteriów jest TRUE.

Aby łatwiej było to zrozumieć, rozważmy następujący przykład. Załóżmy, że chcesz znaleźć maksymalny wzrost chłopaków, którzy grają w koszykówkę lub piłkę nożną. Jak to zrobisz? Użycie "koszykówki" jako kryterium1 i "piłki nożnej" jako kryterium2 nie zadziała, ponieważ Excel założy, że oba kryteria powinny ocenić TRUE.

Rozwiązaniem jest stworzenie 2 oddzielnych formuł MAXIFS, po jednej na każdy sport, a następnie użycie starej dobrej funkcji MAX, aby zwrócić wyższą liczbę:

=MAX(MAXIFS(C2:C11, B2:B11, "koszykówka"), MAXIFS(C2:C11, B2:B11, "piłka nożna"))

Poniższy zrzut ekranu pokazuje tę formułę, ale z kryteriami w predefiniowanych komórkach wejściowych, F1 i H1:

Innym sposobem jest użycie formuły MAX IF z logiką OR.

7 rzeczy, o których warto pamiętać o MAXIFS w Excelu

Poniżej znajdziesz kilka uwag, które pomogą udoskonalić Twoje formuły i uniknąć typowych błędów. Niektóre z tych uwag zostały już omówione jako wskazówki i uwagi w naszych przykładach, ale pomocne może być krótkie podsumowanie tego, czego już się nauczyłeś:

1. Funkcja MAXIFS w Excelu może uzyskać najwyższą wartość na podstawie jeden lub wiele kryteriów .
2. Domyślnie Excel MAXIFS pracuje z. Logika AND , czyli zwraca maksymalną liczbę, która spełnia wszystkie podane warunki.
3. Aby funkcja działała, zakresy max i kryteria muszą mieć wartość ten sam rozmiar oraz kształt .
4. Funkcja SUMIF to. bez rozróżniania wielkości liter , czyli nie rozpoznaje wielkości liter w kryteriach tekstowych.
5. Pisząc formułę MAXIFS dla wielu komórek, należy pamiętać, aby zablokować zakresy z bezwzględnymi odniesieniami do komórek, aby formuła została poprawnie skopiowana.
6. Rozumiecie? składnia Twoich kryteriów ! Oto główne zasady:
   • Przy samodzielnym użyciu tekst i daty powinny być ujęte w cudzysłów, liczby i odwołania do komórek nie.
   • Gdy liczba, data lub tekst są używane z operatorem logicznym, całe wyrażenie musi być ujęte w podwójne cudzysłowy, jak ">=10"; odwołania do komórek i inne funkcje muszą być konkatenowane przez użycie ampersanda, jak ">"&G1.
7. MAXIFS jest dostępny tylko w programie Excel 2019 i Excel dla Office 365. We wcześniejszych wersjach ta funkcja nie jest dostępna.

Tak właśnie można znaleźć maksymalną wartość w Excelu za pomocą warunków. Dziękuję za przeczytanie i mam nadzieję, że wkrótce zobaczymy się na naszym blogu!

Pobierz zeszyt ćwiczeń:

Przykłady formuł MAXIFS w Excelu (plik .xlsx)