Tento návod ukazuje, jak použít funkci MAXIFS v aplikaci Excel k získání maximální hodnoty s podmínkami.

Tradičně, když jste někdy potřebovali zjistit nejvyšší hodnotu pomocí podmínek v aplikaci Excel, museli jste si vytvořit vlastní vzorec MAX IF. I když to pro zkušené uživatele není velký problém, pro nováčky to může představovat určité potíže, protože jednak byste si měli pamatovat syntaxi vzorce a jednak musíte umět pracovat se vzorci pole. Naštěstí společnost Microsoft nedávno představila novou funkcifunkce, která nám umožňuje provádět podmíněné maximalizování jednoduchým způsobem!

Funkce MAXIFS aplikace Excel

Funkce MAXIFS vrací největší číselnou hodnotu v zadaném rozsahu na základě jednoho nebo více kritérií.

Syntaxe funkce MAXIFS je následující:

Kde:

• Max_range (povinné) - rozsah buněk, ve kterých chcete najít maximální hodnotu.
• Kritéria_rozsahu1 (povinné) - první rozsah, který se vyhodnotí pomocí kritéria1 .
• Kritéria1 - podmínka, která se použije pro první rozsah. Může být reprezentována číslem, textem nebo výrazem.
• Kritéria_rozsahu2 / kritéria2 , ...(nepovinné) - další rozsahy a související kritéria. Podporováno je až 126 dvojic rozsah/kritérium.

Tato funkce MAXIFS je k dispozici v aplikacích Excel 2019, Excel 2021 a Excel pro Microsoft 365 v systémech Windows a Mac.

Jako příklad uveďme hledání nejvyššího fotbalisty v naší místní škole. Předpokládejme, že výšky studentů jsou v buňkách D2:D11 (max_rozsah) a sporty jsou v buňkách B2:B11 (kritérium_rozsah1), jako kritérium1 použijte slovo "fotbal" a získáte tento vzorec:

=MAXIFS(D2:D11, B2:B11, "football")

Aby byl vzorec univerzálnější, můžete zadat cílový sport v některé buňce (například G1) a zahrnout odkaz na buňku do vzorce. kritéria1 argument:

=MAXIFS(D2:D11, B2:B11, G1)

Poznámka. max_range a criteria_range argumenty musí mít stejnou velikost a tvar, tj. musí obsahovat stejný počet řádků a sloupců, jinak je vrácena chyba #VALUE!.

Jak používat funkci MAXIFS v aplikaci Excel - příklady vzorců

Jak jste se právě přesvědčili, funkce MAXIFS v Excelu je poměrně jednoduchá a snadno použitelná. Má však několik drobných nuancí, které mají velký význam. V následujících příkladech se pokusíme podmíněný max v Excelu maximálně využít.

Vyhledání maximální hodnoty na základě více kritérií

V první části tohoto tutoriálu jsme vytvořili vzorec MAXIFS v jeho nejjednodušší podobě pro získání maximální hodnoty na základě jedné podmínky. Nyní tento příklad posuneme dále a vyhodnotíme dvě různá kritéria.

Předpokládejme, že chcete najít nejvyššího basketbalistu v juniorské škole. Abyste to mohli udělat, definujte následující argumenty:

• Max_range - rozsah buněk obsahující výšky - D2:D11.
• Kritéria_rozsahu1 - rozsah buněk obsahující sporty - B2:B11.
• Kritéria1 - "basketbal", který je zadán v buňce G1.
• Kritéria_rozsahu2 - rozsah buněk definující typ školy - C2:C11.
• Kritéria2 - "junior", který je zadán v buňce G2.

Po spojení argumentů získáme tyto vzorce:

S "pevně zakódovanými" kritérii:

=MAXIFS(D2:D11, B2:B11, "basketbal", C2:C11, "junior")

S kritérii v předdefinovaných buňkách:

=MAXIFS(D2:D11, B2:B11, G1, C2:C11, G2)

Všimněte si, že funkce MAXIFS v aplikaci Excel je rozlišování velkých a malých písmen , takže si nemusíte dělat starosti s velikostí písmen v kritériích.

Pokud plánujete vzorec použít ve více buňkách, nezapomeňte všechny rozsahy uzamknout pomocí absolutních odkazů na buňky, například takto:

=MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2)

Tím se zajistí správné kopírování vzorce do jiných buněk - odkazy na kritéria se změní podle relativní polohy buňky, do které se vzorec kopíruje, zatímco rozsahy zůstanou nezměněny:

Jako další bonus vám ukážu rychlý způsob, jak z jiné buňky získat hodnotu, která je spojena s hodnotou max. V našem případě to bude jméno nejvyššího člověka. K tomu použijeme klasický vzorec INDEX MATCH a do prvního argumentu MATCH vnoříme jako vyhledávací hodnotu MAXIFS:

=INDEX($A$2:$A$11, MATCH(MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2), $D$2:$D$11, 0))

Vzorec nám říká, že jméno nejvyššího hráče basketbalu na nižší škole je Liam:

MAXIFS aplikace Excel s logickými operátory

Pokud potřebujete vyhodnotit číselná kritéria, použijte logické operátory, jako jsou:

• větší než (>)
• méně než (<)
• větší nebo rovno (>=)
• menší nebo rovno (<=)
• nerovná se ()

Operátor "rovná se" (=) lze ve většině případů vynechat.

Výběr operátoru obvykle není problém, nejsložitější je sestavit kritéria se správnou syntaxí. Zde je návod, jak na to:

• Logický operátor následovaný číslem nebo textem musí být uzavřen ve dvojitých uvozovkách, například ">=14" nebo "running".
• V případě odkazu na buňku nebo jinou funkci použijte uvozovky pro začátek řetězce a ampersand pro spojení odkazu a ukončení řetězce, např. ">"&B1 nebo "<"&TODAY().

Abychom viděli, jak to funguje v praxi, přidejme do naší vzorové tabulky sloupec Věk (sloupec C) a zjistěme maximální výšku mezi chlapci ve věku 13 až 14 let. To lze provést pomocí následujících kritérií:

Kritérium1: ">=13"

Kritérium2: "<=14"

Protože porovnáváme čísla ve stejném sloupci, je rozsah_kritérií v obou případech stejný (C2:C11):

=MAXIFS(D2:D11, C2:C11, ">=13", C2:C11, "<=14")

Pokud nechcete kritéria ve vzorci zadávat natvrdo, zadejte je do samostatných buněk (např. G1 a H1) a použijte následující syntaxi:

=MAXIFS(D2:D11, C2:C11, ">="&G1, C2:C11, "<="&H1)

Výsledek je zobrazen na následujícím snímku obrazovky:

Kromě čísel mohou logické operátory pracovat také s textovými kritérii. Operátor "nerovná se" se hodí zejména tehdy, když chcete něco z výpočtu vyloučit. Chcete-li například zjistit nejvyššího studenta ve všech sportech kromě volejbalu, použijte následující vzorec:

=MAXIFS(D2:D11, B2:B11, "volejbal")

Nebo tento, kde je G1 vyloučeným sportem:

=MAXIFS(D2:D11, B2:B11, ""&G1)

Vzorce MAXIFS se zástupnými znaky (částečná shoda)

Chcete-li vyhodnotit podmínku, která obsahuje konkrétní text nebo znak, uveďte do kritérií jeden z následujících zástupných znaků:

• Otazník (?) pro přiřazení libovolného jednotlivého znaku.
• Hvězdička (*) pro přiřazení libovolné posloupnosti znaků.

Pro tento příklad zjistíme nejvyššího muže v herních sportech. Protože názvy všech herních sportů v našem souboru dat končí slovem "míč", zahrneme toto slovo do kritérií a použijeme hvězdičku pro porovnání všech předchozích znaků:

=MAXIFS(D2:D11, B2:B11, "*ball")

Do některé buňky, např. G1, můžete také napsat "ball" a spojit zástupný znak s odkazem na buňku:

=MAXIFS(D2:D11, B2:B11, "*"&G1)

Výsledek bude vypadat takto:

Získání maximální hodnoty v rámci rozsahu dat

Vzhledem k tomu, že data jsou v interním systému Excelu uložena jako pořadová čísla, pracujete s kritérii dat stejným způsobem jako s čísly.

Pro ilustraci nahradíme Věk sloupec s Datum narození a pokusíme se zjistit maximální výšku mezi chlapci narozenými v určitém roce, řekněme v roce 2004. Abychom tento úkol splnili, musíme "vyfiltrovat" data narození, která jsou větší nebo rovna 1. lednu 2004 a menší nebo rovna 31. prosinci 2004.

Při sestavování kritérií je důležité zadávat data ve formátu, kterému Excel rozumí:

=MAXIFS(D2:D11, C2:C11, ">=1.ledna-2004", C2:C11, "<=31.prosince-2004")

Nebo

=MAXIFS(D2:D11, C2:C11, ">=1/1/2004", C2:C11, "<=12/31/2004")

Aby nedošlo k chybné interpretaci, je vhodné použít funkci DATE:

=MAXIFS(D2:D11, C2:C11, ">="&DATE(2004,1,1), C2:C11, "<="&DATE(2004,12,31))

V tomto příkladu zadáme cílový rok do pole G1 a poté použijeme funkci DATE pro zadání dat:

=MAXIFS(D2:D11, C2:C11, ">="&DATE(G1,1,1), C2:C11, "<="&DATE(G1,12,31))

Poznámka: Na rozdíl od čísel by data měla být při samostatném použití v kritériích uvedena v uvozovkách. Například:

=MAXIFS(D2:D11, C2:C11, "10/5/2005")

Nalezení maximální hodnoty na základě více kritérií pomocí logiky OR

Funkce MAXIFS aplikace Excel je určena k testování podmínek pomocí logiky AND - tj. zpracovává pouze ta čísla, která se nacházejí v položce max_range V některých situacích však může být nutné vyhodnotit podmínky pomocí logiky OR - tj. zpracovat všechna čísla, pro která je některé ze zadaných kritérií TRUE.

Pro snazší pochopení uvažujte následující příklad. Předpokládejme, že chcete zjistit maximální výšku chlapců, kteří hrají buď basketbal, nebo fotbal. Jak byste to udělali? Použití kritéria "basketbal" jako kritéria1 a kritéria "fotbal "2 nebude fungovat, protože Excel by předpokládal, že obě kritéria by se měla vyhodnotit jako TRUE.

Řešením je vytvořit 2 samostatné vzorce MAXIFS, jeden pro každý sport, a pak použít starou dobrou funkci MAX pro vrácení vyššího čísla:

=MAX(MAXIFS(C2:C11, B2:B11, "basketbal"), MAXIFS(C2:C11, B2:B11, "fotbal"))

Na obrázku níže je zobrazen tento vzorec, ale s kritérii v předdefinovaných vstupních buňkách F1 a H1:

Dalším způsobem je použití vzorce MAX IF s logikou OR.

7 věcí, které je třeba si zapamatovat o aplikaci Excel MAXIFS

Níže najdete několik poznámek, které vám pomohou zlepšit vaše vzorce a vyvarovat se častých chyb. Některé z těchto poznámek jsme již probrali jako tipy a poznámky v našich příkladech, ale možná vám pomůže krátké shrnutí toho, co jste se již naučili:

1. Funkce MAXIFS v aplikaci Excel může získat nejvyšší hodnotu na základě jeden nebo více kritérií .
2. Ve výchozím nastavení pracuje aplikace Excel MAXIFS se symbolem Logika AND , tj. vrátí maximální číslo, které splňuje všechny zadané podmínky.
3. Aby funkce fungovala, musí mít rozsahy max a kritéria hodnotu stejná velikost a tvar .
4. Funkce SUMIF je rozlišování velkých a malých písmen , tj. nerozpoznává velikost písmen v textových kritériích.
5. Při psaní vzorce MAXIFS pro více buněk nezapomeňte. uzamknout rozsahy s absolutními odkazy na buňky, aby se vzorec správně zkopíroval.
6. Pozor na syntaxe vašich kritérií ! Zde jsou hlavní pravidla:
   • Při samostatném použití by text a data měly být uvedeny v uvozovkách, čísla a odkazy na buňky nikoli.
   • Při použití čísla, data nebo textu s logickým operátorem musí být celý výraz uzavřen do dvojitých uvozovek jako ">=10"; odkazy na buňky a další funkce musí být spojeny pomocí ampersandu jako ">"&G1.
7. Funkce MAXIFS je k dispozici pouze v aplikaci Excel 2019 a Excel pro Office 365. V dřívějších verzích tato funkce není k dispozici.

Takto můžete v Excelu pomocí podmínek najít maximální hodnotu. Děkuji vám za přečtení a doufám, že se brzy uvidíme na našem blogu!

Stáhněte si cvičebnici:

Příklady vzorců aplikace Excel MAXIFS (.xlsx soubor)