Hướng dẫn chỉ ra cách sử dụng hàm MAXIFS trong Excel để nhận giá trị lớn nhất kèm theo điều kiện.

Thông thường, khi bạn cần tìm giá trị lớn nhất kèm theo điều kiện trong Excel, bạn phải xây dựng công thức MAX IF của riêng mình. Mặc dù không phải là vấn đề lớn đối với người dùng có kinh nghiệm, nhưng điều đó có thể gây ra một số khó khăn nhất định cho người mới vì trước tiên, bạn nên nhớ cú pháp của công thức và thứ hai, bạn cần biết cách làm việc với công thức mảng. May mắn thay, Microsoft gần đây đã giới thiệu một hàm mới cho phép chúng ta thực hiện giá trị tối đa có điều kiện một cách dễ dàng!

Hàm MAXIFS của Excel

Hàm MAXIFS trả về giá trị số lớn nhất trong phạm vi đã chỉ định dựa trên một hoặc nhiều tiêu chí.

Cú pháp của hàm MAXIFS như sau:

Ở đâu:

• Max_range (bắt buộc) - phạm vi ô mà bạn muốn tìm giá trị lớn nhất.
• Criteria_range1 (bắt buộc) - phạm vi phạm vi đầu tiên để đánh giá với tiêu chí1 .
• Criteria1 - điều kiện để sử dụng trên phạm vi đầu tiên. Nó có thể được biểu thị bằng một số, văn bản hoặc biểu thức.
• Criteria_range2 / criteria2 , …(tùy chọn) - phạm vi bổ sung và tiêu chí liên quan của chúng. Hỗ trợ tối đa 126 cặp phạm vi/tiêu chí.

Hàm MAXIFS này khả dụng trong Excel 2019, Excel 2021 vàExcel cho Microsoft 365 trên Windows và Mac.

Ví dụ: hãy tìm cầu thủ bóng đá cao nhất ở trường học địa phương của chúng ta. Giả sử chiều cao của học sinh nằm trong các ô D2:D11 (phạm vi tối đa) và các môn thể thao nằm trong B2:B11 (phạm vi_tiêu chí1), hãy sử dụng từ "bóng đá" làm tiêu chí1 và bạn sẽ nhận được công thức sau:

=MAXIFS(D2:D11, B2:B11, "football")

Để làm cho công thức trở nên linh hoạt hơn, bạn có thể nhập môn thể thao mục tiêu vào một số ô (ví dụ: G1) và bao gồm tham chiếu ô trong đối số criteria1 :

=MAXIFS(D2:D11, B2:B11, G1)

Lưu ý. Các đối số max_range và criteria_range phải có cùng kích thước và hình dạng, tức là chứa số lượng hàng và cột bằng nhau, nếu không thì lỗi #VALUE! lỗi được trả lại.

Cách sử dụng hàm MAXIFS trong Excel - ví dụ về công thức

Như bạn vừa thấy, hàm MAXIFS trong Excel khá đơn giản và dễ sử dụng. Tuy nhiên, nó có một vài sắc thái nhỏ tạo nên sự khác biệt lớn. Trong các ví dụ bên dưới, chúng tôi sẽ cố gắng tận dụng tối đa giá trị tối đa có điều kiện trong Excel.

Tìm giá trị tối đa dựa trên nhiều tiêu chí

Trong phần đầu tiên của hướng dẫn này, chúng tôi đã tạo công thức MAXIFS ở dạng đơn giản nhất để nhận giá trị tối đa dựa trên một điều kiện. Bây giờ, chúng ta sẽ tiếp tục lấy ví dụ đó và đánh giá hai tiêu chí khác nhau.

Giả sử bạn muốn tìm cầu thủ bóng rổ cao nhất ở trường trung học cơ sở. Để hoàn thành nó, hãy xác định như sauđối số:

• Max_range - dải ô chứa chiều cao - D2:D11.
• Criteria_range1 - dải ô chứa thể thao - B2:B11.
• Criteria1 - "bóng rổ", được nhập vào ô G1.
• Criteria_range2 - một dải ô xác định loại trường học - C2:C11.
• Criteria2 - "junior", là giá trị nhập vào trong ô G2.

Kết hợp các đối số lại với nhau, chúng tôi nhận được các công thức này :

Với tiêu chí "mã hóa cứng":

=MAXIFS(D2:D11, B2:B11, "basketball", C2:C11, "junior")

Với tiêu chí trong các ô được xác định trước:

=MAXIFS(D2:D11, B2:B11, G1, C2:C11, G2)

Xin lưu ý rằng MAXIFS hàm trong Excel phân biệt chữ hoa chữ thường , vì vậy bạn không cần lo lắng về chữ hoa chữ thường trong tiêu chí của mình.

Trong trường hợp bạn định sử dụng công thức trên nhiều ô, hãy đảm bảo khóa tất cả các phạm vi bằng tham chiếu ô tuyệt đối, như sau:

=MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2)

Điều này sẽ đảm bảo rằng công thức sao chép chính xác sang các ô khác - tham chiếu tiêu chí thay đổi dựa trên trên vị trí tương đối của ô nơi công thức được sao chép trong khi t phạm vi của anh ấy không thay đổi:

Ngoài ra, tôi sẽ chỉ cho bạn một cách nhanh chóng để trích xuất một giá trị từ một ô khác được liên kết với giá trị tối đa. Trong trường hợp của chúng tôi, đó sẽ là tên của người cao nhất. Đối với điều này, chúng tôi sẽ sử dụng công thức INDEX MATCH cổ điển và lồng MAXIFS vào đối số đầu tiên của MATCH làm giá trị tra cứu:

=INDEX($A$2:$A$11, MATCH(MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2), $D$2:$D$11, 0))

Công thức cho chúng tôi biết rằng têncầu thủ bóng rổ cao nhất ở trường trung học cơ sở là Liam:

Excel MAXIFS với các toán tử logic

Trong trường hợp bạn cần đánh giá các tiêu chí số, hãy sử dụng các toán tử logic chẳng hạn như:

• lớn hơn (>)
• nhỏ hơn (<)
• lớn hơn hoặc bằng (>=)
• nhỏ hơn hoặc bằng (<=)
• không bằng ()

Toán tử "bằng" (=) có thể được bỏ qua trong hầu hết các trường hợp.

Thông thường, chọn toán tử không thành vấn đề, khó nhất là xây dựng tiêu chí đúng cú pháp. Dưới đây là cách thực hiện:

• Một toán tử logic theo sau bởi một số hoặc văn bản phải được đặt trong dấu ngoặc kép như ">=14" hoặc "running".
• Trong trường hợp là một ô tham chiếu hoặc hàm khác, hãy sử dụng dấu ngoặc kép để bắt đầu một chuỗi và dấu và để nối tham chiếu và kết thúc chuỗi, ví dụ: ">"&B1 hoặc "<"&TODAY().

Để xem tính năng này hoạt động như thế nào trong thực tế, hãy thêm cột Tuổi (cột C) vào bảng mẫu của chúng ta và tìm chiều cao tối đa của các bé trai trong độ tuổi từ 13 đến 14. Điều này có thể được thực hiện với các tiêu chí sau:

Tiêu chí1: ">=13"

Tiêu chí2: "<=14"

Vì chúng ta so sánh các số trong cùng một cột, nên phạm vi tiêu chí trong cả hai trường hợp đều giống nhau (C2:C11):

=MAXIFS(D2:D11, C2:C11, ">=13", C2:C11, "<=14")

Nếu bạn không muốn mã hóa cứng tiêu chí trong công thức, hãy nhập chúng vào các ô riêng biệt (ví dụ: G1 và H1) và sử dụng thông tin saucú pháp:

=MAXIFS(D2:D11, C2:C11, ">="&G1, C2:C11, "<="&H1)

Ảnh chụp màn hình bên dưới hiển thị kết quả:

Ngoài số, toán tử logic cũng có thể hoạt động với tiêu chí văn bản. Đặc biệt, toán tử "không bằng" rất hữu ích khi bạn muốn loại trừ một số thứ khỏi tính toán của mình. Ví dụ: để tìm học sinh cao nhất trong tất cả các môn thể thao trừ bóng chuyền, hãy sử dụng công thức sau:

=MAXIFS(D2:D11, B2:B11, "volleyball")

Hoặc công thức này, trong đó G1 là môn thể thao bị loại:

=MAXIFS(D2:D11, B2:B11, ""&G1)

Công thức MAXIFS có ký tự đại diện (khớp một phần)

Để đánh giá một điều kiện chứa văn bản hoặc ký tự cụ thể, hãy đưa một trong các ký tự đại diện sau vào tiêu chí của bạn:

• Dấu chấm hỏi (?) để khớp với bất kỳ ký tự đơn nào.
• Dấu hoa thị (*) để khớp với bất kỳ chuỗi ký tự nào.

Dành cho ví dụ này, chúng ta hãy tìm ra anh chàng cao nhất trong trò chơi thể thao. Vì tên của tất cả các môn thể thao trò chơi trong tập dữ liệu của chúng tôi kết thúc bằng từ "bóng", nên chúng tôi đưa từ này vào tiêu chí và sử dụng dấu hoa thị để khớp với bất kỳ ký tự nào trước đó:

=MAXIFS(D2:D11, B2:B11, "*ball")

Bạn có thể cũng gõ "quả bóng" trong một số ô, ví dụ: G1 và nối ký tự đại diện với tham chiếu ô:

=MAXIFS(D2:D11, B2:B11, "*"&G1)

Kết quả sẽ như sau:

Nhận giá trị tối đa trong phạm vi ngày

Vì ngày được lưu trữ dưới dạng số sê-ri trong hệ thống Excel nội bộ nên bạn làm việc với tiêu chí ngày theo cách giống như cách bạn làm việc với số.

Đểminh họa điều này, chúng ta sẽ thay thế cột Tuổi bằng Ngày sinh và cố gắng tính chiều cao tối đa của các bé trai sinh vào một năm cụ thể, chẳng hạn như năm 2004. Để hoàn thành nhiệm vụ này , chúng ta cần "lọc" ngày sinh lớn hơn hoặc bằng ngày 1 tháng 1 năm 2004 và nhỏ hơn hoặc bằng ngày 31 tháng 12 năm 2004.

Khi xây dựng tiêu chí của mình, điều quan trọng là bạn phải cung cấp ngày ở định dạng mà Excel có thể hiểu:

=MAXIFS(D2:D11, C2:C11, ">=1-Jan-2004", C2:C11, "<=31-Dec-2004")

Hoặc

=MAXIFS(D2:D11, C2:C11, ">=1/1/2004", C2:C11, "<=12/31/2004")

Để tránh hiểu sai, bạn nên sử dụng hàm DATE :

=MAXIFS(D2:D11, C2:C11, ">="&DATE(2004,1,1), C2:C11, "<="&DATE(2004,12,31))

Đối với ví dụ này, chúng tôi sẽ nhập năm mục tiêu vào G1, sau đó sử dụng hàm DATE để cung cấp ngày:

=MAXIFS(D2:D11, C2:C11, ">="&DATE(G1,1,1), C2:C11, "<="&DATE(G1,12,31))

Lưu ý. Không giống như số, ngày phải được đặt trong dấu ngoặc kép khi được sử dụng riêng trong tiêu chí. Ví dụ:

=MAXIFS(D2:D11, C2:C11, "10/5/2005")

Tìm giá trị lớn nhất dựa trên nhiều tiêu chí với logic OR

Hàm MAXIFS trong Excel được thiết kế để kiểm tra các điều kiện với logic AND - tức là hàm này chỉ xử lý các số đó trong max_range mà tất cả tiêu chí là TRUE. Tuy nhiên, trong một số trường hợp, bạn có thể cần phải đánh giá các điều kiện bằng logic OR - tức là xử lý tất cả các số mà bất kỳ tiêu chí nào được chỉ định là TRUE.

Để dễ hiểu hơn, vui lòng xem xét những điều sau thí dụ. Giả sử bạn muốn tìm chiều cao cực đại của những người chơi bóng rổ hoặcbóng đá. Bạn làm điều đó như thế nào? Việc sử dụng "bóng rổ" làm tiêu chí 1 và tiêu chí 2 làm "bóng đá" sẽ không hiệu quả, vì Excel sẽ cho rằng cả hai tiêu chí đều phải đánh giá là TRUE.

Giải pháp là tạo 2 công thức MAXIFS riêng biệt, mỗi công thức cho mỗi môn thể thao, rồi sử dụng hàm MAX cũ để trả về số cao hơn:

=MAX(MAXIFS(C2:C11, B2:B11, "basketball"), MAXIFS(C2:C11, B2:B11, "football"))

Ảnh chụp màn hình bên dưới hiển thị công thức này nhưng với tiêu chí trong các ô nhập liệu được xác định trước, F1 và H1:

Một cách khác là sử dụng công thức MAX IF với logic OR.

7 điều cần nhớ về hàm MAXIFS trong Excel

Dưới đây, bạn sẽ tìm thấy một vài nhận xét điều đó sẽ giúp cải thiện công thức của bạn và tránh các lỗi phổ biến. Một số quan sát này đã được thảo luận dưới dạng các mẹo và ghi chú trong các ví dụ của chúng tôi, nhưng có thể hữu ích nếu bạn có một bản tóm tắt ngắn về những gì bạn đã học:

1. Hàm MAXIFS trong Excel có thể nhận giá trị cao nhất dựa trên một hoặc nhiều tiêu chí .
2. Theo mặc định, Excel MAXIFS hoạt động với logic AND , tức là trả về số tối đa đáp ứng tất cả các điều kiện đã chỉ định.
3. Để hàm hoạt động, phạm vi tiêu chí và phạm vi tối đa phải có cùng kích thước và hình dạng .
4. Hàm SUMIF không phân biệt chữ hoa chữ thường , tức là nó không nhận dạng chữ hoa chữ thường trong tiêu chí văn bản.
5. Khi viết công thức MAXIFS cho nhiều ô, hãy nhớ khóa phạm vi vớitham chiếu ô tuyệt đối để công thức sao chép chính xác.
6. Lưu ý cú pháp của tiêu chí của bạn ! Dưới đây là các quy tắc chính:
   • Khi được sử dụng riêng lẻ, văn bản và ngày tháng phải được đặt trong dấu ngoặc kép, số và tham chiếu ô thì không.
   • Khi sử dụng số, ngày tháng hoặc văn bản với toán tử logic, toàn bộ biểu thức phải được đặt trong dấu ngoặc kép như ">=10"; các tham chiếu ô và các hàm khác phải được nối bằng cách sử dụng dấu và như ">"&G1.
7. MAXIFS chỉ khả dụng trong Excel 2019 và Excel for Office 365. Trong các phiên bản cũ hơn, chức năng này không khả dụng.

Đó là cách bạn có thể tìm giá trị lớn nhất trong Excel có điều kiện. Tôi cảm ơn bạn đã đọc và hy vọng sớm gặp lại bạn trên blog của chúng tôi!

Tải xuống sách bài tập thực hành:

Các ví dụ về công thức MAXIFS trong Excel (tệp .xlsx)