Dok Microsoft Excel nudi niz funkcija za rad sa danima u nedelji, mesecima i godinama, samo jedna je dostupna nedeljama - funkcija WEEKNUM. Dakle, ako tražite način da dobijete broj sedmice iz datuma, WEEKNUM je funkcija koju želite.

U ovom kratkom vodiču, ukratko ćemo govoriti o sintaksi i argumentima Excel WEEKNUM, i zatim razgovarajte o nekoliko primjera formule koji pokazuju kako možete koristiti funkciju WEEKNUM za izračunavanje brojeva sedmica u vašim Excel radnim listovima.

Excel funkcija WEEKNUM - sintaksa

Funkcija WEEKNUM je koristi se u Excelu za vraćanje broja sedmice određenog datuma u godini (broj između 1 i 54). Ima dva argumenta, prvi je obavezan, a 2. opcioni:

• Serijski_broj - bilo koji datum u sedmici čiji broj pokušavate naći. Ovo može biti referenca na ćeliju koja sadrži datum, datum unet korištenjem funkcije DATE ili vraćen nekom drugom formulom.
• Vrsta_povrata (opcionalno) - broj koji određuje na kojem dan u sedmici. Ako se izostavi, koristi se podrazumevani tip 1 (sedmica koja počinje u nedelju).

Ovde je kompletna lista return_type vrednosti podržanih u formulama WEEKNUM.

U funkciji WEEKNUM koriste se dva različita sistema numeriranja sedmica :

• Sistem 1. Smatra se sedmica koja sadrži 1. januar 1. sedmica u godini i označena je brojem sedmica 1. U ovom sistemu sedmica tradicionalno počinje nedjeljom.
• Sistem 2. Ovo je ISO sistem datuma u sedmici koji je dio ISO 8601 standard datuma i vremena. U ovom sistemu sedmica počinje u ponedjeljak, a sedmica koja sadrži prvi četvrtak u godini smatra se sedmicom 1. Općenito je poznat kao evropski sistem brojeva sedmica i koristi se uglavnom u vladi i poslovanju za fiskalne godine i mjerenje vremena.

Svi gore navedeni tipovi povrata primjenjuju se na Sistem 1, osim za tip povrata 21 koji se koristi u Sistemu 2.

Napomena. U programu Excel 2007 i starijim verzijama dostupne su samo opcije 1 i 2. Tipovi povrata od 11 do 21 podržani su samo u Excel 2010 i Excel 2013.

Excel WEEKNUM formule za pretvaranje datuma u broj sedmice (od 1 do 54)

Sljedeći snimak ekrana pokazuje kako možete dobiti brojeve sedmica iz datuma pomoću najjednostavnije formule =WEEKNUM(A2) :

U gore navedenomformule, argument return_type je izostavljen, što znači da se koristi zadani tip 1 - sedmica koja počinje nedjeljom.

Ako biste radije počeli s nekim drugim danom u sedmici, recimo ponedjeljkom, onda koristite 2 u drugom argumentu:

=WEEKNUM(A2, 2)

Umjesto da se pozivate na ćeliju, možete odrediti datum direktno u formuli korištenjem funkcije DATE(godina, mjesec, dan), na primjer:

=WEEKNUM(DATE(2015,4,15), 2)

Gorenja formula vraća 16, što je broj sedmice koja sadrži 15. april 2015., sa sedmicom koja počinje u ponedjeljak.

U stvarnim scenarijima , funkcija Excel WEEKNUM se rijetko koristi samostalno. Najčešće biste ga koristili u kombinaciji s drugim funkcijama za izvođenje različitih izračuna na osnovu broja sedmice, kao što je prikazano u daljnjim primjerima.

Kako pretvoriti broj sedmice u datum u Excelu

Kao što Upravo smo vidjeli, nije velika stvar pretvoriti datum u broj sedmice pomoću funkcije Excel WEEKNUM. Ali šta ako tražite suprotno, tj. pretvaranje broja sedmice u datum? Nažalost, ne postoji Excel funkcija koja bi to mogla učiniti odmah. Dakle, morat ćemo konstruirati naše vlastite formule.

Pretpostavimo da imate godinu u ćeliji A2 i broj sedmice u B2, a sada želite izračunati početni i završni datum u ovoj sedmici.

Napomena. Ovaj primjer formule je zasnovan na ISO brojevima sedmica, pri čemu sedmica počinje u ponedjeljak.

Formula za vraćanje Startdatum u sedmici je kako slijedi:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7

Gdje je A2 godina, a B2 broj sedmice.

Imajte na umu da formula vraća datum kao serijski broj, a da bi se prikazao kao datum, potrebno je da formatirate ćeliju u skladu s tim. Detaljna uputstva možete pronaći u Promena formata datuma u programu Excel. A evo rezultata koji daje formula:

Naravno, formula za pretvaranje broja sedmice u datum nije trivijalna i može potrajati da se dobije tvoja glava oko logike. U svakom slučaju, dat ću sve od sebe da pružim smisleno objašnjenje za one koji su znatiželjni da dođu do dna.

Kao što vidite, naša formula se sastoji od 2 dijela:

• DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) - izračunava datum posljednjeg ponedjeljka u prethodnoj godini.
• B2 * 7 - dodaje broj sedmica pomnožen sa 7 (broj dana u sedmici) da bi se dobio ponedjeljak (datum početka) u sedmici u pitanje.

U ISO sistemu numerisanja sedmica, sedmica 1 je sedmica koja sadrži prvi četvrtak u godini. Prema tome, prvi ponedjeljak je uvijek između 29. decembra i 4. januara. Dakle, da bismo pronašli taj datum, moramo pronaći ponedjeljak neposredno prije 5. januara.

U Microsoft Excelu možete izdvojiti dan u sedmici iz datum korištenjem funkcije WEEKDAY. I možete koristiti sljedeću generičku formulu da dobijete ponedjeljak neposredno prije bilo kojeg datuma:

Ako je naškrajnji cilj je bio pronaći ponedjeljak neposredno prije 5. januara godine u A2, mogli bismo koristiti sljedeće funkcije DATE:

=DATE(A2,1,5) - WEEKDAY(DATE(A2,1,3))

Ali ono što nam zapravo treba nije prvi ponedjeljak u ove godine, već posljednjeg ponedjeljka prethodne godine. Dakle, morate oduzeti 7 dana od 5. januara i tako ćete dobiti -2 u prvoj funkciji DATE:

=DATE(A2,1,-2) - WEEKDAY(DATE(A2,1,3))

U poređenju sa lukavom formulom koju ste upravo naučili, računajući Završni datum sedmice je pravi komad :) Da biste dobili nedjelju u sedmici o kojoj je riječ, jednostavno dodate 6 dana Datumu početka , tj. =D2+6

Alternativno, možete dodati 6 direktno u formulu:

=DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7 + 6

Da biste bili sigurni da formule uvijek isporučuju prave datume, pogledajte sljedeće screenshot. Formule datuma početka i datuma završetka koje smo gore raspravljali kopiraju se u kolonu D i E, redom:

Drugi načini za pretvaranje broja sedmice u datum u Excelu

Ako gornja formula zasnovana na ISO sistemu datuma u sedmici ne ispunjava vaše zahtjeve, pokušajte sa jednim od sljedećih rješenja.

Formula 1. Sedmica koja sadrži januar-1 je sedmica 1, pon-ned sedmica

Kao što se sjećate, prethodna formula funkcionira na osnovu ISO sistema datuma gdje se prvi četvrtak u godini smatra sedmicom 1. Ako radite na osnovu sistema datuma gdje se sedmica koja sadrži 1. januar smatra sedmicom 1, koristite sljedećeformule:

Datum početka:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1

Datum završetka:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),2) + B2*7

Formula 2. Sedmica koja sadrži januar-1 je sedmica 1, ned-sub sedmica

Ove formule su slične gornjim sa jedinom razlikom što su napisane za nedelju - subota.

Datum početka:

=DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1

Datum završetka:

=DATE(A2,1,1)- WEEKDAY(DATE(A2,1,1),1) + B2*7

Formula 3. Uvijek počnite računati 1. januara, sedmica pon-ned

Dok se prethodne formule vraćaju u ponedjeljak (ili nedjelju) 1. sedmice, bez obzira od toga da li spada u ovu ili prethodnu godinu, ova formula datuma početka uvijek vraća 1. januar kao datum početka 1. sedmice bez obzira na dan u sedmici. Po analogiji, formula krajnjeg datuma uvijek vraća 31. decembar kao krajnji datum posljednje sedmice u godini, bez obzira na dan u sedmici. U svim ostalim aspektima, ove formule rade slično kao Formula 1 iznad.

Datum početka:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + (B2-1)*7 + 1)

Datum završetka:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),2) + B2*7)

Formula 4. Uvijek počnite računati od 1. januara, nedjelja-subota

Za izračunavanje datuma početka i završetka za nedelju - subota, sve što je potrebno je jedno malo podešavanje u gornjim formulama :)

Datum početka:

=MAX(DATE(A2,1,1), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + (B2-1)*7 + 1)

Datum završetka:

=MIN(DATE(A2+1,1,0), DATE(A2,1,1) - WEEKDAY(DATE(A2,1,1),1) + B2*7)

Kako dobiti mjesec od broja sedmice

Da biste dobili mjesec koji odgovara sedmici broj, nalazite prvi dan u datoj sedmici kao što je objašnjeno u ovomeprimjer, a zatim zamotajte tu formulu u Excel funkciju MJESEC na sljedeći način:

=MONTH(DATE(A2, 1, -2) - WEEKDAY(DATE(A2, 1, 3)) + B2 * 7)

Napomena. Imajte na umu da gornja formula radi na osnovu ISO sistema datuma u sedmici , gdje sedmica počinje u ponedjeljak, a sedmica koja sadrži 1. četvrtak u godini se smatra sedmicom 1. Na primjer, u 2016. godini, prvi četvrtak je 7. januar i zato prva sedmica počinje 4. januara 2016. godine.

Kako dobiti broj sedmice u mjesecu (od 1 do 6)

Ako vaša poslovna logika zahtijeva pretvaranje određenog datuma u broj sedmice unutar odgovarajućeg mjeseca, možete koristiti kombinaciju WEEKNUM, Funkcije DATE i MONTH:

Pod pretpostavkom da ćelija A2 sadrži originalni datum, koristite sljedeću formulu za sedmicu koja počinje ponedjeljkom (obavijest 21 u argumentu return_type WEEKNUM):

=WEEKNUM($A2,21)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1),21)+1

Za nedelju koja počinje nedeljom , izostavite argument return_type:

=WEEKNUM($A2)-WEEKNUM(DATE(YEAR($A2), MONTH($A2),1))+1

Kako zbroj vrijednosti i pronađite prosjek prema broju sedmice

Sada kada znate kako pretvoriti datum u broj sedmice u Excelu, da vidimo kako možete koristiti brojeve sedmica u drugim izračunima.

Pretpostavimo , imate neke mjesečne brojke prodaje i želite znati ukupan broj za svaku sedmicu.

Za početak, hajde da saznamo broj sedmica koji odgovara svakoj prodaji. Ako su vaši datumi u koloni A, a prodaja u koloni B, kopirajte formulu =WEEKNUM(A2) preko stupca C počevši od ćelijeC2.

I onda napravite listu brojeva sedmica u nekoj drugoj koloni (recimo u koloni E) i izračunajte prodaju za svaku sedmicu koristeći sljedeću formulu ZBIR:

=SUMIF($C$2:$C$15, $E2, $B$2:$B$15)

Gdje je E2 broj sedmice.

U ovom primjeru radimo sa listom martovskih rasprodaja, tako da imamo brojeve sedmica od 10 do 14, kao prikazano na sljedećem snimku ekrana:

Na sličan način možete izračunati prosjek prodaje za datu sedmicu:

=AVERAGEIF($C$2:$C$15, $E2, $B$2:$B$15)

Ako se pomoćni stupac s formulom WEEKNUM ne uklapa dobro u vaš raspored podataka, sa žaljenjem vam moram reći da ne postoji jednostavan način da ga se riješite jer je Excel WEEKNUM jedna od tih funkcija koji ne prihvata argumente opsega. Stoga se ne može koristiti unutar SUMPRODUCT ili bilo koje druge formule polja kao što je funkcija MONTH u sličnom scenariju.

Kako istaknuti ćelije na osnovu broja sedmice

Recimo da imate dugačku listu datuma u nekoj koloni i želite da istaknete samo one koji se odnose na datu sedmicu. Sve što vam treba je pravilo uslovnog formatiranja sa WEEKNUM formulom sličnom ovoj:

=WEEKNUM($A2)=10

Kao što je prikazano na snimku ekrana ispod, pravilo naglašava prodaju ostvarene unutar 10. sedmice, a to je prva sedmica u martu 2015. Pošto se pravilo primjenjuje na A2:B15, ono ističe vrijednosti u oba stupca. Ovdje možete saznati više o kreiranju pravila uvjetnog oblikovanjaTutorial: Excel uvjetno oblikovanje na osnovu druge vrijednosti ćelije.

Ovo je način na koji možete izračunati brojeve sedmica u Excelu, pretvoriti broj sedmice u datum i izdvojiti broj sedmice iz datuma. Nadamo se da će se formule WEEKNUM koje ste danas naučili pokazati korisnima u vašim radnim listovima. U sljedećem tutorijalu govorit ćemo o izračunavanju starosti i godina u Excelu. Zahvaljujem vam na čitanju i nadam se da se vidimo sljedeće sedmice!