El tutorial muestra cómo utilizar la función MAXIFS en Excel para obtener el valor máximo con condiciones.

Tradicionalmente, cuando alguna vez necesitabas encontrar el valor más alto con condiciones en Excel, tenías que construir tu propia fórmula MAX IF. Aunque no es un gran problema para los usuarios experimentados, eso puede presentar ciertas dificultades para los novatos porque, en primer lugar, debes recordar la sintaxis de la fórmula y, en segundo lugar, necesitas saber cómo trabajar con fórmulas de matrices. Por suerte, Microsoft ha introducido recientemente una nueva función de¡que nos permite hacer condicional max de una manera fácil!

Función MAXIFS de Excel

La función MAXIFS devuelve el mayor valor numérico del rango especificado en función de uno o varios criterios.

La sintaxis de la función MAXIFS es la siguiente:

Dónde:

• Rango_máx (obligatorio) - el rango de celdas donde desea encontrar el valor máximo.
• Criterios_rango1 (requerido) - el primer rango a evaluar con criterios1 .
• Criterios1 - la condición que se utilizará en el primer rango. Puede representarse mediante un número, un texto o una expresión.
• Criterios_rango2 / criterios2 ...(opcional) - rangos adicionales y sus criterios relacionados. Se admiten hasta 126 pares rango/criterio.

Esta función MAXIFS está disponible en Excel 2019, Excel 2021 y Excel para Microsoft 365 en Windows y Mac.

Como ejemplo, busquemos al jugador de fútbol más alto de nuestra escuela local. Suponiendo que las alturas de los estudiantes están en las celdas D2:D11 (rango_máximo) y los deportes están en B2:B11 (rango_criterios1), utilice la palabra "fútbol" como criterio1, y obtendrá esta fórmula:

=MAXIFS(D2:D11, B2:B11, "fútbol")

Para que la fórmula sea más versátil, puede introducir el deporte de destino en alguna celda (por ejemplo, G1) e incluir la referencia a la celda en el campo criterios1 argumento:

=MAXIFS(D2:D11, B2:B11, G1)

Nota. rango_máximo y rango_de_criterios deben tener el mismo tamaño y forma, es decir, contener el mismo número de filas y columnas, de lo contrario se devuelve el error #¡VALOR!

Cómo utilizar la función MAXIFS en Excel - ejemplos de fórmulas

Como acabas de ver, el MAXIFS de Excel es bastante sencillo y fácil de usar. Sin embargo, tiene algunos pequeños matices que marcan una gran diferencia. En los siguientes ejemplos, intentaremos sacar el máximo partido del max condicional en Excel.

Buscar el valor máximo en función de varios criterios

En la primera parte de este tutorial, creamos una fórmula MAXIFS en su forma más simple para obtener el valor máximo basado en una condición. Ahora, vamos a llevar ese ejemplo más allá y evaluar dos criterios diferentes.

Supongamos que quieres encontrar al jugador de baloncesto más alto del colegio. Para ello, define los siguientes argumentos:

• Rango_máx - un rango de celdas que contengan alturas - D2:D11.
• Criterios_rango1 - un rango de celdas que contenga deportes - B2:B11.
• Criterios1 - "baloncesto", que se introduce en la celda G1.
• Criterios_rango2 - un rango de celdas que definen el tipo de centro escolar - C2:C11.
• Criterios2 - "junior", que se introduce en la celda G2.

Uniendo los argumentos, obtenemos estas fórmulas:

Con criterios "codificados":

=MAXIFS(D2:D11, B2:B11, "baloncesto", C2:C11, "junior")

Con criterios en celdas predefinidas:

=MAXIFS(D2:D11, B2:B11, G1, C2:C11, G2)

Tenga en cuenta que la función MAXIFS en Excel es distingue entre mayúsculas y minúsculas por lo que no debe preocuparse por las mayúsculas y minúsculas en sus criterios.

En caso de que planees utilizar tu fórmula en múltiples celdas, asegúrate de bloquear todos los rangos con referencias absolutas de celda, de esta manera:

=MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2)

Esto garantizará que la fórmula se copie correctamente en otras celdas: las referencias de los criterios cambian en función de la posición relativa de la celda en la que se copia la fórmula, mientras que los rangos permanecen inalterados:

Como extra, te mostraré una forma rápida de extraer un valor de otra celda que esté asociado al valor máximo. En nuestro caso, será el nombre de la persona más alta. Para ello, utilizaremos la clásica fórmula INDEX MATCH y anidaremos MAXIFS en el primer argumento de MATCH como valor de búsqueda:

=INDEX($A$2:$A$11, MATCH(MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2), $D$2:$D$11, 0))

La fórmula nos dice que el nombre del jugador de baloncesto más alto del colegio es Liam:

Excel MAXIFS con operadores lógicos

En situaciones en las que necesite evaluar criterios numéricos, utilice operadores lógicos como:

• mayor que (>)
• menor que (<)
• mayor o igual que (>=)
• menor o igual que (<=)
• no igual a ()

El operador "igual a" (=) puede omitirse en la mayoría de los casos.

Por lo general, elegir un operador no es un problema, lo más complicado es construir criterios con la sintaxis correcta. He aquí cómo:

• Un operador lógico seguido de un número o texto debe ir entre comillas dobles, como ">=14" o "running".
• En el caso de una referencia de celda u otra función, utilice las comillas para comenzar una cadena y un ampersand para concatenar la referencia y terminar la cadena, por ejemplo, ">"&B1 o "<"&HOY().

Para ver cómo funciona en la práctica, añadamos la columna Edad (columna C) a nuestra tabla de muestra y encontremos la altura máxima entre los chicos de 13 a 14 años. Esto puede hacerse con los siguientes criterios:

Criterio1: ">=13"

Criterio2: "<=14"

Como comparamos los números de la misma columna, rango_criterios en ambos casos es el mismo (C2:C11):

=MAXIFS(D2:D11, C2:C11, ">=13", C2:C11, "<=14")

Si no desea codificar los criterios en la fórmula, introdúzcalos en celdas separadas (por ejemplo, G1 y H1) y utilice la siguiente sintaxis:

=MAXIFS(D2:D11, C2:C11, ">="&G1, C2:C11, "<="&H1)

La siguiente captura de pantalla muestra el resultado:

Además de con números, los operadores lógicos también pueden funcionar con criterios de texto. En concreto, el operador "no igual a" resulta muy útil cuando se desea excluir algo de los cálculos. Por ejemplo, para hallar el alumno más alto en todos los deportes, excluyendo el voleibol, utilice la siguiente fórmula:

=MAXIFS(D2:D11, B2:B11, "voleibol")

O éste, donde G1 es el deporte excluido:

=MAXIFS(D2:D11, B2:B11, ""&G1)

Fórmulas MAXIFS con caracteres comodín (coincidencia parcial)

Para evaluar una condición que contenga un texto o carácter específico, incluya uno de los siguientes caracteres comodín en sus criterios:

• Signo de interrogación (?) para que coincida con cualquier carácter.
• Asterisco (*) para que coincida con cualquier secuencia de caracteres.

Para este ejemplo, vamos a averiguar el tipo más alto en deportes de juego. Como los nombres de todos los deportes de juego de nuestro conjunto de datos terminan con la palabra "pelota", incluimos esta palabra en los criterios y utilizamos un asterisco para que coincida con cualquier carácter anterior:

=MAXIFS(D2:D11, B2:B11, "*ball")

También puede escribir "bola" en alguna celda, por ejemplo G1, y concatenar el carácter comodín con la referencia de la celda:

=MAXIFS(D2:D11, B2:B11, "*"&G1)

El resultado será el siguiente:

Obtener el valor máximo dentro de un intervalo de fechas

Dado que las fechas se almacenan como números de serie en el sistema interno de Excel, se trabaja con los criterios de fechas de la misma manera que con los números.

Para ilustrarlo, sustituiremos el Edad columna con Fecha de nacimiento e intentamos calcular la altura máxima de los niños nacidos en un año determinado, por ejemplo en 2004. Para ello, tenemos que "filtrar" las fechas de nacimiento mayores o iguales que el 1 de enero de 2004 y menores o iguales que el 31 de diciembre de 2004.

Cuando construya sus criterios, es importante que proporcione las fechas en el formato que Excel pueda entender:

=MAXIFS(D2:D11, C2:C11, ">=1-Ene-2004", C2:C11, "<=31-Dic-2004")

O

=MAXIFS(D2:D11, C2:C11, ">=1/1/2004", C2:C11, "<=31/12/2004")

Para evitar interpretaciones erróneas, tiene sentido utilizar la función DATE:

=MAXIFS(D2:D11, C2:C11, ">="&DATE(2004,1,1), C2:C11, "<="&DATE(2004,12,31))

Para este ejemplo, escribiremos el año objetivo en G1 y, a continuación, utilizaremos la función FECHA para suministrar las fechas:

=MAXIFS(D2:D11, C2:C11, ">="&DATE(G1,1,1), C2:C11, "<="&DATE(G1,12,31))

Nota. A diferencia de los números, las fechas deben ir entre comillas cuando se utilizan solas en los criterios. Por ejemplo:

=MAXIFS(D2:D11, C2:C11, "10/5/2005")

Encontrar el valor máximo basado en múltiples criterios con lógica OR

La función MAXIFS de Excel está diseñada para comprobar las condiciones con la lógica AND, es decir, procesa sólo aquellos números en rango_máximo En algunas situaciones, sin embargo, puede que necesite evaluar las condiciones con la lógica OR, es decir, procesar todos los números para los que alguno de los criterios especificados sea TRUE.

Para facilitar la comprensión, considere el siguiente ejemplo. Supongamos que desea encontrar la altura máxima de los chicos que juegan al baloncesto o al fútbol. ¿Cómo lo haría? Utilizar "baloncesto" como criterio1 y "fútbol" como criterio2 no funcionaría, porque Excel asumiría que ambos criterios deberían evaluarse como VERDADERO.

La solución es crear 2 fórmulas MAXIFS separadas, una para cada deporte, y utilizar la función MAX para obtener un número mayor:

=MAX(MAXIFS(C2:C11, B2:B11, "baloncesto"), MAXIFS(C2:C11, B2:B11, "fútbol"))

La siguiente captura de pantalla muestra esta fórmula pero con los criterios en celdas de entrada predefinidas, F1 y H1:

Otra forma es utilizar una fórmula MAX IF con lógica OR.

7 cosas que debe recordar sobre Excel MAXIFS

A continuación encontrará algunas observaciones que le ayudarán a mejorar sus fórmulas y evitar errores comunes. Algunas de estas observaciones ya se han tratado como consejos y notas en nuestros ejemplos, pero puede resultarle útil obtener un breve resumen de lo que ya ha aprendido:

1. La función MAXIFS de Excel puede obtener el valor más alto basándose en un o criterios múltiples .
2. Por defecto, Excel MAXIFS trabaja con la función Lógica AND es decir, devuelve el número máximo que cumple todas las condiciones especificadas.
3. Para que la función funcione, el rango máximo y los rangos de criterios deben tener el valor mismo tamaño y forma .
4. La función SUMIF es distingue entre mayúsculas y minúsculas es decir, no reconoce las mayúsculas y minúsculas en los criterios de texto.
5. Cuando escriba una fórmula MAXIFS para varias celdas, recuerde bloquear las gamas con referencias absolutas de celda para que la fórmula se copie correctamente.
6. Cuidado con sintaxis de sus criterios Estas son las reglas principales:
   • Cuando se utilizan solos, el texto y las fechas deben ir entre comillas, no así los números y las referencias a celdas.
   • Cuando se utiliza un número, una fecha o un texto con un operador lógico, toda la expresión debe ir entre comillas dobles como ">=10"; las referencias a celdas y otras funciones deben concatenarse utilizando un ampersand como ">"&G1.
7. MAXIFS solo está disponible en Excel 2019 y Excel para Office 365. En versiones anteriores, esta función no está disponible.

Así es como puedes encontrar el valor máximo en Excel con condiciones. Gracias por leer y ¡espero verte pronto por nuestro blog!

Descargar cuaderno de prácticas:

Ejemplos de fórmulas MAXIFS de Excel (archivo .xlsx)