A bemutató azt mutatja be, hogyan használhatja a MAXIFS függvényt az Excelben a maximális érték feltételek mellett történő kiszámításához.

Hagyományosan, ha valaha is meg kellett találni a legmagasabb értéket feltételekkel az Excelben, akkor saját MAX IF képletet kellett készíteni. Bár tapasztalt felhasználók számára ez nem jelent nagy problémát, a kezdők számára ez bizonyos nehézségeket okozhat, mivel egyrészt emlékeznie kell a képlet szintaxisára, másrészt tudnia kell, hogyan kell tömbképletekkel dolgozni. Szerencsére a Microsoft nemrég bevezetett egy újfüggvény, amely lehetővé teszi számunkra, hogy feltételes max egy egyszerű módon!

Excel MAXIFS funkció

A MAXIFS függvény a megadott tartományban a legnagyobb numerikus értéket adja vissza egy vagy több kritérium alapján.

A MAXIFS függvény szintaxisa a következő:

Hol:

• Max_range (kötelező) - a cellák azon tartománya, ahol a maximális értéket szeretné megtalálni.
• Criteria_range1 (kötelező) - az első tartomány, amelyet ki kell értékelni a kritériumok1 .
• Kritériumok1 - az első tartományra alkalmazandó feltétel, amely számmal, szöveggel vagy kifejezéssel is megadható.
• Criteria_range2 / kritérium2 , ...(opcionális) - további tartományok és a hozzájuk tartozó kritériumok. Legfeljebb 126 tartomány/kritérium páros támogatott.

Ez a MAXIFS funkció elérhető az Excel 2019, Excel 2021 és Excel for Microsoft 365 programokban Windows és Mac rendszereken.

Példaként keressük meg a legmagasabb focistát a helyi iskolában. Feltételezve, hogy a diákok magassága a D2:D11 cellákban (max_range), a sportágak pedig a B2:B11 cellákban (criteria_range1) vannak, használjuk a "football" szót criteria1-ként, és ezt a képletet kapjuk:

=MAXIFS(D2:D11, B2:B11, "futball")

Hogy a képletet sokoldalúbbá tegye, a célsportot beírhatja valamelyik cellába (mondjuk G1), és a cellahivatkozást beillesztheti a kritériumok1 érv:

=MAXIFS(D2:D11, B2:B11, G1)

Megjegyzés. max_range és criteria_range argumentumoknak azonos méretűeknek és alakúaknak kell lenniük, azaz ugyanannyi sort és oszlopot kell tartalmazniuk, különben a #VALUE! hibát kapjuk vissza.

A MAXIFS függvény használata az Excelben - képletpéldák

Mint az imént láthattad, az Excel MAXIFS meglehetősen egyszerű és könnyen használható. Van azonban néhány apró árnyalat, amely nagy különbséget jelent. Az alábbi példákban megpróbáljuk a legtöbbet kihozni a feltételes max Excelben.

Max érték keresése több kritérium alapján

A bemutató első részében létrehoztunk egy MAXIFS képletet a legegyszerűbb formában, hogy megkapjuk a maximális értéket egy feltétel alapján. Most továbbvisszük ezt a példát, és két különböző kritériumot fogunk értékelni.

Tegyük fel, hogy meg akarod találni a legmagasabb kosárlabdázót az általános iskolában. Ehhez határozd meg a következő érveket:

• Max_range - a magasságokat tartalmazó cellák tartománya - D2:D11.
• Criteria_range1 - a sportot tartalmazó cellák tartománya - B2:B11.
• Kritériumok1 - "kosárlabda", amely a G1 cellába kerül bevitelre.
• Criteria_range2 - az iskolatípust meghatározó cellák tartománya - C2:C11.
• Kritériumok2 - "junior", amely a G2 cellába kerül bevitelre.

Az érveket összerakva a következő képleteket kapjuk:

"Keményen kódolt" kritériumokkal:

=MAXIFS(D2:D11, B2:B11, "kosárlabda", C2:C11, "junior")

Előre meghatározott cellákban lévő kritériumokkal:

=MAXIFS(D2:D11, B2:B11, G1, C2:C11, G2)

Kérjük, vegye figyelembe, hogy az Excel MAXIFS funkciója a következő case-insensitive , így nem kell aggódnia a betűjelek miatt a kritériumokban.

Ha a képletet több cellában is használni kívánja, akkor feltétlenül rögzítse az összes tartományt abszolút cellahivatkozásokkal, például így:

=MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2)

Ez biztosítja, hogy a képlet helyesen másolódik más cellákba - a kritériumhivatkozások a képlet másolásának cellájához viszonyított pozíciója alapján változnak, míg a tartományok változatlanok maradnak:

Extra bónuszként mutatok egy gyors módszert arra, hogy egy másik cellából kivonjunk egy olyan értéket, amely a max értékhez kapcsolódik. Esetünkben ez a legmagasabb személy neve lesz. Ehhez a klasszikus INDEX MATCH képletet fogjuk használni, és a MATCH első argumentumába MAXIFS értéket fészkelünk be keresési értékként:

=INDEX($A$2:$A$11, MATCH(MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2), $D$2:$D$11, 0)))

A képletből kiderül, hogy az általános iskola legmagasabb kosárlabdázójának neve Liam:

Excel MAXIFS logikai operátorokkal

Olyan helyzetekben, amikor numerikus kritériumokat kell értékelnie, használjon logikai operátorokat, például:

• nagyobb, mint (>)
• kisebb, mint (<)
• nagyobb vagy egyenlő (>=)
• kisebb vagy egyenlő (<=)
• nem egyenlő ()

Az "egyenlő" operátor (=) a legtöbb esetben elhagyható.

Általában az operátor kiválasztása nem jelent problémát, a legtrükkösebb rész a megfelelő szintaxisú kritériumok összeállítása. Íme, hogyan:

• A logikai operátort, amelyet egy szám vagy szöveg követ, idézőjelek közé kell zárni, mint például ">=14" vagy "running".
• Cellahivatkozás vagy más függvény esetén az idézőjelekkel kezdje a karakterláncot, és az erősítőjellel kapcsolja össze a hivatkozást és fejezze be a karakterláncot, például ">"&B1 vagy "<"&TODAY().

Hogy lássuk, hogyan működik a gyakorlatban, adjuk hozzá a mintatáblázatunkhoz az Életkor oszlopot (C oszlop), és keressük meg a 13 és 14 év közötti fiúk maximális magasságát. Ezt a következő feltételekkel tehetjük meg:

Criteria1: ">=13"

Criteria2: "<=14"

Mivel ugyanabban az oszlopban lévő számokat hasonlítjuk össze, a criteria_range mindkét esetben ugyanaz (C2:C11):

=MAXIFS(D2:D11, C2:C11, ">=13", C2:C11, "<=14")

Ha nem szeretné a feltételeket a képletbe keményen beírni, írja be őket külön cellákba (pl. G1 és H1), és használja a következő szintaxist:

=MAXIFS(D2:D11, C2:C11, ">="&G1, C2:C11, "<="&H1)

Az alábbi képernyőképen látható az eredmény:

A számok mellett a logikai operátorok szöveges feltételekkel is dolgozhatnak. Különösen a "nem egyenlő" operátor jön jól, ha valamit ki akarsz zárni a számításokból. Például, ha a röplabda kivételével az összes sportág legmagasabb diákját szeretnéd megtalálni, használd a következő képletet:

=MAXIFS(D2:D11, B2:B11, "röplabda")

Vagy ez, ahol a G1 a kizárt sportág:

=MAXIFS(D2:D11, B2:B11, ""&G1)

MAXIFS képletek helyettesítő karakterekkel (részleges egyezés)

Egy adott szöveget vagy karaktert tartalmazó feltétel kiértékeléséhez a következő helyettesítő karakterek valamelyikét adja meg a feltételekben:

• Kérdőjel (?), hogy bármelyik karakterrel megegyezzen.
• Csillag (*) bármely karaktersorozathoz.

Ebben a példában keressük meg a legmagasabb fickót a játéksportok közül. Mivel az adathalmazunkban szereplő összes játéksport neve a "labda" szóra végződik, ezt a szót is felvesszük a feltételek közé, és csillaggal illesztjük a korábbi karaktereket:

=MAXIFS(D2:D11, B2:B11, "*ball")

A "labda" szót is beírhatja valamelyik cellába, például a G1-be, és a joker karaktert összekapcsolhatja a cellahivatkozással:

=MAXIFS(D2:D11, B2:B11, "*"&G1)

Az eredmény a következőképpen néz ki:

Max érték lekérdezése egy dátumtartományon belül

Mivel a dátumokat sorszámként tárolja az Excel belső rendszere, a dátumkritériumokkal ugyanúgy dolgozhat, mint a számokkal.

Ennek illusztrálására kicseréljük a Kor oszlop a Születési dátum és megpróbáljuk kiszámítani a maximális magasságot egy adott évben, mondjuk 2004-ben született fiúk között. A feladat elvégzéséhez "ki kell szűrnünk" azokat a születési dátumokat, amelyek nagyobbak vagy egyenlőek 2004. január 1-jével és kisebbek vagy egyenlőek 2004. december 31-ével.

A kritériumok összeállításakor fontos, hogy a dátumokat az Excel által érthető formátumban adja meg:

=MAXIFS(D2:D11, C2:C11, ">=1-Jan-2004", C2:C11, "<=31-Dec-2004")

Vagy

=MAXIFS(D2:D11, C2:C11, ">=1/1/2004", C2:C11, "<=12/31/2004")

A félreértelmezések elkerülése érdekében érdemes a DATE funkciót használni:

=MAXIFS(D2:D11, C2:C11, ">="&DATE(2004,1,1), C2:C11, "<="&DATE(2004,12,31))

Ebben a példában a G1-be írjuk be a célévet, majd a DATE függvényt használjuk a dátumok megadására:

=MAXIFS(D2:D11, C2:C11, ">="&DATE(G1,1,1), C2:C11, "<="&DATE(G1,12,31))

Megjegyzés: A számokkal ellentétben a dátumokat idézőjelbe kell tenni, ha a kritériumokban önmagukban használják őket. Például:

=MAXIFS(D2:D11, C2:C11, "10/5/2005")

Maximális érték keresése több kritérium alapján VAGY logikával

Az Excel MAXIFS függvényét úgy tervezték, hogy az ÉS logikával tesztelje a feltételeket - azaz csak azokat a számokat dolgozza fel, amelyek a max_range Bizonyos helyzetekben azonban szükség lehet arra, hogy a feltételeket a VAGY logikával értékelje ki - azaz feldolgozza az összes olyan számot, amelynél a megadott feltételek bármelyike IGAZ.

A dolgok könnyebb megértése érdekében tekintse át a következő példát. Tegyük fel, hogy meg akarja találni a kosárlabdázó vagy focizó srácok maximális magasságát. Hogyan tenné ezt? A "kosárlabda" mint kritérium1 és a "foci" mint kritérium2 használata nem fog működni, mert az Excel azt feltételezné, hogy mindkét kritériumnak TRUE-ra kell értékelődnie.

A megoldás az, hogy 2 külön MAXIFS képletet készítünk, sportáganként egyet-egyet, majd a jó öreg MAX függvényt használjuk a magasabb szám visszaadására:

=MAX(MAXIFS(C2:C11, B2:B11, "kosárlabda"), MAXIFS(C2:C11, B2:B11, "futball"))

Az alábbi képernyőkép ezt a képletet mutatja, de a kritériumokat az előre definiált F1 és H1 beviteli cellákban:

Egy másik lehetőség a MAX IF formula használata VAGY logikával.

7 dolog, amit érdemes megjegyezni az Excel MAXIFS-ről

Az alábbiakban találsz néhány észrevételt, amelyek segítenek a képleteid javításában és a gyakori hibák elkerülésében. Ezen észrevételek egy részét már tárgyaltuk tippek és megjegyzések formájában a példáinkban, de hasznos lehet egy rövid összefoglaló a már megtanultakról:

1. Az Excel MAXIFS függvénye a legmagasabb értéket kaphatja meg a következők alapján egy vagy több kritérium .
2. Alapértelmezés szerint az Excel MAXIFS a következővel dolgozik ÉS-logika , azaz azt a maximális számot adja vissza, amely megfelel az összes megadott feltételnek.
3. Ahhoz, hogy a függvény működjön, a max tartománynak és a kritériumtartományoknak rendelkezniük kell a azonos méret és shape .
4. A SUMIF függvény case-insensitive , azaz nem ismeri fel a betűket a szöveges kritériumokban.
5. Amikor több cellára MAXIFS képletet ír, ne feledje, hogy zárolja a tartományokat abszolút cellahivatkozásokkal, hogy a képlet helyesen másolódjon.
6. Vigyázz a az Ön kritériumainak szintaxisa Íme a főbb szabályok:
   • Önálló használat esetén a szöveget és a dátumokat idézőjelbe kell tenni, a számokat és a cellahivatkozásokat nem.
   • Amikor egy számot, dátumot vagy szöveget használunk logikai operátorral, az egész kifejezést idézőjelek közé kell zárni, mint például ">=10"; a cellahivatkozásokat és más függvényeket egyvégződéssel kell összekapcsolni, mint például ">"&G1.
7. A MAXIFS csak az Excel 2019-ben és az Excel for Office 365-ben érhető el. A korábbi verziókban ez a funkció nem áll rendelkezésre.

Így találhatod meg a maximális értéket az Excelben feltételekkel. Köszönöm, hogy elolvastad és remélem, hamarosan találkozunk a blogon!

Gyakorlati munkafüzet letöltése:

Excel MAXIFS képlet példák (.xlsx fájl)