Заавар нь Excel-ийн MAXIFS функцийг нөхцөлтэй хамт хамгийн их утгыг авахын тулд хэрхэн ашиглахыг харуулж байна.

Уламжлалт ёсоор бол Excel-д нөхцөлтэй хамгийн дээд утгыг олох шаардлагатай үед, Та өөрийн MAX IF томьёо бүтээх хэрэгтэй болсон. Туршлагатай хэрэглэгчдийн хувьд энэ нь тийм ч том асуудал биш ч гэсэн шинэхэн хүмүүст тодорхой бэрхшээл учруулж болзошгүй тул нэгдүгээрт, та томьёоны синтаксийг санаж байх хэрэгтэй, хоёрдугаарт, массив томьёотой хэрхэн ажиллахаа мэдэх хэрэгтэй. Аз болоход Майкрософт саяхан нөхцөлт максыг хялбар аргаар хийх боломжийг олгодог шинэ функцийг танилцууллаа!

Excel MAXIFS функц

MAXIFS функц нь хамгийн том тоон утгыг буцаадаг. нэг буюу хэд хэдэн шалгуурт тулгуурлан тодорхойлсон муж.

MAXIFS функцийн синтакс нь дараах байдалтай байна:

Хаана:

• Макс_муж (шаардлагатай) - хамгийн их утгыг олохыг хүсэж буй нүдний муж.
• Шалгуур_муж1 (шаардлагатай) - шалгуур1 -аар үнэлэх эхний муж.
• Шалгуур1 - эхний мужид ашиглах нөхцөл. Үүнийг тоо, текст эсвэл илэрхийллээр илэрхийлж болно.
• Шалгуур_муж2 / шалгуур2 , …(заавал биш) - нэмэлт мужууд болон тэдгээртэй холбоотой шалгуурууд. 126 хүртэлх муж/шалгуур хосыг дэмждэг.

Энэ MAXIFS функц нь Excel 2019, Excel 2021, болонWindows болон Mac дээрх Microsoft 365-д зориулсан Excel.

Жишээ нь манай сургуулийн хамгийн өндөр хөлбөмбөгчийг олъё. Сурагчдын өндрийг D2:D11 (хамгийн их_муж), спортыг B2:B11 (шалгуурын_муж1) нүдэнд тусгавал "хөлбөмбөг" гэсэн үгийг шалгуур1 болгон ашиглавал дараах томьёо гарна:

=MAXIFS(D2:D11, B2:B11, "football")

Томьёог илүү уян хатан болгохын тулд та зорилтот спортыг зарим нүдэнд (G1 гэх мэт) оруулж, нүдний лавлагааг шалгуур1 аргументад оруулах боломжтой:

=MAXIFS(D2:D11, B2:B11, G1)

Тайлбар. хамгийн их_муж ба шалгуурын_муж аргументууд нь ижил хэмжээ, хэлбэртэй байх ёстой, өөрөөр хэлбэл ижил тооны мөр, багана агуулсан байх ёстой, эс тэгвээс #VALUE! алдаа буцаж байна.

Excel-д MAXIFS функцийг хэрхэн ашиглах вэ - томъёоны жишээ

Таны харж байгаагаар Excel MAXIFS нь маш энгийн бөгөөд хэрэглэхэд хялбар юм. Гэсэн хэдий ч энэ нь томоохон өөрчлөлтийг бий болгодог хэд хэдэн жижиг нюансуудтай байдаг. Доорх жишээн дээр бид Excel-ийн нөхцөлт max-ыг хамгийн их ашиглахыг хичээх болно.

Олон шалгуурт үндэслэн хамгийн их утгыг олох

Энэхүү хичээлийн эхний хэсэгт бид MAXIFS томьёог үүсгэсэн. нэг нөхцөл дээр үндэслэн хамгийн их утгыг авахын тулд хамгийн энгийн хэлбэрээр. Одоо бид энэ жишээг цааш нь авч, хоёр өөр шалгуураар үнэлэх болно.

Та бага сургуулийн хамгийн өндөр сагсан бөмбөгчийг олохыг хүсч байна гэж бодъё. Үүнийг хийхийн тулд дараахь зүйлийг тодорхойлно ууаргументууд:

• Хамгийн их_муж - өндрийг агуулсан нүднүүдийн муж - D2:D11.
• Шалгуур_муж1 - спорт агуулсан нүднүүдийн муж - B2:B11.
• Шалгуур1 - G1 нүдэнд оруулах "сагсан бөмбөг".
• Шалгуурын_муж2 - үзүүлэлтийг тодорхойлох нүднүүдийн муж сургуулийн төрөл - C2:C11.
• Шалгуур2 - G2 нүдэнд оруулах "junior".

Аргументуудыг нэгтгэснээр бид эдгээр томьёог олж авна. :

"Хатуу кодлогдсон" шалгууртай:

=MAXIFS(D2:D11, B2:B11, "basketball", C2:C11, "junior")

Урьдчилан тодорхойлсон нүднүүдийн шалгууртай:

=MAXIFS(D2:D11, B2:B11, G1, C2:C11, G2)

MAXIFS гэдгийг анхаарна уу. Excel-ийн функц нь Үсгийн жижиг үсэг мэдрэгддэггүй тул та өөрийн шалгуурт том үсгийн талаар санаа зовох хэрэггүй.

Хэрэв та өөрийн бичвэрээ ашиглахаар төлөвлөж байгаа бол Олон нүдэн дээрх томьёотой бол бүх мужийг үнэмлэхүй нүдний лавлагаагаар түгжихээ мартуузай:

=MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2)

Энэ нь томьёог бусад нүднүүдэд зөв хуулахыг баталгаажуулна - шалгуур үзүүлэлтийн лавлагаа нь үндсэндээ өөрчлөгдөнө. t байхад томьёог хуулж байгаа нүдний харьцангуй байрлал дээр Тэр мужууд өөрчлөгдөөгүй хэвээр байна:

Нэмэлт урамшууллын хувьд би хамгийн их утгатай холбоотой өөр нүднээс утгыг хурдан гаргаж авах аргыг танд үзүүлэх болно. Манай тохиолдолд энэ нь хамгийн өндөр хүний ​​нэр байх болно. Үүний тулд бид сонгодог INDEX MATCH томьёог ашиглаж, MATCH-ийн эхний аргумент дахь хайлтын утга болгон MAXIFS-ийг үүрлэнэ:

=INDEX($A$2:$A$11, MATCH(MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2), $D$2:$D$11, 0))

Томьёо нь нэр гэдгийг хэлж байна.Бага сургуулийн хамгийн өндөр сагсан бөмбөгчин бол Лиам:

Логик оператортой Excel MAXIFS

Тоон шалгуурыг үнэлэх шаардлагатай тохиолдолд логик операторуудыг ашигла. тухайлбал:

• (>)-аас их
• (<)-аас бага
• (>=)-ээс их буюу тэнцүү
• бага буюу тэнцүү (<=)
• тэнцэхгүй ()

Ихэнх тохиолдолд "тэнцүү" операторыг (=) орхиж болно.

Ихэвчлэн оператор сонгох нь асуудал биш бөгөөд хамгийн төвөгтэй зүйл бол зөв синтакс бүхий шалгуурыг бий болгох явдал юм. Үүнд:

• Тоо эсвэл текстийн араас орсон логик операторыг ">=14" эсвэл "ажиллаж байна" гэх мэт давхар хашилтанд оруулах ёстой.
• Нүдний хувьд лавлагаа эсвэл өөр функцийг ашиглахын тулд ишлэлийг мөр болон амперсанд эхлүүлэхийн тулд ишлэлийг ашиглан холбож, мөрийг унтрааж дуусгах, жишээлбэл. ">"&B1 эсвэл "<"&ӨНӨӨДӨР().

Практикт хэрхэн ажилладгийг харахын тулд Нас баганыг (C багана) түүвэр хүснэгтдээ нэмж олъё. 13-14 насны хөвгүүдийн хамгийн өндөр өндөр. Үүнийг дараах шалгуураар хийж болно:

Шалгуур1: ">=13"

Шалгуур2: "<=14"

Бид нэг баганад байгаа тоонуудыг харьцуулж байгаа тул хоёр тохиолдолд шалгуурын_муж ижил байна (C2:C11):

=MAXIFS(D2:D11, C2:C11, ">=13", C2:C11, "<=14")

Хэрэв та шалгуурыг хатуу кодлохыг хүсэхгүй байвал Томъёоны хувьд тэдгээрийг тусдаа нүдэнд (жишээ нь G1 ба H1) оруулаад дараахыг ашиглана уусинтакс:

=MAXIFS(D2:D11, C2:C11, ">="&G1, C2:C11, "<="&H1)

Доорх дэлгэцийн агшинд үр дүнг харуулав:

Тооноос гадна логик операторууд текстийн шалгууртай ажиллах боломжтой. Ялангуяа "тэнцүү биш" оператор нь таны тооцоололд ямар нэг зүйлийг оруулахгүй байхыг хүсвэл хэрэг болно. Жишээлбэл, волейболоос бусад бүх спортын хамгийн өндөр сурагчийг олохын тулд дараах томъёог ашиглана уу:

=MAXIFS(D2:D11, B2:B11, "volleyball")

Эсвэл G1 хасагдсан спорт:

=MAXIFS(D2:D11, B2:B11, ""&G1)

Оролцогч тэмдэгт бүхий MAXIFS томьёо (хэсэгчилсэн таарах)

Тодорхой текст эсвэл тэмдэгт агуулсан нөхцөлийг үнэлэхийн тулд дараах орлуулагч тэмдэгтүүдийн аль нэгийг оруулна уу. таны шалгуур:

• Асуултын тэмдэг (?) аль нэг тэмдэгттэй таарч байна.
• Од (*) тэмдэгтийн дараалалд тааруулна.

Энэ жишээн дээр тоглоомын спортын хамгийн өндөр залууг олж мэдье. Манай өгөгдлийн багц дахь бүх спортын нэрс "бөмбөг" гэсэн үгээр төгсдөг тул бид энэ үгийг шалгуурт оруулж, өмнөх тэмдэгтүүдтэй тааруулахын тулд одоор ашигладаг:

=MAXIFS(D2:D11, B2:B11, "*ball")

Та мөн зарим нүдэнд "бөмбөг" гэж бичнэ үү, жишээ нь. G1 ба орлуулагч тэмдэгтийг нүдний лавлагаатай холбоно уу:

=MAXIFS(D2:D11, B2:B11, "*"&G1)

Үр дүн дараах байдлаар харагдана:

Хамгийн их утгыг авах огнооны хязгаарт

Огноог дотоод Excel системд серийн дугаар болгон хадгалдаг тул та тоонуудтай ажилладаг шиг огнооны шалгууртай ажилладаг.

Үүнийг тайлбарлавал, бид Нас баганыг Төрсөн огноо гэж сольж, 2004 онд төрсөн хөвгүүдийн хамгийн их өндрийг тооцоолохыг хичээх болно. Энэ даалгаврыг биелүүлэхийн тулд , бид 2004 оны 1-р сарын 1-ээс их буюу тэнцүү, 2004 оны 12-р сарын 31-нээс бага буюу түүнээс бага төрсөн огноог "шүүх" хэрэгтэй.

Шалгуураа бүрдүүлэхдээ та чухал ач холбогдолтой. Огноог Excel-ийн ойлгож чадах форматаар оруулна уу:

=MAXIFS(D2:D11, C2:C11, ">=1-Jan-2004", C2:C11, "<=31-Dec-2004")

Эсвэл

=MAXIFS(D2:D11, C2:C11, ">=1/1/2004", C2:C11, "<=12/31/2004")

Буруу тайлбараас сэргийлэхийн тулд DATE функцийг ашиглах нь зүйтэй. :

=MAXIFS(D2:D11, C2:C11, ">="&DATE(2004,1,1), C2:C11, "<="&DATE(2004,12,31))

Энэ жишээний хувьд бид G1-д зорилтот оныг бичиж, огноог оруулахын тулд DATE функцийг ашиглана:

=MAXIFS(D2:D11, C2:C11, ">="&DATE(G1,1,1), C2:C11, "<="&DATE(G1,12,31))

Тайлбар. Тооноос ялгаатай нь огноог шалгуурт дангаар нь ашигласан тохиолдолд хашилтанд оруулах ёстой. Жишээ нь:

=MAXIFS(D2:D11, C2:C11, "10/5/2005")

OR логик бүхий олон шалгуурт тулгуурлан хамгийн их утгыг олох

Excel MAXIFS функц нь AND логикоор нөхцөлийг шалгахад зориулагдсан - өөрөөр хэлбэл зөвхөн тэдгээр тоонуудыг боловсруулдаг. хамгийн их_муж -д бүх шалгуур нь ҮНЭН байна. Гэсэн хэдий ч зарим тохиолдолд та нөхцөлийг OR логикоор үнэлэх шаардлагатай байж болно - өөрөөр хэлбэл заасан шалгууруудын аль нэг нь ҮНЭН байгаа бүх тоог боловсруулах.

Ойлгоход хялбар болгохын тулд дараах зүйлсийг анхаарна уу. жишээ. Та сагсан бөмбөг тоглодог залуусын хамгийн дээд өндрийг олохыг хүсч байна гэж бодъёхөлбөмбөг. Та үүнийг яаж хийх вэ? "Сагсан бөмбөг"-ийг шалгуур1 болон "хөлбөмбөгийн" шалгуур2 болгон ашиглах нь ажиллахгүй, учир нь Excel аль аль шалгуурыг ҮНЭН гэж үнэлэх ёстой.

Шийдлийн шийдэл нь спорт тус бүрд нэг MAXIFS томьёо гаргах явдал юм. дараа нь хуучин сайн MAX функцийг ашиглан илүү өндөр тоог буцаана уу:

=MAX(MAXIFS(C2:C11, B2:B11, "basketball"), MAXIFS(C2:C11, B2:B11, "football"))

Доорх дэлгэцийн агшинд энэ томьёо харуулсан боловч F1 ба H1 гэсэн шалгуурыг урьдчилан тодорхойлсон оролтын нүднүүдэд харуулав:

Өөр нэг арга бол MAX IF томьёог OR логиктой ашиглах явдал юм.

Excel MAXIFS-ийн талаар санах ёстой 7 зүйл

Доор та цөөн хэдэн тайлбарыг олох болно. Энэ нь таны томъёог сайжруулах, нийтлэг алдаанаас зайлсхийхэд тусална. Эдгээр ажиглалтын заримыг манай жишээн дээр аль хэдийн зөвлөмж, тэмдэглэл болгон авч үзсэн боловч аль хэдийн сурсан зүйлсийнхээ товч хураангуйг авах нь тустай байж болох юм:

1. Excel-ийн MAXIFS функцийг авч болно. нэг эсвэл олон шалгуур дээр үндэслэсэн хамгийн дээд утга.
2. Өгөгдмөлөөр Excel MAXIFS нь БӨЛӨН логик -тай ажилладаг, өөрөөр хэлбэл хамгийн их тоог буцаана. Энэ нь заасан бүх нөхцөлийг хангасан байна.
3. Функц ажиллахын тулд хамгийн их хүрээ ба шалгуурын мужууд ижил хэмжээтэй ба хэлбэр байх ёстой.
4. SUMIF функц нь Үсгийн жижиг томьёо мэдэрдэггүй , өөрөөр хэлбэл текстийн шалгуурт том жижиг үсгийг танихгүй.
5. Олон нүдэнд MAXIFS томьёо бичихдээ түгжихээ мартуузай. мужууд -тайтомъёог зөв хуулахын тулд үнэмлэхүй нүдний лавлагаа.
6. Шалгуурынхаа синтаксийг анхаарна уу ! Энд гол дүрмүүд байна:
   • Текст, огноог дангаар нь хашилтанд оруулахгүй, тоо болон нүдний лавлагааг оруулах ёсгүй.
   • Тоо, огноо, текстийг ашиглах үед логик оператортой бол илэрхийллийг бүхэлд нь ">=10" гэх мэт давхар хашилтанд оруулах ёстой; нүдний лавлагаа болон бусад функцийг ">"&G1 гэх мэт тэмдэгт ашиглан холбох ёстой.
7. MAXIFS нь зөвхөн Excel 2019 болон Office 365-д зориулсан Excel-д байдаг. Өмнөх хувилбаруудад, Энэ функц байхгүй байна.

Ингэснээр та Excel-ийн нөхцөлийн дагуу хамгийн их утгыг олох боломжтой. Уншиж байгаад баярлалаа, удахгүй манай блог дээр уулзана гэж найдаж байна!

Дадлагын ажлын номыг татаж авах:

Excel MAXIFS томъёоны жишээнүүд (.xlsx файл)