El tutorial mostra com s'utilitza la funció MAXIFS a Excel per obtenir el valor màxim amb condicions.

Tradicionalment, quan alguna vegada necessiteu trobar el valor més alt amb condicions a Excel, vau haver de crear la vostra pròpia fórmula MAX IF. Tot i que no és un gran problema per als usuaris experimentats, això pot presentar certes dificultats per als novells perquè, en primer lloc, hauríeu de recordar la sintaxi de la fórmula i, en segon lloc, heu de saber com treballar amb fórmules de matriu. Afortunadament, Microsoft ha introduït recentment una nova funció que ens permet fer el màxim condicional d'una manera fàcil!

Funció MAXIFS d'Excel

La funció MAXIFS retorna el valor numèric més gran del interval especificat basat en un o més criteris.

La sintaxi de la funció MAXIFS és la següent:

On:

• Interval_màxim (obligatori): l'interval de cel·les on voleu trobar el valor màxim.
• Interval_criteri1 (obligatori) - el primer interval a avaluar amb criteri1 .
• Criteri1 : la condició que cal utilitzar al primer interval. Es pot representar amb un nombre, text o expressió.
• Interval_criteri2 / criteri2 , … (opcional) - intervals addicionals i els seus criteris relacionats. S'admeten fins a 126 parells d'interval/criteri.

Aquesta funció MAXIFS està disponible a Excel 2019, Excel 2021 iExcel per a Microsoft 365 a Windows i Mac.

Com a exemple, busquem el jugador de futbol més alt de la nostra escola local. Suposant que l'alçada dels estudiants es troba a les cel·les D2:D11 (max_range) i els esports estan a B2:B11 (criteria_range1), utilitzeu la paraula "futbol" com a criteri1 i obtindreu aquesta fórmula:

=MAXIFS(D2:D11, B2:B11, "football")

Per fer que la fórmula sigui més versàtil, podeu introduir l'esport objectiu en alguna cel·la (per exemple, G1) i incloure la referència de la cel·la a l'argument criteri1 :

=MAXIFS(D2:D11, B2:B11, G1)

Nota. Els arguments max_range i criteria_range han de tenir la mateixa mida i forma, és a dir, contenir el mateix nombre de files i columnes, en cas contrari el #VALOR! es retorna l'error.

Com utilitzar la funció MAXIFS a Excel: exemples de fórmules

Com acabeu de veure, l'Excel MAXIFS és bastant senzill i fàcil d'utilitzar. Tanmateix, té alguns petits matisos que marquen una gran diferència. En els exemples següents, intentarem treure el màxim profit del màxim condicional a Excel.

Trobar el valor màxim en funció de diversos criteris

A la primera part d'aquest tutorial, hem creat una fórmula MAXIFS en la seva forma més senzilla per obtenir el valor màxim basat en una condició. Ara, anem a portar aquest exemple més enllà i avaluar dos criteris diferents.

Suposem que voleu trobar el jugador de bàsquet més alt de l'escola secundària. Per fer-ho, definiu el següentarguments:

• Rang_màxim : un rang de cel·les que contenen altures - D2:D11.
• Range_criteri1 : un rang de cel·les que contenen esports - B2:B11.
• Criteri1 - "bàsquet", que s'introdueix a la cel·la G1.
• Criteria_range2 - un rang de cel·les que defineixen el tipus d'escola - C2:C11.
• Criteri2 - "junior", que s'introdueix a la cel·la G2.

Ajuntant els arguments, obtenim aquestes fórmules :

Amb criteris "codificats":

=MAXIFS(D2:D11, B2:B11, "basketball", C2:C11, "junior")

Amb criteris en cel·les predefinides:

=MAXIFS(D2:D11, B2:B11, G1, C2:C11, G2)

Tingueu en compte que el MAXIFS La funció d'Excel no distingeix entre majúscules i minúscules , per la qual cosa no us haureu de preocupar per les majúscules i minúscules dels vostres criteris.

En cas que penseu utilitzar el vostre criteri. fórmula en diverses cel·les, assegureu-vos de bloquejar tots els intervals amb referències de cel·les absolutes, com aquesta:

=MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2)

Això s'assegurarà que la fórmula es copie correctament a altres cel·les; les referències de criteri canvien en funció de a la posició relativa de la cel·la on es copia la fórmula mentre t Els intervals romanen sense canvis:

Com a avantatge addicional, us mostraré una manera ràpida d'extreure un valor d'una altra cel·la que estigui associada amb el valor màxim. En el nostre cas, aquest serà el nom de la persona més alta. Per a això, utilitzarem la fórmula clàssica INDEX MATCH i anirem MAXIFS al primer argument de MATCH com a valor de cerca:

=INDEX($A$2:$A$11, MATCH(MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2), $D$2:$D$11, 0))

La fórmula ens indica que el nomEl jugador de bàsquet més alt de l'escola secundària és Liam:

Excel MAXIFS amb operadors lògics

En situació en què necessiteu avaluar criteris numèrics, utilitzeu operadors lògics com ara:

• més gran que (>)
• menys que (<)
• més gran o igual que (>=)
• menor o igual a (<=)
• no igual a ()

L'operador "igual a" (=) es pot ometre en la majoria dels casos.

Normalment, triar un operador no és un problema, la part més complicada és construir criteris amb la sintaxi correcta. A continuació s'explica com:

• Un operador lògic seguit d'un número o text s'ha d'incloure entre cometes dobles, com ara ">=14" o "en execució".
• En el cas d'una cel·la referència o una altra funció, utilitzeu les cometes per començar una cadena i un ampersand per concatenar la referència i acabar la cadena, p. ">"&B1 o "<"&AVUI().

Per veure com funciona a la pràctica, afegim la columna Edat (columna C) a la nostra taula de mostra i cerquem l'alçada màxima entre els nois d'entre 13 i 14 anys. Es pot fer amb els criteris següents:

Criteri1: ">=13"

Criteri2: "<=14"

Com que comparem els números de la mateixa columna, criteria_range en tots dos casos és el mateix (C2:C11):

=MAXIFS(D2:D11, C2:C11, ">=13", C2:C11, "<=14")

Si no voleu codificar els criteris a la fórmula, introduïu-los en cel·les separades (per exemple, G1 i H1) i utilitzeu el següentsintaxi:

=MAXIFS(D2:D11, C2:C11, ">="&G1, C2:C11, "<="&H1)

La captura de pantalla següent mostra el resultat:

A part dels números, els operadors lògics també poden treballar amb criteris de text. En particular, l'operador "no igual a" és útil quan voleu excloure alguna cosa dels vostres càlculs. Per exemple, per trobar l'alumne més alt de tots els esports excepte el voleibol, utilitzeu la fórmula següent:

=MAXIFS(D2:D11, B2:B11, "volleyball")

O aquesta, on G1 és l'esport exclòs:

=MAXIFS(D2:D11, B2:B11, ""&G1)

Fórmules MAXIFS amb caràcters comodí (concordança parcial)

Per avaluar una condició que contingui un text o un caràcter específic, incloeu un dels següents caràcters comodís a els vostres criteris:

• Sign d'interrogació (?) per fer coincidir qualsevol caràcter.
• Asterisc (*) per fer coincidir qualsevol seqüència de caràcters.

Per aquest exemple, anem a descobrir el noi més alt dels esports de joc. Com que els noms de tots els esports del nostre conjunt de dades acaben amb la paraula "pilota", incloem aquesta paraula als criteris i fem servir un asterisc per fer coincidir els caràcters anteriors:

=MAXIFS(D2:D11, B2:B11, "*ball")

Podeu també escriviu "bola" en alguna cel·la, p. ex. G1 i concatena el caràcter comodí amb la referència de la cel·la:

=MAXIFS(D2:D11, B2:B11, "*"&G1)

El resultat serà el següent:

Obtén el valor màxim dins d'un interval de dates

Com que les dates s'emmagatzemen com a números de sèrie al sistema Excel intern, treballeu amb els criteris de dates de la mateixa manera que ho feu amb els números.

PerPer il·lustrar-ho, substituirem la columna Edat per Data de naixement i intentarem calcular l'alçada màxima entre els nens nascuts en un any determinat, per exemple, el 2004. Per dur a terme aquesta tasca , hem de "filtrar" les dates de naixement que siguin iguals o superiors a l'1 de gener de 2004 i inferiors o iguals al 31 de desembre de 2004.

En crear els vostres criteris, és important que proporcioneu les dates en el format que Excel pugui entendre:

=MAXIFS(D2:D11, C2:C11, ">=1-Jan-2004", C2:C11, "<=31-Dec-2004")

O

=MAXIFS(D2:D11, C2:C11, ">=1/1/2004", C2:C11, "<=12/31/2004")

Per evitar interpretacions errònies, té sentit utilitzar la funció DATA :

=MAXIFS(D2:D11, C2:C11, ">="&DATE(2004,1,1), C2:C11, "<="&DATE(2004,12,31))

Per a aquest exemple, escriurem l'any objectiu a G1 i després utilitzarem la funció DATA per proporcionar les dates:

=MAXIFS(D2:D11, C2:C11, ">="&DATE(G1,1,1), C2:C11, "<="&DATE(G1,12,31))

Nota. A diferència dels números, les dates s'han d'entregar entre cometes quan s'utilitzen en els criteris per si soles. Per exemple:

=MAXIFS(D2:D11, C2:C11, "10/5/2005")

Troba el valor màxim basat en múltiples criteris amb lògica OR

La funció MAXIFS d'Excel està dissenyada per provar les condicions amb la lògica AND, és a dir, només processa aquests nombres. a max_range per al qual tots els criteris són VERDADERS. En algunes situacions, però, és possible que hàgiu d'avaluar les condicions amb la lògica OR, és a dir, processar tots els nombres per als quals qualsevol dels criteris especificats és CERT.

Per facilitar la comprensió de les coses, tingueu en compte el següent exemple. Suposant que voleu trobar l'alçada màxima dels nois que juguen a bàsquet o béfutbol. Com ho faries? L'ús de "bàsquet" com a criteri1 i com a criteri de "futbol"2 no funcionarà, perquè Excel suposaria que tots dos criteris s'han de valorar com a VERTADER.

La solució és fer 2 fórmules MAXIFS separades, una per cada esport, i, a continuació, utilitzeu la bona vella funció MAX per retornar un nombre més alt:

=MAX(MAXIFS(C2:C11, B2:B11, "basketball"), MAXIFS(C2:C11, B2:B11, "football"))

La captura de pantalla següent mostra aquesta fórmula però amb els criteris a les cel·les d'entrada predefinides, F1 i H1:

Una altra manera és utilitzar una fórmula MAX IF amb lògica OR.

7 coses a recordar sobre Excel MAXIFS

A continuació trobareu algunes observacions que ajudarà a millorar les teves fórmules i evitar errors comuns. Algunes d'aquestes observacions ja s'han comentat com a consells i notes als nostres exemples, però pot ser útil obtenir un breu resum del que ja heu après:

1. La funció MAXIFS d'Excel pot obtenir el valor més alt basat en un o diversos criteris .
2. Per defecte, Excel MAXIFS funciona amb la lògica AND , és a dir, retorna el nombre màxim. que compleixi totes les condicions especificades.
3. Per tal que la funció funcioni, l'interval màxim i els intervals de criteris han de tenir la la mateixa mida i la forma .
4. La funció SUMIF és insensible a majúscules i minúscules , és a dir, no reconeix les majúscules i minúscules als criteris de text.
5. Quan escriviu una fórmula MAXIFS per a diverses cel·les, recordeu bloquejar el intervals ambreferències de cel·les absolutes perquè la fórmula es copie correctament.
6. Tingueu en compte la sintaxi dels vostres criteris ! Aquestes són les regles principals:
   • Quan s'utilitzen sols, el text i les dates han d'anar entre cometes, els números i les referències de cel·les no.
   • Quan s'utilitza un número, una data o un text. amb un operador lògic, tota l'expressió s'ha de tancar entre cometes dobles com ">=10"; les referències de cel·les i altres funcions s'han de concatenar utilitzant un ampersand com ">"&G1.
7. MAXIFS només està disponible a Excel 2019 i Excel per a Office 365. En versions anteriors, aquesta funció no està disponible.

Així és com podeu trobar el valor màxim a Excel amb condicions. Us agraeixo la lectura i esperem veure-us aviat al nostre bloc!

Descarregueu el quadern de pràctiques:

Excels de fórmules MAXIFS d'Excel (fitxer .xlsx)