يوضح البرنامج التعليمي كيفية استخدام وظيفة MAXIFS في Excel للحصول على أقصى قيمة مع الشروط.

تقليديًا ، عندما تحتاج في أي وقت إلى العثور على أعلى قيمة بشروط في Excel ، كان عليك بناء صيغة MAX IF الخاصة بك. على الرغم من أنه لا يمثل مشكلة كبيرة للمستخدمين ذوي الخبرة ، فقد يمثل ذلك بعض الصعوبات للمبتدئين لأنه ، أولاً ، يجب أن تتذكر بناء جملة الصيغة ، وثانيًا ، تحتاج إلى معرفة كيفية التعامل مع صيغ الصفيف. لحسن الحظ ، قدمت Microsoft مؤخرًا وظيفة جديدة تتيح لنا إجراء الحد الأقصى الشرطي بطريقة سهلة! النطاق المحدد بناءً على معيار واحد أو أكثر.

يكون بناء جملة الدالة MAXIFS كما يلي:

حيث:

• Max_range (مطلوب) - نطاق الخلايا حيث تريد العثور على القيمة القصوى.
• Criteria_range1 (مطلوب) - النطاق الأول للتقييم باستخدام معايير 1 .
• Criteria1 - الشرط المراد استخدامه في النطاق الأول. يمكن تمثيلها برقم أو نص أو تعبير.
• Criteria_range2 / criteria2 ، ... (اختياري) - نطاقات إضافية ومعاييرها ذات الصلة. يتم دعم ما يصل إلى 126 زوجًا من النطاق / المعايير.

تتوفر وظيفة MAXIFS هذه في Excel 2019 و Excel 2021 وExcel for Microsoft 365 على نظامي التشغيل Windows و Mac.

كمثال ، دعنا نجد أطول لاعب كرة قدم في مدرستنا المحلية. بافتراض أن ارتفاعات الطلاب موجودة في الخلايا D2: D11 (max_range) والرياضة في B2: B11 (criteria_range1) ، استخدم كلمة "football" كمعايير 1 ، وستحصل على هذه الصيغة:

=MAXIFS(D2:D11, B2:B11, "football")

لجعل الصيغة أكثر تنوعًا ، يمكنك إدخال الرياضة المستهدفة في بعض الخلايا (على سبيل المثال ، G1) وتضمين مرجع الخلية في الوسيطة criteria1 :

=MAXIFS(D2:D11, B2:B11, G1)

ملاحظة. يجب أن تكون الوسيطتان max_range و نطاق_المعايير من نفس الحجم والشكل ، أي أن تحتوي على عدد متساوٍ من الصفوف والأعمدة ، وإلا فإن الوسيطتين #VALUE! تم إرجاع الخطأ.

كيفية استخدام دالة MAXIFS في Excel - أمثلة على الصيغ

كما رأيت للتو ، فإن Excel MAXIFS واضح تمامًا وسهل الاستخدام. ومع ذلك ، فإنه يحتوي على بعض الفروق الدقيقة التي تحدث فرقًا كبيرًا. في الأمثلة أدناه ، سنحاول تحقيق أقصى استفادة من الحد الأقصى الشرطي في Excel.

ابحث عن القيمة القصوى بناءً على معايير متعددة

في الجزء الأول من هذا البرنامج التعليمي ، أنشأنا صيغة MAXIFS في أبسط أشكاله للحصول على أقصى قيمة بناءً على شرط واحد. الآن ، سنأخذ هذا المثال إلى أبعد من ذلك ونقيم معيارين مختلفين.

لنفترض أنك تريد العثور على أطول لاعب كرة سلة في المدرسة الإعدادية. للقيام بذلك ، حدد ما يليالوسيطات:

• Max_range - نطاق من الخلايا يحتوي على ارتفاعات - D2: D11.
• Criteria_range1 - نطاق من الخلايا يحتوي على رياضات - B2: B11.
• Criteria1 - "كرة السلة" ، والتي يتم إدخالها في الخلية G1.
• Criteria_range2 - نطاق من الخلايا يحدد نوع المدرسة - C2: C11.
• Criteria2 - "junior" ، والتي يتم إدخالها في الخلية G2.

بجمع الوسائط معًا ، نحصل على هذه الصيغ :

بمعايير "مضمنة":

=MAXIFS(D2:D11, B2:B11, "basketball", C2:C11, "junior")

مع المعايير في الخلايا المحددة مسبقًا:

=MAXIFS(D2:D11, B2:B11, G1, C2:C11, G2)

يرجى ملاحظة أن MAXIFS الوظيفة في Excel غير حساسة لحالة الأحرف ، لذلك لا داعي للقلق بشأن حالة الأحرف في المعايير الخاصة بك.

في حال كنت تخطط لاستخدام الصيغة في خلايا متعددة ، تأكد من قفل جميع النطاقات بمراجع خلية مطلقة ، مثل هذا:

=MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2)

سيضمن هذا نسخ الصيغة إلى خلايا أخرى بشكل صحيح - تتغير مراجع المعايير بناءً على في الموضع النسبي للخلية حيث يتم نسخ الصيغة أثناء t تظل نطاقاته دون تغيير:

كمكافأة إضافية ، سأوضح لك طريقة سريعة لاستخراج قيمة من خلية أخرى مرتبطة بالقيمة القصوى. في حالتنا ، سيكون هذا هو اسم أطول شخص. لهذا ، سنستخدم صيغة INDEX MATCH الكلاسيكية وتداخل MAXIFS في الوسيطة الأولى لـ MATCH كقيمة البحث:

=INDEX($A$2:$A$11, MATCH(MAXIFS($D$2:$D$11, $B$2:$B$11, G1, $C$2:$C$11, G2), $D$2:$D$11, 0))

تخبرنا الصيغة أن الاسمليام من أطول لاعب كرة سلة في المدرسة الإعدادية:

Excel MAXIFS مع عوامل منطقية

في الحالة التي تحتاج فيها إلى تقييم معايير رقمية ، استخدم عوامل التشغيل المنطقية مثل:

• أكبر من (& gt ؛)
• أصغر من (& lt ؛)
• أكبر من أو يساوي (& gt ؛ =)
• أقل من أو يساوي (& lt؛ =)
• لا يساوي ()

يمكن حذف عامل التشغيل "يساوي" (=) في معظم الحالات.

عادة ، اختيار عامل لا يمثل مشكلة ، الجزء الأصعب هو بناء معايير بالصيغة الصحيحة. وإليك الطريقة:

• يجب وضع عامل منطقي متبوعًا برقم أو نص بين علامتي اقتباس مثل "& gt؛ = 14" أو "قيد التشغيل".
• في حالة وجود خلية مرجع أو وظيفة أخرى ، استخدم علامات الاقتباس لبدء سلسلة وعلامة العطف لتوصيل المرجع وإنهاء السلسلة ، على سبيل المثال "& amp؛ B1 أو" & lt؛ "& amp؛ TODAY ().

لمعرفة كيفية عملها عمليًا ، دعنا نضيف عمود" العمر "(العمود C) إلى نموذج الجدول ونبحث عن الحد الأقصى للارتفاع بين الأولاد الذين تتراوح أعمارهم بين 13 و 14. ويمكن القيام بذلك بالمعايير التالية:

المعايير 1: "& gt؛ = 13"

Criteria2: "& lt؛ = 14"

لأننا نقارن الأرقام في نفس العمود ، فإن criteria_range في كلتا الحالتين هي نفسها (C2: C11):

=MAXIFS(D2:D11, C2:C11, ">=13", C2:C11, "<=14")

إذا كنت لا تريد ترميز المعايير في الصيغة ، أدخلها في خلايا منفصلة (مثل G1 و H1) واستخدم ما يليبناء الجملة:

=MAXIFS(D2:D11, C2:C11, ">="&G1, C2:C11, "<="&H1)

توضح لقطة الشاشة أدناه النتيجة:

بصرف النظر عن الأرقام ، يمكن للعوامل المنطقية أيضًا العمل مع معايير النص. على وجه الخصوص ، يكون عامل التشغيل "لا يساوي" مفيدًا عندما ترغب في استبعاد شيء ما من حساباتك. على سبيل المثال ، للعثور على أطول طالب في جميع الرياضات باستثناء الكرة الطائرة ، استخدم الصيغة التالية:

=MAXIFS(D2:D11, B2:B11, "volleyball")

أو هذه ، حيث G1 هي الرياضة المستبعدة:

=MAXIFS(D2:D11, B2:B11, ""&G1)

صيغ MAXIFS مع أحرف البدل (مطابقة جزئية)

لتقييم شرط يحتوي على نص أو حرف معين ، قم بتضمين أحد أحرف البدل التالية في المعايير الخاصة بك:

• علامة الاستفهام (؟) لمطابقة أي حرف واحد.
• النجمة (*) لمطابقة أي تسلسل من الأحرف.

بالنسبة إلى في هذا المثال ، دعنا نكتشف أطول رجل في الألعاب الرياضية. نظرًا لأن أسماء جميع الألعاب الرياضية في مجموعة البيانات الخاصة بنا تنتهي بكلمة "كرة" ، فإننا ندرج هذه الكلمة في المعايير ونستخدم علامة النجمة لمطابقة أي أحرف سابقة:

=MAXIFS(D2:D11, B2:B11, "*ball")

يمكنك اكتب أيضًا "كرة" في بعض الخلايا ، على سبيل المثال G1 ، وسلسل حرف البدل مع مرجع الخلية:

=MAXIFS(D2:D11, B2:B11, "*"&G1)

ستبدو النتيجة كما يلي:

الحصول على أقصى قيمة ضمن نطاق تاريخ

نظرًا لأنه يتم تخزين التواريخ كأرقام تسلسلية في نظام Excel الداخلي ، فإنك تستخدم معايير التواريخ بنفس الطريقة التي تستخدم بها الأرقام.

إلىلتوضيح ذلك ، سنستبدل العمود العمر بـ تاريخ الميلاد ونحاول تحديد أقصى ارتفاع بين الأولاد المولودين في سنة معينة ، على سبيل المثال في عام 2004. لإنجاز هذه المهمة ، نحتاج إلى "تصفية" تواريخ الميلاد الأكبر من أو المساوية لـ 1-Jan-2004 وأقل من أو تساوي 31-Dec-2004.

عند بناء المعايير الخاصة بك ، من المهم أن قدم التواريخ بالتنسيق الذي يمكن أن يفهمه Excel:

=MAXIFS(D2:D11, C2:C11, ">=1-Jan-2004", C2:C11, "<=31-Dec-2004")

أو

=MAXIFS(D2:D11, C2:C11, ">=1/1/2004", C2:C11, "<=12/31/2004")

لمنع التفسير الخاطئ ، من المنطقي استخدام وظيفة DATE :

=MAXIFS(D2:D11, C2:C11, ">="&DATE(2004,1,1), C2:C11, "<="&DATE(2004,12,31))

في هذا المثال ، سنكتب السنة المستهدفة في G1 ، ثم نستخدم وظيفة DATE لتوفير التواريخ:

=MAXIFS(D2:D11, C2:C11, ">="&DATE(G1,1,1), C2:C11, "<="&DATE(G1,12,31))

ملاحظة. على عكس الأرقام ، يجب وضع التواريخ بين علامات اقتباس عند استخدامها في المعايير بمفردها. على سبيل المثال:

=MAXIFS(D2:D11, C2:C11, "10/5/2005")

ابحث عن القيمة القصوى بناءً على معايير متعددة مع منطق OR

تم تصميم وظيفة Excel MAXIFS لاختبار الشروط باستخدام منطق AND - أي أنها تعالج هذه الأرقام فقط في max_range تكون جميع المعايير الخاصة بها TRUE. ومع ذلك ، في بعض الحالات ، قد تحتاج إلى تقييم الشروط باستخدام منطق OR - أي معالجة جميع الأرقام التي يكون أي من المعايير المحددة لها TRUE.

لتسهيل فهم الأمور ، يرجى مراعاة ما يلي مثال. لنفترض أنك تريد العثور على أقصى ارتفاع للاعبين الذين يلعبون كرة السلة أوكرة القدم. كيف يمكنك أن تفعل ذلك؟ لن ينجح استخدام "كرة السلة" كمعيار 1 ومعيار "كرة القدم" 2 ، لأن Excel يفترض أن كلا المعيارين يجب أن يتم تقييمهما إلى TRUE.

الحل هو عمل صيغتين منفصلتين من MAXIFS ، واحدة لكل رياضة ، ثم استخدم وظيفة MAX القديمة الجيدة لإرجاع رقم أعلى:

=MAX(MAXIFS(C2:C11, B2:B11, "basketball"), MAXIFS(C2:C11, B2:B11, "football"))

توضح لقطة الشاشة أدناه هذه الصيغة ولكن مع المعايير الموجودة في خلايا الإدخال المحددة مسبقًا ، F1 و H1:

هناك طريقة أخرى وهي استخدام صيغة MAX IF مع منطق OR.

7 أشياء يجب تذكرها حول Excel MAXIFS

ستجد أدناه بعض الملاحظات سيساعد ذلك في تحسين الصيغ الخاصة بك وتجنب الأخطاء الشائعة. تمت مناقشة بعض هذه الملاحظات بالفعل كنصائح وملاحظات في أمثلةنا ، ولكن قد يكون من المفيد الحصول على ملخص قصير لما تعلمته بالفعل:

1. يمكن أن تحصل وظيفة MAXIFS في Excel أعلى قيمة تستند إلى واحد أو معايير متعددة .
2. افتراضيًا ، يعمل Excel MAXIFS مع ومنطق ، أي يُرجع الحد الأقصى للرقم يفي بجميع الشروط المحددة.
3. لكي تعمل الوظيفة ، يجب أن يكون للنطاق الأقصى ونطاقات المعايير نفس الحجم والشكل .
4. وظيفة SUMIF هي حساسة لحالة الأحرف ، أي أنها لا تتعرف على حالة الأحرف في معايير النص.
5. عند كتابة صيغة MAXIFS لخلايا متعددة ، تذكر أن قفل نطاقات معمراجع الخلية المطلقة للصيغة لنسخها بشكل صحيح.
6. ضع في اعتبارك بناء جملة لمعاييرك ! فيما يلي القواعد الرئيسية:
   • عند استخدامها بمفردها ، يجب وضع النص والتواريخ بين علامتي اقتباس ، ويجب ألا يتم وضع الأرقام ومراجع الخلايا.
   • عند استخدام رقم أو تاريخ أو نص باستخدام عامل منطقي ، يجب وضع التعبير بالكامل بين علامتي اقتباس مثل "& gt؛ = 10"؛ يجب أن تكون مراجع الخلايا والوظائف الأخرى متسلسلة باستخدام علامة العطف مثل "& gt؛" & amp؛ G1.
7. يتوفر MAXIFS فقط في Excel 2019 و Excel for Office 365. في الإصدارات السابقة ، هذه الوظيفة غير متوفرة.

هذه هي الطريقة التي يمكنك بها العثور على القيمة القصوى في Excel بشروط. أشكرك على القراءة وآمل أن أراك على مدونتنا قريبًا!

تنزيل المصنف التدريبي:

أمثلة صيغ Excel MAXIFS (ملف .xlsx)