Падручнік паказвае, як выкарыстоўваць функцыю MAXIFS у Excel, каб атрымаць максімальнае значэнне з умовамі.

Традыцыйна, калі вам калі-небудзь трэба было знайсці найбольшае значэнне з умовамі ў Excel, вы павінны былі стварыць сваю ўласную формулу MAX IF. Хоць для дасведчаных карыстальнікаў гэта не складае вялікай працы, для пачаткоўцаў гэта можа выклікаць пэўныя цяжкасці, таму што, па-першае, трэба памятаць сінтаксіс формулы, а па-другое, трэба ведаць, як працаваць з формуламі масіваў. На шчасце, Microsoft нядаўна прадставіла новую функцыю, якая дазваляе нам рабіць умоўны максімум простым спосабам!

Функцыя MAXIFS Excel

Функцыя MAXIFS вяртае найбольшае лікавае значэнне ў вызначаны дыяпазон на аснове аднаго або некалькіх крытэрыяў.

Сінтаксіс функцыі MAXIFS наступны:

Дзе:

• Max_range (абавязкова) - дыяпазон ячэек, дзе вы хочаце знайсці максімальнае значэнне.
• Criteria_range1 (абавязкова) - першы дыяпазон для ацэнкі з дапамогай criteria1 .
• Criteria1 - умова для выкарыстання ў першым дыяпазоне. Ён можа быць прадстаўлены лікам, тэкстам або выразам.
• Дыяпазон_крытэрыяў2 / крытэрый2 , …(неабавязкова) - дадатковыя дыяпазоны і звязаныя з імі крытэрыі. Падтрымліваецца да 126 пар дыяпазон/крытэрый.

Гэтая функцыя MAXIFS даступная ў Excel 2019, Excel 2021 іExcel для Microsoft 365 на Windows і Mac.

У якасці прыкладу давайце знойдзем самага высокага футбаліста ў нашай мясцовай школе. Калі выказаць здагадку, што рост вучняў знаходзіцца ў ячэйках D2:D11 (максімальны_дыяпазон), а спорт — у B2:B11 (крытэрый_дыяпазон1), выкарыстоўвайце слова "футбол" у якасці крытэрыя1, і вы атрымаеце наступную формулу:

=MAXIFS(D2:D11, B2:B11, "football")

Каб зрабіць формулу больш універсальнай, вы можаце ўвесці мэтавы від спорту ў нейкую ячэйку (напрыклад, G1) і ўключыць спасылку на ячэйку ў аргумент criteria1 :

=MAXIFS(D2:D11, B2:B11, G1)

Заўвага. Аргументы max_range і criteria_range павінны быць аднолькавага памеру і формы, г. зн. утрымліваць аднолькавую колькасць радкоў і слупкоў, інакш #VALUE! вяртаецца памылка.

Як выкарыстоўваць функцыю MAXIFS у Excel - прыклады формул

Як вы толькі што бачылі, MAXIFS Excel даволі просты і просты ў выкарыстанні. Аднак у яго ёсць некалькі невялікіх нюансаў, якія маюць вялікае значэнне. У прыведзеных ніжэй прыкладах мы паспрабуем максімальна выкарыстоўваць умоўны максімум у Excel.

Знайдзіце максімальнае значэнне на аснове некалькіх крытэрыяў

У першай частцы гэтага падручніка мы стварылі формулу MAXIFS у найпростай форме, каб атрымаць максімальнае значэнне на аснове адной умовы. Зараз мы разгледзім гэты прыклад далей і ацэнім два розныя крытэрыі.

Дапусцім, вы хочаце знайсці самага высокага баскетбаліста ў малодшай школе. Каб зрабіць гэта, вызначце наступнаеаргументы:

• Макс_дыяпазон - дыяпазон ячэек, якія змяшчаюць вышыні - D2:D11.
• Дыяпазон_крытэрыяў1 - дыяпазон ячэек, якія змяшчаюць віды спорту - B2:B11.
• Criteria1 - "баскетбол", які ўводзіцца ў ячэйку G1.
• Criteria_range2 - дыяпазон ячэек, якія вызначаюць тып школы - C2:C11.
• Крытэрый2 - "малодшы", які ўводзіцца ў ячэйку G2.

Складваючы аргументы разам, атрымліваем гэтыя формулы :

З "жорстка закадаванымі" крытэрамі:

=MAXIFS(D2:D11, B2:B11, "basketball", C2:C11, "junior")

З крытэрамі ў загадзя вызначаных ячэйках:

=MAXIFS(D2:D11, B2:B11, G1, C2:C11, G2)

Звярніце ўвагу, што MAXIFS функцыя ў Excel неадчувальная да рэгістра , таму вам не трэба турбавацца аб рэгістры літар у вашых крытэрыях.

У выпадку, калі вы плануеце выкарыстоўваць свой формула ў некалькіх ячэйках, не забудзьцеся заблакіраваць усе дыяпазоны абсалютнымі спасылкамі на ячэйкі, напрыклад:

=MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2)

Гэта гарантуе правільнае капіраванне формулы ў іншыя ячэйкі - спасылкі на крытэрыі змяняюцца ў залежнасці на адноснае размяшчэнне ячэйкі, у якую капіюецца формула, а t дыяпазоны застаюцца нязменнымі:

У якасці дадатковага бонуса я пакажу вам хуткі спосаб атрымаць значэнне з іншай ячэйкі, якое звязана з максімальным значэннем. У нашым выпадку гэта будзе імя самага высокага чалавека. Для гэтага мы будзем выкарыстоўваць класічную формулу INDEX MATCH і ўкладзем MAXIFS у першы аргумент MATCH у якасці значэння пошуку:

=INDEX($A$2:$A$11, MATCH(MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2), $D$2:$D$11, 0))

Формула кажа нам, што імясамы высокі баскетбаліст у малодшай школе - Ліам:

Excel MAXIFS з лагічнымі аператарамі

У сітуацыі, калі вам трэба ацаніць лікавыя крытэрыі, выкарыстоўвайце лагічныя аператары напрыклад:

• больш (>)
• менш (<)
• больш або роўна (>=)
• менш або роўна (<=)
• не роўна ()

Аператар "роўна" (=) у большасці выпадкаў можна апусціць.

Звычайна выбар аператара не з'яўляецца праблемай, самая складаная частка - пабудаваць крытэрыі з правільным сінтаксісам. Вось як:

• Лагічны аператар, за якім ідзе лічба або тэкст, павінен быць заключаны ў падвойныя двукоссе, напрыклад ">=14" або "працуе".
• У выпадку ячэйкі спасылку або іншую функцыю, выкарыстоўвайце двукоссі для пачатку радка і амперсанд для аб'яднання спасылкі і завяршэння радка, напрыклад. ">"&B1 або "<"&TODAY().

Каб убачыць, як гэта працуе на практыцы, давайце дададзім слупок "Узрост" (слупок C) у нашу прыкладную табліцу і знойдзем максімальны рост сярод хлопчыкаў ва ўзросце ад 13 да 14 гадоў. Гэта можна зрабіць з дапамогай наступных крытэрыяў:

Крытэрый1: ">=13"

Крытэрый2: "<=14"

Паколькі мы параўноўваем лічбы ў адным слупку, дыяпазон_крытэрыяў у абодвух выпадках аднолькавы (C2:C11):

=MAXIFS(D2:D11, C2:C11, ">=13", C2:C11, "<=14")

Калі вы не жадаеце жорстка кадзіраваць крытэрыі у формуле, увядзіце іх у асобныя ячэйкі (напрыклад, G1 і H1) і выкарыстоўвайце наступнаесінтаксіс:

=MAXIFS(D2:D11, C2:C11, ">="&G1, C2:C11, "<="&H1)

На скрыншоце ніжэй паказаны вынік:

Акрамя лікаў, лагічныя аператары таксама могуць працаваць з тэкставымі крытэрамі. У прыватнасці, аператар "не роўна" спатрэбіцца, калі вы хочаце нешта выключыць са сваіх разлікаў. Напрыклад, каб знайсці самага высокага студэнта ва ўсіх відах спорту, за выключэннем валейбола, выкарыстоўвайце наступную формулу:

=MAXIFS(D2:D11, B2:B11, "volleyball")

Або гэтую, дзе G1 з'яўляецца выключаным відам спорту:

=MAXIFS(D2:D11, B2:B11, ""&G1)

Формулы MAXIFS з сімваламі падстаноўкі (частковае супадзенне)

Каб ацаніць умову, якая змяшчае пэўны тэкст або сімвал, уключыце адзін з наступных сімвалаў падстаноўкі ў вашыя крытэрыі:

• Пытальнік (?) для адпаведнасці любому асобнаму сімвалу.
• Зорачка (*) для адпаведнасці любой паслядоўнасці сімвалаў.

Для на гэтым прыкладзе давайце даведаемся, які самы высокі хлопец у гульнявых відах спорту. Паколькі назвы ўсіх гульнявых відаў спорту ў нашым наборы даных заканчваюцца словам "мяч", мы ўключаем гэтае слова ў крытэрыі і выкарыстоўваем зорачку, каб адпавядаць любым папярэднім сімвалам:

=MAXIFS(D2:D11, B2:B11, "*ball")

Вы можаце таксама ўвядзіце "шар" у нейкай ячэйцы, напр. G1 і аб'яднайце сімвал падстаноўкі са спасылкай на ячэйку:

=MAXIFS(D2:D11, B2:B11, "*"&G1)

Вынік будзе выглядаць наступным чынам:

Атрымаць максімальнае значэнне у дыяпазоне дат

Паколькі даты захоўваюцца ў выглядзе парадкавых нумароў ва ўнутранай сістэме Excel, вы працуеце з крытэрамі дат такім жа чынам, як і з лікамі.

Кабкаб праілюстраваць гэта, мы заменім слупок Узрост на Дата нараджэння і паспрабуем вызначыць максімальны рост сярод хлопчыкаў, якія нарадзіліся ў пэўны год, скажам, у 2004. Каб выканаць гэтую задачу , нам трэба "адфільтраваць" даты нараджэння, якія большыя або роўныя 1 студзеня 2004 г. і меншыя або роўныя 31 снежня 2004 г.

Пры стварэнні крытэрыяў важна, каб вы падайце даты ў фармаце, які Excel можа зразумець:

=MAXIFS(D2:D11, C2:C11, ">=1-Jan-2004", C2:C11, "<=31-Dec-2004")

Ці

=MAXIFS(D2:D11, C2:C11, ">=1/1/2004", C2:C11, "<=12/31/2004")

Каб прадухіліць памылковае тлумачэнне, мае сэнс выкарыстоўваць функцыю ДАТА :

=MAXIFS(D2:D11, C2:C11, ">="&DATE(2004,1,1), C2:C11, "<="&DATE(2004,12,31))

Для гэтага прыкладу мы ўвядзём мэтавы год у G1, а затым выкарыстаем функцыю ДАТА, каб увесці даты:

=MAXIFS(D2:D11, C2:C11, ">="&DATE(G1,1,1), C2:C11, "<="&DATE(G1,12,31))

Заўвага. У адрозненне ад лічбаў, даты павінны быць заключаны ў двукоссе, калі выкарыстоўваюцца ў крытэрыях самастойна. Напрыклад:

=MAXIFS(D2:D11, C2:C11, "10/5/2005")

Знайдзіце максімальнае значэнне на аснове некалькіх крытэрыяў з дапамогай логікі АБО

Функцыя Excel MAXIFS прызначана для праверкі ўмоў з дапамогай логікі І - гэта значыць, яна апрацоўвае толькі гэтыя лічбы у max_range , для якога ўсе крытэрыі TRUE. У некаторых сітуацыях, аднак, вам можа спатрэбіцца ацаніць умовы з дапамогай логікі АБО - г.зн. апрацаваць усе лічбы, для якіх любы з указаных крытэраў з'яўляецца ІСТЫННЫМ.

Каб палегчыць разуменне, звярніце ўвагу на наступнае. прыклад. Выкажам здагадку, што вы хочаце знайсці максімальны рост хлопцаў, якія гуляюць у баскетбол абофутбол. Як бы вы гэта зрабілі? Выкарыстанне «баскетбола» ў якасці крытэрыяў1 і «футбола» крытэрыяў2 не будзе працаваць, таму што Excel мяркуе, што абодва крытэрыі павінны мець значэнне TRUE.

Рашэнне складаецца ў тым, каб стварыць 2 асобныя формулы MAXIFS, па адной для кожнага віду спорту, а затым выкарыстайце старую добрую функцыю MAX, каб вярнуць большы лік:

=MAX(MAXIFS(C2:C11, B2:B11, "basketball"), MAXIFS(C2:C11, B2:B11, "football"))

На скрыншоце ніжэй паказана гэтая формула, але з крытэрамі ў загадзя вызначаных ячэйках уводу, F1 і H1:

Іншы спосаб - выкарыстоўваць формулу MAX IF з логікай АБО.

7 рэчаў, якія трэба памятаць пра Excel MAXIFS

Ніжэй вы знойдзеце некалькі заўваг. гэта дапаможа палепшыць вашы формулы і пазбегнуць распаўсюджаных памылак. Некаторыя з гэтых назіранняў ужо абмяркоўваліся ў якасці парад і заўваг у нашых прыкладах, але можа быць карысна атрымаць кароткае рэзюмэ таго, што вы ўжо даведаліся:

1. Функцыя MAXIFS у Excel можа атрымаць найбольшае значэнне на аснове аднаго або некалькіх крытэрыяў .
2. Па змаўчанні Excel MAXIFS працуе з логікай І , г.зн. вяртае максімальную колькасць які адпавядае ўсім зададзеным умовам.
3. Каб функцыя працавала, максімальны дыяпазон і дыяпазоны крытэрыяў павінны мець аднолькавы памер і форму .
4. Функцыя SUMIF неадчувальная да рэгістра , г.зн. яна не распазнае рэгістр літар у крытэрыях тэксту.
5. Калі пішаце формулу MAXIFS для некалькіх ячэек, памятайце заблакіраваць дыяпазоны сабсалютныя спасылкі на ячэйкі для правільнага капіявання формулы.
6. Звярніце ўвагу на сінтаксіс вашых крытэрыяў ! Вось асноўныя правілы:
   • Калі яны выкарыстоўваюцца самі па сабе, тэкст і даты павінны быць заключаны ў двукоссе, а лічбы і спасылкі на вочкі не павінны.
   • Калі выкарыстоўваюцца лік, дата або тэкст з лагічным аператарам увесь выраз павінен быць заключаны ў двукоссе, напрыклад ">=10"; спасылкі на ячэйкі і іншыя функцыі павінны быць аб'яднаны з дапамогай амперсанда, напрыклад ">"&G1.
7. MAXIFS даступны толькі ў Excel 2019 і Excel для Office 365. У больш ранніх версіях, гэтая функцыя недаступная.

Вось як вы можаце знайсці максімальнае значэнне ў Excel з умовамі. Я дзякую вам за чытанне і спадзяюся неўзабаве ўбачыць вас у нашым блогу!

Спампуйце сшытак практыкі:

Прыклады формул Excel MAXIFS (файл .xlsx)