Udžbenik pokazuje kako koristiti funkciju MAXIFS u Excelu da biste dobili maksimalnu vrijednost s uvjetima.

Tradicionalno, kada ste ikad trebali pronaći najveću vrijednost s uvjetima u Excelu, morali ste izgraditi vlastitu MAX IF formulu. Iako nije velika stvar za iskusne korisnike, to bi moglo predstavljati određene poteškoće za početnike jer, prvo, trebali biste zapamtiti sintaksu formule i, drugo, morate znati kako raditi s formulama polja. Srećom, Microsoft je nedavno predstavio novu funkciju koja nam omogućuje da na jednostavan način napravimo uvjetni max!

Funkcija Excel MAXIFS

Funkcija MAXIFS vraća najveću numeričku vrijednost u navedeni raspon na temelju jednog ili više kriterija.

Sintaksa funkcije MAXIFS je sljedeća:

Gdje je:

• Max_range (obavezno) - raspon ćelija u kojima želite pronaći maksimalnu vrijednost.
• Criteria_range1 (obavezno) - prvi raspon za procjenu s criteria1 .
• Criteria1 - uvjet za korištenje na prvom rasponu. Može se predstaviti brojem, tekstom ili izrazom.
• Raspon_kriterija2 / kriterij2 , …(neobavezno) - dodatni rasponi i njima povezani kriteriji. Podržano je do 126 parova raspona/kriterija.

Ova funkcija MAXIFS dostupna je u Excelu 2019, Excelu 2021 iExcel za Microsoft 365 na Windows i Macu.

Kao primjer, hajdemo pronaći najvišeg nogometaša u našoj lokalnoj školi. Pod pretpostavkom da su visine učenika u ćelijama D2:D11 (max_range), a sportovi u B2:B11 (criteria_range1), upotrijebite riječ "nogomet" kao kriterij1 i dobit ćete ovu formulu:

=MAXIFS(D2:D11, B2:B11, "football")

Kako biste formulu učinili svestranijom, možete unijeti ciljani sport u neku ćeliju (recimo, G1) i uključiti referencu ćelije u argument kriterija1 :

=MAXIFS(D2:D11, B2:B11, G1)

Napomena. Argumenti max_range i criteria_range moraju biti iste veličine i oblika, tj. sadržavati jednak broj redaka i stupaca, inače #VALUE! vraća se pogreška.

Kako koristiti funkciju MAXIFS u Excelu - primjeri formula

Kao što ste upravo vidjeli, Excel MAXIFS prilično je jednostavan i jednostavan za korištenje. Međutim, ima nekoliko malih nijansi koje čine veliku razliku. U primjerima u nastavku pokušat ćemo maksimalno iskoristiti uvjetni maksimum u Excelu.

Pronađite maksimalnu vrijednost na temelju više kriterija

U prvom dijelu ovog vodiča stvorili smo MAXIFS formulu u svom najjednostavnijem obliku da biste dobili najveću vrijednost na temelju jednog uvjeta. Sada ćemo taj primjer uzeti dalje i procijeniti dva različita kriterija.

Pretpostavimo da želite pronaći najvišeg košarkaša u juniorskoj školi. Da biste to učinili, definirajte sljedećeargumenti:

• Max_range - raspon ćelija koje sadrže visine - D2:D11.
• Criteria_range1 - raspon ćelija koje sadrže sportove - B2:B11.
• Criteria1 - "košarkaška lopta", koja je unesena u ćeliju G1.
• Criteria_range2 - raspon ćelija koje definiraju tip škole - C2:C11.
• Kriterij2 - "junior", koji je unesen u ćeliju G2.

Spajanjem argumenata, dobivamo ove formule :

S "tvrdo kodiranim" kriterijima:

=MAXIFS(D2:D11, B2:B11, "basketball", C2:C11, "junior")

S kriterijima u unaprijed definiranim ćelijama:

=MAXIFS(D2:D11, B2:B11, G1, C2:C11, G2)

Molimo primijetite da MAXIFS funkcija u Excelu je neosjetljiva na velika i mala slova , tako da ne morate brinuti o velikim slovima u vašim kriterijima.

U slučaju da planirate koristiti svoj formulu na više ćelija, svakako zaključajte sve raspone s apsolutnim referencama ćelije, ovako:

=MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2)

Ovo će osigurati da se formula ispravno kopira u druge ćelije - reference kriterija mijenjaju se na temelju o relativnom položaju ćelije u koju se kopira formula dok t Rasponi ostaju nepromijenjeni:

Kao dodatni bonus, pokazat ću vam brz način izdvajanja vrijednosti iz druge ćelije koja je povezana s maksimalnom vrijednošću. U našem slučaju to će biti ime najviše osobe. Za ovo ćemo koristiti klasičnu formulu INDEX MATCH i ugnijezditi MAXIFS u prvi argument MATCH kao vrijednost traženja:

=INDEX($A$2:$A$11, MATCH(MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2), $D$2:$D$11, 0))

Formula nam govori da nazivod najviših košarkaša u juniorskoj školi je Liam:

Excel MAXIFS s logičkim operatorima

U situaciji kada trebate procijeniti numeričke kriterije, koristite logičke operatore kao što je:

• veće od (>)
• manje od (<)
• veće od ili jednako (>=)
• manje ili jednako (<=)
• nije jednako ()

Operator "jednako" (=) može se izostaviti u većini slučajeva.

Obično odabir operatora nije problem, najteži dio je izgraditi kriterij s ispravnom sintaksom. Evo kako:

• Logički operator iza kojeg slijedi broj ili tekst mora biti zatvoren u dvostruke navodnike kao što je ">=14" ili "trči".
• U slučaju ćelije referenca ili neka druga funkcija, upotrijebite navodnike za početak niza i ampersand za spajanje reference i završetak niza, npr. ">"&B1 ili "<"&TODAY().

Da vidimo kako to funkcionira u praksi, dodajmo stupac Dob (stupac C) u našu oglednu tablicu i pronađimo najveća visina među dječacima u dobi između 13 i 14 godina. To se može učiniti sa sljedećim kriterijima:

Kriterij1: ">=13"

Kriterij2: "<=14"

Budući da uspoređujemo brojeve u istom stupcu, kriterij_raspon u oba slučaja je isti (C2:C11):

=MAXIFS(D2:D11, C2:C11, ">=13", C2:C11, "<=14")

Ako ne želite kodirati kriterije u formulu, unesite ih u zasebne ćelije (npr. G1 i H1) i upotrijebite sljedećesintaksa:

=MAXIFS(D2:D11, C2:C11, ">="&G1, C2:C11, "<="&H1)

Snimak zaslona u nastavku prikazuje rezultat:

Osim s brojevima, logički operatori također mogu raditi s tekstualnim kriterijima. Konkretno, operator "nije jednako" koristan je kada želite nešto isključiti iz svojih izračuna. Na primjer, da biste pronašli najvišeg učenika u svim sportovima osim odbojke, upotrijebite sljedeću formulu:

=MAXIFS(D2:D11, B2:B11, "volleyball")

Ili ovu, gdje je G1 izuzeti sport:

=MAXIFS(D2:D11, B2:B11, ""&G1)

MAXIFS formule sa zamjenskim znakovima (djelomično podudaranje)

Da biste procijenili uvjet koji sadrži određeni tekst ili znak, uključite jedan od sljedećih zamjenskih znakova u Vaši kriteriji:

• Upitnik (?) za podudaranje s bilo kojim pojedinačnim znakom.
• Zvjezdica (*) za podudaranje s bilo kojim nizom znakova.

Za na ovom primjeru saznajmo koji je najviši tip u igranim sportovima. Budući da nazivi svih sportskih igara u našem skupu podataka završavaju riječju "lopta", tu riječ uključujemo u kriterije i koristimo zvjezdicu za podudaranje s prethodnim znakovima:

=MAXIFS(D2:D11, B2:B11, "*ball")

Možete također upišite "lopta" u neku ćeliju, npr. G1 i spojite zamjenski znak s referencom ćelije:

=MAXIFS(D2:D11, B2:B11, "*"&G1)

Rezultat će izgledati ovako:

Dohvati maksimalnu vrijednost unutar datumskog raspona

Budući da su datumi pohranjeni kao serijski brojevi u internom sustavu Excel, s kriterijima datuma radite na isti način kao što radite s brojevima.

Zada bismo to ilustrirali, zamijenit ćemo stupac Dob s Datum rođenja i pokušati izračunati maksimalnu visinu među dječacima rođenim u određenoj godini, recimo 2004. Da bismo izvršili ovaj zadatak , moramo "filtrirati" datume rođenja koji su veći ili jednaki 1. siječnja 2004. i manji ili jednaki 31. prosinca 2004.

Kada gradite svoje kriterije, važno je da navedite datume u formatu koji Excel može razumjeti:

=MAXIFS(D2:D11, C2:C11, ">=1-Jan-2004", C2:C11, "<=31-Dec-2004")

Ili

=MAXIFS(D2:D11, C2:C11, ">=1/1/2004", C2:C11, "<=12/31/2004")

Da biste spriječili pogrešno tumačenje, ima smisla koristiti funkciju DATE :

=MAXIFS(D2:D11, C2:C11, ">="&DATE(2004,1,1), C2:C11, "<="&DATE(2004,12,31))

Za ovaj primjer, upisat ćemo ciljnu godinu u G1, a zatim upotrijebiti funkciju DATE za unos datuma:

=MAXIFS(D2:D11, C2:C11, ">="&DATE(G1,1,1), C2:C11, "<="&DATE(G1,12,31))

Napomena. Za razliku od brojeva, datume treba staviti u navodnike kada se koriste sami u kriterijima. Na primjer:

=MAXIFS(D2:D11, C2:C11, "10/5/2005")

Pronađi maksimalnu vrijednost na temelju više kriterija s logikom OR

Funkcija Excel MAXIFS dizajnirana je za testiranje uvjeta s logikom AND - tj. obrađuje samo one brojeve u max_range za koji su svi kriteriji TRUE. U nekim situacijama, međutim, možda ćete morati procijeniti uvjete logikom ILI - tj. obraditi sve brojeve za koje je bilo koji od navedenih kriterija TRUE.

Da biste lakše razumjeli stvari, razmotrite sljedeće primjer. Pretpostavimo da želite pronaći maksimalnu visinu momaka koji igraju košarku ilinogomet. Kako biste to učinili? Korištenje "košarke" kao kriterija1 i kao "nogometnog" kriterija2 neće funkcionirati, jer bi Excel pretpostavio da bi oba kriterija trebala dati vrijednost TRUE.

Rješenje je napraviti 2 zasebne formule MAXIFS, jednu za svaki sport, a zatim upotrijebite dobru staru funkciju MAX da vratite veći broj:

=MAX(MAXIFS(C2:C11, B2:B11, "basketball"), MAXIFS(C2:C11, B2:B11, "football"))

Snimka zaslona u nastavku prikazuje ovu formulu, ali s kriterijima u unaprijed definiranim ulaznim ćelijama, F1 i H1:

Drugi način je korištenje formule MAX IF s logikom OR.

7 stvari koje treba zapamtiti o Excel MAXIFS

U nastavku ćete pronaći nekoliko napomena koji će vam pomoći da poboljšate svoje formule i izbjegnete uobičajene pogreške. Neka od ovih zapažanja već su razmatrana kao savjeti i bilješke u našim primjerima, no moglo bi biti korisno dobiti kratki sažetak onoga što ste već naučili:

1. Funkcija MAXIFS u Excelu može dobiti najveća vrijednost na temelju jednog ili višestrukih kriterija .
2. Prema zadanim postavkama, Excel MAXIFS radi s I logikom , tj. vraća maksimalan broj koji ispunjava sve navedene uvjete.
3. Da bi funkcija radila, maksimalni raspon i rasponi kriterija moraju imati istu veličinu i oblik .
4. Funkcija SUMIF je neosjetljiva na velika i mala slova , tj. ne prepoznaje velika slova u tekstualnim kriterijima.
5. Kada pišete MAXIFS formulu za više ćelija, ne zaboravite zaključati rasponi saapsolutne reference ćelija za ispravno kopiranje formule.
6. Pazite na sintaksu svojih kriterija ! Evo glavnih pravila:
   • Kada se koriste sami, tekst i datumi trebaju biti u navodnicima, a brojevi i reference na ćelije ne.
   • Kada se koriste broj, datum ili tekst s logičkim operatorom, cijeli izraz mora biti u dvostrukim navodnicima poput ">=10"; reference ćelija i druge funkcije moraju biti spojene pomoću znaka & kao što je ">"&G1.
7. MAXIFS je dostupan samo u Excelu 2019 i Excelu za Office 365. U ranijim verzijama, ova funkcija nije dostupna.

Tako možete pronaći maksimalnu vrijednost u Excelu s uvjetima. Zahvaljujem vam na čitanju i nadam se da se uskoro vidimo na našem blogu!

Preuzmite radnu bilježnicu za vježbanje:

Primjeri formula Excel MAXIFS (.xlsx datoteka)