В урока е показано как да използвате функцията MAXIFS в Excel, за да получите максималната стойност при определени условия.

Традиционно, когато ви се налагаше да намерите най-високата стойност с условия в Excel, трябваше да създадете своя собствена формула MAX IF. Макар че това не е голям проблем за опитните потребители, за начинаещите това може да представлява известна трудност, тъй като, първо, трябва да запомните синтаксиса на формулата и, второ, трябва да знаете как да работите с формули за масиви. За щастие, Microsoft наскоро въведе новафункция, която ни позволява да правим условен максимум по лесен начин!

Функция MAXIFS на Excel

Функцията MAXIFS връща най-голямата числова стойност в зададения диапазон въз основа на един или повече критерии.

Синтаксисът на функцията MAXIFS е следният:

Къде:

• Max_range (задължително) - обхватът от клетки, в който искате да намерите максималната стойност.
• Критерии_обхват1 (задължително) - първият диапазон, който се оценява с критерии1 .
• Критерии1 - условието, което се използва за първия диапазон. То може да бъде представено като число, текст или израз.
• Criteria_range2 / критерии2 , ...(по избор) - допълнителни диапазони и свързаните с тях критерии. Поддържат се до 126 двойки диапазони/критерии.

Тази функция MAXIFS е налична в Excel 2019, Excel 2021 и Excel за Microsoft 365 в Windows и Mac.

Като пример, нека намерим най-високия футболист в местното училище. Ако приемем, че височината на учениците е в клетки D2:D11 (max_range), а спортът е в B2:B11 (criterion_range1), използваме думата "football" като criterion1 и ще получим тази формула:

=MAXIFS(D2:D11, B2:B11, "футбол")

За да направите формулата по-универсална, можете да въведете целевия спорт в някоя клетка (например G1) и да включите препратката към клетката в критерии1 аргумент:

=MAXIFS(D2:D11, B2:B11, G1)

Забележка. max_range и criteria_range Аргументите трябва да са с еднакъв размер и форма, т.е. да съдържат еднакъв брой редове и колони, в противен случай се връща грешка #VALUE!.

Как да използвате функцията MAXIFS в Excel - примери за формули

Както току-що видяхте, MAXIFS на Excel е доста проста и лесна за използване. Въпреки това тя има няколко малки нюанса, които са от голямо значение. В примерите по-долу ще се опитаме да се възползваме максимално от условната максимална стойност в Excel.

Намиране на максимална стойност въз основа на множество критерии

В първата част на този урок създадохме формулата MAXIFS в нейната най-проста форма, за да получим максималната стойност въз основа на едно условие. Сега ще доразвием този пример и ще оценим два различни критерия.

Да предположим, че искате да намерите най-високия баскетболист в младшата школа. За да го направите, дефинирайте следните аргументи:

• Max_range - диапазон от клетки, съдържащи височини - D2:D11.
• Критерии_обхват1 - диапазон от клетки, съдържащи спортове - B2:B11.
• Критерии1 - "баскетбол", който е въведен в клетка G1.
• Criteria_range2 - диапазон от клетки, определящи вида на училището - C2:C11.
• Критерии2 - "junior", който се въвежда в клетка G2.

Ако съберем аргументите, ще получим следните формули:

С "твърдо кодирани" критерии:

=MAXIFS(D2:D11, B2:B11, "баскетбол", C2:C11, "младши")

С критерии в предварително дефинирани клетки:

=MAXIFS(D2:D11, B2:B11, G1, C2:C11, G2)

Обърнете внимание, че функцията MAXIFS в Excel е без значение на размера на буквите , така че не е необходимо да се притеснявате за големината на буквите в критериите си.

В случай че планирате да използвате формулата си в няколко клетки, не забравяйте да заключите всички диапазони с абсолютни препратки към клетките, както е показано по-долу:

=MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2)

Това ще гарантира, че формулата се копира правилно в други клетки - препратките към критериите се променят в зависимост от относителната позиция на клетката, в която се копира формулата, а диапазоните остават непроменени:

Като допълнителен бонус ще ви покажа бърз начин за извличане на стойност от друга клетка, която е свързана с максималната стойност. В нашия случай това ще бъде името на най-високия човек. За целта ще използваме класическата формула INDEX MATCH и ще вложим MAXIFS в първия аргумент на MATCH като стойност за търсене:

=INDEX($A$2:$A$11, MATCH(MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2), $D$2:$D$11, 0))

Формулата ни казва, че името на най-високия баскетболист в юношеската школа е Лиъм:

MAXIFS на Excel с логически оператори

В случаите, когато трябва да оцените числови критерии, използвайте логически оператори, като например:

• по-голямо от (>)
• по-малко от (<)
• по-голямо от или равно на (>=)
• по-малко от или равно на (<=)
• не е равно на ()

Операторът "равно на" (=) може да бъде пропуснат в повечето случаи.

Обикновено изборът на оператор не е проблем, най-сложното е да се създадат критерии с правилен синтаксис. Ето как:

• Логически оператор, последван от число или текст, трябва да бъде заграден в двойни кавички, например ">=14" или "running".
• В случай на препратка към клетка или друга функция използвайте кавичките, за да започнете низ, и амперсанд, за да съедините препратката и да завършите низа, например ">"&B1 или "<"&TODAY().

За да видим как работи на практика, нека добавим колона "Възраст" (колона C) към нашата примерна таблица и да намерим максималния ръст сред момчетата на възраст между 13 и 14 г. Това може да стане със следните критерии:

Критерий1: ">=13"

Критерий2: "<=14"

Тъй като сравняваме числата в една и съща колона, критерий_обхват и в двата случая е един и същ (C2:C11):

=MAXIFS(D2:D11, C2:C11, ">=13", C2:C11, "<=14")

Ако не искате да кодирате критериите във формулата, въведете ги в отделни клетки (напр. G1 и H1) и използвайте следния синтаксис:

=MAXIFS(D2:D11, C2:C11, ">="&G1, C2:C11, "<="&H1)

Резултатът е показан на снимката на екрана по-долу:

Освен с числа, логическите оператори могат да работят и с текстови критерии. По-специално операторът "не е равно на" е полезен, когато искате да изключите нещо от изчисленията си. Например, за да намерите най-високия ученик във всички спортове без волейбола, използвайте следната формула:

=MAXIFS(D2:D11, B2:B11, "волейбол")

Или пък тази, в която G1 е изключен спорт:

=MAXIFS(D2:D11, B2:B11, ""&G1)

Формули MAXIFS със заместващи символи (частично съвпадение)

За да оцените условие, което съдържа конкретен текст или символ, включете в критериите си един от следните заместващи символи:

• Въпросителен знак (?) за съвпадение с всеки отделен символ.
• Звездичка (*) за съвпадение на всяка последователност от символи.

За този пример нека да открием най-високия човек в игрите със спортни игри. Тъй като имената на всички игри със спортни игри в нашето набор от данни завършват с думата "топка", включваме тази дума в критериите и използваме звездичка, за да сравним всички предишни символи:

=MAXIFS(D2:D11, B2:B11, "*ball")

Можете също така да въведете "ball" в някоя клетка, например G1, и да свържете заместващия символ с препратката към клетката:

=MAXIFS(D2:D11, B2:B11, "*"&G1)

Резултатът ще изглежда по следния начин:

Получаване на максимална стойност в рамките на диапазон от дати

Тъй като датите се съхраняват като серийни номера във вътрешната система на Excel, с критериите за дати се работи по същия начин, както с числата.

За да илюстрираме това, ще заменим Възраст колона с Дата на раждане и да се опитаме да определим максималния ръст сред момчетата, родени през определена година, да речем през 2004 г. За да изпълним тази задача, трябва да "филтрираме" рождените дати, които са по-големи или равни на 1 януари 2004 г. и по-малки или равни на 31 декември 2004 г.

Когато изграждате критериите си, е важно да предоставите датите във формат, който Excel разбира:

=MAXIFS(D2:D11, C2:C11, ">=1-януари-2004", C2:C11, "<=31-декември-2004")

Или

=MAXIFS(D2:D11, C2:C11, ">=1/1/2004", C2:C11, "<=12/31/2004")

За да се предотврати погрешно тълкуване, е целесъобразно да се използва функцията DATE:

=MAXIFS(D2:D11, C2:C11, ">="&DATE(2004,1,1), C2:C11, "<="&DATE(2004,12,31))

В този пример ще въведем целевата година в G1 и след това ще използваме функцията DATE, за да въведем датите:

=MAXIFS(D2:D11, C2:C11, ">="&DATE(G1,1,1), C2:C11, "<="&DATE(G1,12,31))

Забележка. За разлика от числата, датите трябва да се поставят в кавички, когато се използват самостоятелно в критериите. Например:

=MAXIFS(D2:D11, C2:C11, "10/5/2005")

Намиране на максимална стойност въз основа на множество критерии с логиката OR

Функцията MAXIFS на Excel е предназначена за тестване на условията с логиката AND - т.е. тя обработва само числата в max_range В някои ситуации обаче може да се наложи да оцените условията с логиката ИЛИ - т.е. да обработите всички числа, за които някой от посочените критерии е ИСТИНСКИ.

За да разберете нещата по-лесно, разгледайте следния пример. Да предположим, че искате да намерите максималния ръст на момчетата, които играят баскетбол или футбол. Как ще направите това? Използването на "баскетбол" като критерий1 и на "футбол" като критерий2 няма да работи, защото Excel ще приеме, че и двата критерия трябва да се оценят като TRUE.

Решението е да се направят 2 отделни формули MAXIFS, по една за всеки спорт, и след това да се използва добрата стара функция MAX, за да се върне по-голямо число:

=MAX(MAXIFS(C2:C11, B2:B11, "баскетбол"), MAXIFS(C2:C11, B2:B11, "футбол"))

Снимката на екрана по-долу показва тази формула, но с критериите в предварително дефинирани входни клетки F1 и H1:

Друг начин е да се използва формула MAX IF с логика OR.

7 неща, които трябва да запомните за MAXIFS на Excel

По-долу ще намерите няколко забележки, които ще ви помогнат да подобрите формулите си и да избегнете често срещани грешки. Някои от тези забележки вече са разгледани като съвети и бележки в нашите примери, но може да е полезно да получите кратко обобщение на това, което вече сте научили:

1. Функцията MAXIFS в Excel може да получи най-високата стойност въз основа на един или множество критерии .
2. По подразбиране Excel MAXIFS работи с Логика AND , т.е. връща максималното число, което отговаря на всички посочени условия.
3. За да работи функцията, диапазоните на максималния обхват и критериите трябва да имат същия размер и форма .
4. Функцията SUMIF е без значение на големи и малки букви , т.е. не разпознава големината на буквите в текстовите критерии.
5. Когато пишете формула MAXIFS за няколко клетки, не забравяйте да заключване на диапазоните с абсолютни препратки към клетките, за да може формулата да се копира правилно.
6. Имайте предвид синтаксис на вашите критерии ! Ето основните правила:
   • Когато се използват самостоятелно, текстът и датите трябва да се поставят в кавички, а числата и препратките към клетките - не.
   • Когато се използва число, дата или текст с логически оператор, целият израз трябва да бъде затворен в двойни кавички, например ">=10"; препратките към клетки и други функции трябва да бъдат обединени с помощта на амперсанд, например ">"&G1.
7. MAXIFS е налична само в Excel 2019 и Excel за Office 365. В по-ранните версии тази функция не е налична.

Ето как можете да откриете максималната стойност в Excel с помощта на условия. Благодаря ви, че прочетохте, и се надявам скоро да се видим в нашия блог!

Изтегляне на работна тетрадка за упражнения:

Примери за формули на Excel MAXIFS (.xlsx файл)