Tabela e përmbajtjes
Udhëzuesi tregon se si të përdoret funksioni i ri TEXTSPLIT për të ndarë vargjet në Excel 365 nga çdo kufizues që specifikoni.
Mund të ketë situata të ndryshme kur duhet të ndani qelizat në Excel. Në versionet e mëparshme, ne ishim të pajisur tashmë me një sërë instrumentesh për të përmbushur detyrën si Text to Columns dhe Fill Flash. Tani, ne kemi gjithashtu një funksion të veçantë për këtë, TEXTSPLIT, që mund të ndajë një varg në qeliza të shumta nëpër kolona ose/dhe rreshta bazuar në parametrat që specifikoni.
Funksioni Excel TEXTSPLIT
Funksioni TEXTSPLIT në Excel ndan vargjet e tekstit sipas një kufiri të caktuar nëpër kolona ose/dhe rreshta. Rezultati është një grup dinamik që derdhet në disa qeliza automatikisht.
Funksioni merr deri në 6 argumente, nga të cilat kërkohen vetëm dy të parat.
TEXTSPLIT(tekst, col_delimiter, [row_delimiter], [injoroj_empty], [match_mode], [pad_with])tekst (kërkohet) - teksti për t'u ndarë. Mund të jepet si një varg ose referencë qelize.
col_delimiter (kërkohet) - një karakter(a) që tregon se ku duhet ndarë teksti nëpër kolona. Nëse hiqet, duhet të përcaktohet delimiter_row_2>.
row_delimiter (opsionale) - një karakter(a) që tregon se ku duhet ndarë teksti nëpër rreshta.
0> ignore_empty (opsionale) - specifikon nëse do të injorohen vlerat boshe apo jo:- FALSE (e parazgjedhur) -krijoni qeliza boshe për kufizues të njëpasnjëshëm pa një vlerë në mes.
- E VËRTETË - injoroni vlerat boshe, d.m.th. mos krijoni qeliza boshe për dy ose më shumë përcaktues të njëpasnjëshëm>match_mode
- 0 (e parazgjedhur) - e ndjeshme ndaj shkronjave të vogla
- 1 - e pandjeshme ndaj shkronjave
pad_me (opsionale ) - një vlerë për t'u përdorur në vend të vlerave që mungojnë në vargjet dy-dimensionale. Parazgjedhja është një gabim #N/A.
Për shembull, për të ndarë një varg teksti në A2 në qeliza të shumta duke përdorur një presje dhe një hapësirë si ndarës, formula është:
=TEXTSPLIT(A2, ", ") 
Disponueshmëria e TEXTSPLIT
Funksioni TEXTSPLIT disponohet vetëm në Excel për Microsoft 365 (Windows dhe Mac) dhe Excel për ueb.
Këshilla:
- Në versionet e Excel ku funksioni TEXTSPLIT nuk është i disponueshëm (përveç Excel 365), mund të përdorni magjistarin "Text to Columns" për të ndarë qelizat.
- Për të kryer detyrën e kundërt, d.m.th. për të bashkuar përmbajtjet e qeliza të shumta në një duke përdorur një ndarës të caktuar, TEXTJOIN është funksioni që duhet përdorur.
Formula bazë TEXTSPLIT për të ndarë një qelizë në Excel
Për fillestarët, le të shohim se si të përdorim një TEXTSPLIT formula në formën e saj më të thjeshtë për të ndarë një varg teksti nga një ndarës i caktuar.
Ndani një qelizë horizontalisht nëpër kolona
Për të ndarë përmbajtjen e një qelize të caktuar në kolona të shumta, jepni njëreferojuni qelizës që përmban vargun origjinal për argumentin e parë ( tekst ) dhe delimiterin që shënon pikën ku duhet të ndodhë ndarja për argumentin e dytë ( col_delimiter ).
Për shembull, për të ndarë vargun në A2 horizontalisht me presje, formula është:
=TEXTSPLIT(A2, ",")
Për ndarësin, ne përdorim një presje të mbyllur në thonjëza të dyfishta ("") .
Si rezultat, çdo artikull i ndarë me presje shkon në një kolonë individuale: 
Ndani një qelizë vertikalisht nëpër rreshta
Për të ndarë tekstin në disa rreshta, e treta argumenti ( delimiter_row ) është vendi ku vendosni përcaktuesin. Argumenti i dytë ( col_delimiter ) është hequr në këtë rast.
Për shembull, për të ndarë vlerat në A2 në rreshta të ndryshëm, formula është:
=TEXTSPLIT(A2, ,",") 
Ju lutemi, vini re se, në të dyja rastet, formula futet vetëm në një qelizë (C2). Në qelizat fqinje, vlerat e kthyera derdhen automatikisht. Vargu që rezulton (i cili quhet diapazon i derdhjes) theksohet me një kufi blu që tregon se gjithçka brenda tij është llogaritur me formulën në qelizën e sipërme majtas.
Ndajeni tekstin me nënvarg
Në shumë raste, vlerat në vargun burimor ndahen nga një sekuencë karakteresh, një presje dhe një hapësirë është një shembull tipik. Për të trajtuar këtë skenar, përdorni një nënvarg për ndarësin.
Për shembull, për të ndarë tekstin në A2 në kolona të shumtame presje dhe një hapësirë, përdorni vargun ", " për col_delimiter .
=TEXTSPLIT(A2, ", ")
Kjo formulë shkon në B2 dhe më pas ju e kopjoni atë në po aq qelizat sipas nevojës. 
Ndani vargun në kolona dhe rreshta menjëherë
Për të ndarë një varg teksti në rreshta dhe kolona në të njëjtën kohë, përcaktoni të dy ndarësit në formulën tuaj TEXTSPLIT.
Për shembull, për të ndarë vargun e tekstit në A2 nëpër kolona dhe rreshta, ne japim:
- Shenjën e barabartë ("=") për col_delimiter
- Një presje dhe një space (", ") për row_delimiter
Formula e plotë merr këtë formë:
=TEXTSPLIT(A2, "=", ", ")
Rezultati është një 2-D grup i përbërë nga 2 kolona dhe 3 rreshta: 
Ndajini qelizat me përcaktues të shumtë
Për të trajtuar kufijtë e shumtë ose të paqëndrueshëm në vargun burimor, përdorni një konstante grupi si {"x","y" "z"} për argumentin ndarës.
Në pamjen e mëposhtme të ekranit, teksti në A2 kufizohet me presje (",") dhe me pikëpresje (";") me dhe pa hapësira. Për të ndarë vargun vertikalisht në rreshta nga të 4 variacionet e ndarësit, formula është:
=TEXTSPLIT(A2, , {",",", ",";","; "})
Ose, mund të përfshini vetëm një presje ("") dhe një pikëpresje ("; ") në grup, dhe më pas hiqni hapësirat shtesë me ndihmën e funksionit TRIM:
=TRIM(TEXTSPLIT(A2, , {",",";"}))
Ndajeni tekstin duke injoruar vlerat boshe
Nëse vargu përmban dy ose më shumë përcaktues të njëpasnjëshëm pa një vlerë ndërmjet tyre, ju mund të zgjidhni nëse do të shpërfillni ato boshevlerat apo jo. Kjo sjellje kontrollohet nga parametri i katërt ignore_empty , i cili parazgjedhur është FALSE.
Si parazgjedhje, funksioni TEXTSPLIT nuk i injoron vlerat boshe. Sjellja e paracaktuar funksionon mirë për të dhënat e strukturuara si në shembullin e mëposhtëm.
Në këtë tabelë mostër, rezultatet mungojnë në disa vargje. Formula TEXTSPLIT me argumentin ignore_empty të hequr ose të vendosur në FALSE e trajton këtë rast në mënyrë të përsosur, duke krijuar një qelizë boshe për çdo vlerë boshe.
=TEXTSPLIT(A2, ", ")
Ose
=TEXTSPLIT(A2, ", ", FALSE)
Si rezultat, të gjitha vlerat shfaqen në kolonat përkatëse. 
Në rast se vargjet tuaja përmbajnë të dhëna homogjene, mund të jetë e arsyeshme të injorohen vlerat boshe. Për këtë, vendosni argumentin ignore_empty në TRUE ose 1.
Për shembull, për të ndarë t vargjet e mëposhtme duke vendosur secilën aftësi në një qelizë të veçantë pa boshllëqe, formula është:
=TEXTSPLIT(A2, ", ", ,TRUE)
Në këtë rast, vlerat që mungojnë midis përcaktuesve të njëpasnjëshëm shpërfillen plotësisht: 
Qeliza e ndarjes është e ndjeshme ose e pandjeshme ndaj shkronjave
Për të kontrolluar shkronja- ndjeshmëria e delimiterit, përdorni argumentin e pestë, match_mode .
Si parazgjedhje, match_mode është vendosur në 0, duke e bërë TEXTSPLIT ndjeshme ndaj shkronjave të vogla .
Në këtë shembull, numrat ndahen me shkronjat "x" të vogla dhe të mëdha "X".
Formula me ndjeshmërinë e paracaktuar ndaj shkronjave pranon vetëm shkronjat e vogla "x". "sidelimiter:
=TEXTSPLIT(A2, " x ")
Ju lutemi, kushtojini vëmendje që ndarësi të ketë një hapësirë në të dy anët e shkronjës " x " në mënyrë që të parandalohen hapësirat kryesore dhe pasuese në rezultate. 
Për të çaktivizuar ndjeshmërinë e shkronjave, ju jepni 1 për match_mode për të detyruar formulën TEXTSPLIT të injorojë shkronjën:
=TEXTSPLIT(A2, " x ", , ,1)
Tani, të gjitha vargjet ndahen në mënyrë korrekte nga cilido përcaktues: 
Mungojnë vlerat në panelin 2D
Argumenti i fundit i funksionit TEXTSPLIT, pad_with , është i dobishëm në rast se një ose më shumë vlera mungojnë në vargun burimor. Kur një varg i tillë ndahet si në kolona ashtu edhe në rreshta, si parazgjedhje, Excel kthen gabimet #N/A në vend të vlerave që mungojnë për të mos ngatërruar strukturën e një grupi dydimensional.
Në vargun e mëposhtëm, nuk ka "=" ( col_delimiter ) pas "Rezultatit". Për të ruajtur integritetin e grupit që rezulton, TEXTSPLIT nxjerr #N/A pranë "Score". 
Për ta bërë rezultatin më miqësor për përdoruesit, mund ta zëvendësoni gabimin #N/A me çdo vlerë që dëshironi. Thjesht, shkruani vlerën e dëshiruar në argumentin pad_with .
Në rastin tonë, kjo mund të jetë një vizë ndarëse ("-"):
=TEXTSPLIT(A2, "=", ", ", , ,"-") 
Ose një varg bosh (""):
=TEXTSPLIT(A2, "=", ", ", , ,"") 
Tani që keni mësuar përdorimet praktike të secilit argument të funksionit TEXTSPLIT, le të diskutojmë disa shembuj të avancuar që mund t'ju ndihmojnë përballoni sfidat jo të parëndësishme në tabelat tuaja Excel.
Ndani datatnë ditë, muaj dhe vit
Për të ndarë një datë në njësi individuale, fillimisht duhet të konvertoni datën në tekst sepse funksioni TEXTSPLIT merret me vargjet e tekstit ndërsa datat e Excel janë numra.
Më e thjeshta mënyra për të kthyer një vlerë numerike në tekst është duke përdorur funksionin TEXT. Vetëm sigurohuni që të jepni një kod të formatit të përshtatshëm për datën tuaj.
Në rastin tonë, formula është:
=TEXT(A2, "m/d/yyyy")
Hapi tjetër është futja e funksionit të mësipërm në argumentin e parë të TEXTSPLIT dhe futni kufizuesin përkatës për argumentin e 2-të ose të 3-të, në varësi të faktit nëse po ndaheni nëpër kolona ose rreshta. Në këtë shembull, njësitë e datës kufizohen me të pjerrëta, kështu që ne përdorim "/" për argumentin col_delimiter :
=TEXTSPLIT(TEXT(A2, "m/d/yyyy"), "/") 
Ndajini qelizat dhe hiqni disa karaktere
Imagjinoni këtë: ju keni ndarë një varg të gjatë në copa, por grupi që rezulton ende përmban disa karaktere të padëshiruara, të tilla si kllapat në pamjen e mëposhtme të ekranit:
=TEXTSPLIT(A2, " ", "; ") 
Për të hequr largoni kllapat hapëse dhe mbyllëse në të njëjtën kohë, vendosni dy funksione SUBSTITUTE njëri në tjetrin (secili duke zëvendësuar një kllapa me një varg bosh) dhe përdorni formulën TEXTSPLIT për argumentin text të SUBSTITUTE të brendshëm:
=SUBSTITUTE(SUBSTITUTE(TEXTSPLIT(A2, " ", "; "), "(", ""), ")", "") 
Këshillë. Nëse grupi përfundimtar përmban shumë karaktere shtesë, mund t'i pastroni duke përdorur një nga metodat e përshkruara në këtë artikull: Si të hiqni karakteret e padëshiruara në Excel.
Ndani vargjet duke kapërcyer vlera të caktuara
Si të supozojmë se dëshironi të ndani vargjet e mëposhtme në 4 kolona: Emri , Mbiemri , Rezultati , dhe Rezultati . Problemi është se disa vargje përmbajnë titullin "Mr." ose "Ms.", për shkak të së cilës rezultatet janë të gjitha të gabuara: 
Zgjidhja nuk është e dukshme, por mjaft e thjeshtë :)
Përveç kufijve ekzistues, të cilët janë një hapësirë (" ") dhe një presje dhe një hapësirë (", "), ju përfshini vargjet "Mr." dhe "Ms." në konstantën e grupit col_delimiter , në mënyrë që funksioni të përdorë vetë titujt për të ndarë teksti. Për të injoruar vlerat boshe, ju vendosni argumentin ignore_empty në TRUE.
=TEXTSPLIT(A2, {" ",", ","Mr. ","Ms. "}, ,TRUE)
Tani, rezultatet janë absolutisht perfekte! 
Alternativat TEXTSPLIT
Në versionet e Excel ku funksioni TEXTSPLIT nuk mbështetet, mund të ndani vargjet duke përdorur kombinime të ndryshme të funksionit SEARCH / FIND me LEFT, RIGHT dhe MID. Në veçanti:
- SEARCH pa ndjeshmëri ndaj shkronjave dhe shkronjave të vogla FIND përcakton pozicionin e ndarësit brenda një vargu dhe
- Funksionet LEFT, RIGHT dhe MID nxjerrin një nënvarg përpara , pas ose midis dy shembujve të delimiterit.
Në rastin tonë, për të ndarë vlerat e ndara me presje dhe një hapësirë , formulat shkojnë si më poshtë.
Për të nxjerrë emrin:
=LEFT(A2, SEARCH(",", A2, 1) -1)
Për të tërhequr rezultatin:
=MID(A2, SEARCH(",", A2) + 2, SEARCH(",", A2, SEARCH(",",A2)+1) - SEARCH(",", A2) - 2)
Për të marrërezultat:
=RIGHT(A2, LEN(A2) - SEARCH(",", A2, SEARCH(",", A2) + 1)-1)
Për shpjegimin e detajuar të logjikës së formulave, shihni Si të ndani vargjet sipas karakterit ose maskës.
Ju lutemi mbani parasysh se ndryshe nga grupi dinamik Funksioni TEXTSPLIT, këto formula ndjekin qasjen tradicionale një formulë-një qelizë. Ju futni formulën në qelizën e parë dhe më pas tërhiqni atë poshtë kolonës për ta kopjuar në qelizat e mëposhtme.
Pamja e ekranit më poshtë tregon rezultatet: 
Kështu mund të ndahen qelizat në Excel 365 duke përdorur TEXTSPLIT ose zgjidhje alternative në versionet e mëparshme. Ju falënderoj që lexoni dhe shpresoj t'ju shohim në blogun tonë javën tjetër!
Praktikoni librin e punës për shkarkim
Funksioni TEXTSPLIT për ndarjen e vargjeve – shembuj formulash (skedari .xlsx)
> 3>