Õpetus näitab, kuidas kasutada Excelis funktsiooni MAXIFS, et saada maksimaalne väärtus koos tingimustega.

Traditsiooniliselt, kui teil oli kunagi vaja leida Excelis tingimustega kõrgeimat väärtust, pidite koostama oma MAX IF valemi. Kuigi kogenud kasutajatele ei ole see suur probleem, võib see algajatele tekitada teatavaid raskusi, sest esiteks peaksite meeles pidama valemi süntaksit ja teiseks peate oskama töötada massiivi valemitega. Õnneks on Microsoft hiljuti kasutusele võtnud uuefunktsioon, mis võimaldab meil teha tingimuslike max lihtsal viisil!

Exceli MAXIFS funktsioon

Funktsioon MAXIFS tagastab ühe või mitme kriteeriumi alusel suurima arvväärtuse määratud vahemikus.

Funktsiooni MAXIFS süntaks on järgmine:

Kus:

• Max_range (nõutav) - lahtrite vahemik, kust soovite leida maksimaalse väärtuse.
• Criteria_range1 (nõutav) - esimene vahemik, mida tuleb hinnata koos kriteeriumid1 .
• Kriteeriumid1 - tingimus, mida kasutatakse esimese vahemiku puhul. Seda võib esitada numbri, teksti või väljendusena.
• Criteria_range2 / kriteeriumid2 , ...(valikuline) - täiendavad vahemikud ja nendega seotud kriteeriumid. Toetatakse kuni 126 vahemiku/kriteeriumi paari.

See MAXIFS-funktsioon on saadaval Excel 2019, Excel 2021 ja Excel for Microsoft 365 Windowsis ja Macis.

Leiame näiteks meie kohaliku kooli kõige pikema jalgpalluri. Eeldades, et õpilaste pikkused on lahtrites D2:D11 (max_range) ja spordiala on lahtrites B2:B11 (criteria_range1), kasutame kriteeriumina1 sõna "football", ja saame järgmise valemi:

=MAXIFS(D2:D11, B2:B11, "jalgpall")

Et valemit mitmekülgsemaks muuta, võite sisestada sihtspordi mõnda lahtrisse (näiteks G1) ja lisada lahtriviite lahtrisse kriteeriumid1 argument:

=MAXIFS(D2:D11, B2:B11, G1)

Märkus. max_range ja kriteeriumid_vahemik argumendid peavad olema ühesuurused ja -kujulised, st sisaldama võrdset arvu ridu ja veerge, vastasel juhul tagastatakse #VALUE! viga.

Kuidas kasutada MAXIFS funktsiooni Excelis - valemite näited

Nagu äsja nägite, on Exceli MAXIFS üsna lihtne ja hõlpsasti kasutatav. Siiski on sellel mõned väikesed nüansid, mis teevad suurt vahet. Järgnevates näidetes püüame Exceli tingimuslikku maxi maksimaalselt ära kasutada.

Leia maksimaalne väärtus mitme kriteeriumi alusel

Selle õpetuse esimeses osas lõime MAXIFS-valemi selle kõige lihtsamas vormis, et saada maksimaalne väärtus ühe tingimuse alusel. Nüüd võtame selle näite edasi ja hindame kahte erinevat kriteeriumi.

Oletame, et soovite leida kõige pikemat korvpallurit nooremas kooliastmes. Selleks defineerige järgmised argumendid:

• Max_range - kõrgusi sisaldavate lahtrite vahemik - D2:D11.
• Kriteeriumid_vahemik1 - spordialasid sisaldavate lahtrite vahemik - B2:B11.
• Kriteeriumid1 - "korvpall", mis sisestatakse lahtrisse G1.
• Criteria_range2 - koolitüüpi määratlev lahtrite vahemik - C2:C11.
• Kriteeriumid2 - "junior", mis sisestatakse lahtrisse G2.

Kui panna argumendid kokku, saame järgmised valemid:

"Kõvakooditud" kriteeriumidega:

=MAXIFS(D2:D11, B2:B11, "korvpall", C2:C11, "juunior")

Eelnevalt määratletud lahtrites olevate kriteeriumidega:

=MAXIFS(D2:D11, B2:B11, G1, C2:C11, G2)

Pange tähele, et Exceli funktsioon MAXIFS on suur- ja väiketähelepanuta , nii et te ei pea muretsema oma kriteeriumide kirjapõhisuse pärast.

Kui kavatsete kasutada oma valemit mitmes lahtris, lukustage kindlasti kõik vahemikud absoluutsete lahtriviidetega, näiteks nii:

=MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2)

See tagab, et valem kopeeritakse teistesse lahtritesse õigesti - kriteeriumide viited muutuvad vastavalt lahtri suhtelisele positsioonile, kuhu valem kopeeritakse, samas kui vahemikud jäävad muutumatuks:

Lisaboonusena näitan teile kiiret viisi, kuidas ekstraheerida väärtus teisest lahtrist, mis on seotud max väärtusega. Meie puhul on selleks kõige kõrgema inimese nimi. Selleks kasutame klassikalist INDEX MATCH valemit ja pesitseme MATCHi esimese argumendi MAXIFS otsinguväärtuseks:

=INDEX($A$2:$A$11, MATCH(MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2), $D$2:$D$11, 0))

Valem ütleb meile, et noorema kooli kõige pikema korvpalluri nimi on Liam:

Exceli MAXIFS loogiliste operaatoritega

Olukorras, kus on vaja hinnata numbrilisi kriteeriume, kasutage loogilisi operaatoreid, näiteks:

• suurem kui (>)
• väiksem kui (<)
• suurem või võrdne (>=)
• väiksem või võrdne (<=)
• ei ole võrdne ()

Operaatori "võrdne" (=) võib enamikul juhtudel ära jätta.

Tavaliselt ei ole operaatori valimine probleemiks, kõige keerulisem osa on õige süntaksiga kriteeriumide koostamine. Siin on, kuidas:

• Loogiline operaator, millele järgneb number või tekst, peab olema ümbritsetud kahekordsete jutumärkidega, näiteks ">=14" või "running".
• Kui tegemist on lahtriviidetega või mõne muu funktsiooniga, kasutage jutumärke stringi alustamiseks ja amperandit viite ühendamiseks ja stringi lõpetamiseks, nt ">"&B1 või "<"&TODAY().

Et näha, kuidas see praktikas toimib, lisame meie näidistabelisse vanuse veeru (veerg C) ja leiame maksimaalse pikkuse 13-14-aastaste poiste seas. Seda saab teha järgmiste kriteeriumide abil:

Kriteerium1: ">=13"

Kriteerium2: "<=14"

Kuna me võrdleme numbreid samas veerus, on kriteeriumide vahemik mõlemal juhul sama (C2:C11):

=MAXIFS(D2:D11, C2:C11, ">=13", C2:C11, "<=14")

Kui te ei soovi kriteeriume valemisse sisestada, sisestage need eraldi lahtritesse (nt G1 ja H1) ja kasutage järgmist süntaksit:

=MAXIFS(D2:D11, C2:C11, ">="&G1, C2:C11, "<="&H1)

Tulemus on näha alloleval ekraanipildil:

Lisaks numbritele saavad loogilised operaatorid töötada ka tekstikriteeriumidega. Eelkõige tuleb operaator "ei ole võrdne" kasuks, kui soovite midagi arvutustest välja jätta. Näiteks, et leida kõige pikem õpilane kõigil spordialadel, välja arvatud võrkpall, kasutage järgmist valemit:

=MAXIFS(D2:D11, B2:B11, "võrkpall")

Või see, kus G1 on välistatud spordiala:

=MAXIFS(D2:D11, B2:B11, ""&G1)

MAXIFSi valemid koos jokerkaardimärkidega (osaline kokkulangevus)

Konkreetset teksti või märki sisaldava tingimuse hindamiseks lisage oma kriteeriumidesse üks järgmistest jokkeritest:

• Küsimärk (?), mis vastab mis tahes üksikule tähemärgile.
• tärn (*), et sobitada mis tahes tähemärkide jada.

Selle näite puhul otsime välja kõige pikema mehe mänguspordis. Kuna meie andmestikus olevate kõikide mänguspordialade nimed lõpevad sõnaga "pall", lisame selle sõna kriteeriumidesse ja kasutame tärni, et sobitada kõik eelnevad tähed:

=MAXIFS(D2:D11, B2:B11, "*ball")

Võite ka kirjutada "pall" mõnda lahtrisse, nt G1, ja liita metsiku sümboliga lahtri viide:

=MAXIFS(D2:D11, B2:B11, "*"&G1)

Tulemus näeb välja järgmiselt:

Saada maksimaalne väärtus kuupäeva vahemikus

Kuna kuupäevad salvestatakse Exceli sisesüsteemis seerianumbritena, töötate kuupäevade kriteeriumidega samamoodi nagu numbritega.

Selle illustreerimiseks asendame Vanus veerg koos Sünniaeg ja püüame välja töötada maksimaalse pikkuse teataval aastal, näiteks 2004. aastal sündinud poiste seas. Selle ülesande täitmiseks peame "filtreerima" sünnikuupäevad, mis on suuremad või võrdsed 1-Jan-2004 ja väiksemad või võrdsed 31-Dets-2004.

Kriteeriumide koostamisel on oluline, et esitate kuupäevad Excelile arusaadavas vormingus:

=MAXIFS(D2:D11, C2:C11, ">=1-Jan-2004", C2:C11, "<=31-Dets-2004")

Või

=MAXIFS(D2:D11, C2:C11, ">=1/1/2004", C2:C11, "<=12/31/2004")

Vääritõlgenduste vältimiseks on mõistlik kasutada funktsiooni DATE:

=MAXIFS(D2:D11, C2:C11, ">="&DATE(2004,1,1), C2:C11, "<="&DATE(2004,12,31))

Selle näite puhul kirjutame G1-sse sihtaasta ja seejärel kasutame kuupäevade sisestamiseks funktsiooni DATE:

=MAXIFS(D2:D11, C2:C11, ">="&DATE(G1,1,1), C2:C11, "<="&DATE(G1,12,31))

Märkus. Erinevalt numbritest tuleb kuupäevad, kui neid kasutatakse kriteeriumides eraldi, sulgeda jutumärkidesse. Näiteks:

=MAXIFS(D2:D11, C2:C11, "10/5/2005")

Leia maksimaalne väärtus mitme kriteeriumi alusel OR-loogikaga

Exceli funktsioon MAXIFS on mõeldud tingimuste testimiseks AND-loogikaga - st ta töötleb ainult neid numbreid, mis on esitatud dokumendis max_range mille puhul kõik kriteeriumid on TRUE. Mõnes olukorras võib aga olla vaja tingimusi hinnata VÕI-loogikaga - st töödelda kõiki numbreid, mille puhul mõni määratud kriteeriumidest on TRUE.

Et asi oleks arusaadavam, vaadake järgmist näidet. Oletame, et soovite leida maksimaalse pikkuse nende poiste kohta, kes mängivad kas korvpalli või jalgpalli. Kuidas te seda teeksite? "Korvpalli" kasutamine kriteeriumina1 ja "jalgpalli" kriteeriumina2 ei tööta, sest Excel eeldaks, et mõlemad kriteeriumid peaksid hindama TRUE.

Lahendus on teha 2 eraldi MAXIFS-vormelit, üks iga spordiala kohta, ja seejärel kasutada vana head MAX-funktsiooni suurema arvu tagastamiseks:

=MAX(MAXIFS(C2:C11, B2:B11, "korvpall"), MAXIFS(C2:C11, B2:B11, "jalgpall"))

Allpool olev ekraanipilt näitab seda valemit, kuid kriteeriumid on esitatud eelnevalt määratletud sisendruutudes F1 ja H1:

Teine võimalus on kasutada MAX IF valemit OR loogikaga.

7 asja, mida Exceli MAXIFSi kohta meeles pidada

Allpool leiate mõned märkused, mis aitavad parandada teie valemeid ja vältida tavalisi vigu. Mõningaid neist tähelepanekutest on juba meie näidetes näpunäidete ja märkustena käsitletud, kuid võib olla kasulik saada lühike kokkuvõte sellest, mida olete juba õppinud:

1. Exceli funktsioon MAXIFS võib saada kõrgeima väärtuse, mis põhineb üks või mitu kriteeriumi .
2. Vaikimisi töötab Excel MAXIFS koos järgmisega AND loogika , st tagastab maksimaalse arvu, mis vastab kõigile määratud tingimustele.
3. Et funktsioon toimiks, peavad max vahemik ja kriteeriumide vahemikud olema väärtusega sama suurus ja kuju .
4. Funktsioon SUMIF on suur- ja väiketähelepanuta , st see ei tunnista teksti kriteeriumide puhul tähtede suurust.
5. Kui kirjutate MAXIFS valemit mitme lahtri jaoks, pidage meeles, et lukustada vahemikud absoluutsete lahtriviidetega, et valemit saaks õigesti kopeerida.
6. Meeles teie kriteeriumide süntaks ! Siin on peamised reeglid:
   • Kui teksti ja kuupäevi kasutatakse iseseisvalt, tuleb need sulgeda jutumärkidesse, numbreid ja lahtriviiteid aga mitte.
   • Kui numbrit, kuupäeva või teksti kasutatakse koos loogilise operaatoriga, tuleb kogu väljendus sulgeda topeltkriipsu sisse, näiteks ">=10"; lahtriviited ja muud funktsioonid tuleb liita kokku, kasutades amperandit, näiteks ">"&G1.
7. MAXIFS on saadaval ainult Excel 2019 ja Excel for Office 365. Varasemates versioonides ei ole see funktsioon saadaval.

Nii saab Excelis tingimuste abil leida maksimaalse väärtuse. Tänan teid lugemise eest ja loodan, et näeme teid varsti meie blogis!

Lae alla praktiline töövihik:

Exceli MAXIFS valemite näited (.xlsx fail)