En aquest tutorial, aprendràs a comptar valors únics a Excel amb fórmules i a obtenir un recompte automàtic de valors diferents en una taula dinàmica. També parlarem d'una sèrie d'exemples de fórmules per comptar noms únics, textos, números, valors únics sensibles a majúscules i molt més.

Quan treballeu amb un conjunt de dades gran a Excel, sovint haureu de fer-ho. saber quants valors duplicats i únics hi ha. I de vegades, potser voldreu comptar només els valors distints (diferents).

Si heu estat visitant aquest bloc de manera habitual, ja coneixeu la fórmula d'Excel per comptar els duplicats. I avui, explorarem diferents maneres de comptar valors únics a Excel. Però per motius de claredat, primer definim els termes.

• Valors únics : aquests són els valors que només apareixen una vegada a la llista.
• Valors diferents: tots aquests són valors diferents de la llista, és a dir, valors únics més les primeres ocurrències de valors duplicats.

La captura de pantalla següent mostra la diferència:

I ara, vegem com es poden comptar valors únics i diferents a Excel mitjançant fórmules i funcions de taula dinàmica.

Com comptar valors únics a Excel

Aquí hi ha una tasca habitual que tots els usuaris d'Excel han de realitzar de tant en tant. Teniu una llista de dades i heu d'esbrinar el nombre de valors únics que hi haestigueu atents!

Comptar valors únics en una columna

Suposant que teniu una columna de noms al vostre Excel full de treball i heu de comptar els noms únics en aquesta columna. La solució és utilitzar la funció SUMA en combinació amb SI i COUNTIF:

Nota . Aquesta és una fórmula de matriu, així que assegureu-vos de prémer Ctrl + Maj + Retorn per completar-la. Un cop fet això, Excel tancarà automàticament la fórmula entre {clapes} com a la captura de pantalla següent. En cap cas hauríeu d'escriure les claus manualment, això no funcionarà.

En aquest exemple, estem comptant noms únics a l'interval A2:A10, de manera que la nostra fórmula pren la forma següent:

=SUM(IF(COUNTIF(A2:A10,A2:A10)=1,1,0))

Més endavant en aquest tutorial, parlarem d'un grapat d'altres fórmules per comptar valors únics de diferents tipus. I com que totes aquestes fórmules són variacions de la fórmula bàsica de valors únics d'Excel, té sentit desglossar la fórmula anterior, de manera que pugueu entendre completament com funciona i ajustar-la per a les vostres dades. Si algú no està interessat en els aspectes tècnics, podeu passar directament a l'exemple de fórmula següent.

Com funciona la fórmula de recompte de valors únics d'Excel

Com veieu, s'utilitzen 3 funcions diferents a la nostra fórmula única. fórmula de valors - SUMA, SIi COUNTIF. Mirant des de dins cap a fora, aquí teniu el que fa cada funció:

• La funció COUNTIF compta el nombre de vegades que apareix cada valor individual a l'interval especificat.

  En aquest exemple, COUNTIF(A2:A10,A2:A10) retorna la matriu {1;2;2;1;2;2;2;1;2} .

• La funció SI avalua cada valor de la matriu que retorna COUNTIF, conserva tots els 1 (valors únics) i substitueix tots els altres valors per zeros. .

  Així, la funció IF(COUNTIF(A2:A10,A2:A10)=1,1,0) es converteix en IF(1;2;2;1;2;2;2;1;2) = 1,1,0, que es converteix en la matriu {1;0;0;1;0;0;0;1;0} on 1 és un valor únic i 0 és un valor duplicat.

• Finalment, la funció SUMA suma els valors de la matriu que retorna IF i mostra el nombre total de valors únics, que és exactament el que volíem.

Consell . Per veure com avalua una part específica de la vostra fórmula de valors únics d'Excel, seleccioneu aquesta part a la barra de fórmules i premeu la tecla F9.

Comptar valors de text únics a Excel

Si la vostra llista d'Excel conté valors tant numèrics com de text i voleu comptar només valors de text únics, afegiu la funció ISTEXT a la fórmula de matriu que s'ha comentat anteriorment:

=SUM(IF(ISTEXT(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

Com sabeu, la funció ISTEXT d'Excel retorna TRUE si un valor avaluat és text, FALSE en cas contrari. Com que l'asterisc (*) funciona com a operador AND a les fórmules de matriu, la funció SI només retorna 1 si un valor és alhora text i únic, 0 en cas contrari. I després que la funció SUMA sumi tots els 1, obtindreu un recompte de valors de text únics a l'especificatinterval.

No us oblideu de prémer Ctrl + Maj + Retorn per introduir correctament la fórmula de matriu i obtindreu un resultat semblant a aquest:

Com podeu veure a la captura de pantalla anterior, la fórmula retorna el nombre total de valors de text únics, excloent cel·les en blanc, números, valors lògics de VERTADER i FALS i errors.

Comptar valors numèrics únics a Excel

Per comptar números únics en una llista de dades, utilitzeu una fórmula de matriu com acabem d'utilitzar per comptar valors de text únics, amb l'única diferència que incrusteu ISNUMBER en lloc d'ISTEXT a la vostra fórmula de valors únics:

=SUM(IF(ISNUMBER(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

Nota. Com que Microsoft Excel emmagatzema les dates i les hores com a números de sèrie, també es compten.

Comptar els valors únics que distingeixen entre majúscules i minúscules a Excel

Si la vostra taula conté dades que distingeixen entre majúscules i minúscules, la manera més fàcil de comptar els valors únics serien crear una columna d'ajuda amb la fórmula de matriu següent per identificar els elements duplicats i únics:

=IF(SUM((--EXACT($A$2:$A$10,A2)))=1,"Unique","Dupe")

I després, utilitzeu una funció simple COUNTIF per comptar valors únics:

=COUNTIF(B2:B10, "unique")

Comptar valors diferents a Excel (ocurrències úniques i primeres duplicades)

Per obtenir un recompte de valors diferents en una llista, utilitzeu el següent fórmula:

Recordeu que és una fórmula matricial i, per tant, hauríeu de prémer Ctrl + Maj + Intro drecera en lloc de l'habitual Entertecla.

Com a alternativa, podeu utilitzar la funció SUMAPRODUCTE i completar la fórmula de la manera habitual prement la tecla Intro:

Per exemple, per comptar els diferents valors de l'interval A2:A10, podeu anar amb:

=SUM(1/COUNTIF(A2:A10,A2:A10))

O

=SUMPRODUCT(1/COUNTIF(A2:A10,A2:A10))

Com funciona la fórmula diferent d'Excel

Com ja sabeu, utilitzem la funció COUNTIF per saber quantes vegades apareix cada valor individual al rang especificat. A l'exemple anterior, el resultat de la funció COUNTIF és la matriu següent: {2;2;3;1;2;2;3;1;3} .

Després d'això, es realitzen diverses operacions de divisió, on cada valor de la matriu s'utilitza com a divisor amb 1 com a dividend. Això converteix tots els valors duplicats en nombres fraccionaris corresponents al nombre d'ocurrències duplicades. Per exemple, si un valor apareix 2 vegades a la llista, genera 2 elements a la matriu amb un valor de 0,5 (1/2=0,5). I si un valor apareix 3 vegades, produeix 3 elements a la matriu amb un valor de 0,3(3). En el nostre exemple, el resultat de 1/COUNTIF(A2:A10,A2:A10)) és la matriu {0.5;0.5;0.3(3);1;0.5;0.5;0.3(3);1;0.3(3)} .

No té gaire sentit fins ara? Això és perquè encara no hem aplicat la funció SUMA / SUMAPRODUCTE. Quan una d'aquestes funcions suma els valors de la matriu, la suma de tots els nombres fraccionaris de cada element individual sempre dóna 1, sense importar quantes ocurrències d'aquest element hi hagi a la llista. Icom que tots els valors únics apareixen a la matriu com a 1 (1/1=1), el resultat final que retorna la fórmula és el nombre total de tots els diferents valors de la llista.

Fórmules per comptar diferents valors de diferents tipus

Com passa amb el recompte de valors únics a Excel, podeu utilitzar variacions de la fórmula bàsica de recompte d'Excel per gestionar tipus de valors específics, com ara números, text i valors que distingeixen entre majúscules i minúscules.

Recordeu que totes les fórmules següents són fórmules de matriu i requereixen prémer Ctrl + Maj + Retorn .

Comptar valors diferents ignorant les cel·les buides

Si una columna on voleu comptar valors diferents pot contenir cel·les en blanc, hauríeu d'afegir una funció SI que comprovarà l'interval especificat per als espais en blanc (la fórmula bàsica d'Excel diferent que es va comentar anteriorment retornaria l'error #DIV/0 en aquest cas):

Per exemple, per comptar valors diferents a l'interval A2:A10, utilitzeu el següent fórmula de matriu :

=SUM(IF(A2:A10"",1/COUNTIF(A2:A10, A2:A10), 0))

Fórmula per comptar diferents valors de text

Per comptar diferents valors de text en una columna, farem servir el mateix enfocament que acabem d'utilitzar per excloure cel·les buides.

Com podeu endevinar fàcilment, simplement inserirem la funció ISTEXT a la nostra fórmula diferent de recompte d'Excel:

I aquí hi ha una vida realExemple de fórmula:

=SUM(IF(ISTEXT(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

Fórmula per comptar diferents números

Per comptar diferents valors numèrics (nombres, dates i hores), utilitzeu la funció ISNUMBER:

Per exemple, per comptar tots els números diferents a l'interval A2:A10, utilitzeu la fórmula següent:

=SUM(IF(ISNUMBER(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

Comptar els valors diferents que distingeixen entre majúscules i minúscules a Excel

De manera semblant a comptar els valors únics que distingeixen entre majúscules i minúscules, la manera més senzilla comptar els valors diferents que distingeixen entre majúscules i minúscules és afegir una columna auxiliar amb la fórmula de matriu que identifiqui valors únics, incloses les primeres ocurrències duplicades. La fórmula és bàsicament la mateixa que la que hem utilitzat per comptar els valors únics que distingeixen entre majúscules i minúscules, amb un petit canvi a la referència d'una cel·la que fa una gran diferència:

=IF(SUM((--EXACT($A$2:$A2,$A2)))=1,"Distinct","")

Com recordeu, totes les fórmules de matriu d'Excel requereixen prémer Ctrl + Maj + Retorn .

Un cop finalitzada la fórmula anterior, podeu comptar els valors "diferents" amb una fórmula COUNTIF habitual com aquesta:

=COUNTIF(B2:B10, "distinct")

Si no hi ha manera d'afegir una columna d'ajuda al vostre full de treball, podeu utilitzar la següent complexa fórmula de matriu per comptar valors diferents que distingeixen entre majúscules i minúscules sense creant una columna addicional:

=SUM(IFERROR(1/IF($A$2:$A$10"", FREQUENCY(IF(EXACT($A$2:$A$10, TRANSPOSE($A$2:$A$10)), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10)), ""), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10))), 0), 0))

Comptar files úniques i diferents a Excel

Comptar files úniques/diferents a Excel és semblant a comptar valors únics i diferents, amb l'únic diferènciaque utilitzeu la funció COUNTIFS en lloc de COUNTIF, que us permet especificar diverses columnes per comprovar si hi ha valors únics.

Per exemple, per comptar noms únics o diferents segons els valors de les columnes A (Nom) i B (Cognoms), utilitzeu una de les fórmules següents:

Fórmula per comptar files úniques:

=SUM(IF(COUNTIFS(A2:A10,A2:A10, B2:B10,B2:B10)=1,1,0))

Fórmula per comptar diferents files:

=SUM(1/COUNTIFS(A2:A10,A2:A10,B2:B10,B2:B10))

Naturalment, no us limiteu a comptar files úniques basades només en dues columnes, la funció d'Excel COUNTIFS pot processar fins a 127 parells d'interval/criteri.

Comptar diferents valors a Excel mitjançant una taula dinàmica

Les últimes versions d' Excel 2013 i Excel 2016 tenen un característica especial que permet comptar diferents valors automàticament en una taula dinàmica. La captura de pantalla següent dóna una idea de com es veu el Recompte diferent d'Excel:

Per crear una taula dinàmica amb el recompte diferent d'una columna determinada, realitzeu els passos següents.

1. Seleccioneu les dades que voleu incloure en una taula dinàmica, canvieu a la pestanya Insereix , grup Taules i feu clic al botó Botó Taula dinàmica .
2. Al diàleg Crea una taula dinàmica , trieu si voleu col·locar la vostra taula dinàmica en un full de treball nou o existent i assegureu-vos de seleccionar el Afegeix. aquestes dades a la casella Model de dades .

També pots donar un nom personalitzat al teu Distinct Count si vols.

Fet! La taula dinàmica de nova creació mostrarà el recompte diferent com es mostra a la primera captura de pantalla d'aquesta secció.

Consell. Després d'actualitzar les dades d'origen, recordeu actualitzar la taula dinàmica per actualitzar el recompte diferent. Per actualitzar una taula dinàmica, només cal que feu clic al botó Actualitza de la pestanya Analitza , al grup Dades .

Així és com compteu. valors diferents i únics a Excel. Si algú vol mirar més de prop les fórmules que es comenten en aquest tutorial, us convidem a descarregar-vos el llibre de treball d'Excel Count Unique de mostra.

Gràcies per llegir-lo i espero tornar-vos a veure la setmana vinent. En el següent article, parlarem de diverses maneres de trobar, filtrar, extreure i ressaltar valors únics a Excel. Si us plau