Denne vejledning viser, hvordan du bruger MAXIFS-funktionen i Excel til at få den maksimale værdi med betingelser.

Traditionelt set har du, når du skulle finde den højeste værdi med betingelser i Excel, været nødt til at lave din egen MAX IF-formel. Selvom det ikke er noget stort problem for erfarne brugere, kan det give visse vanskeligheder for nybegyndere, fordi du for det første skal huske formlens syntaks, og for det andet skal du vide, hvordan du arbejder med array-formler. Heldigvis har Microsoft for nylig introduceret en nyfunktion, der gør det nemt at lave betinget max!

Excel MAXIFS-funktion

Funktionen MAXIFS returnerer den største numeriske værdi i det angivne område baseret på et eller flere kriterier.

Syntaksen for MAXIFS-funktionen er som følger:

Hvor:

• Max_range (påkrævet) - det område af celler, hvor du ønsker at finde den maksimale værdi.
• Kriterier_range1 (påkrævet) - det første interval, der skal evalueres med kriterier1 .
• Kriterier1 - den betingelse, der skal anvendes på det første område. Den kan være et tal, tekst eller udtryk.
• Kriterier_range2 / kriterier2 , ...(valgfrit) - yderligere intervaller og deres tilhørende kriterier. Der understøttes op til 126 intervaller/kriterier-par.

Denne MAXIFS-funktion er tilgængelig i Excel 2019, Excel 2021 og Excel for Microsoft 365 på Windows og Mac.

Lad os f.eks. finde den højeste fodboldspiller på vores lokale skole. Hvis vi antager, at elevernes højde er i cellerne D2:D11 (max_range) og sportsgrene er i B2:B11 (criteria_range1), skal vi bruge ordet "football" som criteria1, og du får denne formel:

=MAXIFS(D2:D11, B2:B11, "fodbold")

For at gøre formlen mere alsidig kan du indtaste målsporten i en celle (f.eks. G1) og inkludere cellehenvisningen i kriterier1 argument:

=MAXIFS(D2:D11, B2:B11, G1)

Bemærk. max_range og criteria_range argumenterne skal have samme størrelse og form, dvs. indeholde lige mange rækker og kolonner, ellers returneres fejlen #VALUE!.

Sådan bruger du MAXIFS-funktionen i Excel - eksempler på formler

Som du lige har set, er Excel MAXIFS ret ligetil og let at bruge. Det har dog nogle små nuancer, som gør en stor forskel. I nedenstående eksempler vil vi forsøge at få mest muligt ud af betinget max i Excel.

Find maks. værdi baseret på flere kriterier

I første del af denne vejledning oprettede vi en MAXIFS-formel i sin enkleste form for at få den maksimale værdi baseret på én betingelse. Nu vil vi videreudvikle dette eksempel og evaluere to forskellige kriterier.

Antag, at du ønsker at finde den højeste basketballspiller i skolen. For at få det gjort, skal du definere følgende argumenter:

• Max_range - en række celler, der indeholder højder - D2:D11.
• Kriterier_range1 - en række celler, der indeholder sport - B2:B11.
• Kriterier1 - "basketball", som er indtastet i celle G1.
• Kriterier_range2 - en række celler, der definerer skoletypen - C2:C11.
• Kriterier2 - "junior", som er indtastet i celle G2.

Ved at sætte argumenterne sammen får vi disse formler:

Med "hardcoded" kriterier:

=MAXIFS(D2:D11, B2:B11, "basketball", C2:C11, "junior")

Med kriterier i foruddefinerede celler:

=MAXIFS(D2:D11, B2:B11, G1, C2:C11, G2)

Bemærk venligst, at MAXIFS-funktionen i Excel er skift mellem store og små bogstaver , så du behøver ikke at bekymre dig om bogstaverne i dine kriterier.

Hvis du har planer om at bruge din formel på flere celler, skal du sørge for at låse alle områderne med absolutte cellehenvisninger, som her:

=MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2)

Dette vil sikre, at formlen kopieres korrekt til andre celler - kriterierne ændres baseret på den relative position i den celle, hvor formlen kopieres, mens intervallerne forbliver uændrede:

Som en ekstra bonus vil jeg vise dig en hurtig måde at udtrække en værdi fra en anden celle, der er forbundet med max-værdien. I vores tilfælde vil det være navnet på den højeste person. Til dette formål vil vi bruge den klassiske INDEX MATCH-formel og indlejre MAXIFS i det første argument i MATCH som opslagsværdi:

=INDEX($A$2:$A$11, MATCH(MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2), $D$2:$D$11, 0))

Formlen fortæller os, at navnet på den højeste basketballspiller i juniorskolen er Liam:

Excel MAXIFS med logiske operatorer

I situationer, hvor du skal vurdere numeriske kriterier, skal du bruge logiske operatorer som f.eks:

• større end (>)
• mindre end (<)
• større end eller lig med (>=)
• mindre end eller lig med (<=)
• ikke lig med ()

Operatoren "lig med" (=) kan udelades i de fleste tilfælde.

Normalt er det ikke noget problem at vælge en operatør, det vanskeligste er at opstille kriterier med den korrekte syntaks. Her er hvordan:

• En logisk operator efterfulgt af et tal eller tekst skal omsluttes af dobbelte anførselstegn som ">=14" eller "running".
• Hvis der er tale om en cellehenvisning eller en anden funktion, skal du bruge anførselstegn til at begynde en streng og et ampersand til at sammenkæde referencen og afslutte strengen, f.eks. ">"&B1 eller "<"&TODAY().

For at se, hvordan det fungerer i praksis, kan vi tilføje kolonnen Alder (kolonne C) til vores eksempeltabel og finde den maksimale højde blandt drengene i alderen 13-14 år. Dette kan gøres ved hjælp af følgende kriterier:

Kriterium1: ">=13"

Kriterium2: "<=14"

Da vi sammenligner tallene i den samme kolonne, er criteria_range i begge tilfælde det samme (C2:C11):

=MAXIFS(D2:D11, C2:C11, ">=13", C2:C11, "<=14")

Hvis du ikke ønsker at indkode kriterierne i formlen, kan du indtaste dem i separate celler (f.eks. G1 og H1) og bruge følgende syntaks:

=MAXIFS(D2:D11, C2:C11, ">="&G1, C2:C11, "<="&H1)

Nedenstående skærmbillede viser resultatet:

Ud over tal kan logiske operatorer også arbejde med tekstkriterier. Især operatoren "ikke lig med" er praktisk, når du ønsker at udelukke noget fra dine beregninger. Hvis du f.eks. vil finde den højeste elev i alle sportsgrene undtagen volleyball, skal du bruge følgende formel:

=MAXIFS(D2:D11, B2:B11, "volleyball")

Eller denne, hvor G1 er den udelukkede sport:

=MAXIFS(D2:D11, B2:B11, ""&G1)

MAXIFS formler med jokertegn (delvis match)

Hvis du vil evaluere en betingelse, der indeholder en bestemt tekst eller et bestemt tegn, skal du inkludere et af følgende jokertegn i dine kriterier:

• Spørgsmålstegn (?) til at matche et hvilket som helst enkelt tegn.
• Asterisk (*) for at matche en hvilken som helst sekvens af tegn.

I dette eksempel skal vi finde ud af, hvem der er den højeste fyr inden for spilsport. Da navnene på alle spilsport i vores datasæt slutter med ordet "ball", medtager vi dette ord i kriterierne og bruger en stjerne til at matche eventuelle tidligere tegn:

=MAXIFS(D2:D11, B2:B11, "*ball")

Du kan også skrive "bold" i en celle, f.eks. G1, og sammenkæde jokertegnet med cellereferencen:

=MAXIFS(D2:D11, B2:B11, "*"&G1)

Resultatet vil se således ud:

Få den maksimale værdi inden for et datointerval

Da datoer er gemt som løbenumre i det interne Excel-system, kan du arbejde med datakriterierne på samme måde som med tal.

For at illustrere dette vil vi erstatte Alder kolonne med Fødselsdato og forsøge at finde den maksimale højde blandt drengene, der er født i et bestemt år, f.eks. i 2004. For at løse denne opgave skal vi "filtrere" de fødselsdatoer, der er større end eller lig med 1.1.2004 og mindre end eller lig med 31.12.2004.

Når du opbygger dine kriterier, er det vigtigt, at du angiver datoerne i et format, som Excel kan forstå:

=MAXIFS(D2:D11, C2:C11, ">=1-Jan-2004", C2:C11, "<=31-Dec-2004")

Eller

=MAXIFS(D2:D11, C2:C11, ">=1/1/2004", C2:C11, "<=31/12/2004")

For at undgå fejlfortolkninger er det fornuftigt at bruge DATE-funktionen:

=MAXIFS(D2:D11, C2:C11, ">="&DATE(2004,1,1), C2:C11, "<="&DATE(2004,12,31)))

I dette eksempel skriver vi målåret i G1 og bruger derefter DATE-funktionen til at angive datoerne:

=MAXIFS(D2:D11, C2:C11, ">="&DATE(G1,1,1), C2:C11, "<="&DATE(G1,12,31))

Bemærk. I modsætning til tal skal datoer omsluttes af anførselstegn, når de anvendes alene i kriterierne, f.eks:

=MAXIFS(D2:D11, C2:C11, "10/5/2005")

Find maksimal værdi baseret på flere kriterier med OR-logik

Excel MAXIFS-funktionen er designet til at teste betingelserne med AND-logikken - dvs. at den kun behandler de tal i max_range I nogle situationer kan det dog være nødvendigt at evaluere betingelserne med OR-logikken - dvs. at behandle alle de tal, for hvilke et af de angivne kriterier er SANDT.

For at gøre det lettere at forstå, kan du se på følgende eksempel: Hvis du vil finde den maksimale højde af de fyre, der spiller enten basketball eller fodbold, hvordan vil du så gøre det? At bruge "basketball" som kriterium1 og "fodbold" som kriterium2 vil ikke fungere, fordi Excel vil antage, at begge kriterier skal være SANDT.

Løsningen er at lave 2 separate MAXIFS formler, en for hver sport, og derefter bruge den gode gamle MAX-funktion til at returnere et højere tal:

=MAX(MAXIFS(C2:C11, B2:B11, "basketball"), MAXIFS(C2:C11, B2:B11, "fodbold"))

Skærmbilledet nedenfor viser denne formel, men med kriterierne i de foruddefinerede inputceller F1 og H1:

En anden måde er at bruge en MAX IF-formel med OR-logik.

7 ting, du skal huske om Excel MAXIFS

Nedenfor finder du et par bemærkninger, der kan hjælpe dig med at forbedre dine formler og undgå almindelige fejl. Nogle af disse bemærkninger er allerede blevet diskuteret som tips og noter i vores eksempler, men det kan være nyttigt at få et kort resumé af det, du allerede har lært:

1. MAXIFS-funktionen i Excel kan få den højeste værdi baseret på en eller flere kriterier .
2. Som standard arbejder Excel MAXIFS med den AND-logik , dvs. returnerer det højeste antal, der opfylder alle de angivne betingelser.
3. For at funktionen kan fungere, skal max-området og kriterierne for områderne have den samme størrelse og form .
4. SUMIF-funktionen er skift mellem store og små bogstaver , dvs. at den ikke genkender bogstaver i tekstkriterierne.
5. Når du skriver en MAXIFS-formel for flere celler, skal du huske at låse områderne med absolutte cellereferencer, for at formlen kan kopieres korrekt.
6. Pas på syntaks af dine kriterier Her er de vigtigste regler:
   • Når de anvendes alene, skal tekst og datoer sættes i anførselstegn, mens tal og cellehenvisninger ikke skal sættes i anførselstegn.
   • Når et tal, en dato eller tekst anvendes med en logisk operatør, skal hele udtrykket omsluttes af dobbelte anførselstegn som ">=10"; cellehenvisninger og andre funktioner skal sammenkædes ved hjælp af et ampersand som ">"&G1.
7. MAXIFS er kun tilgængelig i Excel 2019 og Excel for Office 365. I tidligere versioner er denne funktion ikke tilgængelig.

Sådan kan du finde den maksimale værdi i Excel med betingelser. Jeg takker for din læsning og håber at se dig snart på vores blog!

Download arbejdsbog til øvelser:

Eksempler på Excel MAXIFS formler (.xlsx-fil)