سبق ښیي چې څنګه په Excel کې د MAXIFS فعالیت وکاروئ ترڅو د شرایطو سره اعظمي ارزښت ترلاسه کړئ.

په دودیز ډول، کله چې تاسو اړتیا لرئ په Excel کې د شرایطو سره لوړ ارزښت ومومئ، تاسو باید خپل MAX IF فارمول جوړ کړئ. پداسې حال کې چې د تجربه لرونکو کاروونکو لپاره لویه معامله نه ده، دا ممکن د نويو کسانو لپاره ځینې ستونزې وړاندې کړي ځکه چې لومړی، تاسو باید د فورمول ترکیب په یاد ولرئ او دویم، تاسو اړتیا لرئ چې پوه شئ چې څنګه د صف فارمولونو سره کار وکړئ. خوشبختانه، مایکروسافټ پدې وروستیو کې یو نوی فنکشن معرفي کړی چې موږ ته اجازه راکوي چې مشروط اعظمي یوه اسانه لاره ترسره کړو!

د ایکسل MAXIFS فنکشن

د MAXIFS فنکشن په کې ترټولو لوی شمیري ارزښت بیرته راګرځوي. ټاکل شوې حد د یو یا ډیرو معیارونو پراساس.

د MAXIFS فنکشن ترکیب په لاندې ډول دی:

چیرته:

• Max_range (ضروري) - د حجرو سلسله چیرې چې تاسو غواړئ اعظمي ارزښت ومومئ.
• Criteria_range1 (ضروري) - لومړی رینج د معیار1 سره ارزول کیږي.
• معیار1 - هغه حالت چې په لومړي رینج کې کارول کیږي. دا د یو شمیر، متن یا بیان لخوا نمایش کیدی شي.
• Criteria_range2 / معیار2 ، …(اختیاري) - اضافي سلسلې او د دوی اړوند معیارونه. تر 126 حد / معیارونو جوړه ملاتړ کیږي.

دا MAXIFS فعالیت په Excel 2019، Excel 2021، او کې شتون لريپه وینډوز او میک کې د مایکروسافټ 365 لپاره Excel.

د مثال په توګه، راځئ چې زموږ په محلي ښوونځي کې د فوټبال ترټولو لوړ لوبغاړی ومومئ. فرض کړئ چې د زده کونکو لوړوالی په حجرو کې دي D2:D11 (max_range) او سپورتونه په B2:B11 (criteria_range1) کې دي، د "فوټبال" کلمه د معیار1 په توګه وکاروئ، او تاسو به دا فورمول ترلاسه کړئ:

=MAXIFS(D2:D11, B2:B11, "football")

د دې لپاره چې فورمول ډیر متنوع کړي، تاسو کولی شئ هدف سپورت په ځینې حجرو کې داخل کړئ (وایئ، G1) او د حجرې حواله په معیار1 دلیل کې شامل کړئ:

=MAXIFS(D2:D11, B2:B11, G1)

یادونه. د max_range او criteria_range دلیلونه باید د ورته اندازې او شکل څخه وي، د بیلګې په توګه د قطارونو او کالمونو مساوي شمیر ولري، که نه د #VALUE! تېروتنه بېرته راګرځي.

په Excel کې د MAXIFS فنکشن کارولو څرنګوالی - د فورمول مثالونه

لکه څنګه چې تاسو لیدلي، د Excel MAXIFS خورا ساده او کارول اسانه دي. په هرصورت، دا یو څو کوچني باریکونه لري چې لوی توپیر لري. په لاندې مثالونو کې، موږ به هڅه وکړو چې په Excel کې د شرطي max څخه ډیره ګټه پورته کړو.

د ډیری معیارونو پراساس اعظمي ارزښت ومومئ

د دې ټیوټوریل په لومړۍ برخه کې، موږ د MAXIFS فورمول جوړ کړ په ساده شکل کې د یو شرط پراساس اعظمي ارزښت ترلاسه کولو لپاره. اوس، موږ به دا مثال نور هم واخلو او دوه مختلف معیارونه و ارزوو.

فرض کړئ، تاسو غواړئ په کوچني ښوونځي کې د باسکیټبال ترټولو لوړ لوبغاړی ومومئ. د دې کولو لپاره، لاندې تعریف کړئدلیلونه:

• Max_range - د حجرو یوه سلسله چې لوړوالی لري - D2:D11.
• Criteria_range1 - د حجرو لړۍ چې سپورت لري - B2:B11.
• Criteria1 - "باسکټبال"، کوم چې په G1 حجره کې داخلیږي.
• Criteria_range2 - د حجرو یوه لړۍ چې تعریف کوي د ښوونځي ډول - C2:C11.
• معیار2 - "جونیور" چې په G2 حجره کې داخلیږي.

د دلیلونو سره یوځای کول، موږ دا فورمول ترلاسه کوو :

د "هارډ کوډ شوي" معیارونو سره:

=MAXIFS(D2:D11, B2:B11, "basketball", C2:C11, "junior")

په وړاندې ټاکل شوي حجرو کې د معیارونو سره:

=MAXIFS(D2:D11, B2:B11, G1, C2:C11, G2)

مهرباني وکړئ په یاد ولرئ چې MAXIFS په Excel کې فعالیت د قضیې غیر حساس دی، نو تاسو اړتیا نلرئ په خپلو معیارونو کې د لیک قضیې په اړه اندیښنه ولرئ.

15>

په هغه صورت کې چې تاسو د خپل کارولو پلان لرئ په څو حجرو کې فورمول، ډاډ ترلاسه کړئ چې ټول سلسلې د مطلق حجرو حوالې سره لاک کړئ، لکه دا:

=MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2)

دا به ډاډ ترلاسه کړي چې فورمول نورو حجرو ته په سمه توګه کاپي کوي - د معیارونو حوالې په اساس بدلیږي د حجرې په نسبي موقعیت کې چیرې چې فورمول کاپي کیږي پداسې حال کې چې t د هغه سلسله بدله پاتې ده:

د اضافي بونس په توګه، زه به تاسو ته د یو بل حجرې څخه د ارزښت د استخراج لپاره چټکه لاره وښیم چې د اعظمي ارزښت سره تړاو لري. زموږ په قضیه کې، دا به د ترټولو لوړ کس نوم وي. د دې لپاره، موږ به د MATCH په لومړي دلیل کې د کلاسیک INDEX MATCH فورمول او Nest MAXIFS د لټون ارزښت په توګه وکاروو:

=INDEX($A$2:$A$11, MATCH(MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2), $D$2:$D$11, 0))

فارمول موږ ته وايي چې نومپه جونیئر ښوونځي کې د باسکیټبال ترټولو لوړ لوبغاړی لیام دی:

Excel MAXIFS د منطقي آپریټرونو سره

په هغه حالت کې چې تاسو د شمیرو معیارونو ارزولو ته اړتیا لرئ، منطقي آپریټرونه وکاروئ لکه:

• له (>) څخه لوی
• له (<)
• له (>=) څخه لوی یا مساوي
• له (<=) څخه لږ یا مساوي
• مساوي نه ()

د "مساوي ته" آپریټر (=) په ډیرو مواردو کې پریښودل کیدی شي.

معمولا، د آپریټر غوره کول کومه ستونزه نده، ترټولو ستونزمنه برخه د سم نحو سره د معیارونو جوړول دي. دلته دا دی چې څنګه:

• یو منطقي آپریټر د یو شمیر یا متن سره تعقیب باید په دوه اړخیزو نرخونو لکه ">=14" یا "چلونکي" کې تړل شي.
• د حجرې په صورت کې حواله یا بل فنکشن، د حوالې د یوځای کولو لپاره د تار او امپرسنډ پیل کولو لپاره نرخونه وکاروئ او تار پای ته ورسوي، د بیلګې په توګه. ">"&B1 یا "<"&TODAY().

معیار1: ">=13"

معیار2: "<=14"

ځکه چې موږ په ورته کالم کې شمیرې پرتله کوو، په دواړو حالتونو کې معیار_رینج یو شان دی (C2:C11):

=MAXIFS(D2:D11, C2:C11, ">=13", C2:C11, "<=14")

که تاسو نه غواړئ معیارونه سخت کړئ په فورمول کې، دوی په جلا حجرو کې داخل کړئ (د بیلګې په توګه G1 او H1) او لاندې یې وکاروئنحو:

=MAXIFS(D2:D11, C2:C11, ">="&G1, C2:C11, "<="&H1)

لاندې سکرین شاټ پایله ښیې:

18>

د شمیرو سربیره، منطقي چلونکي هم کولی شي د متن معیارونو سره کار وکړي. په ځانګړې توګه، "مساوي نه" آپریټر په کار کې راځي کله چې تاسو غواړئ یو څه له خپلو محاسبو څخه خارج کړئ. د مثال په توګه، د والیبال پرته په ټولو سپورتونو کې د لوړ زده کونکي موندلو لپاره، لاندې فورمول وکاروئ:

=MAXIFS(D2:D11, B2:B11, "volleyball")

یا دا یو، چیرته چې G1 خارج شوی سپورت دی:

=MAXIFS(D2:D11, B2:B11, ""&G1)

MAXIFS فورمولونه د وائلډ کارډ حروف سره (جزوي میچ)

د داسې حالت ارزولو لپاره چې یو ځانګړی متن یا کرکټر لري، د لاندې وائلډ کارډ کرکټرونو څخه یو پکې شامل کړئ ستاسو معیارونه:

• د پوښتنې نښه (؟) د هر یو حرف سره سمون لپاره.
• ستوری (*) د حروفونو هر ترتیب سره سمون لپاره.

لپاره دا مثال، راځئ چې د لوبې سپورت کې ترټولو لوړ سړی ومومئ. ځکه چې زموږ په ډیټاسیټ کې د ټولو لوبو سپورتونو نومونه د "بال" کلمې سره پای ته رسیږي، موږ دا کلمه په معیارونو کې شاملوو او د پخوانیو حروفونو سره د سمون لپاره ستوری کاروو:

=MAXIFS(D2:D11, B2:B11, "*ball")

تاسو کولی شئ په ځینو حجرو کې "بال" هم ټایپ کړئ، د بیلګې په توګه G1، او د وائلډ کارډ کرکټر د حجرې حوالې سره یوځای کړئ:

=MAXIFS(D2:D11, B2:B11, "*"&G1)

پایله به په لاندې ډول ښکاري:

20>

اعظمي ارزښت ترلاسه کړئ د نیټې په حد کې

ځکه چې نیټې په داخلي اکسل سیسټم کې د سیریل نمبرونو په توګه زیرمه شوي ، تاسو د نیټې معیارونو سره په ورته ډول کار کوئ لکه څنګه چې تاسو د شمیرو سره کار کوئ.

تردا په ډاګه کړئ، موږ به د عمر کالم د د زیږون نیټه سره بدل کړو او هڅه وکړو چې په 2004 کې ویل شوي په یو ځانګړي کال کې زیږیدلي هلکانو تر مینځ اعظمي لوړوالی وټاکو. موږ اړتیا لرو چې د زیږون نیټه "فلټر" کړو چې د 1-Jan-2004 څخه لوی یا مساوي وي او د 31-Dec-2004 څخه کم یا مساوي وي.

کله چې ستاسو معیارونه جوړ کړئ، دا مهمه ده چې تاسو نیټې په هغه شکل کې وړاندې کړئ چې اکسل پرې پوه شي:

=MAXIFS(D2:D11, C2:C11, ">=1-Jan-2004", C2:C11, "<=31-Dec-2004")

یا

=MAXIFS(D2:D11, C2:C11, ">=1/1/2004", C2:C11, "<=12/31/2004")

د غلط تفسیر د مخنیوي لپاره، دا د DATE فنکشن کارولو لپاره معنی لري :

=MAXIFS(D2:D11, C2:C11, ">="&DATE(2004,1,1), C2:C11, "<="&DATE(2004,12,31))

د دې مثال لپاره، موږ به هدف کال په G1 کې ټایپ کړو، او بیا به د نیټې د وړاندې کولو لپاره د DATE فعالیت وکاروو:

=MAXIFS(D2:D11, C2:C11, ">="&DATE(G1,1,1), C2:C11, "<="&DATE(G1,12,31))

یادونه. د شمیرو برعکس، نیټې باید د نرخ نښانونو کې تړل شي کله چې پخپله په معیارونو کې کارول کیږي. د مثال په توګه:

=MAXIFS(D2:D11, C2:C11, "10/5/2005")

د OR منطق سره د ډیری معیارونو پراساس اعظمي ارزښت ومومئ

د Excel MAXIFS فنکشن د AND منطق سره د شرایطو ازموینې لپاره ډیزاین شوی - د بیلګې په توګه دا یوازې هغه شمیرې پروسس کوي په max_range کې د کوم لپاره چې ټول معیارونه سم دي. په هرصورت، په ځینو حالتونو کې، تاسو اړتیا لرئ چې شرایط د OR منطق سره ارزونه وکړئ - د بیلګې په توګه ټول هغه شمیرې پروسس کړئ چې کوم ټاکل شوي معیارونه سم دي.

د دې لپاره چې د شیانو پوهیدل اسانه کړي، مهرباني وکړئ لاندې په پام کې ونیسئ مثال فرض کړئ چې تاسو غواړئ د هغو هلکانو اعظمي لوړوالی ومومئ څوک چې یا باسکیټبال لوبوي یافوټبال تاسو به دا څنګه کوئ؟ د "باسکټبال" د معیار1 په توګه او د "فوټبال" معیار2 په توګه کارول به کار ونکړي، ځکه چې ایکسل به داسې انګیري چې دواړه معیارونه باید سم ارزونه وکړي.

حل دا دی چې 2 جلا MAXIFS فورمولونه جوړ کړئ، په هر سپورت کې یو، او بیا د لوړ شمیر بیرته راستنیدو لپاره د ښه زوړ MAX فنکشن وکاروئ:

=MAX(MAXIFS(C2:C11, B2:B11, "basketball"), MAXIFS(C2:C11, B2:B11, "football"))

لاندې سکرین شاټ دا فورمول ښیې مګر د مخکینۍ ټاکل شوي ان پټ حجرو F1 او H1 معیارونو سره:

بله لاره دا ده چې د OR منطق سره د MAX IF فارمول وکاروئ.

7 شیان چې د Excel MAXIFS په اړه په یاد ولرئ

لاندې به تاسو یو څو څرګندونې ومومئ دا به ستاسو د فورمولونو په ښه کولو کې مرسته وکړي او د عام غلطیو مخه ونیسي. د دې لیدنو څخه ځینې دمخه زموږ په مثالونو کې د لارښوونو او نوټونو په توګه بحث شوي ، مګر دا ممکن ګټور وي چې د هغه څه لنډ لنډیز ترلاسه کړئ چې تاسو دمخه زده کړي دي:

1. په Excel کې د MAXIFS فعالیت ترلاسه کولی شي. تر ټولو لوړ ارزښت د یو یا د څو معیارونو پر بنسټ .
2. په ډیفالټ ډول، Excel MAXIFS د AND منطق سره کار کوي، د بیلګې په توګه اعظمي شمیره بیرته راګرځوي کوم چې ټول ټاکل شوي شرایط پوره کوي.
3. د فعالیت د کار کولو لپاره، د اعظمي حد او معیارونو سلسلې باید ورته اندازه او شکل ولري.
4. د SUMIF فعالیت کیس غیر حساس دی، د بیلګې په توګه دا د متن په معیارونو کې د خط کیسه نه پیژني.
5. کله چې د ډیری حجرو لپاره د MAXIFS فورمول لیکئ، په یاد ولرئ چې لاک کړئ. سلسله سرهد فورمول په سمه توګه د کاپي کولو لپاره مطلق سیل حوالې.
6. د خپل معیارونو نحو ته پام وکړئ ! دلته اساسي اصول دي:
   • کله چې پخپله کارول کیږي، متن او نیټې باید د حوالې نښانونو کې تړل شي، شمیرې او د حجرې حوالې باید نه وي.
   • کله چې شمیره، نیټه یا متن کارول کیږي د منطقي آپریټر سره، ټول بیان باید په دوه اړخیزو ټکو کې تړل شي لکه ">=10"؛ د حجرې حوالې او نورې دندې باید د امپرسنډ په کارولو سره یوځای شي لکه ">"&G1.
7. MAXIFS یوازې په Excel 2019 او Excel for Office 365 کې شتون لري. په پخوانیو نسخو کې، دا فنکشن شتون نلري.

په دې توګه تاسو کولی شئ د شرایطو سره په Excel کې اعظمي ارزښت ومومئ. زه د لوستلو لپاره مننه کوم او هیله لرم چې تاسو به ژر زموږ په بلاګ کې وګورم!

د تمرین کاري کتاب ډاونلوډ کړئ:

د ایکسل MAXIFS فورمول مثالونه (.xlsx فایل)