Das Tutorial zeigt, wie man die Funktion MAXIFS in Excel verwendet, um den Maximalwert mit Bedingungen zu ermitteln.

Wenn Sie in Excel den höchsten Wert mit Bedingungen ermitteln wollten, mussten Sie traditionell eine eigene MAX-IF-Formel erstellen. Für erfahrene Benutzer ist das keine große Sache, aber für Neulinge kann das gewisse Schwierigkeiten mit sich bringen, da Sie sich erstens die Syntax der Formel merken müssen und zweitens wissen müssen, wie man mit Array-Formeln arbeitet. Glücklicherweise hat Microsoft kürzlich eine neueFunktion, mit der wir auf einfache Weise bedingte Maximalwerte erreichen können!

Excel-Funktion MAXIFS

Die Funktion MAXIFS gibt den größten numerischen Wert im angegebenen Bereich auf der Grundlage eines oder mehrerer Kriterien zurück.

Die Syntax der MAXIFS-Funktion lautet wie folgt:

Wo:

• Max_Bereich (erforderlich) - der Bereich von Zellen, in dem Sie den Höchstwert finden möchten.
• Kriterium_Bereich1 (erforderlich) - der erste zu bewertende Bereich mit Kriterien1 .
• Kriterien1 - die für den ersten Bereich zu verwendende Bedingung, die durch eine Zahl, einen Text oder einen Ausdruck dargestellt werden kann.
• Kriterium_Bereich2 / Kriterien2 , ...(optional) - zusätzliche Bereiche und die dazugehörigen Kriterien. Es werden bis zu 126 Paare von Bereichen/Kriterien unterstützt.

Diese MAXIFS-Funktion ist in Excel 2019, Excel 2021 und Excel für Microsoft 365 auf Windows und Mac verfügbar.

Angenommen, die Größe der Schüler befindet sich in den Zellen D2:D11 (max_range) und die Sportart in B2:B11 (criteria_range1), dann verwenden Sie das Wort "football" als criterion1, und Sie erhalten diese Formel:

=MAXIFS(D2:D11, B2:B11, "Fußball")

Um die Formel vielseitiger zu gestalten, können Sie den Zielsport in eine Zelle (z. B. G1) eingeben und den Zellverweis in die Kriterien1 Argument:

=MAXIFS(D2:D11, B2:B11, G1)

Anmerkung: Die max_range und kriterien_bereich Argumente müssen die gleiche Größe und Form haben, d.h. die gleiche Anzahl von Zeilen und Spalten enthalten, ansonsten wird der Fehler #VALUE! zurückgegeben.

Verwendung der Funktion MAXIFS in Excel - Formelbeispiele

Wie Sie soeben gesehen haben, ist Excel MAXIFS recht unkompliziert und einfach zu bedienen. Dennoch gibt es ein paar kleine Nuancen, die einen großen Unterschied machen. In den folgenden Beispielen werden wir versuchen, das Beste aus der bedingten Maximalformel in Excel herauszuholen.

Maximalwert auf der Grundlage mehrerer Kriterien finden

Im ersten Teil dieses Tutorials haben wir eine MAXIFS-Formel in ihrer einfachsten Form erstellt, um den Maximalwert auf der Grundlage einer Bedingung zu ermitteln. Jetzt werden wir dieses Beispiel weiterführen und zwei verschiedene Kriterien auswerten.

Angenommen, Sie wollen den größten Basketballspieler der Grundschule ermitteln. Dazu müssen Sie die folgenden Argumente definieren:

• Max_Bereich - einen Bereich von Zellen mit den Höhen D2:D11.
• Kriterium_Bereich1 - einen Bereich von Zellen, der Sportarten enthält - B2:B11.
• Kriterien1 - "Basketball", der in Zelle G1 eingegeben wird.
• Kriterium_Bereich2 - eine Reihe von Zellen, die den Schultyp definieren - C2:C11.
• Kriterien2 - "junior", die in Zelle G2 eingegeben wird.

Setzt man die Argumente zusammen, erhält man diese Formeln:

Mit "hart kodierten" Kriterien:

=MAXIFS(D2:D11, B2:B11, "Basketball", C2:C11, "Junior")

Mit Kriterien in vordefinierten Zellen:

=MAXIFS(D2:D11, B2:B11, G1, C2:C11, G2)

Bitte beachten Sie, dass die Funktion MAXIFS in Excel Groß- und Kleinschreibung wird nicht berücksichtigt Sie brauchen sich also keine Gedanken über die Groß- und Kleinschreibung in Ihren Kriterien zu machen.

Wenn Sie Ihre Formel auf mehrere Zellen anwenden wollen, müssen Sie alle Bereiche mit absoluten Zellbezügen sperren, etwa so:

=MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2)

Dadurch wird sichergestellt, dass die Formel korrekt in andere Zellen kopiert wird - die Kriterienverweise ändern sich je nach der relativen Position der Zelle, in die die Formel kopiert wird, während die Bereiche unverändert bleiben:

Als zusätzlichen Bonus zeige ich Ihnen eine schnelle Möglichkeit, einen Wert aus einer anderen Zelle zu extrahieren, der mit dem Maximalwert verknüpft ist. In unserem Fall wird das der Name der größten Person sein. Dazu verwenden wir die klassische INDEX MATCH-Formel und verschachteln MAXIFS im ersten Argument von MATCH als Nachschlagewert:

=INDEX($A$2:$A$11, MATCH(MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2), $D$2:$D$11, 0))

Die Formel besagt, dass der Name des größten Basketballspielers der Grundschule Liam ist:

Excel MAXIFS mit logischen Operatoren

In Situationen, in denen Sie numerische Kriterien auswerten müssen, verwenden Sie logische Operatoren wie z. B:

• größer als (>)
• weniger als (<)
• größer als oder gleich (>=)
• kleiner als oder gleich (<=)
• nicht gleich ()

Der Operator "gleich" (=) kann in den meisten Fällen weggelassen werden.

Normalerweise ist die Auswahl eines Operators kein Problem, das Schwierigste ist, Kriterien mit der richtigen Syntax zu erstellen:

• Ein logischer Operator, auf den eine Zahl oder ein Text folgt, muss in doppelte Anführungszeichen gesetzt werden, z. B. ">=14" oder "running".
• Im Falle eines Zellbezugs oder einer anderen Funktion verwenden Sie die Anführungszeichen, um eine Zeichenkette zu beginnen, und ein kaufmännisches Und, um den Bezug zu verketten und die Zeichenkette abzuschließen, z. B. ">"&B1 oder "<"&TODAY().

Um zu sehen, wie es in der Praxis funktioniert, fügen wir die Spalte Alter (Spalte C) zu unserer Beispieltabelle hinzu und finden die maximale Körpergröße der Jungen im Alter zwischen 13 und 14 Jahren anhand der folgenden Kriterien:

Kriterium1: ">=13"

Kriterium2: "<=14"

Da wir die Zahlen in derselben Spalte vergleichen, ist criteria_range in beiden Fällen derselbe (C2:C11):

=MAXIFS(D2:D11, C2:C11, ">=13", C2:C11, "<=14")

Wenn Sie die Kriterien nicht fest in die Formel einfügen möchten, geben Sie sie in separate Zellen ein (z. B. G1 und H1) und verwenden Sie die folgende Syntax:

=MAXIFS(D2:D11, C2:C11, ">="&G1, C2:C11, "<="&H1)

Der folgende Screenshot zeigt das Ergebnis:

Neben Zahlen können logische Operatoren auch mit Textkriterien arbeiten. Insbesondere der Operator "ungleich" ist nützlich, wenn Sie etwas von Ihren Berechnungen ausschließen möchten. Um beispielsweise den größten Schüler in allen Sportarten außer Volleyball zu ermitteln, verwenden Sie die folgende Formel:

=MAXIFS(D2:D11, B2:B11, "Volleyball")

Oder dieses, bei dem G1 die ausgeschlossene Sportart ist:

=MAXIFS(D2:D11, B2:B11, ""&G1)

MAXIFS-Formeln mit Wildcard-Zeichen (teilweise Übereinstimmung)

Um eine Bedingung auszuwerten, die einen bestimmten Text oder ein bestimmtes Zeichen enthält, fügen Sie eines der folgenden Platzhalterzeichen in Ihre Kriterien ein:

• Fragezeichen (?) für die Übereinstimmung mit einem beliebigen einzelnen Zeichen.
• Sternchen (*) für eine beliebige Folge von Zeichen.

Da die Namen aller Sportarten in unserem Datensatz mit dem Wort "Ball" enden, nehmen wir dieses Wort in die Kriterien auf und verwenden ein Sternchen, um alle vorherigen Zeichen abzugleichen:

=MAXIFS(D2:D11, B2:B11, "*Ball")

Sie können auch "ball" in eine Zelle eingeben, z. B. G1, und das Platzhalterzeichen mit dem Zellverweis verketten:

=MAXIFS(D2:D11, B2:B11, "*"&G1)

Das Ergebnis wird wie folgt aussehen:

Maximalwert innerhalb eines Datumsbereichs abrufen

Da Datumsangaben im internen Excel-System als fortlaufende Nummern gespeichert werden, arbeiten Sie mit den Datumskriterien auf dieselbe Weise wie mit Zahlen.

Um dies zu veranschaulichen, ersetzen wir die Alter Spalte mit Geburtsdatum und versuchen, die maximale Größe der in einem bestimmten Jahr, z. B. 2004, geborenen Jungen zu ermitteln. Um diese Aufgabe zu erfüllen, müssen wir die Geburtsdaten filtern, die größer oder gleich dem 1. Januar 2004 und kleiner oder gleich dem 31. Dezember 2004 sind.

Bei der Erstellung Ihrer Kriterien ist es wichtig, dass Sie die Daten in einem Format angeben, das Excel versteht:

=MAXIFS(D2:D11, C2:C11, ">=1-Jan-2004", C2:C11, "<=31-Dez-2004")

Oder

=MAXIFS(D2:D11, C2:C11, ">=1/1/2004", C2:C11, "<=12/31/2004")

Um Fehlinterpretationen zu vermeiden, ist es sinnvoll, die Funktion DATE zu verwenden:

=MAXIFS(D2:D11, C2:C11, ">="&DATE(2004,1,1), C2:C11, "<="&DATE(2004,12,31))

In diesem Beispiel geben wir das Zieljahr in G1 ein und verwenden dann die Funktion DATE, um die Daten einzugeben:

=MAXIFS(D2:D11, C2:C11, ">="&DATE(G1,1,1), C2:C11, "<="&DATE(G1,12,31))

Hinweis: Im Gegensatz zu Zahlen sollten Datumsangaben in Anführungszeichen gesetzt werden, wenn sie allein in den Kriterien verwendet werden, z. B:

=MAXIFS(D2:D11, C2:C11, "10/5/2005")

Maximalwert auf der Grundlage mehrerer Kriterien mit OR-Logik finden

Die Excel-Funktion MAXIFS ist so konzipiert, dass sie die Bedingungen mit der UND-Logik prüft - d.h. sie verarbeitet nur die Zahlen in max_range In manchen Situationen kann es jedoch erforderlich sein, die Bedingungen mit der ODER-Logik auszuwerten, d. h. alle Zahlen zu verarbeiten, für die eines der angegebenen Kriterien WAHR ist.

Um das Verständnis zu erleichtern, betrachten Sie bitte das folgende Beispiel: Angenommen, Sie möchten die maximale Größe der Jungs finden, die entweder Basketball oder Fußball spielen. Wie würden Sie das tun? Die Verwendung von "Basketball" als Kriterium1 und als "Fußball" als Kriterium2 würde nicht funktionieren, da Excel davon ausgehen würde, dass beide Kriterien als WAHR ausgewertet werden sollten.

Die Lösung besteht darin, 2 separate MAXIFS-Formeln zu erstellen, eine für jede Sportart, und dann die gute alte MAX-Funktion zu verwenden, um eine höhere Zahl zu erhalten:

=MAX(MAXIFS(C2:C11, B2:B11, "Basketball"), MAXIFS(C2:C11, B2:B11, "Fußball"))

Der folgende Screenshot zeigt diese Formel, allerdings mit den Kriterien in den vordefinierten Eingabezellen F1 und H1:

Eine andere Möglichkeit ist die Verwendung einer MAX-IF-Formel mit ODER-Logik.

7 Dinge, die Sie über Excel MAXIFS wissen sollten

Im Folgenden finden Sie einige Anmerkungen, die Ihnen helfen werden, Ihre Formeln zu verbessern und häufige Fehler zu vermeiden. Einige dieser Beobachtungen wurden bereits als Tipps und Hinweise in unseren Beispielen besprochen, aber es könnte hilfreich sein, eine kurze Zusammenfassung dessen zu erhalten, was Sie bereits gelernt haben:

1. Die Funktion MAXIFS in Excel kann den höchsten Wert ermitteln, der auf eine oder mehrere Kriterien .
2. Standardmäßig arbeitet Excel MAXIFS mit dem UND-Logik , d. h. es wird die maximale Anzahl zurückgegeben, die alle angegebenen Bedingungen erfüllt.
3. Damit die Funktion funktioniert, müssen der maximale Bereich und die Kriterienbereiche die gleiche Größe und Form .
4. Die Funktion SUMIF lautet Groß- und Kleinschreibung wird nicht berücksichtigt , d.h. es erkennt die Groß- und Kleinschreibung in Textkriterien nicht.
5. Wenn Sie eine MAXIFS-Formel für mehrere Zellen schreiben, denken Sie daran, dass Sie die Bereiche sperren mit absoluten Zellbezügen, damit die Formel korrekt kopiert werden kann.
6. Beachten Sie die die Syntax Ihrer Kriterien Hier sind die wichtigsten Regeln:
   • Wenn sie allein verwendet werden, sollten Text und Daten in Anführungszeichen gesetzt werden, Zahlen und Zellbezüge jedoch nicht.
   • Wenn eine Zahl, ein Datum oder ein Text mit einem logischen Operator verwendet wird, muss der gesamte Ausdruck in doppelte Anführungszeichen eingeschlossen werden, z. B. ">=10"; Zellbezüge und andere Funktionen müssen durch ein kaufmännisches Und verkettet werden, z. B. ">"&G1.
7. MAXIFS ist nur in Excel 2019 und Excel für Office 365 verfügbar. In früheren Versionen ist diese Funktion nicht verfügbar.

So finden Sie den Maximalwert in Excel mit Bedingungen. Ich danke Ihnen für die Lektüre und hoffe, Sie bald in unserem Blog begrüßen zu dürfen!

Arbeitsbuch für die Praxis herunterladen:

Excel MAXIFS Formel Beispiele (.xlsx Datei)