이 자습서에서는 Excel에서 ISNA 함수를 사용하여 #N/A 오류를 처리하는 다양한 방법에 대해 알아봅니다.

Excel에서 요청한 내용을 찾을 수 없는 경우 #N/ 셀에 오류가 나타납니다. 이러한 오류를 가로채서 처리하려면 ISNA 기능을 사용할 수 있습니다. 그것의 실제 사용은 무엇입니까? 본질적으로 수식을 보다 사용자 친화적으로 만들고 워크시트를 보기 좋게 만드는 데 도움이 됩니다.

Excel의 ISNA 기능

Excel의 ISNA 기능은 셀을 확인하는 데 사용됩니다. 또는 #N/A 오류에 대한 수식. 결과는 논리값입니다. #N/A 오류가 감지되면 TRUE, 그렇지 않으면 FALSE입니다.

이 함수는 Excel 2000~2021 및 Excel 365의 모든 버전에서 사용할 수 있습니다.

ISNA 함수의 구문은 다음과 같이 간단합니다.

여기서 value 는 #N/A 오류를 확인하려는 셀 값 또는 수식입니다.

기본 형식으로 ISNA 수식을 만들려면 셀 참조를 유일한 인수로 제공합니다.

=ISNA(A2)

참조된 셀에 #N/A 오류가 있는 경우 당신은 TRUE를 얻을 것이다. 다른 오류, 값 또는 빈 셀의 경우 FALSE:

Excel에서 ISNA 사용 방법

ISNA 함수 사용 순수한 형태로는 실용적인 의미가 거의 없습니다. 더 자주, 특정 수식의 결과를 평가하기 위해 다른 함수와 함께 사용됩니다. 이를 위해 다른 공식을 ISNA:

아래 데이터 세트에서 두 개의 목록(열 A와 D)을 비교하고 두 목록에 모두 있는 이름과 목록에만 나타나는 이름을 식별한다고 가정합니다. 1.

A3의 이름을 D열의 각 이름과 비교하는 공식은 다음과 같습니다.

=MATCH(A3, $D$2:$D$9, 0)

조회 값이 발견되면 MATCH 함수는 해당 값을 반환합니다. 조회 배열의 상대 위치입니다. 그렇지 않으면 #N/A 오류가 발생합니다. MATCH의 결과를 테스트하기 위해 ISNA에 내포합니다.

=ISNA(MATCH(A3, $D$2:$D$9, 0))

이 공식은 B3으로 이동한 다음 B14를 통해 복사됩니다.

이제 명확하게 할 수 있습니다. 어떤 학생이 모든 시험을 통과했는지(D 열에 이름이 없음 > MATCH가 #N/A를 반환함> ISNA가 TRUE를 반환함) 적어도 하나의 시험에 불합격한 학생(D 열에 이름이 나타남> 오류 없음)을 확인합니다> ISNA는 FALSE를 반환함).

팁. Excel 365 및 Excel 2021에서는 보다 현대적인 XMATCH 함수를 사용할 수 있습니다. 대신 MATCH.

Excel의 IF ISNA 수식

ISNA 함수는 기본적으로 두 개의 부울 값만 반환할 수 있습니다. 사용자 지정 메시지를 표시하려면 IF 함수와 함께 사용하십시오.

=IF(ISNA(MATCH(A3,$D$2:$D$9,0)), "No failed tests", "Failed")

이제 결과가 훨씬 더 좋고 직관적으로 보입니다. 동의하십니까?

VLOOKUP을 통해 Excel에서 ISNA를 사용하는 방법

IF ISNA 조합은 데이터 집합에서 무언가를 검색하고 #N/A 오류를 반환하는 모든 함수와 함께 사용할 수 있는 범용 솔루션입니다. 조회 값이 없을 때.

VLOOKUP을 사용한 ISNA 함수의 구문은 다음과 같습니다.

인간의 언어로 번역하면 다음과 같습니다. VLOOKUP에서 #N/A 오류가 발생하면 맞춤 텍스트를 반환하고, 그렇지 않으면 VLOOKUP의 결과를 반환합니다.

샘플 표에서 다음을 원한다고 가정합니다. 학생들이 시험에 실패한 과목을 반환합니다. 모든 시험을 성공적으로 통과한 학생에게는 "시험 불합격 없음"이 표시됩니다.

과목을 조회하기 위해 다음과 같은 고전적인 VLOOKUP 공식을 구성합니다.

=VLOOKUP(A3, $D$3:$E$9, 2, FALSE)

그런 다음 위에서 설명한 일반 IF ISNA 공식에 중첩합니다.

82 32

Excel 2013 이상 버전에서는 IFNA 기능을 활용하여 #N/A 오류를 포착하고 처리할 수 있습니다. 이렇게 하면 공식이 더 짧고 읽기 쉬워집니다.

예를 들어 #N/A 오류를 대시("-")로 대체하면 다음과 같은 우아한 솔루션을 얻을 수 있습니다.

=IFNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "-")

Excel 365 및 2021 사용자는 VLOOKUP의 최신 후속 제품으로 래퍼 기능이 전혀 필요하지 않습니다.XLOOKUP 함수는 기본적으로 #N/A 오류를 처리할 수 있습니다.

=XLOOKUP(A3, $D$3:$D$9, $E$3:$E$9, "-")

결과는 위의 스크린샷에 표시된 것과 정확히 동일합니다.

SUMPRODUCT ISNA 계산 공식 #N/A 오류

특정 범위의 #N/A 오류를 계산하려면 다음과 같이 SUMPRODUCT와 함께 ISNA 함수를 사용하십시오.

여기서 ISNA는 TRUE 및 FALSE 값의 배열을 반환하고 이중 부정(--)은 논리 값을 1과 0으로 강제 변환하고 SUMPRODUCT는 결과를 더합니다.

예를 들어, 모든 테스트에서 얼마나 많은 학생이 성공했는지 확인하고 조회 값 범위(A3:A14)에 대한 MATCH 공식을 수정하여 ISNA에 내포합니다.

=SUMPRODUCT(--ISNA(MATCH(A3:A14, D2:D9, 0)))

공식은 9명의 학생이 실패한 테스트가 없습니다. 즉, MATCH 함수는 9개의 #N/A 오류를 반환합니다.

Excel에서 ISNA 수식을 만들고 사용하는 방법입니다. 읽어 주셔서 감사합니다. 다음 주 블로그에서 뵙기를 기대합니다!

사용 가능한 다운로드

ISNA 수식 예제(.xlsx 파일)