Γνωρίζετε πώς να αθροίζετε αριθμούς σε μια συγκεκριμένη στήλη όταν μια τιμή σε μια άλλη στήλη πληροί οποιαδήποτε από τις καθορισμένες συνθήκες; Σε αυτό το άρθρο, θα μάθετε 3 διαφορετικούς τρόπους για να κάνετε SUMIF χρησιμοποιώντας πολλαπλά κριτήρια και λογική OR.

Το Microsoft Excel διαθέτει μια ειδική συνάρτηση για την άθροιση κελιών με πολλαπλές συνθήκες - τη συνάρτηση SUMIFS. Η συνάρτηση αυτή έχει σχεδιαστεί για να λειτουργεί με τη λογική AND - ένα κελί προστίθεται μόνο όταν όλα τα καθορισμένα κριτήρια είναι TRUE για το συγκεκριμένο κελί. Σε ορισμένες περιπτώσεις, ωστόσο, μπορεί να χρειαστεί να αθροίσετε με πολλαπλά κριτήρια OR, δηλαδή να προσθέσετε ένα κελί όταν οποιαδήποτε από τις συνθήκες είναι TRUE. Και τότε είναι που η συνάρτηση SUMIFείναι χρήσιμη.

SUMIF + SUMIF για να αθροίσετε τα κελιά που είναι ίσα με αυτό ή εκείνο

Όταν θέλετε να αθροίσετε αριθμούς σε μια στήλη όταν μια άλλη στήλη είναι ίση με το Α ή το Β, η πιο προφανής λύση είναι να χειριστείτε κάθε συνθήκη ξεχωριστά και στη συνέχεια να αθροίσετε τα αποτελέσματα:

Στον παρακάτω πίνακα, ας υποθέσουμε ότι θέλετε να αθροίσετε τις πωλήσεις για δύο διαφορετικά προϊόντα, ας πούμε Μήλα και Λεμόνια Για το σκοπό αυτό, μπορείτε να παρέχετε τα στοιχεία που σας ενδιαφέρουν απευθείας στο πεδίο κριτήρια ορίσματα 2 διαφορετικών συναρτήσεων SUMIF:

=SUMIF(A2:A10, "μήλα", B2:B10) + SUMIF(A2:A10, "λεμόνια", B2:B10)

Ή μπορείτε να καταχωρίσετε τα κριτήρια σε ξεχωριστά κελιά και να ανατρέξετε σε αυτά τα κελιά:

=SUMIF(A2:A10, E1, B2:B10) + SUMIF(A2:A10, E2, B2:B10)

Όπου A2:A10 είναι ο κατάλογος των στοιχείων ( εύρος ), B2:B10 είναι οι αριθμοί προς άθροιση ( sum_rage ), E1 και E2 είναι τα αντικείμενα-στόχοι ( κριτήρια ):

Πώς λειτουργεί αυτή η φόρμουλα:

Η πρώτη συνάρτηση SUMIF προσθέτει τα Μήλα πωλήσεις, η δεύτερη SUMIF αθροίζει τις Λεμόνια Η πράξη πρόσθεσης προσθέτει τα επιμέρους σύνολα και εξάγει το σύνολο.

SUMIF με σταθερά πίνακα - συμπαγής τύπος με πολλαπλά κριτήρια

Η προσέγγιση SUMIF + SUMIF λειτουργεί μια χαρά για 2 συνθήκες. Εάν πρέπει να αθροίσετε με 3 ή περισσότερα κριτήρια, ο τύπος θα γίνει πολύ μεγάλος και δύσκολα αναγνώσιμος. Για να επιτύχετε το ίδιο αποτέλεσμα με έναν πιο συμπαγή τύπο, παρέχετε τα κριτήριά σας σε μια σταθερά πίνακα:

Να θυμάστε ότι αυτός ο τύπος λειτουργεί με βάση τη λογική Ή - ένα κελί αθροίζεται όταν πληρούται οποιαδήποτε μεμονωμένη συνθήκη.

Στην περίπτωσή μας, για να αθροίσουμε τις πωλήσεις για 3 διαφορετικά είδη, ο τύπος είναι:

=SUM(SUMIF(A2:A10, {"Μήλα", "Λεμόνια", "Πορτοκάλια"}, B2:B10))

Στο παραπάνω στιγμιότυπο οθόνης, οι συνθήκες είναι κωδικοποιημένες σε έναν πίνακα, πράγμα που σημαίνει ότι θα πρέπει να ενημερώνετε τον τύπο με κάθε αλλαγή στα κριτήρια. Για να το αποφύγετε αυτό, μπορείτε να εισάγετε τα κριτήρια σε προκαθορισμένα κελιά και να τα παρέχετε σε έναν τύπο ως αναφορά περιοχής (E1:E3 σε αυτό το παράδειγμα).

=SUM(SUMIF(A2:A10, E1:E3, B2:B10))

Στο Excel 365 που υποστηρίζει δυναμικούς πίνακες, λειτουργεί ως κανονικός τύπος που ολοκληρώνεται με το πλήκτρο Enter. Στις προ-δυναμικές εκδόσεις του Excel 2019, του Excel 2016, του Excel 2013 και σε προγενέστερες εκδόσεις, θα πρέπει να εισάγεται ως τύπος πίνακα με τη συντόμευση Ctrl + Shift + Enter:

Πώς λειτουργεί αυτή η φόρμουλα:

Μια σταθερά πίνακα που εισάγεται στα κριτήρια του SUMIF το αναγκάζει να επιστρέφει πολλαπλά αποτελέσματα με τη μορφή πίνακα. Στην περίπτωσή μας, πρόκειται για 3 διαφορετικά ποσά: για Μήλα , Λεμόνια και Πορτοκάλια :

{425;425;565}

Για να βγάλουμε το σύνολο, χρησιμοποιούμε τη συνάρτηση SUM και την τυλίγουμε γύρω από τον τύπο SUMIF.

SUMPRODUCT και SUMIF για άθροιση κελιών με πολλαπλές συνθήκες OR

Δεν σας αρέσουν οι πίνακες και αναζητάτε έναν κανονικό τύπο που θα σας επιτρέπει να αθροίζετε με πολλαπλά κριτήρια σε διαφορετικά κελιά; Κανένα πρόβλημα. Αντί της SUM, χρησιμοποιήστε τη συνάρτηση SUMPRODUCT που χειρίζεται εγγενώς τους πίνακες:

SUMPRODUCT(SUMIF(range, crireria_range , sum_range))

Υποθέτοντας ότι οι συνθήκες βρίσκονται στα κελιά E1, E2 και E3, ο τύπος παίρνει την εξής μορφή:

=SUMPRODUCT(SUMIF(A2:A10, E1:E3, B2:B10))

Πώς λειτουργεί αυτή η φόρμουλα:

Όπως και στο προηγούμενο παράδειγμα, η συνάρτηση SUMIF επιστρέφει έναν πίνακα αριθμών, που αντιπροσωπεύει τα αθροίσματα για κάθε μεμονωμένη συνθήκη. Η SUMPRODUCT προσθέτει αυτούς τους αριθμούς και εξάγει ένα τελικό άθροισμα. Σε αντίθεση με τη συνάρτηση SUM, η SUMPRODUCT έχει σχεδιαστεί για να επεξεργάζεται πίνακες, οπότε λειτουργεί ως κανονικός τύπος χωρίς να χρειάζεται να πατήσετε Ctrl + Shift + Enter .

SUMIF με χρήση πολλαπλών κριτηρίων με μπαλαντέρ

Δεδομένου ότι η συνάρτηση SUMIF του Excel υποστηρίζει μπαλαντέρ, μπορείτε να τα συμπεριλάβετε σε πολλαπλά κριτήρια, εάν χρειάζεται.

Για παράδειγμα, για να αθροίσετε τις πωλήσεις για όλα τα είδη Μήλα και Μπανάνες , ο τύπος είναι:

=SUM(SUMIF(A2:A10, {"*Apples", "*Bananas"}, B2:B10))

Εάν οι συνθήκες σας πρέπει να εισάγονται σε μεμονωμένα κελιά, μπορείτε να πληκτρολογήσετε μπαλαντέρ απευθείας σε αυτά τα κελιά και να δώσετε μια αναφορά εύρους ως κριτήριο για τον τύπο SUMPRODUCT SUMIF:

Σε αυτό το παράδειγμα, βάζουμε έναν χαρακτήρα μπαλαντέρ (*) πριν από τα ονόματα των στοιχείων για να ταιριάζει με οποιαδήποτε προηγούμενη ακολουθία χαρακτήρων, όπως Πράσινα μήλα και Μπανάνες Goldfinger Για να λάβετε ένα σύνολο για στοιχεία που περιέχουν συγκεκριμένο κείμενο οπουδήποτε σε ένα κελί, τοποθετήστε έναν αστερίσκο και στις δύο πλευρές, π.χ. "*apple*".

Αυτός είναι ο τρόπος χρήσης του SUMIF στο Excel με πολλαπλές συνθήκες. Σας ευχαριστώ για την ανάγνωση και ελπίζω να σας δω στο blog μας την επόμενη εβδομάδα!

Βιβλίο ασκήσεων για κατέβασμα

SUMIF πολλαπλά κριτήρια (.xlsx αρχείο)