Упатството покажува како да ја користите функцијата MAXIFS во Excel за да ја добиете максималната вредност со условите.

Традиционално, кога некогаш сте требало да ја пронајдете највисоката вредност со условите во Excel, мораше да изградиш своја сопствена формула MAX IF. Иако не е голема работа за искусни корисници, тоа може да претставува одредени потешкотии за почетниците бидејќи, прво, треба да ја запомните синтаксата на формулата и, второ, треба да знаете како да работите со формули на низа. За среќа, Microsoft неодамна воведе нова функција која ни овозможува да го направиме условниот максимум на лесен начин!

Excel MAXIFS функција

Функцијата MAXIFS ја враќа најголемата нумеричка вредност во специфициран опсег врз основа на еден или повеќе критериуми.

Синтаксата на функцијата MAXIFS е следна:

Каде:

• Max_range (задолжително) - опсегот на ќелии каде што сакате да ја најдете максималната вредност.
• Criteria_range1 (задолжително) - првиот опсег што треба да се оцени со критериуми1 .
• Критериуми1 - условот што треба да се користи на првиот опсег. Може да се претстави со број, текст или израз.
• Опсег_критериуми2 / критериуми2 , …(изборно) - дополнителни опсези и нивните поврзани критериуми. Поддржани се до 126 парови опсег/критериум.

Оваа функција MAXIFS е достапна во Excel 2019, Excel 2021 иExcel за Microsoft 365 на Windows и Mac.

Како пример, да го најдеме највисокиот фудбалер во нашето локално училиште. Под претпоставка дека висините на учениците се во ќелиите D2:D11 (max_range) и спортовите се во B2:B11 (criteria_range1), користете го зборот „фудбал“ како критериум1, и ќе ја добиете оваа формула:

=MAXIFS(D2:D11, B2:B11, "football")

За да ја направите формулата поразновидна, можете да го внесете целниот спорт во некоја ќелија (на пример, G1) и да ја вклучите референцата на ќелијата во аргументот criteria1 :

=MAXIFS(D2:D11, B2:B11, G1)

Забелешка. Аргументите max_range и criteria_range мора да бидат со иста големина и форма, односно да содржат еднаков број на редови и колони, во спротивно #VALUE! се враќа грешката.

Како да се користи MAXIFS функцијата во Excel - примери на формула

Како што штотуку видовте, Excel MAXIFS е прилично јасен и лесен за употреба. Сепак, тој има неколку мали нијанси кои прават голема разлика. Во примерите подолу, ќе се обидеме да го искористиме максимумот од условниот макс во Excel.

Најдете максимална вредност врз основа на повеќе критериуми

Во првиот дел од ова упатство, создадовме формула MAXIFS во наједноставна форма да се добие максималната вредност врз основа на еден услов. Сега, ќе го земеме тој пример понатаму и ќе оцениме два различни критериуми.

Да претпоставиме дека сакате да го најдете највисокиот кошаркар во помладото училиште. За да го направите тоа, дефинирајте го следновоаргументи:

• Max_range - опсег на ќелии кои содржат висини - D2:D11.
• Criteria_range1 - опсег на ќелии кои содржат спортови - B2:B11.
• Criteria1 - „кошарка“, која е внесена во ќелијата G1.
• Criteria_range2 - опсег на ќелии што го дефинираат тип на училиште - C2:C11.
• Criteria2 - "junior", кој е влезен во ќелијата G2.

Соединувајќи ги аргументите, ги добиваме овие формули :

Со „тврдокодирани“ критериуми:

=MAXIFS(D2:D11, B2:B11, "basketball", C2:C11, "junior")

Со критериуми во претходно дефинирани ќелии:

=MAXIFS(D2:D11, B2:B11, G1, C2:C11, G2)

Ве молиме забележете дека MAXIFS функцијата во Excel е неосетлива на букви , така што не треба да се грижите за буквите во вашите критериуми.

Во случај да планирате да го користите вашиот формула на повеќе ќелии, погрижете се да ги заклучите сите опсези со апсолутни референци на ќелиите, вака:

=MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2)

Ова ќе осигури дека формулата правилно се копира во други ќелии - референците на критериумите се менуваат врз основа на релативната положба на ќелијата каде што формулата се копира додека т тој опсег останува непроменет:

Како дополнителен бонус, ќе ви покажам брз начин да извлечете вредност од друга ќелија што е поврзана со максималната вредност. Во нашиот случај, тоа ќе биде името на највисоката личност. За ова, ќе ја користиме класичната формула INDEX MATCH и гнездо MAXIFS во првиот аргумент на MATCH како вредност за пребарување:

=INDEX($A$2:$A$11, MATCH(MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2), $D$2:$D$11, 0))

Формулата ни кажува дека иметоод највисокиот кошаркар во јуниорското училиште е Лиам:

Excel MAXIFS со логички оператори

Во ситуација кога треба да оцените нумерички критериуми, користете логички оператори како што се:

• поголемо од (>)
• помалку од (<)
• поголемо или еднакво на (>=)
• помалку или еднаков на (<=)
• не е еднаков на ()

Операторот „еднакво на“ (=) во повеќето случаи може да се испушти.

Обично, изборот на оператор не е проблем, најтешкиот дел е да се изградат критериуми со правилна синтакса. Еве како:

• Логички оператор проследен со број или текст мора да биде затворен во двојни наводници како „>=14“ или „работи“.
• Во случај на ќелија референца или друга функција, користете ги наводниците за да започнете низа и амперсенд за да ја споите референцата и да ја завршите низата, на пр. ">"&B1 или "<"&TODAY().

За да видиме како тоа функционира во пракса, ајде да ја додадеме колоната Age (колона C) во нашата примерна табела и да најдеме максималната висина кај момчињата на возраст меѓу 13 и 14 години. Ова може да се направи со следниве критериуми:

Критериум 1: ">=13"

Критериум 2: "<=14"

Бидејќи ги споредуваме броевите во истата колона, критериумите_опсег и во двата случаи е ист (C2:C11):

=MAXIFS(D2:D11, C2:C11, ">=13", C2:C11, "<=14")

Ако не сакате да ги кодирате критериумите во формулата, внесете ги во посебни ќелии (на пр. G1 и H1) и користете го следновосинтакса:

=MAXIFS(D2:D11, C2:C11, ">="&G1, C2:C11, "<="&H1)

На сликата подолу е прикажан резултатот:

Покрај бројките, логичките оператори можат да работат и со текстуални критериуми. Конкретно, операторот „не е еднаков на“ ни доаѓа кога сакате да исклучите нешто од вашите пресметки. На пример, за да го пронајдете највисокиот ученик во сите спортови со исклучок на одбојката, користете ја следнава формула:

=MAXIFS(D2:D11, B2:B11, "volleyball")

Или оваа, каде што G1 е исклучениот спорт:

=MAXIFS(D2:D11, B2:B11, ""&G1)

Формулите MAXIFS со знаци на џокер (делумно совпаѓање)

За да оцените состојба што содржи специфичен текст или знак, вклучете еден од следните знаци во вашите критериуми:

• прашалник (?) да одговара на кој било знак.
• Ѕвездичка (*) за да одговара на која било низа знаци.

За овој пример, ајде да го дознаеме највисокиот човек во спортови. Бидејќи имињата на сите спортови на игри во нашата база на податоци завршуваат со зборот „топка“, го вклучуваме овој збор во критериумите и користиме ѕвездичка за да одговара на сите претходни знаци:

=MAXIFS(D2:D11, B2:B11, "*ball")

Можете напишете и „топка“ во некоја ќелија, на пр. G1 и поврзете го знакот на џокер со референцата на ќелијата:

=MAXIFS(D2:D11, B2:B11, "*"&G1)

Резултатот ќе изгледа вака:

Добијте максимална вредност во опсег на датуми

Бидејќи датумите се зачувани како сериски броеви во внатрешниот систем на Excel, работите со критериумите за датуми на ист начин како што работите со броевите.

ДаЗа да го илустрираме ова, ќе ја замениме колоната Возраст со Датум на раѓање и ќе се обидеме да ја одредиме максималната висина кај момчињата родени во одредена година, да речеме во 2004 година. За да се постигне оваа задача , треба да ги „филтрираме“ датумите на раѓање кои се поголеми или еднакви на 1-јан-2004 и помали или еднакви на 31-декември-2004.

При градењето на вашите критериуми, важно е да наведете ги датумите во форматот што Excel може да го разбере:

=MAXIFS(D2:D11, C2:C11, ">=1-Jan-2004", C2:C11, "<=31-Dec-2004")

Или

=MAXIFS(D2:D11, C2:C11, ">=1/1/2004", C2:C11, "<=12/31/2004")

За да се спречи погрешно толкување, има смисла да се користи функцијата DATE :

=MAXIFS(D2:D11, C2:C11, ">="&DATE(2004,1,1), C2:C11, "<="&DATE(2004,12,31))

За овој пример, ќе ја напишеме целната година во G1, а потоа ќе ја користиме функцијата DATE за да ги обезбедиме датумите:

=MAXIFS(D2:D11, C2:C11, ">="&DATE(G1,1,1), C2:C11, "<="&DATE(G1,12,31))

Забелешка. За разлика од бројките, датумите треба да се ставаат во наводници кога се користат сами во критериумите. На пример:

=MAXIFS(D2:D11, C2:C11, "10/5/2005")

Најдете максимална вредност врз основа на повеќе критериуми со ИЛИ логика

Функцијата Excel MAXIFS е дизајнирана да ги тестира условите со логиката И - т.е. ги обработува само тие броеви во max_range за кој сите критериуми се ВИСТИНИ. Меѓутоа, во некои ситуации, можеби ќе треба да ги оцените условите со логиката ИЛИ - т.е. обработете ги сите броеви за кои некој од наведените критериуми е ВИСТИНА.

За да ги олесните разбирливите работи, ве молиме разгледајте го следново пример. Да претпоставиме дека сакате да ја пронајдете максималната висина на момците кои играат или кошарка илифудбал. Како би го направиле тоа? Користењето на „кошарка“ како критериум1 и како „фудбалски“ критериуми2 нема да функционира, бидејќи Excel би претпоставил дека и двата критериуми треба да се вреднуваат како ВИСТИНА.

Решението е да се направат 2 посебни MAXIFS формули, по една за секој спорт. а потоа користете ја старата добра функција MAX за да вратите поголем број:

=MAX(MAXIFS(C2:C11, B2:B11, "basketball"), MAXIFS(C2:C11, B2:B11, "football"))

На сликата подолу е прикажана оваа формула, но со критериумите во претходно дефинираните влезни ќелии, F1 и H1:

Друг начин е да се користи формулата MAX IF со ИЛИ логика.

7 работи што треба да се запаметат за Excel MAXIFS

Подолу ќе најдете неколку забелешки што ќе ви помогне да ги подобрите вашите формули и да избегнете вообичаени грешки. Некои од овие набљудувања веќе се дискутирани како совети и белешки во нашите примери, но може да биде корисно да се добие кратко резиме на она што веќе сте го научиле:

1. Функцијата MAXIFS во Excel може да добие највисоката вредност базирана на еден или повеќе критериуми .
2. Стандардно, Excel MAXIFS работи со AND логиката , т.е. го враќа максималниот број што ги исполнува сите наведени услови.
3. За да функционира функцијата, опсегот на максималниот опсег и критериумите мора да имаат иста големина и форма .
4. Функцијата SUMIF е неосетлива на букви , т.е. не ја препознава буквата во критериумите за текст.
5. Кога пишувате формула MAXIFS за повеќе ќелии, не заборавајте да заклучите се движи соапсолутни референци на ќелии за формулата да се копира правилно.
6. Внимавајте на синтаксата на вашите критериуми ! Еве ги главните правила:
   • Кога се користат самостојно, текстот и датумите треба да бидат затворени во наводници, а броевите и референците на ќелиите не треба.
   • Кога се користи број, датум или текст со логички оператор, целиот израз мора да биде затворен во двојни наводници како „>=10“; референците на ќелиите и другите функции мора да се спојат со користење на амперсенд како „>“&G1.
7. MAXIFS е достапен само во Excel 2019 и Excel за Office 365. Во претходните верзии, оваа функција не е достапна.

Така можете да ја пронајдете максималната вредност во Excel со услови. Ви благодарам што прочитавте и се надевам дека наскоро ќе се видиме на нашиот блог!

Преземете ја работната книга за вежбање:

Примери на формула на Excel MAXIFS (датотека .xlsx)