Vejledningen viser, hvordan du bruger PMT-funktionen i Excel til at beregne betalinger for et lån eller en investering baseret på rentesatsen, antallet af betalinger og det samlede lånebeløb.

Før du låner penge, er det godt at vide, hvordan et lån fungerer. Takket være Excel's finansielle funktioner som RATE, PPMT og IPMT er det nemt at beregne den månedlige eller enhver anden periodisk betaling for et lån. I denne vejledning vil vi se nærmere på PMT-funktionen, diskutere dens syntaks i detaljer og vise, hvordan du kan bygge din egen PMT-beregner i Excel.

Hvad er PMT-funktionen i Excel?

Excel PMT-funktionen er en finansiel funktion, der beregner betalingen for et lån baseret på en konstant rentesats, antallet af perioder og lånebeløbet.

"PMT" står for "betaling", deraf navnet på funktionen.

Hvis du f.eks. ansøger om et toårigt billån med en årlig rente på 7 % og et lånebeløb på 30.000 USD, kan en PMT-formel fortælle dig, hvad dine månedlige betalinger vil være.

For at PMT-funktionen kan fungere korrekt i dine regneark, skal du huske på følgende fakta:

• For at være i overensstemmelse med den generelle pengestrømsmodel udskrives betalingsbeløbet som en negativt tal fordi det er en udbetaling af kontanter.
• Den værdi, der returneres af PMT-funktionen, omfatter hovedforpligtet og renter men omfatter ikke gebyrer, skatter eller reservebetalinger, der kan være forbundet med et lån.
• En PMT-formel i Excel kan beregne en lånebetaling for forskellige betalingsfrekvenser, f.eks. ugentlig , månedlig , kvartalsvis , eller årligt Dette eksempel viser, hvordan du gør det korrekt.

PMT-funktionen er tilgængelig i Excel til Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010 og Excel 2007.

Excel PMT-funktion - syntaks og grundlæggende anvendelser

PMT-funktionen har følgende argumenter:

Hvor:

• Vurder (påkrævet) - den konstante rentesats pr. periode. Kan angives som procent eller decimaltal.

  Hvis du f.eks. laver årlige betalinger på et lån med en årlig rente på 10 procent, skal du bruge 10 % eller 0,1 for sats. Hvis du betaler månedlig betalinger på det samme lån, så brug 10 %/12 eller 0,00833 som sats.

• Nper (påkrævet) - antallet af betalinger for lånet, dvs. det samlede antal perioder, som lånet skal betales over.

  Hvis du f.eks. laver årlige afdrag på et 5-årigt lån, skal du angive 5 for nper. Hvis du foretager månedlig betalinger på det samme lån, så ganges antallet af år med 12, og der anvendes 5*12 eller 60 som nper.

• Pv (påkrævet) - nutidsværdien, dvs. det samlede beløb, som alle fremtidige betalinger er værd nu. Hvis der er tale om et lån, er det simpelthen det oprindelige lånte beløb.
• Fv (valgfrit) - den fremtidige værdi eller den kontant saldo, du ønsker at have efter den sidste betaling. Hvis den udelades, antages lånets fremtidige værdi at være nul (0).
• Type (valgfrit) - angiver, hvornår betalingerne skal forfalde:
  • 0 eller udeladt - betalingerne forfalder ved udgangen af hver periode.
  • 1 - betalinger forfalder ved begyndelsen af hver periode.

Hvis du f.eks. låner 100.000 USD i 5 år med en årlig rente på 7 %, vil følgende formel beregne den årlig betaling :

=PMT(7%, 5, 100000)

For at finde den månedlig betaling for det samme lån ved at bruge denne formel:

=PMT(7%/12, 5*12, 100000)

Eller du kan indtaste de kendte komponenter i et lån i separate celler og henvise til disse celler i din PMT-formel. Med rentesatsen i B1, antal år i B2 og lånebeløbet i B3 er formlen så enkel som denne:

=PMT(B1, B2, B3)

Husk, at betalingen returneres som en negativt tal fordi dette beløb vil blive trukket fra din bankkonto.

Som standard viser Excel resultatet i Valuta format, afrundet til 2 decimaler, markeret med rødt og omgivet af parenteser, som vist i den venstre del af billedet nedenfor. Billedet til højre viser det samme resultat i formatet Generelt format.

Hvis du gerne vil have betalingen som en positiv nummer , sætte et minustegn foran enten hele PMT-formlen eller pv argument (lånebeløb):

=-PMT(B1, B2, B3)

eller

=PMT(B1, B2, -B3)

Tip. For at beregne den samlet beløb betalt for lånet, multipliceres den returnerede PMT-værdi med antallet af perioder (nper-værdi). I vores tilfælde bruger vi denne ligning: 24 389,07*5 og finder ud af, at det samlede beløb er lig med 121 945,35 USD.

Sådan bruger du PMT-funktionen i Excel - eksempler på formler

Nedenfor finder du nogle flere eksempler på en Excel PMT-formel, der viser, hvordan du kan beregne forskellige periodiske betalinger for et billån, boliglån, realkreditlån og lignende.

Den fulde form af PMT-funktionen i Excel

For det meste kan du udelade de to sidste argumenter i dine PMT-formler (som vi gjorde i ovenstående eksempler), fordi deres standardværdier dækker de mest typiske tilfælde af brug:

• Fv udeladt - indebærer nul-saldo efter den sidste betaling.
• Type udeladt - betalingerne forfalder ved den end i hver periode.

Hvis dine lånebetingelser er anderledes end de misligholdte lån, skal du bruge den fulde formular af PMT-formlen.

Lad os som eksempel beregne mængden af årlige betalinger på grundlag af disse indgangsceller:

• B1 - årlig rentesats
• B2 - lånets løbetid (i år)
• B3 - lånebeløb
• B4 - fremtidig værdi (saldo efter den sidste betaling)
• B5 - type af livrente:
  • 0 (almindelig livrente) - udbetalingerne sker ved udgangen af hvert år.
  • 1 (forfalden annuitetsydelse) - betalinger foretages ved periodens begyndelse, f.eks. leje eller leasingydelser.

Angiv disse referencer i din Excel PMT-formel:

=PMT(B1, B2, B3, B4, B5)

Og du vil få dette resultat:

Beregne ugentlige, månedlige, kvartalsvise og halvårlige betalinger

Afhængigt af betalingshyppigheden skal du bruge følgende beregninger til at sats og nper argumenter:

• Til sats , dividerer den årlige rente med antallet af betalinger pr. år (som anses for at være lig med antallet af rentes renteperioder).
• Til nper , multiplicer antallet af år med antallet af betalinger pr. år.

Nedenstående tabel indeholder nærmere oplysninger:

Hvis du f.eks. vil finde beløbet for en periodisk betaling på et lån på 5.000 USD med en årlig rente på 8 % og en løbetid på 3 år, skal du bruge en af nedenstående formler.

Ugentlig betaling:

=PMT(8%/52, 3*52, 5000)

Månedlig betaling:

=PMT(8%/12, 3*12, 5000)

Kvartalsvis betaling:

=PMT(8%/4, 3*4, 5000)

Halvårligt betaling:

=PMT(8%/2, 3*2, 5000)

I alle tilfælde antages saldoen efter den sidste betaling at være 0 USD, og betalingerne forfalder ved udgangen af hver periode.

Skærmbilledet nedenfor viser resultaterne af disse formler:

Sådan laver du en PMT-beregner i Excel

Før du går i gang med at låne penge, er det oplagt at sammenligne forskellige lånebetingelser for at finde ud af, hvilke muligheder der passer bedst til dig. Lad os derfor oprette vores egen Excel-låneberegner.

1. Indtast til at begynde med lånebeløb, rentesats og løbetid i separate celler (henholdsvis B3, B4 og B5).
2. For at kunne vælge forskellige perioder og angive, hvornår betalingerne skal forfalde, skal du oprette drop-down-lister med følgende foruddefinerede muligheder (B6 og B7):

   

3. Opsætning af opslagstabellerne for Perioder (E2:F6) og Betalinger forfalder (E8:F9) som vist i skærmbilledet nedenfor. Det er vigtigt, at tekstmærkerne i opslagstabellerne passer nøjagtigt til elementerne i den tilsvarende rulleliste.

   Indtast følgende IFERROR VLOOKUP-formler i cellerne ved siden af rullelisterne, som trækker det tal fra opslagstabellen, der svarer til det element, der er valgt i rullelisten.

   Formel for Perioder (C6):

   =IFERROR(VLOOKUP(B6, E2:F6, 2, 0), "")

   Formel for Betalinger forfalder (C7):

   =IFERROR(VLOOKUP(B7, E8:F9, 2, 0), "")

   

4. Skriv en PMT-formel til at beregne den periodiske betaling ud fra dine celler. I vores tilfælde ser formlen således ud:

   =IFERROR(-PMT(B4/C6, B5*C6, B3, 0, C7), "")

   Vær opmærksom på følgende ting:

   • fv argumentet (0) er hardcoded i formlen, fordi vi altid ønsker en saldo på nul efter den sidste betaling. Hvis du ønsker at give dine brugere mulighed for at indtaste en fremtidig værdi, skal du tildele en separat indtastningscelle til fv-argumentet.
   • PMT-funktionen indledes med et minustegn for at vise resultatet som et positivt tal .
   • PMT-funktionen er pakket ind i IFERROR for at skjule fejl, når nogle inputværdier ikke er defineret.

   Ovenstående formel skal stå i B9. Og i nabocellen (A9) viser vi en etiket, der svarer til den valgte periode (B6). For at gøre dette skal du blot sammenkæde værdien i B6 og den ønskede tekst:

   =B6&" Betaling"

   

5. Til sidst kan du skjule opslagstabellerne fra synligheden, tilføje et par sidste formateringer, og så er din Excel PMT-beregner klar til brug:

   

Excel PMT-funktionen fungerer ikke

Hvis din Excel PMT-formel ikke fungerer eller giver forkerte resultater, skyldes det sandsynligvis følgende årsager:

• Der kan opstå en #NUM! fejl, hvis enten sats argumentet er et negativt tal eller nper er lig med 0.
• Der opstår en #VALUE! fejl, hvis et eller flere af argumenterne er tekstværdier.
• Hvis resultatet af en PMT-formel er meget højere eller lavere end forventet, skal du sikre dig, at du er konsekvent med de enheder, der er angivet for sats og nper argumenter, hvilket betyder, at du har konverteret den årlige rente korrekt til periodens rente og antallet af år til uger, måneder eller kvartaler, som vist i dette eksempel.

Sådan beregner du PMT-funktionen i Excel. Hvis du vil se nærmere på de formler, der er beskrevet i denne vejledning, er du velkommen til at downloade vores prøvearbejdsmappe nedenfor. Tak fordi du læste med og håber at se dig på vores blog i næste uge!

Arbejdsbog til download

PMT-formel i Excel - eksempler(.xlsx-fil)